configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.61)
  25 AC_INIT(emacs, 23.0.60)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" != no; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([freetype],[don't use Freetype for local font support])
 137 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 138 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 139 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 140
 141 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 142 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 143 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 144 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 145
 146 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 147 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 148
 149 ## For the times when you want to build Emacs but don't have
 150 ## a suitable makeinfo, and can live without the manuals.
 151 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 152 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 153
 154 dnl Can remove these in Emacs 24.
 155 AC_ARG_WITH([gtk],,
 156   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 157 specify a toolkit.])],,)
 158
 159 AC_ARG_WITH([gcc],,
 160   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 161 variable to specify a compiler.])],,)
 162
 163 AC_ARG_WITH([pkg-config-prog],dnl
 164 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 165                   [path to pkg-config for finding GTK and librsvg])])
 166 if test "X${with_pkg_config_prog}" != X; then
 167    if test "${with_pkg_config_prog}" != yes; then
 168       PKG_CONFIG="${with_pkg_config_prog}"
 169    fi
 170 fi
 171
 172 AC_ARG_WITH([gnustep-conf],dnl
 173 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 174 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 175   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 176 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 177      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 178
 179 AC_ARG_ENABLE(cocoa-experimental-ctrl-g,
 180 [AS_HELP_STRING([--enable-cocoa-experimental-ctrl-g],
 181                 [enable experimental improved ctrl-g recognition])],
 182    EN_COCOA_EXPERIMENTAL_CTRL_G=$enableval,
 183    EN_COCOA_EXPERIMENTAL_CTRL_G=no)
 184
 185 AC_ARG_ENABLE(ns-self-contained,
 186 [AS_HELP_STRING([--disable-ns-self-contained],
 187                 [disable self contained build under NeXTstep])],
 188    EN_NS_SELF_CONTAINED=$enableval,
 189    EN_NS_SELF_CONTAINED=yes)
 190
 191 AC_ARG_ENABLE(asserts,
 192 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 193       USE_XASSERTS=$enableval,
 194       USE_XASSERTS=no)
 195
 196 AC_ARG_ENABLE(maintainer-mode,
 197 [AS_HELP_STRING([--enable-maintainer-mode],
 198                 [enable make rules and dependencies not useful (and sometimes
 199                  confusing) to the casual installer])],
 200       USE_MAINTAINER_MODE=$enableval,
 201       USE_MAINTAINER_MODE=no)
 202 if test $USE_MAINTAINER_MODE = yes; then
 203   MAINT=
 204 else
 205   MAINT=#
 206 fi
 207 AC_SUBST(MAINT)
 208
 209 AC_ARG_ENABLE(locallisppath,
 210 [AS_HELP_STRING([--enable-locallisppath=PATH],
 211                 [directories Emacs should search for lisp files specific
 212                  to this site])],
 213 if test "${enableval}" = "no"; then
 214   locallisppath=
 215 elif test "${enableval}" != "yes"; then
 216   locallisppath=${enableval}
 217 fi)
 218
 219 #### Make srcdir absolute, if it isn't already.  It's important to
 220 #### avoid running the path through pwd unnecessarily, since pwd can
 221 #### give you automounter prefixes, which can go away.  We do all this
 222 #### so Emacs can find its files when run uninstalled.
 223 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 224 unset CDPATH
 225 case "${srcdir}" in
 226   /* ) ;;
 227   . )
 228     ## We may be able to use the $PWD environment variable to make this
 229     ## absolute.  But sometimes PWD is inaccurate.
 230     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 231     ## but that tested only for a well-formed and valid PWD,
 232     ## it did not object when PWD was well-formed and valid but just wrong.
 233     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 234     then
 235       srcdir="$PWD"
 236     else
 237       srcdir="`(cd ${srcdir}; pwd)`"
 238     fi
 239   ;;
 240   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 241 esac
 242
 243 #### Check if the source directory already has a configured system in it.
 244 if test `pwd` != `(cd ${srcdir} && pwd)` \
 245    && test -f "${srcdir}/src/config.h" ; then
 246   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 247    as a build directory right now; it has been configured in its own
 248    right.  To configure in another directory as well, you MUST
 249    use GNU make.  If you do not have GNU make, then you must
 250    now do `make distclean' in ${srcdir},
 251    and then run $0 again.]])
 252 fi
 253
 254 #### Given the configuration name, set machfile and opsysfile to the
 255 #### names of the m/*.h and s/*.h files we should use.
 256
 257 ### Canonicalize the configuration name.
 258
 259 AC_CANONICAL_HOST
 260 canonical=$host
 261 configuration=${host_alias-${build_alias-$host}}
 262
 263 dnl This used to use changequote, but, apart from `changequote is evil'
 264 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 265 dnl the great gob of text.  Thus it's not processed for possible expansion.
 266 dnl Just make sure the brackets remain balanced.
 267 dnl
 268 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 269 dnl indicated by comments.
 270 dnl quotation begins
 271 [
 272
 273 ### If you add support for a new configuration, add code to this
 274 ### switch statement to recognize your configuration name and select
 275 ### the appropriate operating system and machine description files.
 276
 277 ### You would hope that you could choose an m/*.h file pretty much
 278 ### based on the machine portion of the configuration name, and an s-
 279 ### file based on the operating system portion.  However, it turns out
 280 ### that each m/*.h file is pretty manufacturer-specific - for
 281 ### example mips.h is MIPS
 282 ### So we basically have to have a special case for each
 283 ### configuration name.
 284 ###
 285 ### As far as handling version numbers on operating systems is
 286 ### concerned, make sure things will fail in a fixable way.  If
 287 ### /etc/MACHINES doesn't say anything about version numbers, be
 288 ### prepared to handle anything reasonably.  If version numbers
 289 ### matter, be sure /etc/MACHINES says something about it.
 290 ###
 291 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 292 ### "System V Release 4"; he writes, "The old convention encouraged
 293 ### confusion between `system' and `release' levels'."
 294
 295 machine='' opsys='' unported=no
 296 case "${canonical}" in
 297
 298   ## FreeBSD ports
 299   *-*-freebsd* )
 300     opsys=freebsd
 301     case "${canonical}" in
 302       alpha*-*-freebsd*)        machine=alpha ;;
 303       arm*-*-freebsd*)          machine=arm ;;
 304       ia64-*-freebsd*)          machine=ia64 ;;
 305       sparc-*-freebsd*)         machine=sparc ;;
 306       sparc64-*-freebsd*)       machine=sparc ;;
 307       powerpc-*-freebsd*)       machine=macppc ;;
 308       i[3456]86-*-freebsd*)     machine=intel386 ;;
 309       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 310     esac
 311   ;;
 312
 313   ## FreeBSD kernel + glibc based userland
 314   *-*-kfreebsd*gnu* )
 315     opsys=gnu-kfreebsd
 316     case "${canonical}" in
 317       alpha*-*-kfreebsd*)       machine=alpha ;;
 318       ia64-*-kfreebsd*)         machine=ia64 ;;
 319       sparc-*-kfreebsd*)        machine=sparc ;;
 320       sparc64-*-kfreebsd*)      machine=sparc ;;
 321       powerpc-*-kfreebsd*)      machine=macppc ;;
 322       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 323       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 324     esac
 325   ;;
 326
 327   ## NetBSD ports
 328   *-*-netbsd* )
 329     opsys=netbsd
 330     if test -f /usr/lib/crti.o; then]
 331 dnl The close and open brackets here are because this section is quoted --
 332 dnl see the `changequote' comment above.
 333       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 334 [   fi
 335
 336     case "${canonical}" in
 337       alpha*-*-netbsd*) machine=alpha ;;
 338       i[3456]86-*-netbsd*) machine=intel386 ;;
 339       powerpc-*-netbsd*) machine=macppc ;;
 340       sparc*-*-netbsd*) machine=sparc ;;
 341       vax-*-netbsd*)    machine=vax ;;
 342       arm-*-netbsd*)    machine=arm ;;
 343       x86_64-*-netbsd*) machine=amdx86-64 ;;
 344       hppa-*-netbsd*)   machine=hp800 ;;
 345     esac
 346   ;;
 347
 348   ## OpenBSD ports
 349   *-*-openbsd* )
 350     opsys=openbsd
 351     case "${canonical}" in
 352       alpha*-*-openbsd*)        machine=alpha ;;
 353       arm-*-openbsd*)          machine=arm ;;
 354       i386-*-openbsd*)         machine=intel386 ;;
 355       powerpc-*-openbsd*)      machine=macppc ;;
 356       sparc*-*-openbsd*)       machine=sparc ;;
 357       vax-*-openbsd*)          machine=vax ;;
 358       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 359       hppa-*-openbsd*)         machine=hp800 ;;
 360     esac
 361   ;;
 362
 363   ## LynxOS ports
 364   *-*-lynxos* )
 365     opsys=lynxos
 366     case "${canonical}" in
 367       i[3456]86-*-lynxos*) machine=intel386 ;;
 368       powerpc-*-lynxos*) machine=powerpc ;;
 369     esac
 370   ;;
 371
 372   alpha*-*-linux-gnu* )
 373     machine=alpha opsys=gnu-linux
 374   ;;
 375
 376   arm*-*-linux-gnu* )
 377     machine=arm opsys=gnu-linux
 378   ;;
 379
 380   ## Apple Darwin / Mac OS X
 381   *-apple-darwin* )
 382     case "${canonical}" in
 383       i[3456]86-* )  machine=intel386 ;;
 384       powerpc-* )    machine=macppc ;;
 385       * )            unported=yes ;;
 386     esac
 387     opsys=darwin
 388     # Define CPP as follows to make autoconf work correctly.
 389     CPP="${CC-cc} -E -no-cpp-precomp"
 390     # Use fink packages if available.
 391     if test -d /sw/include && test -d /sw/lib; then
 392       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 393       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 394       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 395     fi
 396   ;;
 397
 398   ## HP 9000 series 700 and 800, running HP/UX
 399   hppa*-hp-hpux10.2* )
 400     machine=hp800 opsys=hpux10-20
 401   ;;
 402   hppa*-hp-hpux1[1-9]* )
 403     machine=hp800 opsys=hpux11
 404     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 405   ;;
 406
 407   hppa*-*-linux-gnu* )
 408     machine=hp800 opsys=gnu-linux
 409   ;;
 410
 411   ## IBM machines
 412   s390-*-linux-gnu* )
 413     machine=ibms390 opsys=gnu-linux
 414   ;;
 415   s390x-*-linux-gnu* )
 416     machine=ibms390x opsys=gnu-linux
 417   ;;
 418   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 419     machine=ibmrs6000 opsys=aix4-2
 420   ;;
 421   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 422     machine=ibmrs6000 opsys=aix4-2
 423   ;;
 424   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 425     machine=ibmrs6000 opsys=aix4-2
 426   ;;
 427   rs6000-ibm-aix5* | powerpc-ibm-aix6*  )
 428     machine=ibmrs6000 opsys=aix4-2
 429   ;;
 430
 431   ## Macintosh PowerPC
 432   powerpc*-*-linux-gnu* )
 433     machine=macppc opsys=gnu-linux
 434   ;;
 435
 436   ## Silicon Graphics machines
 437   ## Iris 4D
 438   mips-sgi-irix6.5 )
 439     machine=iris4d opsys=irix6-5
 440     # Without defining _LANGUAGE_C, things get masked out in the headers
 441     # so that, for instance, grepping for `free' in stdlib.h fails and
 442     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 443     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 444     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 445   ;;
 446
 447   ## Suns
 448   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 449     machine=sparc opsys=gnu-linux
 450   ;;
 451
 452   *-sun-solaris* \
 453     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 454     | rs6000-*-solaris2*)
 455     case "${canonical}" in
 456       i[3456]86-*-* )     machine=intel386 ;;
 457       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 458       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 459       sparc* )          machine=sparc ;;
 460       * )               unported=yes ;;
 461     esac
 462     case "${canonical}" in
 463       *-sunos5.3* | *-solaris2.3* )
 464                 opsys=sol2-3
 465                 NON_GNU_CPP=/usr/ccs/lib/cpp
 466                 ;;
 467       *-sunos5.4* | *-solaris2.4* )
 468                 opsys=sol2-4
 469                 NON_GNU_CPP=/usr/ccs/lib/cpp
 470                 RANLIB="ar -ts"
 471                 ;;
 472       *-sunos5.5* | *-solaris2.5* )
 473                 opsys=sol2-5
 474                 NON_GNU_CPP=/usr/ccs/lib/cpp
 475                 RANLIB="ar -ts"
 476                 ;;
 477       *-sunos5.6* | *-solaris2.6* )
 478                 opsys=sol2-6
 479                 NON_GNU_CPP=/usr/ccs/lib/cpp
 480                 RANLIB="ar -ts"
 481                 ;;
 482       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 483                 opsys=sol2-6
 484                 emacs_check_sunpro_c=yes
 485                 NON_GNU_CPP=/usr/ccs/lib/cpp
 486                 ;;
 487       *-sunos5* | *-solaris* )
 488                 opsys=sol2-10
 489                 emacs_check_sunpro_c=yes
 490                 NON_GNU_CPP=/usr/ccs/lib/cpp
 491                 ;;
 492     esac
 493     ## Watch out for a compiler that we know will not work.
 494     case "${canonical}" in
 495      *-solaris* | *-sunos5* )
 496                 if [ "x$CC" = x/usr/ucb/cc ]; then
 497                   ## /usr/ucb/cc doesn't work;
 498                   ## we should find some other compiler that does work.
 499                   unset CC
 500                 fi
 501                 ;;
 502       *) ;;
 503     esac
 504   ;;
 505
 506   ## Vaxen.
 507   vax-dec-* )
 508     machine=vax
 509     case "${canonical}" in
 510       *-vms* )                                          opsys=vms ;;
 511       * )                                               unported=yes
 512     esac
 513   ;;
 514
 515   ## IA-64
 516   ia64*-*-linux* )
 517     machine=ia64 opsys=gnu-linux
 518   ;;
 519
 520   ## Intel 386 machines where we don't care about the manufacturer
 521   i[3456]86-*-* )
 522     machine=intel386
 523     case "${canonical}" in
 524       *-cygwin )                opsys=cygwin ;;
 525       *-darwin* )               opsys=darwin
 526                                 CPP="${CC-cc} -E -no-cpp-precomp"
 527                                 ;;
 528       *-linux-gnu* )            opsys=gnu-linux ;;
 529       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 530       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 531       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 532       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 533     esac
 534   ;;
 535
 536   ## m68k Linux-based GNU system
 537   m68k-*-linux-gnu* )
 538     machine=m68k opsys=gnu-linux
 539   ;;
 540
 541   ## Mips Linux-based GNU system
 542   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 543     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 544     machine=mips opsys=gnu-linux
 545   ;;
 546
 547   ## AMD x86-64 Linux-based GNU system
 548   x86_64-*-linux-gnu* )
 549     machine=amdx86-64 opsys=gnu-linux
 550   ;;
 551
 552   ## Tensilica Xtensa Linux-based GNU system
 553   xtensa*-*-linux-gnu* )
 554     machine=xtensa opsys=gnu-linux
 555     ;;
 556
 557   ## SuperH Linux-based GNU system
 558   sh[34]*-*-linux-gnu* )
 559     machine=sh3 opsys=gnu-linux
 560   ;;
 561
 562   * )
 563     unported=yes
 564   ;;
 565 esac
 566
 567 ### If the code above didn't choose an operating system, just choose
 568 ### an operating system based on the configuration name.  You really
 569 ### only want to use this when you have no idea what the right
 570 ### operating system is; if you know what operating systems a machine
 571 ### runs, it's cleaner to make it explicit in the case statement
 572 ### above.
 573 if test x"${opsys}" = x; then
 574   case "${canonical}" in
 575     *-gnu* )                            opsys=gnu ;;
 576     *-sysv4.2uw* )                      opsys=unixware ;;
 577     *-sysv5uw* )                        opsys=unixware ;;
 578     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 579     *-sysv4.1* | *-sysvr4.1* )
 580         NON_GNU_CPP=/usr/lib/cpp
 581         opsys=usg5-4 ;;
 582     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 583         if [ x$NON_GNU_CPP = x ]; then
 584           if [ -f /usr/ccs/lib/cpp ]; then
 585             NON_GNU_CPP=/usr/ccs/lib/cpp
 586           else
 587             NON_GNU_CPP=/lib/cpp
 588           fi
 589         fi
 590         opsys=usg5-4-2 ;;
 591     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 592     * )
 593       unported=yes
 594     ;;
 595   esac
 596 fi
 597
 598 ]
 599 dnl quotation ends
 600
 601 if test $unported = yes; then
 602   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 603 Check `etc/MACHINES' for recognized configuration names.])
 604 fi
 605
 606 machfile="m/${machine}.h"
 607 opsysfile="s/${opsys}.h"
 608
 609
 610 #### Choose a compiler.
 611 test -n "$CC" && cc_specified=yes
 612
 613 # Save the value of CFLAGS that the user specified.
 614 SPECIFIED_CFLAGS="$CFLAGS"
 615
 616 dnl Sets GCC=yes if using gcc.
 617 AC_PROG_CC
 618
 619 # On Suns, sometimes $CPP names a directory.
 620 if test -n "$CPP" && test -d "$CPP"; then
 621   CPP=
 622 fi
 623
 624 ## If not using gcc, and on Solaris, and no CPP specified, see if
 625 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 626 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 627  test x"$CPP" = x; then
 628   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 629   AC_CACHE_VAL(emacs_cv_sunpro_c,
 630   [AC_TRY_LINK([],
 631 [#ifndef __SUNPRO_C
 632 fail;
 633 #endif
 634 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 635   AC_MSG_RESULT($emacs_cv_sunpro_c)
 636
 637   if test x"$emacs_cv_sunpro_c" = xyes; then
 638     NON_GNU_CPP="$CC -E -Xs"
 639   fi
 640 fi
 641
 642 #### Some systems specify a CPP to use unless we are using GCC.
 643 #### Now that we know whether we are using GCC, we can decide whether
 644 #### to use that one.
 645 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 646 then
 647   CPP="$NON_GNU_CPP"
 648 fi
 649
 650 #### Some systems specify a CC to use unless we are using GCC.
 651 #### Now that we know whether we are using GCC, we can decide whether
 652 #### to use that one.
 653 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 654   test x$cc_specified != xyes
 655 then
 656   CC="$NON_GNU_CC"
 657 fi
 658
 659 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 660 then
 661   CC="$CC $GCC_TEST_OPTIONS"
 662 fi
 663
 664 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 665 then
 666   CC="$CC $NON_GCC_TEST_OPTIONS"
 667 fi
 668
 669 dnl checks for Unix variants
 670 AC_USE_SYSTEM_EXTENSIONS
 671
 672 ### Use -Wno-pointer-sign if the compiler supports it
 673 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 674 SAVE_CFLAGS="$CFLAGS"
 675 CFLAGS="$CFLAGS -Wno-pointer-sign"
 676 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 677 if test $has_option = yes; then
 678    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 679 fi
 680 AC_MSG_RESULT($has_option)
 681 CFLAGS="$SAVE_CFLAGS"
 682 unset has_option
 683 unset SAVE_CFLAGS
 684
 685 #### Some other nice autoconf tests.
 686
 687 dnl checks for programs
 688 AC_PROG_LN_S
 689 AC_PROG_CPP
 690 AC_PROG_INSTALL
 691 if test "x$RANLIB" = x; then
 692   AC_PROG_RANLIB
 693 fi
 694 AC_PATH_PROG(INSTALL_INFO, install-info)
 695 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 696 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 697 dnl Don't use GZIP, which is used by gzip for additional parameters.
 698 AC_PATH_PROG(GZIP_PROG, gzip)
 699
 700
 701 ## Need makeinfo >= 4.6 (?) to build the manuals.
 702 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 703 dnl By this stage, configure has already checked for egrep and set EGREP,
 704 dnl or exited with an error if no egrep was found.
 705 if test "$MAKEINFO" != "no" && \
 706   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 707    MAKEINFO=no
 708 fi
 709
 710 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 711 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 712 ## therefore in the category of "special tools" not normally required, which
 713 ## configure does not have to check for (eg autoconf itself).
 714 ## In a CVS checkout on the other hand, the manuals are not included.
 715 ## So makeinfo is a requirement to build from CVS, and configure
 716 ## should test for it as it does for any other build requirement.
 717 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 718 ## with pre-built manuals, from a CVS checkout.
 719 if test "$MAKEINFO" = "no"; then
 720   if test "x${with_makeinfo}" = "xno"; then
 721     MAKEINFO=off
 722   elif ! test -e $srcdir/info/emacs; then
 723     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 724 source tree does not seem to have pre-built manuals in the `info' directory.
 725 Either install a suitable version of makeinfo, or re-run configure
 726 with the `--without-makeinfo' option to build without the manuals.] )
 727   fi
 728 fi
 729
 730 dnl Add our options to ac_link now, after it is set up.
 731
 732 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 733 then
 734   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 735 fi
 736
 737 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 738 then
 739   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 740 fi
 741
 742 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 743 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 744 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 745 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 746 dnl if not built to support GNU ld.
 747
 748 late_LDFLAGS=$LDFLAGS
 749 if test "$GCC" = yes; then
 750   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 751 else
 752   LDFLAGS="$LDFLAGS -znocombreloc"
 753 fi
 754
 755 AC_MSG_CHECKING([for -znocombreloc])
 756 AC_LINK_IFELSE([main(){return 0;}],
 757   [AC_MSG_RESULT(yes)],
 758   LDFLAGS=$late_LDFLAGS
 759   [AC_MSG_RESULT(no)])
 760
 761 #### Extract some information from the operating system and machine files.
 762
 763 AC_CHECKING([the machine- and system-dependent files to find out
 764  - which libraries the lib-src programs will want, and
 765  - whether the GNU malloc routines are usable])
 766
 767 ### First figure out CFLAGS (which we use for running the compiler here)
 768 ### and REAL_CFLAGS (which we use for real compilation).
 769 ### The two are the same except on a few systems, where they are made
 770 ### different to work around various lossages.  For example,
 771 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 772 ### as implying static linking.
 773
 774 ### If the CFLAGS env var is specified, we use that value
 775 ### instead of the default.
 776
 777 ### It's not important that this name contain the PID; you can't run
 778 ### two configures in the same directory and have anything work
 779 ### anyway.
 780 tempcname="conftest.c"
 781
 782 echo '
 783 #include "'${srcdir}'/src/'${opsysfile}'"
 784 #include "'${srcdir}'/src/'${machfile}'"
 785 #ifndef LIBS_MACHINE
 786 #define LIBS_MACHINE
 787 #endif
 788 #ifndef LIBS_SYSTEM
 789 #define LIBS_SYSTEM
 790 #endif
 791 #ifndef C_SWITCH_SYSTEM
 792 #define C_SWITCH_SYSTEM
 793 #endif
 794 #ifndef C_SWITCH_MACHINE
 795 #define C_SWITCH_MACHINE
 796 #endif
 797 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 798 configure___ c_switch_system=C_SWITCH_SYSTEM
 799 configure___ c_switch_machine=C_SWITCH_MACHINE
 800
 801 #ifndef LIB_X11_LIB
 802 #define LIB_X11_LIB -lX11
 803 #endif
 804
 805 #ifndef LIBX11_SYSTEM
 806 #define LIBX11_SYSTEM
 807 #endif
 808 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 809
 810 #ifdef UNEXEC
 811 configure___ unexec=UNEXEC
 812 #else
 813 configure___ unexec=unexec.o
 814 #endif
 815
 816 #ifdef SYSTEM_MALLOC
 817 configure___ system_malloc=yes
 818 #else
 819 configure___ system_malloc=no
 820 #endif
 821
 822 #ifdef USE_MMAP_FOR_BUFFERS
 823 configure___ use_mmap_for_buffers=yes
 824 #else
 825 configure___ use_mmap_for_buffers=no
 826 #endif
 827
 828 #ifndef C_DEBUG_SWITCH
 829 #define C_DEBUG_SWITCH -g
 830 #endif
 831
 832 #ifndef C_OPTIMIZE_SWITCH
 833 #ifdef __GNUC__
 834 #define C_OPTIMIZE_SWITCH -O2
 835 #else
 836 #define C_OPTIMIZE_SWITCH -O
 837 #endif
 838 #endif
 839
 840 #ifndef C_WARNINGS_SWITCH
 841 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 842 #endif
 843
 844 #ifndef LD_SWITCH_MACHINE
 845 #define LD_SWITCH_MACHINE
 846 #endif
 847
 848 #ifndef LD_SWITCH_SYSTEM
 849 #define LD_SWITCH_SYSTEM
 850 #endif
 851
 852 #ifndef LD_SWITCH_X_SITE_AUX
 853 #define LD_SWITCH_X_SITE_AUX
 854 #endif
 855
 856 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 857 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 858
 859 #ifdef THIS_IS_CONFIGURE
 860
 861 /* Get the CFLAGS for tests in configure.  */
 862 #ifdef __GNUC__
 863 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 864 #else
 865 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 866 #endif
 867
 868 #else /* not THIS_IS_CONFIGURE */
 869
 870 /* Get the CFLAGS for real compilation.  */
 871 #ifdef __GNUC__
 872 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
 873 #else
 874 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 875 #endif
 876
 877 #endif /* not THIS_IS_CONFIGURE */
 878 ' > ${tempcname}
 879
 880 # The value of CPP is a quoted variable reference, so we need to do this
 881 # to get its actual value...
 882 CPP=`eval "echo $CPP"`
 883 [eval `${CPP} -Isrc ${tempcname} \
 884        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 885 if test "x$SPECIFIED_CFLAGS" = x; then
 886   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 887          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 888 else
 889   REAL_CFLAGS="$CFLAGS"
 890 fi]
 891 rm ${tempcname}
 892
 893 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 894
 895 ### Make sure subsequent tests use flags consistent with the build flags.
 896
 897 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 898   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 899 else
 900   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 901 fi
 902
 903 dnl For AC_FUNC_GETLOADAVG, at least:
 904 AC_CONFIG_LIBOBJ_DIR(src)
 905
 906 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 907 AC_SYS_LARGEFILE
 908
 909
 910 ### The standard library on x86-64 and s390x GNU/Linux distributions can
 911 ### be located in either /usr/lib64 or /usr/lib.
 912 ### In some rare cases, /usr/lib64 exists but does not contain the
 913 ### relevant files (bug#1287).  Hence test for crtn.o.
 914 case "${canonical}" in
 915   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 916     if test -e /usr/lib64/crtn.o; then
 917       AC_DEFINE(HAVE_LIB64_DIR, 1,
 918         [Define to 1 if the directory /usr/lib64 exists.])
 919 fi
 920 esac
 921
 922 dnl This function defintion taken from Gnome 2.0
 923 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
 924 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
 925 dnl also defines GSTUFF_PKG_ERRORS on error
 926 AC_DEFUN([PKG_CHECK_MODULES], [
 927   succeeded=no
 928
 929   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 930
 931   if test "$PKG_CONFIG" = "no" ; then
 932      ifelse([$4], , [AC_MSG_ERROR([
 933       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
 934   else
 935      PKG_CONFIG_MIN_VERSION=0.9.0
 936      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
 937         AC_MSG_CHECKING(for $2)
 938
 939         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
 940             AC_MSG_RESULT(yes)
 941             succeeded=yes
 942
 943             AC_MSG_CHECKING($1_CFLAGS)
 944             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
 945             AC_MSG_RESULT($$1_CFLAGS)
 946
 947             AC_MSG_CHECKING($1_LIBS)
 948             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
 949             AC_MSG_RESULT($$1_LIBS)
 950         else
 951             AC_MSG_RESULT(no)
 952             $1_CFLAGS=""
 953             $1_LIBS=""
 954             ## If we have a custom action on failure, don't print errors, but
 955             ## do set a variable so people can do so.
 956             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
 957             ifelse([$4], ,echo $$1_PKG_ERRORS,)
 958         fi
 959
 960         AC_SUBST($1_CFLAGS)
 961         AC_SUBST($1_LIBS)
 962      else
 963         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
 964         echo "*** See http://www.freedesktop.org/software/pkgconfig"
 965      fi
 966   fi
 967
 968   if test $succeeded = yes; then
 969      ifelse([$3], , :, [$3])
 970   else
 971      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
 972   fi
 973 ])
 974
 975
 976 if test "${with_sound}" != "no"; then
 977   # Sound support for GNU/Linux and the free BSDs.
 978   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
 979   # Emulation library used on NetBSD.
 980   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
 981   AC_SUBST(LIBSOUND)
 982
 983   ALSA_REQUIRED=1.0.0
 984   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
 985   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
 986   if test $HAVE_ALSA = yes; then
 987     SAVE_CFLAGS="$CFLAGS"
 988     SAVE_LDFLAGS="$LDFLAGS"
 989     CFLAGS="$ALSA_CFLAGS $CFLAGS"
 990     LDFLAGS="$ALSA_LIBS $LDFLAGS"
 991     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
 992                     emacs_alsa_normal=yes,
 993                     emacs_alsa_normal=no)
 994     if test "$emacs_alsa_normal" != yes; then
 995       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
 996                      [snd_lib_error_set_handler (0);],
 997                      emacs_alsa_subdir=yes,
 998                      emacs_alsa_subdir=no)
 999       if test "$emacs_alsa_subdir" != yes; then
1000         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1001       fi
1002       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1003     fi
1004
1005     CFLAGS="$SAVE_CFLAGS"
1006     LDFLAGS="$SAVE_LDFLAGS"
1007     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1008     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1009     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1010   fi
1011   AC_SUBST(CFLAGS_SOUND)
1012 fi
1013
1014 dnl checks for header files
1015 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1016   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1017   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1018   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1019   sys/utsname.h pwd.h)
1020
1021 AC_MSG_CHECKING(if personality LINUX32 can be set)
1022 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1023                emacs_cv_personality_linux32=yes,
1024                emacs_cv_personality_linux32=no)
1025 AC_MSG_RESULT($emacs_cv_personality_linux32)
1026
1027 if test $emacs_cv_personality_linux32 = yes; then
1028   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1029             [Define to 1 if personality LINUX32 can be set.])
1030 fi
1031
1032 dnl On Solaris 8 there's a compilation warning for term.h because
1033 dnl it doesn't define `bool'.
1034 AC_CHECK_HEADERS(term.h, , , -)
1035 AC_HEADER_STDC
1036 AC_HEADER_TIME
1037 AC_CHECK_DECLS([sys_siglist])
1038 if test $ac_cv_have_decl_sys_siglist != yes; then
1039   # For Tru64, at least:
1040   AC_CHECK_DECLS([__sys_siglist])
1041   if test $ac_cv_have_decl___sys_siglist = yes; then
1042     AC_DEFINE(sys_siglist, __sys_siglist,
1043               [Define to any substitute for sys_siglist.])
1044   fi
1045 fi
1046 AC_HEADER_SYS_WAIT
1047
1048 dnl Some systems have utime.h but don't declare the struct anyplace.
1049 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1050 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1051 #include <sys/time.h>
1052 #include <time.h>
1053 #else
1054 #ifdef HAVE_SYS_TIME_H
1055 #include <sys/time.h>
1056 #else
1057 #include <time.h>
1058 #endif
1059 #endif
1060 #ifdef HAVE_UTIME_H
1061 #include <utime.h>
1062 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1063   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1064 if test $emacs_cv_struct_utimbuf = yes; then
1065   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1066 fi
1067
1068 dnl checks for typedefs
1069 AC_TYPE_SIGNAL
1070
1071 dnl Check for speed_t typedef.
1072 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1073   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1074     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1075 if test $emacs_cv_speed_t = yes; then
1076   AC_DEFINE(HAVE_SPEED_T, 1,
1077            [Define to 1 if `speed_t' is declared by <termios.h>.])
1078 fi
1079
1080 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1081 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1082 #include <sys/time.h>
1083 #include <time.h>
1084 #else
1085 #ifdef HAVE_SYS_TIME_H
1086 #include <sys/time.h>
1087 #else
1088 #include <time.h>
1089 #endif
1090 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1091   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1092 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1093 if test $emacs_cv_struct_timeval = yes; then
1094   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1095 fi
1096
1097 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1098 AC_TRY_COMPILE([#include <math.h>],
1099 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1100   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1101 HAVE_EXCEPTION=$emacs_cv_struct_exception
1102 if test $emacs_cv_struct_exception != yes; then
1103   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1104 fi
1105
1106 AC_CHECK_HEADERS(sys/socket.h)
1107 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1108 #if HAVE_SYS_SOCKET_H
1109 #include <sys/socket.h>
1110 #endif])
1111
1112 dnl checks for structure members
1113 AC_STRUCT_TM
1114 AC_STRUCT_TIMEZONE
1115 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1116                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1117                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1118                 [#include <time.h>])
1119 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1120                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1121                   struct ifreq.ifr_addr], , ,
1122                  [AC_INCLUDES_DEFAULT
1123 #if HAVE_SYS_SOCKET_H
1124 #include <sys/socket.h>
1125 #endif
1126 #if HAVE_NET_IF_H
1127 #include <net/if.h>
1128 #endif])
1129
1130 dnl checks for compiler characteristics
1131
1132 dnl Testing __STDC__ to determine prototype support isn't good enough.
1133 dnl DEC C, for instance, doesn't define it with default options, and
1134 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1135 dnl and void *.
1136 AC_C_PROTOTYPES
1137 AC_C_VOLATILE
1138 AC_C_CONST
1139 dnl This isn't useful because we can't turn on use of `inline' unless
1140 dnl the compiler groks `extern inline'.
1141 dnl AC_C_INLINE
1142 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1143   [AC_TRY_COMPILE(, [void * foo;],
1144                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1145 if test $emacs_cv_void_star = yes; then
1146   AC_DEFINE(POINTER_TYPE, void)
1147 else
1148   AC_DEFINE(POINTER_TYPE, char)
1149 fi
1150 AH_TEMPLATE(POINTER_TYPE,
1151             [Define as `void' if your compiler accepts `void *'; otherwise
1152              define as `char'.])dnl
1153
1154
1155
1156 dnl This could be used for targets which can have both byte sexes.
1157 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1158 dnl AC_C_BIGENDIAN
1159
1160 dnl check for Make feature
1161 AC_PROG_MAKE_SET
1162
1163 dnl checks for operating system services
1164 AC_SYS_LONG_FILE_NAMES
1165
1166 #### Choose a window system.
1167
1168 AC_PATH_X
1169 if test "$no_x" = yes; then
1170   window_system=none
1171 else
1172   window_system=x11
1173 fi
1174
1175 ## Workaround for bug in autoconf <= 2.62.
1176 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1177 ## No need to do anything special for these standard directories.
1178 ## This is an experiment, take it out if it causes problems.
1179 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1180
1181    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1182
1183 fi
1184
1185 if test "${x_libraries}" != NONE; then
1186   if test -n "${x_libraries}"; then
1187     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1188     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1189   fi
1190   x_default_search_path=""
1191   x_search_path=${x_libraries}
1192   if test -z "${x_search_path}"; then
1193     x_search_path=/usr/lib
1194   fi
1195   for x_library in `echo ${x_search_path}: | \
1196                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1197     x_search_path="\
1198 ${x_library}/X11/%L/%T/%N%C%S:\
1199 ${x_library}/X11/%l/%T/%N%C%S:\
1200 ${x_library}/X11/%T/%N%C%S:\
1201 ${x_library}/X11/%L/%T/%N%S:\
1202 ${x_library}/X11/%l/%T/%N%S:\
1203 ${x_library}/X11/%T/%N%S"
1204     if test x"${x_default_search_path}" = x; then
1205       x_default_search_path=${x_search_path}
1206     else
1207       x_default_search_path="${x_search_path}:${x_default_search_path}"
1208     fi
1209   done
1210 fi
1211 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1212   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1213 fi
1214
1215 if test x"${x_includes}" = x; then
1216   bitmapdir=/usr/include/X11/bitmaps
1217 else
1218   # accumulate include directories that have X11 bitmap subdirectories
1219   bmd_acc="dummyval"
1220   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1221     if test -d "${bmd}/X11/bitmaps"; then
1222       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1223     fi
1224     if test -d "${bmd}/bitmaps"; then
1225       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1226     fi
1227   done
1228   if test ${bmd_acc} != "dummyval"; then
1229     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1230   fi
1231 fi
1232
1233 HAVE_NS=no
1234 NS_IMPL_COCOA=no
1235 NS_IMPL_GNUSTEP=no
1236 tmp_CPPFLAGS="$CPPFLAGS"
1237 tmp_CFLAGS="$CFLAGS"
1238 CPPFLAGS="$CPPFLAGS -x objective-c"
1239 CFLAGS="$CFLAGS -x objective-c"
1240 if test "${with_ns}" != no; then
1241   if test "${opsys}" = darwin; then
1242      NS_IMPL_COCOA=yes
1243      ns_appdir=`pwd`/nextstep/Emacs.app
1244      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1245      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1246      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1247   elif test -f $GNUSTEP_CONFIG_FILE; then
1248      NS_IMPL_GNUSTEP=yes
1249      ns_appdir=`pwd`/nextstep/Emacs.app
1250      ns_appbindir=`pwd`/nextstep/Emacs.app
1251      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1252      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1253      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1254      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1255      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1256      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1257      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1258      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1259      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1260      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1261   fi
1262   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1263                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1264   files are missing or cannot be compiled.])])
1265   NS_HAVE_NSINTEGER=yes
1266   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1267                                      [NSInteger i;])],
1268                     ns_have_nsinteger=yes,
1269                     ns_have_nsinteger=no)
1270   if test $ns_have_nsinteger = no; then
1271     NS_HAVE_NSINTEGER=no
1272   fi
1273 fi
1274 if test "${HAVE_NS}" = yes; then
1275   window_system=nextstep
1276   with_xft=no
1277   with_freetype=no
1278   # set up packaging dirs
1279   exec_prefix=${ns_appbindir}
1280   libexecdir=${ns_appbindir}/libexec
1281   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1282      prefix=${ns_appresdir}
1283   fi
1284 fi
1285 CFLAGS="$tmp_CFLAGS"
1286 CPPFLAGS="$tmp_CPPFLAGS"
1287
1288 case "${window_system}" in
1289   x11 )
1290     HAVE_X_WINDOWS=yes
1291     HAVE_X11=yes
1292     case "${with_x_toolkit}" in
1293       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1294       motif ) USE_X_TOOLKIT=MOTIF ;;
1295       gtk ) with_gtk=yes
1296 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1297 dnl USE_X_TOOLKIT is set.
1298             USE_X_TOOLKIT=none ;;
1299       no ) USE_X_TOOLKIT=none ;;
1300 dnl If user did not say whether to use a toolkit, make this decision later:
1301 dnl use the toolkit if we have gtk, or X11R5 or newer.
1302       * ) USE_X_TOOLKIT=maybe ;;
1303     esac
1304   ;;
1305   nextstep | none )
1306     HAVE_X_WINDOWS=no
1307     HAVE_X11=no
1308     USE_X_TOOLKIT=none
1309   ;;
1310 esac
1311
1312 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1313    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1314    if test "$HAVE_XSERVER" = true ||
1315       test -n "$DISPLAY" ||
1316       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1317         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1318 were found.  You should install the relevant development files for X
1319 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1320 sure you have development files for image handling, i.e.
1321 tiff, gif, jpeg, png and xpm.
1322 If you are sure you want Emacs compiled without X window support, pass
1323   --without-x
1324 to configure.])
1325    fi
1326 fi
1327
1328 ### If we're using X11, we should use the X menu package.
1329 HAVE_MENUS=no
1330 case ${HAVE_X11} in
1331   yes ) HAVE_MENUS=yes ;;
1332 esac
1333
1334 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1335 # Assume not, until told otherwise.
1336 GNU_MALLOC=yes
1337 doug_lea_malloc=yes
1338 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1339 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1340 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1341                emacs_cv_var___after_morecore_hook,
1342 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1343   emacs_cv_var___after_morecore_hook=yes,
1344   emacs_cv_var___after_morecore_hook=no)])
1345 if test $emacs_cv_var___after_morecore_hook = no; then
1346   doug_lea_malloc=no
1347 fi
1348 if test "${system_malloc}" = "yes"; then
1349   GNU_MALLOC=no
1350   GNU_MALLOC_reason="
1351     (The GNU allocators don't work with this system configuration.)"
1352 fi
1353 if test "$doug_lea_malloc" = "yes" ; then
1354   if test "$GNU_MALLOC" = yes ; then
1355     GNU_MALLOC_reason="
1356       (Using Doug Lea's new malloc from the GNU C Library.)"
1357   fi
1358   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1359             [Define to 1 if you are using the GNU C Library.])
1360 fi
1361
1362 if test x"${REL_ALLOC}" = x; then
1363   REL_ALLOC=${GNU_MALLOC}
1364 fi
1365
1366 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1367 dnl the system configuration file (s/*.h) to turn the use of mmap
1368 dnl in the relocating allocator on.
1369
1370 AC_FUNC_MMAP
1371 if test $use_mmap_for_buffers = yes; then
1372   REL_ALLOC=no
1373 fi
1374
1375 LIBS="$libsrc_libs $LIBS"
1376
1377 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1378 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1379 AC_CHECK_LIB(dnet, dnet_ntoa)
1380 dnl This causes -lresolv to get used in subsequent tests,
1381 dnl which causes failures on some systems such as HPUX 9.
1382 dnl AC_CHECK_LIB(resolv, gethostbyname)
1383
1384 dnl FIXME replace main with a function we actually want from this library.
1385 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1386
1387 AC_CHECK_LIB(pthreads, cma_open)
1388
1389 dnl Check for need for bigtoc support on IBM AIX
1390
1391 case ${host_os} in
1392 aix*)
1393   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1394     case $GCC in
1395     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1396     *) gdb_cv_bigtoc=-bbigtoc ;;
1397     esac
1398
1399     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1400     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1401   ])
1402   ;;
1403 esac
1404
1405 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1406 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1407 # REAL_CPPFLAGS later on.
1408
1409 REAL_CPPFLAGS="$CPPFLAGS"
1410
1411 if test "${HAVE_X11}" = "yes"; then
1412   DEFS="$C_SWITCH_X_SITE $DEFS"
1413   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1414   LIBS="$LIBX $LIBS"
1415   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1416   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1417
1418   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1419   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1420   # but it's more convenient here to set LD_RUN_PATH
1421   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1422   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1423     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1424     export LD_RUN_PATH
1425   fi
1426
1427   if test "${opsys}" = "gnu-linux"; then
1428     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1429     AC_TRY_LINK([],
1430      [XOpenDisplay ("foo");],
1431      [xlinux_first_failure=no],
1432      [xlinux_first_failure=yes])
1433     if test "${xlinux_first_failure}" = "yes"; then
1434       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1435       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1436       OLD_CPPFLAGS="$CPPFLAGS"
1437       OLD_LIBS="$LIBS"
1438       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1439       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1440       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1441       LIBS="$LIBS -b i486-linuxaout"
1442       AC_TRY_LINK([],
1443        [XOpenDisplay ("foo");],
1444        [xlinux_second_failure=no],
1445        [xlinux_second_failure=yes])
1446       if test "${xlinux_second_failure}" = "yes"; then
1447         # If we get the same failure with -b, there is no use adding -b.
1448         # So take it out.  This plays safe.
1449         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1450         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1451         CPPFLAGS="$OLD_CPPFLAGS"
1452         LIBS="$OLD_LIBS"
1453         AC_MSG_RESULT(no)
1454       else
1455         AC_MSG_RESULT(yes)
1456       fi
1457     else
1458       AC_MSG_RESULT(no)
1459     fi
1460   fi
1461
1462   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1463   # header files included from there.
1464   AC_MSG_CHECKING(for Xkb)
1465   AC_TRY_LINK([#include <X11/Xlib.h>
1466 #include <X11/XKBlib.h>],
1467         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1468         emacs_xkb=yes, emacs_xkb=no)
1469   AC_MSG_RESULT($emacs_xkb)
1470   if test $emacs_xkb = yes; then
1471     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1472   fi
1473
1474   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1475 XScreenNumberOfScreen XSetWMProtocols)
1476 fi
1477
1478 if test "${window_system}" = "x11"; then
1479   AC_MSG_CHECKING(X11 version 6)
1480   AC_CACHE_VAL(emacs_cv_x11_version_6,
1481   [AC_TRY_LINK([#include <X11/Xlib.h>],
1482 [#if XlibSpecificationRelease < 6
1483 fail;
1484 #endif
1485 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1486   if test $emacs_cv_x11_version_6 = yes; then
1487     AC_MSG_RESULT(6 or newer)
1488     AC_DEFINE(HAVE_X11R6, 1,
1489               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1490   else
1491     AC_MSG_RESULT(before 6)
1492   fi
1493 fi
1494
1495
1496 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1497 HAVE_RSVG=no
1498 if test "${HAVE_X11}" = "yes"; then
1499   if test "${with_rsvg}" != "no"; then
1500     RSVG_REQUIRED=2.0.0
1501     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1502
1503     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1504     AC_SUBST(RSVG_CFLAGS)
1505     AC_SUBST(RSVG_LIBS)
1506
1507     if test ".${RSVG_CFLAGS}" != "."; then
1508       HAVE_RSVG=yes
1509       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1510       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1511       LIBS="$RSVG_LIBS $LIBS"
1512     fi
1513   fi
1514 fi
1515
1516
1517 HAVE_GTK=no
1518 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1519   GLIB_REQUIRED=2.6
1520   GTK_REQUIRED=2.6
1521   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1522
1523   dnl Checks for libraries.
1524   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1525   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1526      AC_MSG_ERROR($GTK_PKG_ERRORS)
1527   fi
1528 fi
1529
1530
1531 if test x"$pkg_check_gtk" = xyes; then
1532
1533   AC_SUBST(GTK_CFLAGS)
1534   AC_SUBST(GTK_LIBS)
1535   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1536   CFLAGS="$CFLAGS $GTK_CFLAGS"
1537   LIBS="$GTK_LIBS $LIBS"
1538   dnl Try to compile a simple GTK program.
1539   GTK_COMPILES=no
1540   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1541   if test "${GTK_COMPILES}" != "yes"; then
1542     if test "$USE_X_TOOLKIT" != "maybe"; then
1543       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1544     fi
1545   else
1546     HAVE_GTK=yes
1547     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1548     USE_X_TOOLKIT=none
1549     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1550       :
1551     else
1552       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1553        closing open displays.  This is no problem if you just use
1554        one display, but if you use more than one and close one of them
1555        Emacs may crash.]])
1556       sleep 3
1557     fi
1558   fi
1559
1560 fi
1561
1562
1563 if test "${HAVE_GTK}" = "yes"; then
1564
1565   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1566   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1567   if test "$with_toolkit_scroll_bars" != no; then
1568     with_toolkit_scroll_bars=yes
1569   fi
1570
1571   dnl  Check if we can use multiple displays with this GTK version.
1572   dnl  If gdk_display_open exists, assume all others are there also.
1573   HAVE_GTK_MULTIDISPLAY=no
1574   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1575   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1576     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1577               [Define to 1 if GTK can handle more than one display.])
1578   fi
1579
1580   dnl  Check if we have the old file selection dialog.
1581   dnl  If gdk_display_open exists, assume all others are there also.
1582   HAVE_GTK_FILE_SELECTION=no
1583   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1584
1585   dnl  Check if we have the new file chooser dialog
1586   dnl  If gdk_display_open exists, assume all others are there also.
1587   HAVE_GTK_FILE_CHOOSER=no
1588   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1589
1590   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1591      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1592     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1593               [Define to 1 if GTK has both file selection and chooser dialog.])
1594   fi
1595
1596   dnl Check if pthreads are available.  Emacs only needs this when using
1597   dnl gtk_file_chooser under Gnome.
1598   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1599     HAVE_GTK_AND_PTHREAD=no
1600     AC_CHECK_HEADERS(pthread.h)
1601     if test "$ac_cv_header_pthread_h"; then
1602       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1603     fi
1604     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1605       case "${canonical}" in
1606         *-hpux*) ;;
1607         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1608       esac
1609       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1610                [Define to 1 if you have GTK and pthread (-lpthread).])
1611     fi
1612   fi
1613 fi
1614
1615 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1616 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1617 dnl also not configured.
1618 HAVE_DBUS=no
1619 if test "${with_dbus}" = "yes"; then
1620    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1621    if test "$HAVE_DBUS" = yes; then
1622       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1623    fi
1624 fi
1625
1626 dnl Do not put whitespace before the #include statements below.
1627 dnl Older compilers (eg sunos4 cc) choke on it.
1628 HAVE_XAW3D=no
1629 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1630   if test "$with_xaw3d" != no; then
1631     AC_MSG_CHECKING(for xaw3d)
1632     AC_CACHE_VAL(emacs_cv_xaw3d,
1633     [AC_TRY_LINK([
1634 #include <X11/Intrinsic.h>
1635 #include <X11/Xaw3d/Simple.h>],
1636       [],
1637       emacs_cv_xaw3d=yes,
1638       emacs_cv_xaw3d=no)])
1639   else
1640     emacs_cv_xaw3d=no
1641   fi
1642   if test $emacs_cv_xaw3d = yes; then
1643     AC_MSG_RESULT([yes; using Lucid toolkit])
1644     USE_X_TOOLKIT=LUCID
1645     HAVE_XAW3D=yes
1646     AC_DEFINE(HAVE_XAW3D, 1,
1647               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1648   else
1649     AC_MSG_RESULT(no)
1650     AC_MSG_CHECKING(for libXaw)
1651     AC_CACHE_VAL(emacs_cv_xaw,
1652     [AC_TRY_LINK([
1653 #include <X11/Intrinsic.h>
1654 #include <X11/Xaw/Simple.h>],
1655       [],
1656       emacs_cv_xaw=yes,
1657       emacs_cv_xaw=no)])
1658     if test $emacs_cv_xaw = yes; then
1659       AC_MSG_RESULT([yes; using Lucid toolkit])
1660       USE_X_TOOLKIT=LUCID
1661     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1662       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1663     else
1664       AC_MSG_RESULT([no; do not use toolkit by default])
1665       USE_X_TOOLKIT=none
1666     fi
1667   fi
1668 fi
1669
1670 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1671
1672 if test "${USE_X_TOOLKIT}" != "none"; then
1673   AC_MSG_CHECKING(X11 toolkit version)
1674   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1675   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1676 [#if XtSpecificationRelease < 6
1677 fail;
1678 #endif
1679 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1680   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1681   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1682     AC_MSG_RESULT(6 or newer)
1683     AC_DEFINE(HAVE_X11XTR6, 1,
1684               [Define to 1 if you have the X11R6 or newer version of Xt.])
1685   else
1686     AC_MSG_RESULT(before 6)
1687   fi
1688
1689 dnl If using toolkit, check whether libXmu.a exists.
1690 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1691   OLDLIBS="$LIBS"
1692   if test x$HAVE_X11XTR6 = xyes; then
1693     LIBS="-lXt -lSM -lICE $LIBS"
1694   else
1695     LIBS="-lXt $LIBS"
1696   fi
1697   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1698   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1699 fi
1700
1701 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1702 if test "${HAVE_X11}" = "yes"; then
1703   if test "${USE_X_TOOLKIT}" != "none"; then
1704     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1705   fi
1706 fi
1707
1708 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1709   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1710   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1711     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1712 int x = 5;
1713 #else
1714 Motif version prior to 2.1.
1715 #endif],
1716     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1717   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1718   if test $emacs_cv_motif_version_2_1 = yes; then
1719     HAVE_LIBXP=no
1720     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1721               [Define to 1 if you have Motif 2.1 or newer.])
1722     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1723     if test ${HAVE_LIBXP} = yes; then
1724       AC_DEFINE(HAVE_LIBXP, 1,
1725                 [Define to 1 if you have the Xp library (-lXp).])
1726     fi
1727   else
1728     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1729     # We put this in CFLAGS temporarily to precede other -I options
1730     # that might be in CFLAGS temporarily.
1731     # We put this in CPPFLAGS where it precedes the other -I options.
1732     OLD_CPPFLAGS=$CPPFLAGS
1733     OLD_CFLAGS=$CFLAGS
1734     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1735     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1736     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1737       [int x = 5;],
1738       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1739     if test $emacs_cv_lesstif = yes; then
1740       # Make sure this -I option remains in CPPFLAGS after it is set
1741       # back to REAL_CPPFLAGS.
1742       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1743       # have those other -I options anyway.  Ultimately, having this
1744       # directory ultimately in CPPFLAGS will be enough.
1745       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1746       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1747     else
1748       CFLAGS=$OLD_CFLAGS
1749       CPPFLAGS=$OLD_CPPFLAGS
1750     fi
1751   fi
1752 fi
1753
1754 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1755 dnl using Motif or Xaw3d is available, and unless
1756 dnl --with-toolkit-scroll-bars=no was specified.
1757
1758 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1759             [Define to 1 if we should use toolkit scroll bars.])dnl
1760 USE_TOOLKIT_SCROLL_BARS=no
1761 if test "${with_toolkit_scroll_bars}" != "no"; then
1762   if test "${USE_X_TOOLKIT}" != "none"; then
1763     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1764       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1765       HAVE_XAW3D=no
1766       USE_TOOLKIT_SCROLL_BARS=yes
1767     elif test "${HAVE_XAW3D}" = "yes"; then
1768       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1769       USE_TOOLKIT_SCROLL_BARS=yes
1770     fi
1771   elif test "${HAVE_GTK}" = "yes"; then
1772     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1773     USE_TOOLKIT_SCROLL_BARS=yes
1774   elif test "${HAVE_NS}" = "yes"; then
1775     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1776     USE_TOOLKIT_SCROLL_BARS=yes
1777   fi
1778 fi
1779
1780 dnl See if XIM is available.
1781 AC_TRY_COMPILE([
1782           #include <X11/Xlib.h>
1783           #include <X11/Xresource.h>],
1784          [XIMProc  callback;],
1785          [HAVE_XIM=yes
1786          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1787          HAVE_XIM=no)
1788
1789 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1790
1791 if test "${with_xim}" != "no"; then
1792   AC_DEFINE(USE_XIM, 1,
1793             [Define to 1 if we should use XIM, if it is available.])
1794 fi
1795
1796
1797 if test "${HAVE_XIM}" != "no"; then
1798   late_CFLAGS=$CFLAGS
1799   if test "$GCC" = yes; then
1800     CFLAGS="$CFLAGS --pedantic-errors"
1801   fi
1802   AC_TRY_COMPILE([
1803 #include <X11/Xlib.h>
1804 #include <X11/Xresource.h>],
1805 [Display *display;
1806 XrmDatabase db;
1807 char *res_name;
1808 char *res_class;
1809 XIMProc  callback;
1810 XPointer *client_data;
1811 #ifndef __GNUC__
1812 /* If we're not using GCC, it's probably not XFree86, and this is
1813    probably right, but we can't use something like --pedantic-errors.  */
1814 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1815                                            char*, XIMProc, XPointer*);
1816 #endif
1817 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1818    client_data);],
1819     [emacs_cv_arg6_star=yes])
1820   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1821          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1822 either XPointer or XPointer*.])dnl
1823   if test "$emacs_cv_arg6_star" = yes; then
1824     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1825   else
1826     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1827   fi
1828   CFLAGS=$late_CFLAGS
1829 fi
1830
1831 ### Start of font-backend section.
1832 PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1833 test "${HAVE_FC}" = "no" && with_freetype=no
1834
1835 ## Use -lXft if available, unless `--with-freetype=no' nor `--with-xft=no'.
1836 HAVE_XFT=maybe
1837 if test "x${with_freetype}" = "xno" || test "x${with_x}" = "xno"; then
1838   with_xft="no";
1839 fi
1840 if test "x${with_xft}" != "xno"; then
1841
1842   PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1843   if test "$HAVE_XFT" != no; then
1844     OLD_CPPFLAGS="$CPPFLAGS"
1845     OLD_CFLAGS="$CFLAGS"
1846     OLD_LIBS="$LIBS"
1847     CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1848     CFLAGS="$CFLAGS $XFT_CFLAGS"
1849     LIBS="$XFT_LIBS $LIBS"
1850     AC_CHECK_HEADER(X11/Xft/Xft.h,
1851       AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1852
1853     if test "${HAVE_XFT}" = "yes"; then
1854       AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1855         AC_SUBST(XFT_LIBS)
1856       C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1857     else
1858       CPPFLAGS="$OLD_CPPFLAGS"
1859       CFLAGS="$OLD_CFLAGS"
1860       LIBS="$OLD_LIBS"
1861     fi                        # "${HAVE_XFT}" = "yes"
1862   fi                          # "$HAVE_XFT" != no
1863 fi                            # "x${with_xft}" != "xno"
1864
1865 dnl For the "Does Emacs use" message at the end.
1866 if test "$HAVE_XFT" != "yes"; then
1867    HAVE_XFT=no
1868 fi
1869
1870
1871 HAVE_FREETYPE=no
1872 ### Use -lfreetype if available, unless `--with-freetype=no'.
1873 if test "${HAVE_XFT}" = "yes"; then
1874   dnl As we use Xft, we anyway use freetype.
1875   dnl In this case, there's no need of additional CFLAGS and LIBS.
1876   HAVE_FREETYPE=yes
1877   FONTCONFIG_CFLAGS=
1878   FONTCONFIG_LIBS=
1879 elif test "x${with_freetype}" != "xno" && test "x${with_x}" != "xno"; then
1880
1881   PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, HAVE_FREETYPE=no)
1882 fi
1883
1884 HAVE_LIBOTF=no
1885 if test "${HAVE_FREETYPE}" = "yes"; then
1886   AC_DEFINE(HAVE_FREETYPE, 1,
1887             [Define to 1 if using the freetype and fontconfig libraries.])
1888   if test "${with_libotf}" != "no"; then
1889     PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
1890                       HAVE_LIBOTF=no)
1891     if test "$HAVE_LIBOTF" = "yes"; then
1892       AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
1893     fi
1894   fi
1895 dnl FIXME should there be an error if HAVE_FREETYPE != yes?
1896 dnl Does the new font backend require it, or can it work without it?
1897 fi
1898
1899 HAVE_M17N_FLT=no
1900 if test "${HAVE_LIBOTF}" = yes; then
1901   if test "${with_m17n_flt}" != "no"; then
1902     PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
1903     if test "$HAVE_M17N_FLT" = "yes"; then
1904       AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
1905     fi
1906   fi
1907 fi
1908
1909 AC_SUBST(FREETYPE_CFLAGS)
1910 AC_SUBST(FREETYPE_LIBS)
1911 AC_SUBST(FONTCONFIG_CFLAGS)
1912 AC_SUBST(FONTCONFIG_LIBS)
1913 AC_SUBST(LIBOTF_CFLAGS)
1914 AC_SUBST(LIBOTF_LIBS)
1915 AC_SUBST(M17N_FLT_CFLAGS)
1916 AC_SUBST(M17N_FLT_LIBS)
1917
1918 ### End of font-backend section.
1919
1920 ### Use -lXpm if available, unless `--with-xpm=no'.
1921 HAVE_XPM=no
1922 if test "${HAVE_X11}" = "yes"; then
1923   if test "${with_xpm}" != "no"; then
1924     AC_CHECK_HEADER(X11/xpm.h,
1925       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
1926     if test "${HAVE_XPM}" = "yes"; then
1927       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
1928       AC_EGREP_CPP(no_return_alloc_pixels,
1929       [#include "X11/xpm.h"
1930 #ifndef XpmReturnAllocPixels
1931 no_return_alloc_pixels
1932 #endif
1933       ], HAVE_XPM=no, HAVE_XPM=yes)
1934
1935       if test "${HAVE_XPM}" = "yes"; then
1936         AC_MSG_RESULT(yes)
1937       else
1938         AC_MSG_RESULT(no)
1939       fi
1940     fi
1941   fi
1942
1943   if test "${HAVE_XPM}" = "yes"; then
1944     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
1945   fi
1946 fi
1947
1948 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1949 HAVE_JPEG=no
1950 if test "${HAVE_X11}" = "yes"; then
1951   if test "${with_jpeg}" != "no"; then
1952     dnl Checking for jpeglib.h can lose because of a redefinition of
1953     dnl  HAVE_STDLIB_H.
1954     AC_CHECK_HEADER(jerror.h,
1955       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
1956   fi
1957
1958   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
1959   if test "${HAVE_JPEG}" = "yes"; then
1960     AC_DEFINE(HAVE_JPEG)
1961     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
1962         [#include <jpeglib.h>
1963          version=JPEG_LIB_VERSION
1964 ],
1965         [AC_DEFINE(HAVE_JPEG)],
1966         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
1967         HAVE_JPEG=no])
1968   fi
1969 fi
1970
1971 ### Use -lpng if available, unless `--with-png=no'.
1972 HAVE_PNG=no
1973 if test "${HAVE_X11}" = "yes"; then
1974   if test "${with_png}" != "no"; then
1975     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
1976     # in /usr/include/libpng.
1977     AC_CHECK_HEADERS(png.h libpng/png.h)
1978     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
1979       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
1980     fi
1981   fi
1982
1983   if test "${HAVE_PNG}" = "yes"; then
1984     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
1985   fi
1986 fi
1987
1988 ### Use -ltiff if available, unless `--with-tiff=no'.
1989 HAVE_TIFF=no
1990 if test "${HAVE_X11}" = "yes"; then
1991   if test "${with_tiff}" != "no"; then
1992     AC_CHECK_HEADER(tiffio.h,
1993       [tifflibs="-lz -lm"
1994       # At least one tiff package requires the jpeg library.
1995       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
1996       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
1997   fi
1998
1999   if test "${HAVE_TIFF}" = "yes"; then
2000     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2001   fi
2002 fi
2003
2004 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2005 HAVE_GIF=no
2006 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2007   AC_CHECK_HEADER(gif_lib.h,
2008 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2009 # Earlier versions can crash Emacs.
2010     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2011
2012   if test "$HAVE_GIF" = yes; then
2013       ac_gif_lib_name="-lgif"
2014   fi
2015
2016 # If gif_lib.h but no libgif, try libungif.
2017   if test x"$try_libungif" = xyes; then
2018     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2019
2020     if test "$HAVE_GIF" = yes; then
2021       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2022       ac_gif_lib_name="-lungif"
2023     fi
2024   fi
2025
2026   if test "${HAVE_GIF}" = "yes"; then
2027     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2028   fi
2029 fi
2030
2031 dnl Check for required libraries.
2032 if test "${HAVE_X11}" = "yes"; then
2033   MISSING=""
2034   WITH_NO=""
2035   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2036     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2037   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2038     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2039   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2040     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2041   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2042     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2043   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2044     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2045
2046   if test "X${MISSING}" != X; then
2047     AC_MSG_ERROR([The following required libraries were not found:
2048     $MISSING
2049 Maybe some development libraries/packages are missing?
2050 If you don't want to link with them give
2051     $WITH_NO
2052 as options to configure])
2053   fi
2054 fi
2055
2056 ### Use -lgpm if available, unless `--with-gpm=no'.
2057 HAVE_GPM=no
2058 if test "${with_gpm}" != "no"; then
2059   AC_CHECK_HEADER(gpm.h,
2060     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2061 fi
2062
2063 if test "${HAVE_GPM}" = "yes"; then
2064   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2065 fi
2066
2067 dnl Check for malloc/malloc.h on darwin
2068 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2069
2070 ### Use NeXTstep API to implement GUI.
2071 if test "${HAVE_NS}" = "yes"; then
2072   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2073   if test "${NS_IMPL_COCOA}" = "yes"; then
2074     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2075     GNU_OBJC_CFLAGS=
2076     LIB_SRC_EXTRA_INSTALLABLES=mac-fix-env
2077   fi
2078   if test "${EN_COCOA_EXPERIMENTAL_CTRL_G}" = "yes"; then
2079     AC_DEFINE(COCOA_EXPERIMENTAL_CTRL_G, 1, [Define to 1 if you are trying experimental enhanced Ctrl-g support using NS windowing under MacOS X.])
2080   fi
2081   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2082     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2083     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2084   fi
2085   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2086     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2087   fi
2088   # We also have mouse menus.
2089   HAVE_MENUS=yes
2090 fi
2091
2092
2093 ### Use session management (-lSM -lICE) if available
2094 HAVE_X_SM=no
2095 if test "${HAVE_X11}" = "yes"; then
2096   AC_CHECK_HEADER(X11/SM/SMlib.h,
2097     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2098
2099   if test "${HAVE_X_SM}" = "yes"; then
2100     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2101     case "$LIBS" in
2102       *-lSM*) ;;
2103       *)      LIBS="-lSM -lICE $LIBS" ;;
2104     esac
2105   fi
2106 fi
2107
2108 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2109 AC_CACHE_CHECK(whether netdb declares h_errno,
2110                emacs_cv_netdb_declares_h_errno,
2111 [AC_TRY_LINK([#include <netdb.h>],
2112   [return h_errno;],
2113   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2114 if test $emacs_cv_netdb_declares_h_errno = yes; then
2115   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2116 fi
2117
2118 AC_FUNC_ALLOCA
2119
2120 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2121 dnl FIXME is there an autoconf test that does the right thing, without
2122 dnl needing to call A_M_E afterwards?
2123 if test x"$ac_cv_func_alloca_works" != xyes; then
2124    AC_MSG_ERROR( [a system implementation of alloca is required] )
2125 fi
2126
2127 # fmod, logb, and frexp are found in -lm on most systems.
2128 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2129 AC_CHECK_LIB(m, sqrt)
2130
2131 # Check for mail-locking functions in a "mail" library.  Probably this should
2132 # have the same check as for liblockfile below.
2133 AC_CHECK_LIB(mail, maillock)
2134 dnl Debian, at least:
2135 AC_CHECK_LIB(lockfile, maillock)
2136 # If we have the shared liblockfile, assume we must use it for mail
2137 # locking (e.g. Debian).  If we couldn't link against liblockfile
2138 # (no liblockfile.a installed), ensure that we don't need to.
2139 if test "$ac_cv_lib_lockfile_maillock" = no; then
2140   dnl This works for files generally, not just executables.
2141   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2142   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2143                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2144   if test $ac_cv_prog_liblockfile = yes; then
2145     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2146 This probably means that movemail could lose mail.
2147 There may be a `development' package to install containing liblockfile.])
2148   else :
2149   fi
2150 fi
2151 AC_CHECK_FUNCS(touchlock)
2152 AC_CHECK_HEADERS(maillock.h)
2153
2154 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2155 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2156 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2157 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2158 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2159 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2160 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2161 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2162 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2163 cfmakeraw cfsetspeed)
2164
2165 AC_CHECK_HEADERS(sys/un.h)
2166
2167 AC_FUNC_MKTIME
2168 if test "$ac_cv_func_working_mktime" = no; then
2169   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2170 fi
2171
2172 AC_FUNC_GETLOADAVG
2173
2174 AC_FUNC_FSEEKO
2175
2176 # Configure getopt.
2177 m4_include([m4/getopt.m4])
2178 gl_GETOPT_IFELSE([
2179   gl_GETOPT_SUBSTITUTE_HEADER
2180   gl_PREREQ_GETOPT
2181   GETOPTOBJS='getopt.o getopt1.o'
2182 ])
2183 AC_SUBST(GETOPTOBJS)
2184
2185 AC_FUNC_GETPGRP
2186
2187 AC_FUNC_STRFTIME
2188
2189 # UNIX98 PTYs.
2190 AC_CHECK_FUNCS(grantpt)
2191
2192 # PTY-related GNU extensions.
2193 AC_CHECK_FUNCS(getpt)
2194
2195 # Check this now, so that we will NOT find the above functions in ncurses.
2196 # That is because we have not set up to link ncurses in lib-src.
2197 # It's better to believe a function is not available
2198 # than to expect to find it in ncurses.
2199 AC_CHECK_LIB(ncurses, tparm)
2200
2201 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2202
2203 resolv=no
2204 AC_TRY_LINK([#include <netinet/in.h>
2205 #include <arpa/nameser.h>
2206 #include <resolv.h>],
2207     [return res_init();],
2208     have_res_init=yes, have_res_init=no)
2209 if test "$have_res_init" = no; then
2210   OLIBS="$LIBS"
2211   LIBS="$LIBS -lresolv"
2212   AC_MSG_CHECKING(for res_init with -lresolv)
2213   AC_TRY_LINK([#include <netinet/in.h>
2214 #include <arpa/nameser.h>
2215 #include <resolv.h>],
2216     [return res_init();],
2217     have_res_init=yes, have_res_init=no)
2218   AC_MSG_RESULT($have_res_init)
2219   if test "$have_res_init" = yes ; then
2220     resolv=yes
2221   fi
2222   LIBS="$OLIBS"
2223 fi
2224
2225 if test "$have_res_init" = yes; then
2226   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2227 fi
2228
2229 # Do we need the Hesiod library to provide the support routines?
2230 if test "$with_hesiod" != no ; then
2231   # Don't set $LIBS here -- see comments above.
2232   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2233      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2234                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2235   if test "$resolv" = yes ; then
2236     RESOLVLIB=-lresolv
2237   else
2238     RESOLVLIB=
2239   fi
2240   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2241         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2242                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2243         :, $RESOLVLIB)])
2244 fi
2245
2246 # Do we need libresolv (due to res_init or Hesiod)?
2247 if test "$resolv" = yes ; then
2248   AC_DEFINE(HAVE_LIBRESOLV, 1,
2249             [Define to 1 if you have the resolv library (-lresolv).])
2250 fi
2251
2252 # These tell us which Kerberos-related libraries to use.
2253 if test "${with_kerberos}" != no; then
2254   AC_CHECK_LIB(com_err, com_err)
2255   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2256   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2257   AC_CHECK_LIB(krb5, krb5_init_context)
2258   if test "${with_kerberos5}" = no; then
2259     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2260                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2261     AC_CHECK_LIB(krb4, krb_get_cred,,
2262                  [AC_CHECK_LIB(krb, krb_get_cred)])
2263   fi
2264
2265   if test "${with_kerberos5}" != no; then
2266     AC_CHECK_HEADERS(krb5.h,
2267       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2268                         [#include <krb5.h>])])
2269   else
2270     AC_CHECK_HEADERS(des.h,,
2271                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2272                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2273     AC_CHECK_HEADERS(krb.h,,
2274                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2275                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2276   fi
2277   AC_CHECK_HEADERS(com_err.h)
2278 fi
2279
2280 # Solaris requires -lintl if you want strerror (which calls dgettext)
2281 # to return localized messages.
2282 AC_CHECK_LIB(intl, dgettext)
2283
2284 AC_MSG_CHECKING(whether localtime caches TZ)
2285 AC_CACHE_VAL(emacs_cv_localtime_cache,
2286 [if test x$ac_cv_func_tzset = xyes; then
2287 AC_TRY_RUN([#include <time.h>
2288 extern char **environ;
2289 unset_TZ ()
2290 {
2291   char **from, **to;
2292   for (to = from = environ; (*to = *from); from++)
2293     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2294       to++;
2295 }
2296 char TZ_GMT0[] = "TZ=GMT0";
2297 char TZ_PST8[] = "TZ=PST8";
2298 main()
2299 {
2300   time_t now = time ((time_t *) 0);
2301   int hour_GMT0, hour_unset;
2302   if (putenv (TZ_GMT0) != 0)
2303     exit (1);
2304   hour_GMT0 = localtime (&now)->tm_hour;
2305   unset_TZ ();
2306   hour_unset = localtime (&now)->tm_hour;
2307   if (putenv (TZ_PST8) != 0)
2308     exit (1);
2309   if (localtime (&now)->tm_hour == hour_GMT0)
2310     exit (1);
2311   unset_TZ ();
2312   if (localtime (&now)->tm_hour != hour_unset)
2313     exit (1);
2314   exit (0);
2315 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2316 [# If we have tzset, assume the worst when cross-compiling.
2317 emacs_cv_localtime_cache=yes])
2318 else
2319         # If we lack tzset, report that localtime does not cache TZ,
2320         # since we can't invalidate the cache if we don't have tzset.
2321         emacs_cv_localtime_cache=no
2322 fi])dnl
2323 AC_MSG_RESULT($emacs_cv_localtime_cache)
2324 if test $emacs_cv_localtime_cache = yes; then
2325   AC_DEFINE(LOCALTIME_CACHE, 1,
2326             [Define to 1 if localtime caches TZ.])
2327 fi
2328
2329 if test "x$HAVE_TIMEVAL" = xyes; then
2330   AC_CHECK_FUNCS(gettimeofday)
2331   if test $ac_cv_func_gettimeofday = yes; then
2332     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2333                    emacs_cv_gettimeofday_two_arguments,
2334     [AC_TRY_COMPILE([
2335 #ifdef TIME_WITH_SYS_TIME
2336 #include <sys/time.h>
2337 #include <time.h>
2338 #else
2339 #ifdef HAVE_SYS_TIME_H
2340 #include <sys/time.h>
2341 #else
2342 #include <time.h>
2343 #endif
2344 #endif],
2345       [struct timeval time;
2346        gettimeofday (&time, 0);],
2347       emacs_cv_gettimeofday_two_arguments=yes,
2348       emacs_cv_gettimeofday_two_arguments=no)])
2349     if test $emacs_cv_gettimeofday_two_arguments = no; then
2350       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2351                 [Define to 1 if gettimeofday accepts only one argument.])
2352     fi
2353   fi
2354 fi
2355
2356 ok_so_far=yes
2357 AC_CHECK_FUNC(socket, , ok_so_far=no)
2358 if test $ok_so_far = yes; then
2359   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2360 fi
2361 if test $ok_so_far = yes; then
2362   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2363 fi
2364 if test $ok_so_far = yes; then
2365 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2366   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2367             [Define to 1 if you have inet sockets.])
2368 fi
2369
2370 AC_CHECK_HEADERS(sys/ioctl.h)
2371
2372 if test -f /usr/lpp/X11/bin/smt.exp; then
2373   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2374             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2375 fi
2376
2377 AC_MSG_CHECKING(whether system supports dynamic ptys)
2378 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2379   AC_MSG_RESULT(yes)
2380   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2381 else
2382   AC_MSG_RESULT(no)
2383 fi
2384
2385 AC_FUNC_FORK
2386
2387 dnl Adapted from Haible's version.
2388 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2389   [AC_TRY_LINK([#include <langinfo.h>],
2390     [char* cs = nl_langinfo(CODESET);],
2391     emacs_cv_langinfo_codeset=yes,
2392     emacs_cv_langinfo_codeset=no)
2393   ])
2394 if test $emacs_cv_langinfo_codeset = yes; then
2395   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2396     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2397 fi
2398
2399 AC_CHECK_TYPES(size_t)
2400
2401 AC_TYPE_MBSTATE_T
2402
2403 dnl Restrict could probably be used effectively other than in regex.c.
2404 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2405   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2406                   emacs_cv_c_restrict=yes,
2407                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2408                                   emacs_cv_c_restrict=__restrict,
2409                                   emacs_cv_c_restrict=no)])])
2410 case "$emacs_cv_c_restrict" in
2411   yes) emacs_restrict=restrict;;
2412   no) emacs_restrict="";;
2413   *) emacs_restrict="$emacs_cv_c_restrict";;
2414 esac
2415 if test "$emacs_restrict" != __restrict; then
2416   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2417     [Define to compiler's equivalent of C99 restrict keyword.
2418      Don't define if equivalent is `__restrict'.])
2419 fi
2420
2421 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2422   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2423                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2424 if test "$emacs_cv_c_restrict_arr" = yes; then
2425   AC_DEFINE(__restrict_arr, __restrict,
2426     [Define to compiler's equivalent of C99 restrict keyword in array
2427      declarations.  Define as empty for no equivalent.])
2428 fi
2429
2430 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2431 dnl how the tty code is related to POSIX and/or other versions of termios.
2432 dnl The following looks like a useful start.
2433 dnl
2434 dnl AC_SYS_POSIX_TERMIOS
2435 dnl if test $ac_cv_sys_posix_termios = yes; then
2436 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2437 dnl                                and macros for terminal control.])
2438 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2439 dnl fi
2440
2441 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2442
2443 # Set up the CFLAGS for real compilation, so we can substitute it.
2444 CFLAGS="$REAL_CFLAGS"
2445 CPPFLAGS="$REAL_CPPFLAGS"
2446
2447 #### Find out which version of Emacs this is.
2448 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2449          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2450 if test x"${version}" = x; then
2451   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2452 fi
2453
2454 ### Specify what sort of things we'll be editing into Makefile and config.h.
2455 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2456 AC_SUBST(version)
2457 AC_SUBST(configuration)
2458 AC_SUBST(canonical)
2459 AC_SUBST(srcdir)
2460 AC_SUBST(prefix)
2461 AC_SUBST(exec_prefix)
2462 AC_SUBST(bindir)
2463 AC_SUBST(datadir)
2464 AC_SUBST(sharedstatedir)
2465 AC_SUBST(libexecdir)
2466 AC_SUBST(mandir)
2467 AC_SUBST(infodir)
2468 AC_SUBST(lispdir)
2469 AC_SUBST(locallisppath)
2470 AC_SUBST(lisppath)
2471 AC_SUBST(x_default_search_path)
2472 AC_SUBST(etcdir)
2473 AC_SUBST(archlibdir)
2474 AC_SUBST(docdir)
2475 AC_SUBST(bitmapdir)
2476 AC_SUBST(gamedir)
2477 AC_SUBST(gameuser)
2478 AC_SUBST(c_switch_system)
2479 AC_SUBST(c_switch_machine)
2480 AC_SUBST(LD_SWITCH_X_SITE)
2481 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2482 AC_SUBST(C_SWITCH_X_SITE)
2483 AC_SUBST(CFLAGS)
2484 AC_SUBST(X_TOOLKIT_TYPE)
2485 AC_SUBST(machfile)
2486 AC_SUBST(opsysfile)
2487 AC_SUBST(GETLOADAVG_LIBS)
2488 AC_SUBST(ns_appdir)
2489 AC_SUBST(ns_appbindir)
2490 AC_SUBST(ns_appresdir)
2491 AC_SUBST(ns_appsrc)
2492 AC_SUBST(GNUSTEP_MAKEFILES)
2493 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2494 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2495 AC_SUBST(GNU_OBJC_CFLAGS)
2496 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2497
2498 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2499                    [Define to the canonical Emacs configuration name.])
2500 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2501                    [Define to the options passed to configure.])
2502 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2503                    [Define to the used machine dependent file.])
2504 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2505                    [Define to the used os dependent file.])
2506 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2507 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2508  may need to deal with X Windows.  For instance, if you've defined
2509  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2510  your loader can find on its own, you might want to add "-L/..." or
2511  something similar.])
2512 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2513                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2514                     in case it's needed (for Solaris, for example).])
2515 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2516 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2517  may need to deal with X Windows.  For instance, if you've defined
2518  HAVE_X_WINDOWS above and your X include files aren't in a place
2519  that your compiler can find on its own, you might want to add
2520  "-I/..." or something similar.])
2521 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2522                    [Define to the unexec source file name.])
2523
2524 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2525   AC_DEFINE(HAVE_X_WINDOWS, 1,
2526             [Define to 1 if you want to use the X window system.])
2527 fi
2528 if test "${USE_X_TOOLKIT}" != "none" ; then
2529   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2530   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2531     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2532   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2533     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2534   fi
2535 fi
2536 if test "${HAVE_X11}" = "yes" ; then
2537   AC_DEFINE(HAVE_X11, 1,
2538             [Define to 1 if you want to use version 11 of X windows.
2539              Otherwise, Emacs expects to use version 10.])
2540 fi
2541 if test "${HAVE_MENUS}" = "yes" ; then
2542   AC_DEFINE(HAVE_MENUS, 1,
2543             [Define to 1 if you have mouse menus.
2544              (This is automatic if you use X, but the option to specify it remains.)
2545              It is also defined with other window systems that support xmenu.c.])
2546 fi
2547 if test "${GNU_MALLOC}" = "yes" ; then
2548   AC_DEFINE(GNU_MALLOC, 1,
2549             [Define to 1 if you want to use the GNU memory allocator.])
2550 fi
2551 if test "${REL_ALLOC}" = "yes" ; then
2552   AC_DEFINE(REL_ALLOC, 1,
2553             [Define REL_ALLOC if you want to use the relocating allocator for
2554              buffer space.])
2555 fi
2556
2557
2558 AH_TOP([/* GNU Emacs site configuration template file.
2559    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2560      2006, 2007, 2008  Free Software Foundation, Inc.
2561
2562 This file is part of GNU Emacs.
2563
2564 GNU Emacs is free software: you can redistribute it and/or modify
2565 it under the terms of the GNU General Public License as published by
2566 the Free Software Foundation, either version 3 of the License, or
2567 (at your option) any later version.
2568
2569 GNU Emacs is distributed in the hope that it will be useful,
2570 but WITHOUT ANY WARRANTY; without even the implied warranty of
2571 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2572 GNU General Public License for more details.
2573
2574 You should have received a copy of the GNU General Public License
2575 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2576
2577
2578 /* No code in Emacs #includes config.h twice, but some bits of code
2579    intended to work with other packages as well (like gmalloc.c)
2580    think they can include it as many times as they like.  */
2581 #ifndef EMACS_CONFIG_H
2582 #define EMACS_CONFIG_H
2583 ])dnl
2584
2585 AH_BOTTOM([
2586 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2587 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2588 #define HAVE_WINDOW_SYSTEM
2589 #define HAVE_MOUSE
2590 #endif
2591
2592 /* Sadly for now, GNUstep dump does not work.  */
2593 #ifdef NS_IMPL_GNUSTEP
2594 #define CANNOT_DUMP
2595 #endif
2596
2597 /* Define AMPERSAND_FULL_NAME if you use the convention
2598    that & in the full name stands for the login id.  */
2599 /* Turned on June 1996 supposing nobody will mind it.  */
2600 #define AMPERSAND_FULL_NAME
2601
2602 /* Define HAVE_SOUND if we have sound support.  We know it works
2603    and compiles only on the specified platforms.   For others,
2604    it probably doesn't make sense to try.  */
2605
2606 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2607 #ifdef HAVE_MACHINE_SOUNDCARD_H
2608 #define HAVE_SOUND 1
2609 #endif
2610 #ifdef HAVE_SYS_SOUNDCARD_H
2611 #define HAVE_SOUND 1
2612 #endif
2613 #ifdef HAVE_SOUNDCARD_H
2614 #define HAVE_SOUND 1
2615 #endif
2616 #ifdef HAVE_ALSA
2617 #define HAVE_SOUND 1
2618 #endif
2619 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2620
2621 /* If using GNU, then support inline function declarations. */
2622 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2623    generally, because even if non-gcc compilers accept `inline', they
2624    may reject `extern inline'.  */
2625 #if defined (__GNUC__) && defined (OPTIMIZE)
2626 #define INLINE __inline__
2627 #else
2628 #define INLINE
2629 #endif
2630
2631 /* `subprocesses' should be defined if you want to
2632    have code for asynchronous subprocesses
2633    (as used in M-x compile and M-x shell).
2634    Only MSDOS does not support this (it overrides
2635    this in its config_opsysfile below).  */
2636
2637 #define subprocesses
2638
2639 /* Include the os and machine dependent files.  */
2640 #include config_opsysfile
2641 #include config_machfile
2642
2643 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2644   (There is probably a better place to do this, but right now the Cocoa
2645    side does this in s/darwin.h and we cannot
2646    parallel this exactly since GNUstep is multi-OS. */
2647 #ifdef HAVE_NS
2648 #define OTHER_FILES ns-app
2649 # ifdef NS_IMPL_GNUSTEP
2650 /* See also .m.o rule in Makefile.in */
2651 /* FIXME: are all these flags really needed?  Document here why.  */
2652 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2653 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2654 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2655 #  define SYSTEM_PURESIZE_EXTRA 30000
2656 # endif /* NS_IMPL_GNUSTEP */
2657 #endif /* HAVE_NS */
2658
2659 /* SIGTYPE is the macro we actually use.  */
2660 #ifndef SIGTYPE
2661 #define SIGTYPE RETSIGTYPE
2662 #endif
2663
2664 #ifdef emacs /* Don't do this for lib-src.  */
2665 /* Tell regex.c to use a type compatible with Emacs.  */
2666 #define RE_TRANSLATE_TYPE Lisp_Object
2667 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2668 #ifdef make_number
2669 /* If make_number is a macro, use it.  */
2670 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2671 #else
2672 /* If make_number is a function, avoid it.  */
2673 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2674 #endif
2675 #endif
2676
2677 /* Avoid link-time collision with system mktime if we will use our own.  */
2678 #if ! HAVE_MKTIME || BROKEN_MKTIME
2679 #define mktime emacs_mktime
2680 #endif
2681
2682 #define my_strftime nstrftime   /* for strftime.c */
2683
2684 /* The rest of the code currently tests the CPP symbol BSTRING.
2685    Override any claims made by the system-description files.
2686    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2687 #undef BSTRING
2688 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2689 #define BSTRING
2690 #endif
2691
2692 /* Some of the files of Emacs which are intended for use with other
2693    programs assume that if you have a config.h file, you must declare
2694    the type of getenv.
2695
2696    This declaration shouldn't appear when alloca.s or Makefile.in
2697    includes config.h.  */
2698 #ifndef NOT_C_CODE
2699 extern char *getenv ();
2700 #endif
2701
2702 /* These default definitions are good for almost all machines.
2703    The exceptions override them in m/MACHINE.h.  */
2704
2705 #ifndef BITS_PER_CHAR
2706 #define BITS_PER_CHAR 8
2707 #endif
2708
2709 #ifndef BITS_PER_SHORT
2710 #define BITS_PER_SHORT 16
2711 #endif
2712
2713 /* Note that lisp.h uses this in a preprocessor conditional, so it
2714    would not work to use sizeof.  That being so, we do all of them
2715    without sizeof, for uniformity's sake.  */
2716 #ifndef BITS_PER_INT
2717 #define BITS_PER_INT 32
2718 #endif
2719
2720 #ifndef BITS_PER_LONG
2721 #ifdef _LP64
2722 #define BITS_PER_LONG 64
2723 #else
2724 #define BITS_PER_LONG 32
2725 #endif
2726 #endif
2727
2728 /* Define if the compiler supports function prototypes.  It may do so
2729    but not define __STDC__ (e.g. DEC C by default) or may define it as
2730    zero.  */
2731 #undef PROTOTYPES
2732 /* For mktime.c:  */
2733 #ifndef __P
2734 # if defined PROTOTYPES
2735 #  define __P(args) args
2736 # else
2737 #  define __P(args) ()
2738 # endif  /* GCC.  */
2739 #endif /* __P */
2740
2741 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2742 #ifndef NOT_C_CODE
2743 #ifdef HAVE_STRING_H
2744 #include "string.h"
2745 #endif
2746 #ifdef HAVE_STRINGS_H
2747 #include "strings.h"  /* May be needed for bcopy & al. */
2748 #endif
2749 #ifdef HAVE_STDLIB_H
2750 #include <stdlib.h>
2751 #endif
2752 #ifndef __GNUC__
2753 # ifdef HAVE_ALLOCA_H
2754 #  include <alloca.h>
2755 # else /* AIX files deal with #pragma.  */
2756 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2757 char *alloca ();
2758 #  endif
2759 # endif /* HAVE_ALLOCA_H */
2760 #endif /* __GNUC__ */
2761 #ifndef HAVE_SIZE_T
2762 typedef unsigned size_t;
2763 #endif
2764 #endif /* NOT_C_CODE */
2765
2766 /* Define HAVE_X_I18N if we have usable i18n support.  */
2767
2768 #ifdef HAVE_X11R6
2769 #define HAVE_X_I18N
2770 #elif !defined X11R5_INHIBIT_I18N
2771 #define HAVE_X_I18N
2772 #endif
2773
2774 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2775
2776 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2777 #define HAVE_X11R6_XIM
2778 #endif
2779
2780 /* Should we enable expensive run-time checking of data types?  */
2781 #undef ENABLE_CHECKING
2782
2783 #if defined __GNUC__ && (__GNUC__ > 2 \
2784                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2785 #define NO_RETURN       __attribute__ ((__noreturn__))
2786 #else
2787 #define NO_RETURN       /* nothing */
2788 #endif
2789
2790 /* These won't be used automatically yet.  We also need to know, at least,
2791    that the stack is continuous.  */
2792 #ifdef __GNUC__
2793 #  ifndef GC_SETJMP_WORKS
2794   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2795      see NON_SAVING_SETJMP in the target descriptions.  */
2796   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2797      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2798      Fixme: Deal with SVR3.  */
2799 #    define GC_SETJMP_WORKS 1
2800 #  endif
2801 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2802 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2803 #  endif
2804 #endif
2805
2806 #ifndef HAVE_BCOPY
2807 #define bcopy(a,b,s) memcpy (b,a,s)
2808 #endif
2809 #ifndef HAVE_BZERO
2810 #define bzero(a,s) memset (a,0,s)
2811 #endif
2812 #ifndef HAVE_BCMP
2813 #define BCMP memcmp
2814 #endif
2815
2816 #endif /* EMACS_CONFIG_H */
2817
2818 /*
2819 Local Variables:
2820 mode: c
2821 End:
2822 */
2823 ])dnl
2824
2825 #### Report on what we decided to do.
2826 #### Report GTK as a toolkit, even if it doesn't use Xt.
2827 #### It makes printing result more understandable as using GTK sets
2828 #### toolkit_scroll_bars to yes by default.
2829 if test "${HAVE_GTK}" = "yes"; then
2830   USE_X_TOOLKIT=GTK
2831 fi
2832
2833 echo "
2834 Configured for \`${canonical}'.
2835
2836   Where should the build process find the source code?    ${srcdir}
2837   What operating system and machine description files should Emacs use?
2838         \`${opsysfile}' and \`${machfile}'
2839   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2840   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2841   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2842   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2843   What window system should Emacs use?                    ${window_system}
2844   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2845
2846 if test -n "${x_includes}"; then
2847 echo "  Where do we find X Windows header files?                ${x_includes}"
2848 else
2849 echo "  Where do we find X Windows header files?                Standard dirs"
2850 fi
2851 if test -n "${x_libraries}"; then
2852 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2853 else
2854 echo "  Where do we find X Windows libraries?                   Standard dirs"
2855 fi
2856
2857 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2858 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2859 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2860 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2861 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2862 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2863 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2864 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2865 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2866
2867 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
2868 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
2869 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
2870 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
2871
2872 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
2873 echo
2874
2875 if test $USE_XASSERTS = yes; then
2876    echo "  Compiling with asserts turned on."
2877    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
2878 fi
2879
2880 echo
2881
2882 if test "$USE_X_TOOLKIT" = GTK; then
2883   case "$canonical" in
2884   *cygwin*)
2885     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
2886   will probably get a crash on startup.  If this happens, please use another
2887   toolkit for Emacs.  See etc/PROBLEMS for more information."
2888   ;;
2889   esac
2890 fi
2891
2892 if test "$HAVE_NS" = "yes"; then
2893    echo
2894    echo "You must run \"make install\" in order to test the built application.
2895 The installed application will go to nextstep/Emacs.app and can be
2896 run or moved from there."
2897    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
2898       echo "The application will be fully self-contained."
2899     else
2900       echo "The lisp resources for the application will be installed under ${prefix}.
2901 You may need to run \"make install\" with sudo.  The application will fail
2902 to run if these resources are not installed."
2903    fi
2904    echo
2905 fi
2906
2907 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
2908   echo "D-Bus integration has been tested for GNU/Linux only."
2909   echo
2910 fi
2911
2912
2913 # Remove any trailing slashes in these variables.
2914 [test "${prefix}" != NONE &&
2915   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2916 test "${exec_prefix}" != NONE &&
2917   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
2918
2919 # Now get this: Some word that is part of the ${srcdir} directory name
2920 # or the ${configuration} value might, just might, happen to be an
2921 # identifier like `sun4' or `i386' or something, and be predefined by
2922 # the C preprocessor to some helpful value like 1, or maybe the empty
2923 # string.  Needless to say consequent macro substitutions are less
2924 # than conducive to the makefile finding the correct directory.
2925 [cpp_undefs="`echo $srcdir $configuration $canonical |
2926   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
2927   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
2928
2929 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
2930 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2931 ## from Makefile.c can correctly provide the arg `-traditional' to the
2932 ## C preprocessor.
2933
2934 AC_EGREP_CPP(yes..yes,
2935         [yes..yes],
2936         CPP_NEED_TRADITIONAL=no,
2937         CPP_NEED_TRADITIONAL=yes)
2938
2939 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2940         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
2941         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
2942         lwlib/Makefile lisp/Makefile leim/Makefile, [
2943
2944 ### Make the necessary directories, if they don't exist.
2945 for dir in etc lisp ; do
2946   test -d ${dir} || mkdir ${dir}
2947 done
2948
2949 # Build src/Makefile from ${srcdir}/src/Makefile.c
2950 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2951 # This must be done after src/config.h is built, since we rely on that file.
2952
2953 echo creating src/epaths.h
2954 ${MAKE-make} epaths-force
2955
2956 # As of 2000-11-19, newest development versions of GNU cpp preprocess
2957 # `..' to `. .'  unless invoked with -traditional
2958
2959 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
2960   CPPFLAGS="$CPPFLAGS -traditional"
2961 fi
2962
2963 echo creating lib-src/Makefile
2964 ( cd lib-src
2965   rm -f junk.c junk1.c junk2.c
2966   sed -e '/start of cpp stuff/q' \
2967       < Makefile.c > junk1.c
2968   sed -e '1,/start of cpp stuff/d'\
2969       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2970       < Makefile.c > junk.c
2971   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2972       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2973   cat junk1.c junk2.c > Makefile.new
2974   rm -f junk.c junk1.c junk2.c
2975   chmod 444 Makefile.new
2976   mv -f Makefile.new Makefile
2977 )
2978
2979 echo creating src/Makefile
2980 ( cd src
2981   rm -f junk.c junk1.c junk2.c
2982   sed -e '/start of cpp stuff/q' \
2983       < Makefile.c > junk1.c
2984   sed -e '1,/start of cpp stuff/d'\
2985       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2986       < Makefile.c > junk.c
2987   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2988       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2989   cat junk1.c junk2.c > Makefile.new
2990   rm -f junk.c junk1.c junk2.c
2991   chmod 444 Makefile.new
2992   mv -f Makefile.new Makefile
2993 )
2994
2995 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
2996   echo creating src/.gdbinit
2997   echo source $srcdir/src/.gdbinit > src/.gdbinit
2998 fi
2999
3000 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3001
3002 m4_if(dnl       Do not change this comment
3003    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3004 )dnl