configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.2.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 dnl Fairly arbitrary, older versions might work too.
  30 AM_INIT_AUTOMAKE(1.11)
  31
  32 dnl Support for --program-prefix, --program-suffix and
  33 dnl --program-transform-name options
  34 AC_ARG_PROGRAM
  35
  36 dnl It is important that variables on the RHS not be expanded here,
  37 dnl hence the single quotes.  This is per the GNU coding standards, see
  38 dnl (autoconf) Installation Directory Variables
  39 dnl See also epaths.h below.
  40 lispdir='${datadir}/emacs/${version}/lisp'
  41 leimdir='${datadir}/emacs/${version}/leim'
  42 standardlisppath='${lispdir}:${leimdir}'
  43 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  44 '${datadir}/emacs/site-lisp'
  45 lisppath='${locallisppath}:${standardlisppath}'
  46 etcdir='${datadir}/emacs/${version}/etc'
  47 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  48 docdir='${datadir}/emacs/${version}/etc'
  49 gamedir='${localstatedir}/games/emacs'
  50
  51 dnl Special option to disable the most of other options.
  52 AC_ARG_WITH(all,
  53 [AS_HELP_STRING([--without-all],
  54                 [omit almost all features and build
  55                 small executable with minimal dependencies])],
  56   with_features=$withval,
  57   with_features=yes)
  58
  59 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  60 dnl Create a new --with option that defaults to being disabled.
  61 dnl NAME is the base name of the option.  The shell variable with_NAME
  62 dnl   will be set to either the user's value (if the option is
  63 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  64 dnl   option is not specified).  Note that the shell variable name is
  65 dnl   constructed as autoconf does, by replacing non-alphanumeric
  66 dnl   characters with "_".
  67 dnl HELP-STRING is the help text for the option.
  68 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  69   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  70     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  71 ])dnl
  72
  73 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  74 dnl Create a new --with option that defaults to $enable_features.
  75 dnl NAME is the base name of the option.  The shell variable with_NAME
  76 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  77 dnl   'yes' (if the option is not specified).  Note that the shell
  78 dnl   variable name is constructed as autoconf does, by replacing
  79 dnl   non-alphanumeric characters with "_".
  80 dnl HELP-STRING is the help text for the option.
  81 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  82   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  83    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
  84 ])dnl
  85
  86 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  87 if test "$with_pop" = yes; then
  88    AC_DEFINE(MAIL_USE_POP)
  89 fi
  90 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  91
  92 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  93 if test "$with_kerberos" != no; then
  94    AC_DEFINE(KERBEROS)
  95 fi
  96 AH_TEMPLATE(KERBEROS,
  97             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  98
  99 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 100 if test "${with_kerberos5}" != no; then
 101   if test "${with_kerberos}" = no; then
 102     with_kerberos=yes
 103     AC_DEFINE(KERBEROS)
 104   fi
 105   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 106 fi
 107
 108 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 109 dnl FIXME hesiod support may not be present, so it seems like an error
 110 dnl to define, or at least use, this unconditionally.
 111 if test "$with_hesiod" != no; then
 112   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 113 fi
 114
 115 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 116 if test "$with_mmdf" != no; then
 117    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 118 fi
 119
 120 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 121 if test "$with_mail_unlink" != no; then
 122    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 123 fi
 124
 125 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 126     [string giving default POP mail host])],
 127     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 128
 129 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 130
 131 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 132 if test "$with_sync_input" = yes; then
 133    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 134 fi
 135
 136 dnl FIXME currently it is not the last.
 137 dnl This should be the last --with option, because --with-x is
 138 dnl added later on when we find the path of X, and it's best to
 139 dnl keep them together visually.
 140 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 141  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 142 [         case "${withval}" in
 143             y | ye | yes )      val=gtk ;;
 144             n | no )            val=no  ;;
 145             l | lu | luc | luci | lucid )       val=lucid ;;
 146             a | at | ath | athe | athen | athena )      val=athena ;;
 147             m | mo | mot | moti | motif )       val=motif ;;
 148             g | gt | gtk  )     val=gtk ;;
 149             gtk2  )     val=gtk2 ;;
 150             gtk3  )     val=gtk3 ;;
 151             * )
 152 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 153 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 154 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 155 `athena' and `lucid' are synonyms.])
 156             ;;
 157           esac
 158           with_x_toolkit=$val
 159 ])
 160
 161 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 162 if test "$with_wide_int" = yes; then
 163   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 164 fi
 165
 166 dnl _ON results in a '--without' option in the --help output, so
 167 dnl the help text should refer to "don't compile", etc.
 168 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 169 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 170 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 171 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 172 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 173 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 174 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 175 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 176
 177 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 178 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 179 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 180
 181 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 182 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 183 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 184 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 185
 186 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 187 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 188 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 189 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 190 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 191 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 192
 193 ## For the times when you want to build Emacs but don't have
 194 ## a suitable makeinfo, and can live without the manuals.
 195 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 196 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 197
 198 ## Makefile.in needs the cache file name.
 199 AC_SUBST(cache_file)
 200
 201 ## This is an option because I do not know if all info/man support
 202 ## compressed files, nor how to test if they do so.
 203 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 204 if test $with_compress_info = yes; then
 205    GZIP_INFO=yes
 206 else
 207    GZIP_INFO=
 208 fi
 209 AC_SUBST(GZIP_INFO)
 210
 211 AC_ARG_WITH([pkg-config-prog],dnl
 212 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 213                   [path to pkg-config for finding GTK and librsvg])])
 214 if test "X${with_pkg_config_prog}" != X; then
 215    if test "${with_pkg_config_prog}" != yes; then
 216       PKG_CONFIG="${with_pkg_config_prog}"
 217    fi
 218 fi
 219
 220 CRT_DIR=
 221 AC_ARG_WITH([crt-dir],dnl
 222 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 223 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 224 CRT_DIR="${with_crt_dir}"
 225
 226 AC_ARG_WITH(gameuser,dnl
 227 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 228 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 229   && gameuser="${with_gameuser}"
 230 test "X$gameuser" = X && gameuser=games
 231
 232 AC_ARG_WITH([gnustep-conf],dnl
 233 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 234 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 235   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 236 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 237      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 238
 239 AC_ARG_ENABLE(ns-self-contained,
 240 [AS_HELP_STRING([--disable-ns-self-contained],
 241                 [disable self contained build under NeXTstep])],
 242    EN_NS_SELF_CONTAINED=$enableval,
 243    EN_NS_SELF_CONTAINED=yes)
 244
 245 AC_ARG_ENABLE(locallisppath,
 246 [AS_HELP_STRING([--enable-locallisppath=PATH],
 247                 [directories Emacs should search for lisp files specific
 248                  to this site])],
 249 if test "${enableval}" = "no"; then
 250   locallisppath=
 251 elif test "${enableval}" != "yes"; then
 252   locallisppath=${enableval}
 253 fi)
 254
 255 AC_ARG_ENABLE(checking,
 256 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 257                 [enable expensive run-time checks.  With LIST,
 258                  enable only specific categories of checks.
 259                  Categories are: all,yes,no.
 260                  Flags are: stringbytes, stringoverrun, stringfreelist,
 261                  xmallocoverrun, conslist, glyphs])],
 262 [ac_checking_flags="${enableval}"],[])
 263 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 264 for check in $ac_checking_flags
 265 do
 266         case $check in
 267         # these set all the flags to specific states
 268         yes)            ac_enable_checking=1 ;;
 269         no)             ac_enable_checking= ;
 270                         ac_gc_check_stringbytes= ;
 271                         ac_gc_check_string_overrun= ;
 272                         ac_gc_check_string_free_list= ;
 273                         ac_xmalloc_overrun= ;
 274                         ac_gc_check_cons_list= ;
 275                         ac_glyphs_debug= ;;
 276         all)            ac_enable_checking=1 ;
 277                         ac_gc_check_stringbytes=1 ;
 278                         ac_gc_check_string_overrun=1 ;
 279                         ac_gc_check_string_free_list=1 ;
 280                         ac_xmalloc_overrun=1 ;
 281                         ac_gc_check_cons_list=1 ;
 282                         ac_glyphs_debug=1 ;;
 283         # these enable particular checks
 284         stringbytes)    ac_gc_check_stringbytes=1 ;;
 285         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 286         stringfreelist) ac_gc_check_string_free_list=1 ;;
 287         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 288         conslist)       ac_gc_check_cons_list=1 ;;
 289         glyphs)         ac_glyphs_debug=1 ;;
 290         *)      AC_MSG_ERROR(unknown check category $check) ;;
 291         esac
 292 done
 293 IFS="$ac_save_IFS"
 294
 295 if test x$ac_enable_checking != x ; then
 296   AC_DEFINE(ENABLE_CHECKING, 1,
 297 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 298 fi
 299 if test x$ac_gc_check_stringbytes != x ; then
 300   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 301 [Define this temporarily to hunt a bug.  If defined, the size of
 302    strings is redundantly recorded in sdata structures so that it can
 303    be compared to the sizes recorded in Lisp strings.])
 304 fi
 305 if test x$ac_gc_check_string_overrun != x ; then
 306   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 307 [Define this to check for short string overrun.])
 308 fi
 309 if test x$ac_gc_check_string_free_list != x ; then
 310   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 311 [Define this to check the string free list.])
 312 fi
 313 if test x$ac_xmalloc_overrun != x ; then
 314   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 315 [Define this to check for malloc buffer overrun.])
 316 fi
 317 if test x$ac_gc_check_cons_list != x ; then
 318   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 319 [Define this to check for errors in cons list.])
 320 fi
 321 if test x$ac_glyphs_debug != x ; then
 322   AC_DEFINE(GLYPH_DEBUG, 1,
 323 [Define this to enable glyphs debugging code.])
 324 fi
 325
 326 AC_ARG_ENABLE(check-lisp-object-type,
 327 [AS_HELP_STRING([--enable-check-lisp-object-type],
 328                 [enable compile time checks for the Lisp_Object data type.
 329                 This is useful for development for catching certain types of bugs.])],
 330 if test "${enableval}" != "no"; then
 331    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 332    [Define this to enable compile time checks for the Lisp_Object data type.])
 333 fi)
 334
 335
 336 AC_ARG_ENABLE(profiling,
 337 [AS_HELP_STRING([--enable-profiling],
 338                 [build emacs with profiling support.
 339                  This might not work on all platforms])],
 340 [ac_enable_profiling="${enableval}"],[])
 341 if test x$ac_enable_profiling != x ; then
 342    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 343 else
 344    PROFILING_CFLAGS=
 345 fi
 346 AC_SUBST(PROFILING_CFLAGS)
 347
 348 AC_ARG_ENABLE(autodepend,
 349 [AS_HELP_STRING([--enable-autodepend],
 350                 [automatically generate dependencies to .h-files.
 351                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 352                  found])],
 353 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 354
 355 #### Make srcdir absolute, if it isn't already.  It's important to
 356 #### avoid running the path through pwd unnecessarily, since pwd can
 357 #### give you automounter prefixes, which can go away.  We do all this
 358 #### so Emacs can find its files when run uninstalled.
 359 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 360 unset CDPATH
 361 case "${srcdir}" in
 362   /* ) ;;
 363   . )
 364     ## We may be able to use the $PWD environment variable to make this
 365     ## absolute.  But sometimes PWD is inaccurate.
 366     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 367     ## but that tested only for a well-formed and valid PWD,
 368     ## it did not object when PWD was well-formed and valid but just wrong.
 369     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 370     then
 371       srcdir="$PWD"
 372     else
 373       srcdir="`(cd ${srcdir}; pwd)`"
 374     fi
 375   ;;
 376   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 377 esac
 378
 379 ### Canonicalize the configuration name.
 380
 381 AC_CANONICAL_HOST
 382 canonical=$host
 383 configuration=${host_alias-${build_alias-$host}}
 384
 385 dnl This used to use changequote, but, apart from `changequote is evil'
 386 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 387 dnl the great gob of text.  Thus it's not processed for possible expansion.
 388 dnl Just make sure the brackets remain balanced.
 389 dnl
 390 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 391 dnl indicated by comments.
 392 dnl quotation begins
 393 [
 394
 395 ### If you add support for a new configuration, add code to this
 396 ### switch statement to recognize your configuration name and select
 397 ### the appropriate operating system file.
 398
 399 ### You would hope that you could choose an s/*.h
 400 ### file based on the operating system portion.  However, it turns out
 401 ### that each s/*.h file is pretty manufacturer-specific.
 402 ### So we basically have to have a special case for each
 403 ### configuration name.
 404 ###
 405 ### As far as handling version numbers on operating systems is
 406 ### concerned, make sure things will fail in a fixable way.  If
 407 ### /etc/MACHINES doesn't say anything about version numbers, be
 408 ### prepared to handle anything reasonably.  If version numbers
 409 ### matter, be sure /etc/MACHINES says something about it.
 410
 411 opsys='' unported=no
 412 case "${canonical}" in
 413
 414   ## GNU/Linux and similar ports
 415   *-*-linux* )
 416     opsys=gnu-linux
 417   ;;
 418
 419   ## FreeBSD ports
 420   *-*-freebsd* )
 421     opsys=freebsd
 422   ;;
 423
 424   ## FreeBSD kernel + glibc based userland
 425   *-*-kfreebsd*gnu* )
 426     opsys=gnu-kfreebsd
 427   ;;
 428
 429   ## NetBSD ports
 430   *-*-netbsd* )
 431     opsys=netbsd
 432   ;;
 433
 434   ## OpenBSD ports
 435   *-*-openbsd* )
 436     opsys=openbsd
 437   ;;
 438
 439   ## Apple Darwin / Mac OS X
 440   *-apple-darwin* )
 441     case "${canonical}" in
 442       i[3456]86-* )  ;;
 443       powerpc-* )    ;;
 444       x86_64-* )     ;;
 445       * )            unported=yes ;;
 446     esac
 447     opsys=darwin
 448     ## Use fink packages if available.
 449     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 450 ##    if test -d /sw/include && test -d /sw/lib; then
 451 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 452 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 453 ##    fi
 454   ;;
 455
 456   ## HP 9000 series 700 and 800, running HP/UX
 457   hppa*-hp-hpux10.2* )
 458     opsys=hpux10-20
 459   ;;
 460   hppa*-hp-hpux1[1-9]* )
 461     opsys=hpux11
 462     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 463   ;;
 464
 465   ## IBM machines
 466   rs6000-ibm-aix4.[23]* )
 467     opsys=aix4-2
 468   ;;
 469   powerpc-ibm-aix4.[23]*  )
 470     opsys=aix4-2
 471   ;;
 472   rs6000-ibm-aix[56]* )
 473     opsys=aix4-2
 474   ;;
 475   powerpc-ibm-aix[56]*  )
 476     opsys=aix4-2
 477   ;;
 478
 479   ## Silicon Graphics machines
 480   ## Iris 4D
 481   mips-sgi-irix6.5 )
 482     opsys=irix6-5
 483     # Without defining _LANGUAGE_C, things get masked out in the headers
 484     # so that, for instance, grepping for `free' in stdlib.h fails and
 485     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 486     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 487   ;;
 488
 489   ## Suns
 490   *-sun-solaris* \
 491     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 492     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 493     case "${canonical}" in
 494       i[3456]86-*-* )   ;;
 495       amd64-*-*|x86_64-*-*) ;;
 496       sparc* )          ;;
 497       * )               unported=yes ;;
 498     esac
 499     case "${canonical}" in
 500       *-sunos5.6* | *-solaris2.6* )
 501                 opsys=sol2-6
 502                 RANLIB="ar -ts"
 503                 ;;
 504       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 505                 opsys=sol2-6
 506                 emacs_check_sunpro_c=yes
 507                 ;;
 508       *-sunos5* | *-solaris* )
 509                 opsys=sol2-10
 510                 emacs_check_sunpro_c=yes
 511                 ;;
 512     esac
 513     ## Watch out for a compiler that we know will not work.
 514     case "${canonical}" in
 515      *-solaris* | *-sunos5* )
 516                 if [ "x$CC" = x/usr/ucb/cc ]; then
 517                   ## /usr/ucb/cc doesn't work;
 518                   ## we should find some other compiler that does work.
 519                   unset CC
 520                 fi
 521                 ;;
 522       *) ;;
 523     esac
 524   ;;
 525
 526   ## Intel 386 machines where we don't care about the manufacturer.
 527   i[3456]86-*-* )
 528     case "${canonical}" in
 529       *-cygwin )                opsys=cygwin ;;
 530       *-darwin* )               opsys=darwin ;;
 531       *-sysv4.2uw* )            opsys=unixware ;;
 532       *-sysv5uw* )              opsys=unixware ;;
 533       *-sysv5OpenUNIX* )        opsys=unixware ;;
 534       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 535     esac
 536   ;;
 537
 538   * )
 539     unported=yes
 540   ;;
 541 esac
 542
 543 ### If the code above didn't choose an operating system, just choose
 544 ### an operating system based on the configuration name.  You really
 545 ### only want to use this when you have no idea what the right
 546 ### operating system is; if you know what operating systems a machine
 547 ### runs, it's cleaner to make it explicit in the case statement
 548 ### above.
 549 if test x"${opsys}" = x; then
 550   case "${canonical}" in
 551     *-gnu* )                            opsys=gnu ;;
 552     * )
 553       unported=yes
 554     ;;
 555   esac
 556 fi
 557
 558 ]
 559 dnl quotation ends
 560
 561 if test $unported = yes; then
 562   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 563 Check `etc/MACHINES' for recognized configuration names.])
 564 fi
 565
 566
 567 #### Choose a compiler.
 568
 569 dnl Sets GCC=yes if using gcc.
 570 AC_PROG_CC
 571 AM_PROG_CC_C_O
 572
 573 if test x$GCC = xyes; then
 574   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 575 else
 576   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 577 fi
 578
 579 # Initialize gnulib right after choosing the compiler.
 580 gl_EARLY
 581
 582 # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 583 # if -g3 works and the user does not specify CFLAGS.
 584 # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 585 if test "$ac_test_CFLAGS" != set; then
 586   case $CFLAGS in
 587     '-g')
 588       emacs_g3_CFLAGS='-g3';;
 589     '-g -O2')
 590       emacs_g3_CFLAGS='-g3 -O2';;
 591     *)
 592       emacs_g3_CFLAGS='';;
 593   esac
 594   if test -n "$emacs_g3_CFLAGS"; then
 595     emacs_save_CFLAGS=$CFLAGS
 596     CFLAGS=$emacs_g3_CFLAGS
 597     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 598       [emacs_cv_prog_cc_g3],
 599       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 600          [emacs_cv_prog_cc_g3=yes],
 601          [emacs_cv_prog_cc_g3=no])])
 602     if test $emacs_cv_prog_cc_g3 = yes; then
 603       CFLAGS=$emacs_g3_CFLAGS
 604     else
 605       CFLAGS=$emacs_save_CFLAGS
 606     fi
 607   fi
 608 fi
 609
 610 AC_ARG_ENABLE([gcc-warnings],
 611   [AS_HELP_STRING([--enable-gcc-warnings],
 612                   [turn on lots of GCC warnings. This is intended for
 613                    developers, and may generate false alarms when used
 614                    with older or non-GNU development tools.])],
 615   [case $enableval in
 616      yes|no) ;;
 617      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 618    esac
 619    gl_gcc_warnings=$enableval],
 620   [gl_gcc_warnings=no]
 621 )
 622
 623 AC_ARG_ENABLE(link-time-optimization,
 624 [AS_HELP_STRING([--enable-link-time-optimization],
 625                 [build emacs with link-time optimization.
 626                  This is supported only for GCC since 4.5.0.])],
 627 if test "${enableval}" != "no"; then
 628    AC_MSG_CHECKING([whether link-time optimization is supported])
 629    ac_lto_supported=no
 630    if test x$GCC = xyes; then
 631       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 632       if test x$CPUS != x; then
 633          LTO="-flto=$CPUS"
 634       else
 635          LTO="-flto"
 636       fi
 637       old_CFLAGS=$CFLAGS
 638       CFLAGS="$CFLAGS $LTO"
 639       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 640         [ac_lto_supported=yes], [ac_lto_supported=no])
 641       CFLAGS="$old_CFLAGS"
 642    fi
 643    AC_MSG_RESULT([$ac_lto_supported])
 644    if test "$ac_lto_supported" = "yes"; then
 645       CFLAGS="$CFLAGS $LTO"
 646    fi
 647 fi)
 648
 649 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 650 # ------------------------------------------------
 651 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 652 # Otherwise, run RUN-IF-NOT-FOUND.
 653 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 654   [AC_PREPROC_IFELSE(
 655     [AC_LANG_PROGRAM(
 656       [[
 657 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 658 /* ok */
 659 #else
 660 # error "your version of gcc is older than $1.$2"
 661 #endif
 662       ]]),
 663     ], [$3], [$4])
 664   ]
 665 )
 666
 667 # When compiling with GCC, prefer -isystem to -I when including system
 668 # include files, to avoid generating useless diagnostics for the files.
 669 if test "$gl_gcc_warnings" != yes; then
 670   isystem='-I'
 671 else
 672   isystem='-isystem '
 673
 674   # This, $nw, is the list of warnings we disable.
 675   nw=
 676
 677   case $with_x_toolkit in
 678     lucid | athena | motif)
 679        # Old toolkits mishandle 'const'.
 680        nw="$nw -Wwrite-strings"
 681        ;;
 682     *)
 683        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 684        ;;
 685   esac
 686   AC_SUBST([WERROR_CFLAGS])
 687
 688   nw="$nw -Waggregate-return"       # anachronistic
 689   nw="$nw -Wlong-long"              # C90 is anachronistic
 690   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 691   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 692   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 693   nw="$nw -Wcast-qual"              # Too many warnings for now
 694   nw="$nw -Wconversion"             # Too many warnings for now
 695   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 696   nw="$nw -Wsign-conversion"        # Too many warnings for now
 697   nw="$nw -Woverlength-strings"     # Not a problem these days
 698   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 699   nw="$nw -Wunreachable-code"       # so buggy that it's now silently ignored
 700   nw="$nw -Wpadded"                 # Our structs are not padded
 701   nw="$nw -Wredundant-decls"        # we regularly (re)declare functions
 702   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 703   nw="$nw -Wformat-nonliteral"      # we do this a lot
 704   nw="$nw -Wvla"                    # warnings in gettext.h
 705   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 706   nw="$nw -Wswitch-enum"            # Too many warnings for now
 707   nw="$nw -Wswitch-default"         # Too many warnings for now
 708   nw="$nw -Wfloat-equal"            # warns about high-quality code
 709   nw="$nw -Winline"                 # OK to ignore 'inline'
 710   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 711   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 712   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 713
 714   # Emacs doesn't care about shadowing; see
 715   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 716   nw="$nw -Wshadow"
 717
 718   # The following lines should be removable at some point.
 719   nw="$nw -Wstack-protector"
 720   nw="$nw -Wstrict-overflow"
 721   nw="$nw -Wsuggest-attribute=pure"
 722
 723   gl_MANYWARN_ALL_GCC([ws])
 724   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 725   for w in $ws; do
 726     gl_WARN_ADD([$w])
 727   done
 728   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 729   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 730   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 731   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 732   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 733   gl_WARN_ADD([-Wno-format-nonliteral])
 734
 735   # In spite of excluding -Wlogical-op above, it is enabled, as of
 736   # gcc 4.5.0 20090517.
 737   gl_WARN_ADD([-Wno-logical-op])
 738
 739   gl_WARN_ADD([-fdiagnostics-show-option])
 740   gl_WARN_ADD([-funit-at-a-time])
 741
 742   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 743   AH_VERBATIM([FORTIFY_SOURCE],
 744   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 745       without upsetting glibc 2.15+. */
 746    #if defined __OPTIMIZE__ && __OPTIMIZE__
 747    # define _FORTIFY_SOURCE 2
 748    #endif
 749   ])
 750   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 751
 752   # We use a slightly smaller set of warning options for lib/.
 753   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 754   nw=
 755   nw="$nw -Wunused-macros"
 756
 757   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 758   AC_SUBST([GNULIB_WARN_CFLAGS])
 759 fi
 760
 761
 762
 763 dnl Some other nice autoconf tests.
 764 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 765 dnl AC_PROG_INSTALL
 766 dnl AC_PROG_MKDIR_P
 767 dnl if test "x$RANLIB" = x; then
 768 dnl   AC_PROG_RANLIB
 769 dnl fi
 770 AC_PROG_LN_S
 771
 772 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 773   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 774 dnl Don't use GZIP, which is used by gzip for additional parameters.
 775 AC_PATH_PROG(GZIP_PROG, gzip)
 776
 777 if test $opsys = gnu-linux; then
 778   AC_PATH_PROG(PAXCTL, paxctl,,
 779     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 780   if test "X$PAXCTL" != X; then
 781     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 782     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 783       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 784       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 785   fi
 786 fi
 787
 788 ## Need makeinfo >= 4.7 (?) to build the manuals.
 789 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 790 dnl By this stage, configure has already checked for egrep and set EGREP,
 791 dnl or exited with an error if no egrep was found.
 792 if test "$MAKEINFO" != "no" && \
 793   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 794    MAKEINFO=no
 795 fi
 796
 797 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 798 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 799 ## therefore in the category of "special tools" not normally required, which
 800 ## configure does not have to check for (eg autoconf itself).
 801 ## In a Bazaar checkout on the other hand, the manuals are not included.
 802 ## So makeinfo is a requirement to build from Bazaar, and configure
 803 ## should test for it as it does for any other build requirement.
 804 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 805 ## with pre-built manuals, from a Bazaar checkout.
 806 HAVE_MAKEINFO=yes
 807
 808 if test "$MAKEINFO" = "no"; then
 809   MAKEINFO=makeinfo
 810   if test "x${with_makeinfo}" = "xno"; then
 811     HAVE_MAKEINFO=no
 812   elif test ! -e $srcdir/info/emacs; then
 813     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 814 source tree does not seem to have pre-built manuals in the `info' directory.
 815 Either install a suitable version of makeinfo, or re-run configure
 816 with the `--without-makeinfo' option to build without the manuals.] )
 817   fi
 818 fi
 819 AC_SUBST(HAVE_MAKEINFO)
 820
 821 dnl Just so that there is only a single place we need to edit.
 822 INFO_EXT=.info
 823 INFO_OPTS=--no-split
 824 AC_SUBST(INFO_EXT)
 825 AC_SUBST(INFO_OPTS)
 826
 827 dnl Add our options to ac_link now, after it is set up.
 828
 829 if test x$GCC = xyes; then
 830   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 831     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 832 else
 833   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 834     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 835 fi
 836
 837 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 838 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 839 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 840 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 841 dnl if not built to support GNU ld.
 842
 843 late_LDFLAGS=$LDFLAGS
 844 if test x$GCC = xyes; then
 845   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 846 else
 847   LDFLAGS="$LDFLAGS -znocombreloc"
 848 fi
 849
 850 AC_MSG_CHECKING([for -znocombreloc])
 851 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 852   [AC_MSG_RESULT(yes)],
 853   LDFLAGS=$late_LDFLAGS
 854   [AC_MSG_RESULT(no)])
 855
 856
 857 dnl The function dump-emacs will not be defined and temacs will do
 858 dnl (load "loadup") automatically unless told otherwise.
 859 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 860 case "$opsys" in
 861   your-opsys-here) CANNOT_DUMP=yes ;;
 862 esac
 863
 864 test "$CANNOT_DUMP" = "yes" && \
 865   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 866
 867 AC_SUBST(CANNOT_DUMP)
 868
 869
 870 UNEXEC_OBJ=unexelf.o
 871 case "$opsys" in
 872   # MSDOS uses unexcoff.o
 873   # MSWindows uses unexw32.o
 874   aix4-2)
 875    UNEXEC_OBJ=unexaix.o
 876    ;;
 877   cygwin)
 878    UNEXEC_OBJ=unexcw.o
 879    ;;
 880   darwin)
 881    UNEXEC_OBJ=unexmacosx.o
 882    ;;
 883   hpux10-20 | hpux11)
 884    UNEXEC_OBJ=unexhp9k800.o
 885    ;;
 886   sol2-10)
 887    # Use the Solaris dldump() function, called from unexsol.c, to dump
 888    # emacs, instead of the generic ELF dump code found in unexelf.c.
 889    # The resulting binary has a complete symbol table, and is better
 890    # for debugging and other observability tools (debuggers, pstack, etc).
 891    #
 892    # If you encounter a problem using dldump(), please consider sending
 893    # a message to the OpenSolaris tools-linking mailing list:
 894    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 895    #
 896    # It is likely that dldump() works with older Solaris too, but this has
 897    # not been tested, so for now this change is for Solaris 10 or newer.
 898    UNEXEC_OBJ=unexsol.o
 899    ;;
 900 esac
 901
 902 LD_SWITCH_SYSTEM=
 903 case "$opsys" in
 904   freebsd)
 905    ## Let `ld' find image libs and similar things in /usr/local/lib.
 906    ## The system compiler, GCC, has apparently been modified to not
 907    ## look there, contrary to what a stock GCC would do.
 908 ### It's not our place to do this.  See bug#10313#17.
 909 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 910       :
 911    ;;
 912
 913   gnu-linux)
 914    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 915    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 916    ;;
 917
 918   netbsd)
 919 ### It's not our place to do this.  See bug#10313#17.
 920 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 921       :
 922    ;;
 923
 924   openbsd)
 925    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 926    ## otherwise Emacs dumps core on elf systems.
 927    LD_SWITCH_SYSTEM="-Z"
 928    ;;
 929 esac
 930 AC_SUBST(LD_SWITCH_SYSTEM)
 931
 932 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 933
 934 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 935 ## which has not been defined yet.  When this was handled with cpp,
 936 ## it was expanded to null when configure sourced the s/*.h file.
 937 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 938 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 939 ## (or somesuch), but because it is supposed to go at the _front_
 940 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 941 ## Compare with the gnu-linux case below, which added to the end
 942 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 943 ## LD_SWITCH_SYSTEM_TEMACS.
 944 case "$opsys" in
 945   netbsd|openbsd)
 946    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 947 esac
 948
 949
 950 C_SWITCH_MACHINE=
 951 case $canonical in
 952  alpha*)
 953   AC_CHECK_DECL([__ELF__])
 954   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 955     ## With ELF, make sure that all common symbols get allocated to in the
 956     ## data section.  Otherwise, the dump of temacs may miss variables in
 957     ## the shared library that have been initialized.  For example, with
 958     ## GNU libc, __malloc_initialized would normally be resolved to the
 959     ## shared library's .bss section, which is fatal.
 960     if test "x$GCC" = "xyes"; then
 961       C_SWITCH_MACHINE="-fno-common"
 962     else
 963       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 964     fi
 965   else
 966     UNEXEC_OBJ=unexalpha.o
 967   fi
 968   ;;
 969 esac
 970 AC_SUBST(C_SWITCH_MACHINE)
 971
 972 AC_SUBST(UNEXEC_OBJ)
 973
 974 C_SWITCH_SYSTEM=
 975 ## Some programs in src produce warnings saying certain subprograms
 976 ## are too complex and need a MAXMEM value greater than 2000 for
 977 ## additional optimization.  --nils@exp-math.uni-essen.de
 978 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 979   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 980 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 981 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 982 AC_SUBST(C_SWITCH_SYSTEM)
 983
 984
 985 LIBS_SYSTEM=
 986 case "$opsys" in
 987   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 988   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 989
 990   freebsd) LIBS_SYSTEM="-lutil" ;;
 991
 992   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 993
 994   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 995
 996   ## Motif needs -lgen.
 997   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 998 esac
 999 AC_SUBST(LIBS_SYSTEM)
1000
1001
1002 ### Make sure subsequent tests use flags consistent with the build flags.
1003
1004 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1005   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1006 else
1007   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1008 fi
1009
1010 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1011 AC_DEFUN([AC_TYPE_SIZE_T])
1012 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1013 AC_DEFUN([AC_TYPE_UID_T])
1014
1015
1016 LIB_MATH=-lm
1017 LIB_STANDARD=
1018 START_FILES=
1019 dnl Current possibilities handled by sed (aix4-2 -> aix,
1020 dnl gnu-linux -> gnu/linux, etc.):
1021 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1022 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1023 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1024
1025 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
1026 case $opsys in
1027   cygwin )
1028     LIB_MATH=
1029     START_FILES='pre-crt0.o'
1030     ;;
1031   darwin )
1032     ## Adding -lm confuses the dynamic linker, so omit it.
1033     LIB_MATH=
1034     START_FILES='pre-crt0.o'
1035     ;;
1036   freebsd )
1037     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1038     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1039     SYSTEM_TYPE=berkeley-unix
1040     ;;
1041   gnu-linux | gnu-kfreebsd )
1042     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1043     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1044     ;;
1045   hpux10-20 | hpux11 )
1046     LIB_STANDARD=-lc
1047     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1048     ;;
1049   dnl NB this may be adjusted below.
1050   netbsd | openbsd )
1051     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1052     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1053     SYSTEM_TYPE=berkeley-unix
1054     ;;
1055
1056   sol2* | unixware )
1057     SYSTEM_TYPE=usg-unix-v
1058     ;;
1059
1060 esac
1061
1062 AC_SUBST(LIB_MATH)
1063 AC_SUBST(START_FILES)
1064 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1065   [The type of system you are compiling for; sets `system-type'.])
1066
1067 dnl Not all platforms use crtn.o files.  Check if the current one does.
1068 crt_files=
1069
1070 for file in x $LIB_STANDARD $START_FILES; do
1071   case "$file" in
1072     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1073   esac
1074 done
1075
1076 if test "x$crt_files" != x; then
1077
1078   ## If user specified a crt-dir, use that unconditionally.
1079   crt_gcc=no
1080
1081   if test "X$CRT_DIR" = "X"; then
1082
1083     CRT_DIR=/usr/lib            # default
1084
1085     case "$canonical" in
1086       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1087       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1088       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1089       ## For anything else (eg /usr/lib32), it is up the user to specify
1090       ## the location (bug#5655).
1091       ## Test for crtn.o, not just the directory, because sometimes the
1092       ## directory exists but does not have the relevant files (bug#1287).
1093       ## FIXME better to test for binary compatibility somehow.
1094       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1095       ;;
1096
1097       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1098     esac
1099
1100     case "$opsys" in
1101       hpux10-20) CRT_DIR=/lib ;;
1102     esac
1103
1104     test "x${GCC}" = xyes && crt_gcc=yes
1105
1106   fi                            # CRT_DIR = ""
1107
1108   crt_missing=
1109
1110   for file in $crt_files; do
1111
1112     ## If we're using gcc, try to determine it automatically by asking
1113     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1114     ## system-dependent default from above.]
1115     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1116
1117        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1118        case "$crt_file" in
1119          */*)
1120            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1121            ;;
1122        esac
1123     fi
1124
1125     dnl We expect all the files to be in a single directory, so after the
1126     dnl first there is no point asking gcc.
1127     crt_gcc=no
1128
1129     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1130   done                          # $crt_files
1131
1132   test "x$crt_missing" = x || \
1133     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1134 Try using the --with-crt-dir option.])
1135
1136 fi                              # crt_files != ""
1137
1138 AC_SUBST(CRT_DIR)
1139
1140 case $opsys in
1141   netbsd | openbsd )
1142     if test -f $CRT_DIR/crti.o; then
1143
1144         test -f $CRT_DIR/crtn.o || \
1145           AC_MSG_ERROR([Required file not found: crtn.o])
1146
1147         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1148         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1149     fi
1150     ;;
1151 esac
1152
1153
1154 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1155 pre_PKG_CONFIG_LIBS=$LIBS
1156
1157 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1158
1159 dnl This function definition taken from Gnome 2.0
1160 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1161 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1162 dnl also defines GSTUFF_PKG_ERRORS on error
1163 AC_DEFUN([PKG_CHECK_MODULES], [
1164   succeeded=no
1165
1166   if test "$PKG_CONFIG" = "no" ; then
1167      ifelse([$4], , [AC_MSG_ERROR([
1168       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1169   else
1170      PKG_CONFIG_MIN_VERSION=0.9.0
1171      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1172         AC_MSG_CHECKING(for $2)
1173
1174         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1175            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1176            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1177             edit_cflags="
1178               s,///*,/,g
1179               s/^/ /
1180               s/ -I/ $isystem/g
1181               s/^ //
1182             "
1183             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1184             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1185             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1186             succeeded=yes
1187         else
1188             AC_MSG_RESULT(no)
1189             $1_CFLAGS=""
1190             $1_LIBS=""
1191             ## If we have a custom action on failure, don't print errors, but
1192             ## do set a variable so people can do so.
1193             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1194             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1195         fi
1196
1197         AC_SUBST($1_CFLAGS)
1198         AC_SUBST($1_LIBS)
1199      else
1200         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1201         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1202      fi
1203   fi
1204
1205   if test $succeeded = yes; then
1206      ifelse([$3], , :, [$3])
1207   else
1208      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1209   fi
1210 ])
1211
1212
1213 if test "${with_sound}" != "no"; then
1214   # Sound support for GNU/Linux and the free BSDs.
1215   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1216     have_sound_header=yes)
1217   # Emulation library used on NetBSD.
1218   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1219   AC_SUBST(LIBSOUND)
1220
1221   ALSA_REQUIRED=1.0.0
1222   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1223   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1224   if test $HAVE_ALSA = yes; then
1225     SAVE_CFLAGS="$CFLAGS"
1226     SAVE_LIBS="$LIBS"
1227     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1228     LIBS="$ALSA_LIBS $LIBS"
1229     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1230                     emacs_alsa_normal=yes,
1231                     emacs_alsa_normal=no)
1232     if test "$emacs_alsa_normal" != yes; then
1233       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1234                      [[snd_lib_error_set_handler (0);]])],
1235                      emacs_alsa_subdir=yes,
1236                      emacs_alsa_subdir=no)
1237       if test "$emacs_alsa_subdir" != yes; then
1238         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1239       fi
1240       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1241     fi
1242
1243     CFLAGS="$SAVE_CFLAGS"
1244     LIBS="$SAVE_LIBS"
1245     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1246     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1247     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1248   fi
1249
1250   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1251   dnl compiles only on the specified platforms.  For others, it
1252   dnl probably doesn't make sense to try.
1253   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1254      case "$opsys" in
1255        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1256        gnu-linux|freebsd|netbsd)
1257          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1258          ;;
1259      esac
1260   fi
1261
1262   AC_SUBST(CFLAGS_SOUND)
1263 fi
1264
1265 dnl checks for header files
1266 AC_CHECK_HEADERS_ONCE(
1267   linux/version.h sys/systeminfo.h
1268   stdio_ext.h fcntl.h coff.h pty.h
1269   sys/vlimit.h sys/resource.h
1270   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1271
1272 AC_MSG_CHECKING(if personality LINUX32 can be set)
1273 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1274                emacs_cv_personality_linux32=yes,
1275                emacs_cv_personality_linux32=no)
1276 AC_MSG_RESULT($emacs_cv_personality_linux32)
1277
1278 if test $emacs_cv_personality_linux32 = yes; then
1279   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1280             [Define to 1 if personality LINUX32 can be set.])
1281 fi
1282
1283 dnl On Solaris 8 there's a compilation warning for term.h because
1284 dnl it doesn't define `bool'.
1285 AC_CHECK_HEADERS(term.h, , , -)
1286 AC_HEADER_TIME
1287 AC_CHECK_DECLS([sys_siglist])
1288 if test $ac_cv_have_decl_sys_siglist != yes; then
1289   # For Tru64, at least:
1290   AC_CHECK_DECLS([__sys_siglist])
1291   if test $ac_cv_have_decl___sys_siglist = yes; then
1292     AC_DEFINE(sys_siglist, __sys_siglist,
1293               [Define to any substitute for sys_siglist.])
1294   fi
1295 fi
1296 AC_HEADER_SYS_WAIT
1297
1298 dnl Check for speed_t typedef.
1299 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1300   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1301     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1302 if test $emacs_cv_speed_t = yes; then
1303   AC_DEFINE(HAVE_SPEED_T, 1,
1304            [Define to 1 if `speed_t' is declared by <termios.h>.])
1305 fi
1306
1307 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1308 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1309 #if HAVE_SYS_SOCKET_H
1310 #include <sys/socket.h>
1311 #endif])
1312 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1313 #if HAVE_SYS_SOCKET_H
1314 #include <sys/socket.h>
1315 #endif])
1316 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1317 #if HAVE_SYS_SOCKET_H
1318 #include <sys/socket.h>
1319 #endif])
1320
1321 dnl checks for structure members
1322 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1323                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1324                   struct ifreq.ifr_addr,
1325                   struct ifreq.ifr_addr.sa_len], , ,
1326                  [AC_INCLUDES_DEFAULT
1327 #if HAVE_SYS_SOCKET_H
1328 #include <sys/socket.h>
1329 #endif
1330 #if HAVE_NET_IF_H
1331 #include <net/if.h>
1332 #endif])
1333
1334 dnl Check for endianness.
1335 dnl AC_C_BIGENDIAN is done by gnulib.
1336
1337 dnl check for Make feature
1338 dnl AC_PROG_MAKE_SET is done by Automake.
1339
1340 DEPFLAGS=
1341 MKDEPDIR=":"
1342 deps_frag=deps.mk
1343 dnl check for GNU Make if we have GCC and autodepend is on.
1344 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1345    AC_MSG_CHECKING([whether we are using GNU Make])
1346    HAVE_GNU_MAKE=no
1347    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1348    if test "x$testval" != x; then
1349       HAVE_GNU_MAKE=yes
1350    else
1351       ac_enable_autodepend=no
1352    fi
1353    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1354    if test $HAVE_GNU_MAKE = yes; then
1355       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1356       SAVE_CFLAGS="$CFLAGS"
1357       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1358       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1359       CFLAGS="$SAVE_CFLAGS"
1360       test -f deps.d || ac_enable_autodepend=no
1361       rm -rf deps.d
1362       AC_MSG_RESULT([$ac_enable_autodepend])
1363    fi
1364    if test $ac_enable_autodepend = yes; then
1365       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1366       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1367       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1368       deps_frag=autodeps.mk
1369    fi
1370 fi
1371 deps_frag=$srcdir/src/$deps_frag
1372 AC_SUBST(MKDEPDIR)
1373 AC_SUBST(DEPFLAGS)
1374 AC_SUBST_FILE(deps_frag)
1375
1376
1377 lisp_frag=$srcdir/src/lisp.mk
1378 AC_SUBST_FILE(lisp_frag)
1379
1380
1381 dnl checks for operating system services
1382 AC_SYS_LONG_FILE_NAMES
1383
1384 #### Choose a window system.
1385
1386 ## We leave window_system equal to none if
1387 ## we end up building without one.  Any new window system should
1388 ## set window_system to an appropriate value and add objects to
1389 ## window-system-specific substs.
1390
1391 window_system=none
1392 AC_PATH_X
1393 if test "$no_x" != yes; then
1394   window_system=x11
1395 fi
1396
1397 LD_SWITCH_X_SITE_RPATH=
1398 if test "${x_libraries}" != NONE; then
1399   if test -n "${x_libraries}"; then
1400     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1401     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1402   fi
1403   x_default_search_path=""
1404   x_search_path=${x_libraries}
1405   if test -z "${x_search_path}"; then
1406     x_search_path=/usr/lib
1407   fi
1408   for x_library in `echo ${x_search_path}: | \
1409                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1410     x_search_path="\
1411 ${x_library}/X11/%L/%T/%N%C%S:\
1412 ${x_library}/X11/%l/%T/%N%C%S:\
1413 ${x_library}/X11/%T/%N%C%S:\
1414 ${x_library}/X11/%L/%T/%N%S:\
1415 ${x_library}/X11/%l/%T/%N%S:\
1416 ${x_library}/X11/%T/%N%S"
1417     if test x"${x_default_search_path}" = x; then
1418       x_default_search_path=${x_search_path}
1419     else
1420       x_default_search_path="${x_search_path}:${x_default_search_path}"
1421     fi
1422   done
1423 fi
1424 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1425
1426 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1427   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1428 fi
1429
1430 if test x"${x_includes}" = x; then
1431   bitmapdir=/usr/include/X11/bitmaps
1432 else
1433   # accumulate include directories that have X11 bitmap subdirectories
1434   bmd_acc="dummyval"
1435   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1436     if test -d "${bmd}/X11/bitmaps"; then
1437       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1438     fi
1439     if test -d "${bmd}/bitmaps"; then
1440       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1441     fi
1442   done
1443   if test ${bmd_acc} != "dummyval"; then
1444     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1445   fi
1446 fi
1447
1448 HAVE_NS=no
1449 NS_IMPL_COCOA=no
1450 NS_IMPL_GNUSTEP=no
1451 tmp_CPPFLAGS="$CPPFLAGS"
1452 tmp_CFLAGS="$CFLAGS"
1453 CPPFLAGS="$CPPFLAGS -x objective-c"
1454 CFLAGS="$CFLAGS -x objective-c"
1455 TEMACS_LDFLAGS2="\${LDFLAGS}"
1456 GNU_OBJC_CFLAGS=
1457 if test "${with_ns}" != no; then
1458   if test "${opsys}" = darwin; then
1459      NS_IMPL_COCOA=yes
1460      ns_appdir=`pwd`/nextstep/Emacs.app
1461      ns_appbindir=${ns_appdir}/Contents/MacOS
1462      ns_appresdir=${ns_appdir}/Contents/Resources
1463      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1464   elif test -f $GNUSTEP_CONFIG_FILE; then
1465      NS_IMPL_GNUSTEP=yes
1466      ns_appdir=`pwd`/nextstep/Emacs.app
1467      ns_appbindir=${ns_appdir}
1468      ns_appresdir=${ns_appdir}/Resources
1469      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1470      dnl FIXME sourcing this several times in subshells seems inefficient.
1471      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1472      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1473      dnl I seemed to need these as well with GNUstep-startup 0.25.
1474      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1475      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1476      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1477        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1478      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1479        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1480      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1481      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1482      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1483      LIB_STANDARD=
1484      START_FILES=
1485      TEMACS_LDFLAGS2=
1486      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1487      dnl If they had chosen to either define it or not, we could have
1488      dnl just used AC_CHECK_DECL here.
1489      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1490        emacs_cv_objc_exceptions,
1491 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1492 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1493 1;
1494 #else
1495 fail;
1496 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1497      if test $emacs_cv_objc_exceptions = yes; then
1498        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1499        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1500          [Define if GNUstep uses ObjC exceptions.])
1501        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1502      fi
1503   fi
1504
1505   dnl This is only used while we test the NS headers, it gets reset below.
1506   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1507
1508   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1509                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1510   files are missing or cannot be compiled.])])
1511   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1512                                      [NSInteger i;])],
1513                     ns_have_nsinteger=yes,
1514                     ns_have_nsinteger=no)
1515   if test $ns_have_nsinteger = yes; then
1516     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1517   fi
1518 fi
1519 AC_SUBST(TEMACS_LDFLAGS2)
1520
1521 INSTALL_ARCH_INDEP_EXTRA=install-etc
1522 ns_self_contained=no
1523 ns_frag=/dev/null
1524 NS_OBJ=
1525 NS_OBJC_OBJ=
1526 if test "${HAVE_NS}" = yes; then
1527   if test "$with_toolkit_scroll_bars" = "no"; then
1528     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1529   fi
1530
1531   window_system=nextstep
1532   # set up packaging dirs
1533   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1534      ns_self_contained=yes
1535      prefix=${ns_appresdir}
1536      exec_prefix=${ns_appbindir}
1537      dnl This one isn't really used, only archlibdir is.
1538      libexecdir="\${ns_appbindir}/libexec"
1539      archlibdir="\${ns_appbindir}/libexec"
1540      docdir="\${ns_appresdir}/etc"
1541      etcdir="\${ns_appresdir}/etc"
1542      dnl FIXME maybe set datarootdir instead.
1543      dnl That would also get applications, icons, man.
1544      infodir="\${ns_appresdir}/info"
1545      mandir="\${ns_appresdir}/man"
1546      lispdir="\${ns_appresdir}/lisp"
1547      leimdir="\${ns_appresdir}/leim"
1548      INSTALL_ARCH_INDEP_EXTRA=
1549   fi
1550   ns_frag=$srcdir/src/ns.mk
1551   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1552 fi
1553 CFLAGS="$tmp_CFLAGS"
1554 CPPFLAGS="$tmp_CPPFLAGS"
1555 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1556 AC_SUBST(ns_self_contained)
1557 AC_SUBST(NS_OBJ)
1558 AC_SUBST(NS_OBJC_OBJ)
1559 AC_SUBST(LIB_STANDARD)
1560 AC_SUBST_FILE(ns_frag)
1561
1562 ## $window_system is now set to the window system we will
1563 ## ultimately use.
1564
1565 term_header=
1566 HAVE_X_WINDOWS=no
1567 HAVE_X11=no
1568 USE_X_TOOLKIT=none
1569
1570 case "${window_system}" in
1571   x11 )
1572     HAVE_X_WINDOWS=yes
1573     HAVE_X11=yes
1574     term_header=xterm.h
1575     case "${with_x_toolkit}" in
1576       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1577       motif ) USE_X_TOOLKIT=MOTIF ;;
1578       gtk ) with_gtk=yes
1579             term_header=gtkutil.h
1580 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1581 dnl USE_X_TOOLKIT is set.
1582             USE_X_TOOLKIT=none ;;
1583       gtk2 ) with_gtk2=yes
1584              term_header=gtkutil.h
1585              USE_X_TOOLKIT=none ;;
1586       gtk3 ) with_gtk3=yes
1587              term_header=gtkutil.h
1588              USE_X_TOOLKIT=none ;;
1589       no ) USE_X_TOOLKIT=none ;;
1590 dnl If user did not say whether to use a toolkit, make this decision later:
1591 dnl use the toolkit if we have gtk, or X11R5 or newer.
1592       * ) USE_X_TOOLKIT=maybe ;;
1593     esac
1594   ;;
1595   nextstep )
1596     term_header=nsterm.h
1597   ;;
1598 esac
1599
1600 if test -n "${term_header}"; then
1601     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
1602         [Define to the header for the built-in window system.])
1603 fi
1604
1605 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1606    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1607    if test "$HAVE_XSERVER" = true ||
1608       test -n "$DISPLAY" ||
1609       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1610         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1611 were found.  You should install the relevant development files for X
1612 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1613 sure you have development files for image handling, i.e.
1614 tiff, gif, jpeg, png and xpm.
1615 If you are sure you want Emacs compiled without X window support, pass
1616   --without-x
1617 to configure.])
1618    fi
1619 fi
1620
1621 ### If we're using X11, we should use the X menu package.
1622 HAVE_MENUS=no
1623 case ${HAVE_X11} in
1624   yes ) HAVE_MENUS=yes ;;
1625 esac
1626
1627 # Does the opsystem file prohibit the use of the GNU malloc?
1628 # Assume not, until told otherwise.
1629 GNU_MALLOC=yes
1630
1631 AC_CACHE_CHECK(
1632   [whether malloc is Doug Lea style],
1633   [emacs_cv_var_doug_lea_malloc],
1634   [AC_LINK_IFELSE(
1635      [AC_LANG_PROGRAM(
1636         [[#include <malloc.h>
1637           static void hook (void) {}]],
1638         [[malloc_set_state (malloc_get_state ());
1639           __after_morecore_hook = hook;
1640           __malloc_initialize_hook = hook;]])],
1641      [emacs_cv_var_doug_lea_malloc=yes],
1642      [emacs_cv_var_doug_lea_malloc=no])])
1643 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1644
1645
1646 dnl See comments in aix4-2.h about maybe using system malloc there.
1647 system_malloc=no
1648 case "$opsys" in
1649   ## darwin ld insists on the use of malloc routines in the System framework.
1650   darwin|sol2-10) system_malloc=yes ;;
1651 esac
1652
1653 if test "${system_malloc}" = "yes"; then
1654   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1655   GNU_MALLOC=no
1656   GNU_MALLOC_reason="
1657     (The GNU allocators don't work with this system configuration.)"
1658   GMALLOC_OBJ=
1659   VMLIMIT_OBJ=
1660 else
1661   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1662   VMLIMIT_OBJ=vm-limit.o
1663 fi
1664 AC_SUBST(GMALLOC_OBJ)
1665 AC_SUBST(VMLIMIT_OBJ)
1666
1667 if test "$doug_lea_malloc" = "yes" ; then
1668   if test "$GNU_MALLOC" = yes ; then
1669     GNU_MALLOC_reason="
1670       (Using Doug Lea's new malloc from the GNU C Library.)"
1671   fi
1672   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1673             [Define to 1 if you are using the GNU C Library.])
1674
1675   ## Use mmap directly for allocating larger buffers.
1676   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1677   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1678   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1679   case "$opsys" in
1680     gnu*) REL_ALLOC=no ;;
1681   esac
1682 fi
1683
1684 if test x"${REL_ALLOC}" = x; then
1685   REL_ALLOC=${GNU_MALLOC}
1686 fi
1687
1688 use_mmap_for_buffers=no
1689 case "$opsys" in
1690   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1691 esac
1692
1693 AC_FUNC_MMAP
1694 if test $use_mmap_for_buffers = yes; then
1695   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1696   REL_ALLOC=no
1697 fi
1698
1699 LIBS="$LIBS_SYSTEM $LIBS"
1700
1701 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1702 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1703 AC_CHECK_LIB(dnet, dnet_ntoa)
1704 dnl This causes -lresolv to get used in subsequent tests,
1705 dnl which causes failures on some systems such as HPUX 9.
1706 dnl AC_CHECK_LIB(resolv, gethostbyname)
1707
1708 dnl FIXME replace main with a function we actually want from this library.
1709 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1710
1711 dnl Check if pthreads is available.
1712 LIB_PTHREAD=
1713 AC_CHECK_HEADERS_ONCE(pthread.h)
1714 if test "$ac_cv_header_pthread_h"; then
1715   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1716   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1717   dnl testing for pthread_self if Emacs uses gmalloc.c.
1718   if test "$GMALLOC_OBJ" = gmalloc.o; then
1719     emacs_pthread_function=pthread_atfork
1720   else
1721     emacs_pthread_function=pthread_self
1722   fi
1723   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1724 fi
1725 if test "$HAVE_PTHREAD" = yes; then
1726   case "${canonical}" in
1727     *-hpux*) ;;
1728     *) LIB_PTHREAD="-lpthread"
1729        LIBS="$LIB_PTHREAD $LIBS" ;;
1730   esac
1731   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1732 fi
1733 AC_SUBST([LIB_PTHREAD])
1734
1735 AC_CHECK_LIB(pthreads, cma_open)
1736
1737 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1738 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1739 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1740 ## added to LIBS in configure would never contain the pthreads part,
1741 ## but the value used in Makefiles might.  FIXME?
1742 ##
1743 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1744 ## be harmless on older versions of X where it happens to exist.
1745 test "$opsys" = "aix4-2" && \
1746   test $ac_cv_lib_pthreads_cma_open = yes && \
1747   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1748
1749 dnl Check for need for bigtoc support on IBM AIX
1750
1751 case ${host_os} in
1752 aix*)
1753   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1754     case $GCC in
1755     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1756     *) gdb_cv_bigtoc=-bbigtoc ;;
1757     esac
1758
1759     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1760     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1761   ])
1762   ;;
1763 esac
1764
1765 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1766 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1767 # REAL_CPPFLAGS later on.
1768
1769 REAL_CFLAGS="$CFLAGS"
1770 REAL_CPPFLAGS="$CPPFLAGS"
1771
1772 if test "${HAVE_X11}" = "yes"; then
1773   DEFS="$C_SWITCH_X_SITE $DEFS"
1774   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1775   LIBS="-lX11 $LIBS"
1776   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1777   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1778
1779   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1780   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1781   # but it's more convenient here to set LD_RUN_PATH since this
1782   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1783   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1784     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1785     export LD_RUN_PATH
1786   fi
1787
1788   if test "${opsys}" = "gnu-linux"; then
1789     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1790     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1791      [[XOpenDisplay ("foo");]])],
1792      [xgnu_linux_first_failure=no],
1793      [xgnu_linux_first_failure=yes])
1794     if test "${xgnu_linux_first_failure}" = "yes"; then
1795       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1796       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1797       OLD_CPPFLAGS="$CPPFLAGS"
1798       OLD_LIBS="$LIBS"
1799       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1800       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1801       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1802       LIBS="$LIBS -b i486-linuxaout"
1803       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1804        [[XOpenDisplay ("foo");]])],
1805        [xgnu_linux_second_failure=no],
1806        [xgnu_linux_second_failure=yes])
1807       if test "${xgnu_linux_second_failure}" = "yes"; then
1808         # If we get the same failure with -b, there is no use adding -b.
1809         # So take it out.  This plays safe.
1810         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1811         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1812         CPPFLAGS="$OLD_CPPFLAGS"
1813         LIBS="$OLD_LIBS"
1814         AC_MSG_RESULT(no)
1815       else
1816         AC_MSG_RESULT(yes)
1817       fi
1818     else
1819       AC_MSG_RESULT(no)
1820     fi
1821   fi
1822
1823   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1824   # header files included from there.
1825   AC_MSG_CHECKING(for Xkb)
1826   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1827 #include <X11/XKBlib.h>]],
1828         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1829         emacs_xkb=yes, emacs_xkb=no)
1830   AC_MSG_RESULT($emacs_xkb)
1831   if test $emacs_xkb = yes; then
1832     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1833   fi
1834
1835   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1836 XScreenNumberOfScreen)
1837 fi
1838
1839 if test "${window_system}" = "x11"; then
1840   AC_MSG_CHECKING(X11 version 6)
1841   AC_CACHE_VAL(emacs_cv_x11_version_6,
1842   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1843 [[#if XlibSpecificationRelease < 6
1844 fail;
1845 #endif
1846 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1847   if test $emacs_cv_x11_version_6 = yes; then
1848     AC_MSG_RESULT(6 or newer)
1849     AC_DEFINE(HAVE_X11R6, 1,
1850               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1851     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1852     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1853     ## XIM support.
1854     case "$opsys" in
1855       sol2-*) : ;;
1856       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1857            [Define if you have usable X11R6-style XIM support.])
1858          ;;
1859     esac
1860   else
1861     AC_MSG_RESULT(before 6)
1862   fi
1863 fi
1864
1865
1866 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1867 HAVE_RSVG=no
1868 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1869   if test "${with_rsvg}" != "no"; then
1870     RSVG_REQUIRED=2.11.0
1871     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1872
1873     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1874     AC_SUBST(RSVG_CFLAGS)
1875     AC_SUBST(RSVG_LIBS)
1876
1877     if test $HAVE_RSVG = yes; then
1878       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1879       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1880       LIBS="$RSVG_LIBS $LIBS"
1881     fi
1882   fi
1883 fi
1884
1885 HAVE_IMAGEMAGICK=no
1886 if test "${HAVE_X11}" = "yes"; then
1887   if test "${with_imagemagick}" != "no"; then
1888     ## 6.2.8 is the earliest version known to work, but earlier versions
1889     ## might work - let us know if you find one.
1890     ## 6.0.7 does not work.  See bug#7955.
1891     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1892     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1893     AC_SUBST(IMAGEMAGICK_CFLAGS)
1894     AC_SUBST(IMAGEMAGICK_LIBS)
1895
1896     if test $HAVE_IMAGEMAGICK = yes; then
1897       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1898       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1899       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1900       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1901     fi
1902   fi
1903 fi
1904
1905
1906 HAVE_GTK=no
1907 GTK_OBJ=
1908 check_gtk2=no
1909 gtk3_pkg_errors=
1910 if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1911   GLIB_REQUIRED=2.28
1912   GTK_REQUIRED=3.0
1913   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1914
1915   dnl Checks for libraries.
1916   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1917   if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
1918      AC_MSG_ERROR($GTK_PKG_ERRORS)
1919   fi
1920   if test "$pkg_check_gtk" = "yes"; then
1921      AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1922      GTK_OBJ=emacsgtkfixed.o
1923      term_header=gtkutil.h
1924   else
1925      check_gtk2=yes
1926      gtk3_pkg_errors="$GTK_PKG_ERRORS "
1927   fi
1928 fi
1929
1930 if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
1931   GLIB_REQUIRED=2.10
1932   GTK_REQUIRED=2.10
1933   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1934
1935   dnl Checks for libraries.
1936   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1937   if test "$pkg_check_gtk" = "no"; then
1938      if test "$USE_X_TOOLKIT" = "maybe" || test "$with_gtk" = "yes" || test "$with_gtk2" = "yes"; then
1939         AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
1940      fi
1941   fi
1942 fi
1943
1944 if test x"$pkg_check_gtk" = xyes; then
1945
1946   AC_SUBST(GTK_CFLAGS)
1947   AC_SUBST(GTK_LIBS)
1948   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1949   CFLAGS="$CFLAGS $GTK_CFLAGS"
1950   LIBS="$GTK_LIBS $LIBS"
1951   dnl Try to compile a simple GTK program.
1952   GTK_COMPILES=no
1953   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1954   if test "${GTK_COMPILES}" != "yes"; then
1955     if test "$USE_X_TOOLKIT" != "maybe"; then
1956       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1957     fi
1958   else
1959     HAVE_GTK=yes
1960     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1961     GTK_OBJ="gtkutil.o $GTK_OBJ"
1962     USE_X_TOOLKIT=none
1963     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1964       :
1965     else
1966       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1967        closing open displays.  This is no problem if you just use
1968        one display, but if you use more than one and close one of them
1969        Emacs may crash.]])
1970       sleep 3
1971     fi
1972   fi
1973
1974 fi
1975 AC_SUBST(GTK_OBJ)
1976
1977
1978 if test "${HAVE_GTK}" = "yes"; then
1979
1980   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1981   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1982   if test "$with_toolkit_scroll_bars" != no; then
1983     with_toolkit_scroll_bars=yes
1984   fi
1985
1986   dnl  Check if we have the old file selection dialog declared and
1987   dnl  in the link library.  In 2.x it may be in the library,
1988   dnl  but not declared if deprecated featured has been selected out.
1989   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1990   HAVE_GTK_FILE_SELECTION=no
1991   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1992                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1993 #include <gtk/gtk.h>])
1994   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1995     AC_CHECK_FUNCS(gtk_file_selection_new)
1996   fi
1997
1998
1999   dnl Check for functions introduced in 2.14 and later.
2000   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2001                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2002                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2003                  gtk_orientable_set_orientation \
2004                  gtk_window_set_has_resize_grip)
2005
2006  term_header=gtkutil.h
2007 fi
2008
2009 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2010 dnl other platforms.
2011 HAVE_DBUS=no
2012 DBUS_OBJ=
2013 if test "${with_dbus}" = "yes"; then
2014    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2015    if test "$HAVE_DBUS" = yes; then
2016      LIBS="$LIBS $DBUS_LIBS"
2017      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2018      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2019      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2020      dnl D-Bus 1.5.12.
2021      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2022                     dbus_type_is_valid \
2023                     dbus_validate_bus_name \
2024                     dbus_validate_path \
2025                     dbus_validate_interface \
2026                     dbus_validate_member)
2027      DBUS_OBJ=dbusbind.o
2028    fi
2029 fi
2030 AC_SUBST(DBUS_OBJ)
2031
2032 dnl GSettings has been tested under GNU/Linux only.
2033 HAVE_GSETTINGS=no
2034 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2035    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2036    if test "$HAVE_GSETTINGS" = "yes"; then
2037       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2038       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2039       SETTINGS_LIBS="$GSETTINGS_LIBS"
2040    fi
2041 fi
2042
2043 dnl GConf has been tested under GNU/Linux only.
2044 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2045 HAVE_GCONF=no
2046 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2047    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2048    if test "$HAVE_GCONF" = yes; then
2049       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2050       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2051       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2052       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2053    fi
2054 fi
2055
2056 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2057     PKG_CHECK_MODULES(GOBJECT, gobject-2.0 >= 2.0, HAVE_GOBJECT=yes, HAVE_GOBJECT=no)
2058     if test "$HAVE_GOBJECT" = "yes"; then
2059        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2060        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2061     fi
2062     SAVE_CFLAGS="$CFLAGS"
2063     SAVE_LIBS="$LIBS"
2064     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2065     LIBS="$SETTINGS_LIBS $LIBS"
2066     AC_CHECK_FUNCS([g_type_init])
2067     CFLAGS="$SAVE_CFLAGS"
2068     LIBS="$SAVE_LIBS"
2069 fi
2070 AC_SUBST(SETTINGS_CFLAGS)
2071 AC_SUBST(SETTINGS_LIBS)
2072
2073
2074 dnl SELinux is available for GNU/Linux only.
2075 HAVE_LIBSELINUX=no
2076 LIBSELINUX_LIBS=
2077 if test "${with_selinux}" = "yes"; then
2078    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2079    if test "$HAVE_LIBSELINUX" = yes; then
2080       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2081       LIBSELINUX_LIBS=-lselinux
2082    fi
2083 fi
2084 AC_SUBST(LIBSELINUX_LIBS)
2085
2086 HAVE_GNUTLS=no
2087 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2088 if test "${with_gnutls}" = "yes" ; then
2089   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2090   if test "${HAVE_GNUTLS}" = "yes"; then
2091     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2092   fi
2093
2094   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2095   LIBS="$LIBGNUTLS_LIBS $LIBS"
2096   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2097
2098   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2099     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2100   fi
2101 fi
2102
2103 AC_SUBST(LIBGNUTLS_LIBS)
2104 AC_SUBST(LIBGNUTLS_CFLAGS)
2105
2106 dnl Do not put whitespace before the #include statements below.
2107 dnl Older compilers (eg sunos4 cc) choke on it.
2108 HAVE_XAW3D=no
2109 LUCID_LIBW=
2110 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2111   if test "$with_xaw3d" != no; then
2112     AC_CACHE_VAL(emacs_cv_xaw3d,
2113     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2114 #include <X11/Intrinsic.h>
2115 #include <X11/Xaw3d/Simple.h>]],
2116       [[]])],
2117       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2118                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2119       emacs_cv_xaw3d=no)])
2120   else
2121     emacs_cv_xaw3d=no
2122   fi
2123   if test $emacs_cv_xaw3d = yes; then
2124     AC_MSG_CHECKING(for xaw3d)
2125     AC_MSG_RESULT([yes; using Lucid toolkit])
2126     USE_X_TOOLKIT=LUCID
2127     HAVE_XAW3D=yes
2128     LUCID_LIBW=-lXaw3d
2129     AC_DEFINE(HAVE_XAW3D, 1,
2130               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2131   else
2132     AC_MSG_CHECKING(for xaw3d)
2133     AC_MSG_RESULT(no)
2134     AC_MSG_CHECKING(for libXaw)
2135     AC_CACHE_VAL(emacs_cv_xaw,
2136     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2137 #include <X11/Intrinsic.h>
2138 #include <X11/Xaw/Simple.h>]],
2139       [[]])],
2140       emacs_cv_xaw=yes,
2141       emacs_cv_xaw=no)])
2142     if test $emacs_cv_xaw = yes; then
2143       AC_MSG_RESULT([yes; using Lucid toolkit])
2144       USE_X_TOOLKIT=LUCID
2145       LUCID_LIBW=-lXaw
2146     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2147       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2148     else
2149       AC_MSG_ERROR([No X toolkit could be found.
2150 If you are sure you want Emacs compiled without an X toolkit, pass
2151   --with-x-toolkit=no
2152 to configure.  Otherwise, install the development libraries for the toolkit
2153 that you want to use (e.g. Gtk+) and re-run configure.])
2154     fi
2155   fi
2156 fi
2157
2158 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2159
2160 LIBXTR6=
2161 if test "${USE_X_TOOLKIT}" != "none"; then
2162   AC_MSG_CHECKING(X11 toolkit version)
2163   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2164   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2165 [[#if XtSpecificationRelease < 6
2166 fail;
2167 #endif
2168 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2169   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2170   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2171     AC_MSG_RESULT(6 or newer)
2172     AC_DEFINE(HAVE_X11XTR6, 1,
2173               [Define to 1 if you have the X11R6 or newer version of Xt.])
2174     LIBXTR6="-lSM -lICE"
2175     case "$opsys" in
2176       ## Use libw.a along with X11R6 Xt.
2177       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2178     esac
2179   else
2180     AC_MSG_RESULT(before 6)
2181   fi
2182
2183 dnl If using toolkit, check whether libXmu.a exists.
2184 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2185   OLDLIBS="$LIBS"
2186   if test x$HAVE_X11XTR6 = xyes; then
2187     LIBS="-lXt -lSM -lICE $LIBS"
2188   else
2189     LIBS="-lXt $LIBS"
2190   fi
2191   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2192   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2193   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2194 fi
2195 AC_SUBST(LIBXTR6)
2196
2197 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2198 dnl Why not just test for libxmu in the normal way?
2199 LIBXMU=-lXmu
2200 case $opsys in
2201   ## These systems don't supply Xmu.
2202   hpux* | aix4-2 )
2203     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2204     ;;
2205 esac
2206 AC_SUBST(LIBXMU)
2207
2208 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2209 if test "${HAVE_X11}" = "yes"; then
2210   if test "${USE_X_TOOLKIT}" != "none"; then
2211     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2212   fi
2213 fi
2214
2215 LIBXP=
2216 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2217   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2218   if test -d /usr/include/openmotif; then
2219     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2220     emacs_cv_openmotif=yes
2221     case "$canonical" in
2222       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2223       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2224       ;;
2225       *)
2226       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2227     esac
2228   else
2229     emacs_cv_openmotif=no
2230   fi
2231   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2232   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2233     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2234 int x = 5;
2235 #else
2236 Motif version prior to 2.1.
2237 #endif]])],
2238     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2239   if test $emacs_cv_motif_version_2_1 = yes; then
2240     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2241     if test x$emacs_cv_openmotif = xyes; then
2242       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2243     fi
2244   else
2245     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2246     # We put this in CFLAGS temporarily to precede other -I options
2247     # that might be in CFLAGS temporarily.
2248     # We put this in CPPFLAGS where it precedes the other -I options.
2249     OLD_CPPFLAGS=$CPPFLAGS
2250     OLD_CFLAGS=$CFLAGS
2251     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2252     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2253     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2254       [[int x = 5;]])],
2255       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2256     if test $emacs_cv_lesstif = yes; then
2257       # Make sure this -I option remains in CPPFLAGS after it is set
2258       # back to REAL_CPPFLAGS.
2259       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2260       # have those other -I options anyway.  Ultimately, having this
2261       # directory ultimately in CPPFLAGS will be enough.
2262       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2263       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2264     else
2265       CFLAGS=$OLD_CFLAGS
2266       CPPFLAGS=$OLD_CPPFLAGS
2267     fi
2268   fi
2269   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2270     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2271 fi
2272
2273 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2274 dnl using Motif or Xaw3d is available, and unless
2275 dnl --with-toolkit-scroll-bars=no was specified.
2276
2277 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2278             [Define to 1 if we should use toolkit scroll bars.])dnl
2279 USE_TOOLKIT_SCROLL_BARS=no
2280 if test "${with_toolkit_scroll_bars}" != "no"; then
2281   if test "${USE_X_TOOLKIT}" != "none"; then
2282     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2283       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2284       HAVE_XAW3D=no
2285       USE_TOOLKIT_SCROLL_BARS=yes
2286     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2287       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2288       USE_TOOLKIT_SCROLL_BARS=yes
2289     fi
2290   elif test "${HAVE_GTK}" = "yes"; then
2291     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2292     USE_TOOLKIT_SCROLL_BARS=yes
2293   elif test "${HAVE_NS}" = "yes"; then
2294     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2295     USE_TOOLKIT_SCROLL_BARS=yes
2296   fi
2297 fi
2298
2299 dnl See if XIM is available.
2300 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2301           #include <X11/Xlib.h>
2302           #include <X11/Xresource.h>]],
2303          [[XIMProc  callback;]])],
2304          [HAVE_XIM=yes
2305          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2306          HAVE_XIM=no)
2307
2308 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2309
2310 if test "${with_xim}" != "no"; then
2311   AC_DEFINE(USE_XIM, 1,
2312             [Define to 1 if we should use XIM, if it is available.])
2313 fi
2314
2315
2316 if test "${HAVE_XIM}" != "no"; then
2317   late_CFLAGS=$CFLAGS
2318   if test "$GCC" = yes; then
2319     CFLAGS="$CFLAGS --pedantic-errors"
2320   fi
2321   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2322 #include <X11/Xlib.h>
2323 #include <X11/Xresource.h>]],
2324 [[Display *display;
2325 XrmDatabase db;
2326 char *res_name;
2327 char *res_class;
2328 XIMProc  callback;
2329 XPointer *client_data;
2330 #ifndef __GNUC__
2331 /* If we're not using GCC, it's probably not XFree86, and this is
2332    probably right, but we can't use something like --pedantic-errors.  */
2333 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2334                                            char*, XIMProc, XPointer*);
2335 #endif
2336 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2337    client_data);]])],
2338     [emacs_cv_arg6_star=yes])
2339   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2340          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2341 either XPointer or XPointer*.])dnl
2342   if test "$emacs_cv_arg6_star" = yes; then
2343     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2344   else
2345     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2346   fi
2347   CFLAGS=$late_CFLAGS
2348 fi
2349
2350 ### Start of font-backend (under any platform) section.
2351 # (nothing here yet -- this is a placeholder)
2352 ### End of font-backend (under any platform) section.
2353
2354 ### Start of font-backend (under X11) section.
2355 if test "${HAVE_X11}" = "yes"; then
2356    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2357
2358    ## Use -lXft if available, unless `--with-xft=no'.
2359    HAVE_XFT=maybe
2360     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2361       with_xft="no";
2362     fi
2363     if test "x${with_xft}" != "xno"; then
2364
2365       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2366       ## Because xftfont.c uses XRenderQueryExtension, we also
2367       ## need to link to -lXrender.
2368       HAVE_XRENDER=no
2369       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2370       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2371         OLD_CPPFLAGS="$CPPFLAGS"
2372         OLD_CFLAGS="$CFLAGS"
2373         OLD_LIBS="$LIBS"
2374         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2375         CFLAGS="$CFLAGS $XFT_CFLAGS"
2376         XFT_LIBS="-lXrender $XFT_LIBS"
2377         LIBS="$XFT_LIBS $LIBS"
2378         AC_CHECK_HEADER(X11/Xft/Xft.h,
2379           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2380
2381         if test "${HAVE_XFT}" = "yes"; then
2382           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2383             AC_SUBST(XFT_LIBS)
2384           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2385         else
2386           CPPFLAGS="$OLD_CPPFLAGS"
2387           CFLAGS="$OLD_CFLAGS"
2388           LIBS="$OLD_LIBS"
2389         fi                        # "${HAVE_XFT}" = "yes"
2390       fi                          # "$HAVE_XFT" != no
2391     fi                            # "x${with_xft}" != "xno"
2392
2393     ## We used to allow building with FreeType and without Xft.
2394     ## However, the ftx font backend driver is not in good shape.
2395     if test "$HAVE_XFT" != "yes"; then
2396        dnl For the "Does Emacs use" message at the end.
2397        HAVE_XFT=no
2398        HAVE_FREETYPE=no
2399     else
2400        dnl Strict linkers fail with
2401        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2402        dnl if -lfreetype is not specified.
2403        dnl The following is needed to set FREETYPE_LIBS.
2404        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2405                          HAVE_FREETYPE=no)
2406
2407        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2408     fi
2409
2410     HAVE_LIBOTF=no
2411     if test "${HAVE_FREETYPE}" = "yes"; then
2412       AC_DEFINE(HAVE_FREETYPE, 1,
2413                 [Define to 1 if using the freetype and fontconfig libraries.])
2414       if test "${with_libotf}" != "no"; then
2415         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2416                           HAVE_LIBOTF=no)
2417         if test "$HAVE_LIBOTF" = "yes"; then
2418           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2419           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2420                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2421                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2422           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2423             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2424                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2425           fi
2426         fi
2427       fi
2428     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2429     dnl Does the new font backend require it, or can it work without it?
2430     fi
2431
2432     HAVE_M17N_FLT=no
2433     if test "${HAVE_LIBOTF}" = yes; then
2434       if test "${with_m17n_flt}" != "no"; then
2435         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2436         if test "$HAVE_M17N_FLT" = "yes"; then
2437           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2438         fi
2439       fi
2440     fi
2441 else
2442     HAVE_XFT=no
2443     HAVE_FREETYPE=no
2444     HAVE_LIBOTF=no
2445     HAVE_M17N_FLT=no
2446 fi
2447
2448 ### End of font-backend (under X11) section.
2449
2450 AC_SUBST(FREETYPE_CFLAGS)
2451 AC_SUBST(FREETYPE_LIBS)
2452 AC_SUBST(FONTCONFIG_CFLAGS)
2453 AC_SUBST(FONTCONFIG_LIBS)
2454 AC_SUBST(LIBOTF_CFLAGS)
2455 AC_SUBST(LIBOTF_LIBS)
2456 AC_SUBST(M17N_FLT_CFLAGS)
2457 AC_SUBST(M17N_FLT_LIBS)
2458
2459 ### Use -lXpm if available, unless `--with-xpm=no'.
2460 HAVE_XPM=no
2461 LIBXPM=
2462 if test "${HAVE_X11}" = "yes"; then
2463   if test "${with_xpm}" != "no"; then
2464     AC_CHECK_HEADER(X11/xpm.h,
2465       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2466     if test "${HAVE_XPM}" = "yes"; then
2467       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2468       AC_EGREP_CPP(no_return_alloc_pixels,
2469       [#include "X11/xpm.h"
2470 #ifndef XpmReturnAllocPixels
2471 no_return_alloc_pixels
2472 #endif
2473       ], HAVE_XPM=no, HAVE_XPM=yes)
2474
2475       if test "${HAVE_XPM}" = "yes"; then
2476         AC_MSG_RESULT(yes)
2477       else
2478         AC_MSG_RESULT(no)
2479       fi
2480     fi
2481   fi
2482
2483   if test "${HAVE_XPM}" = "yes"; then
2484     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2485     LIBXPM=-lXpm
2486   fi
2487 fi
2488 AC_SUBST(LIBXPM)
2489
2490 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2491 HAVE_JPEG=no
2492 LIBJPEG=
2493 if test "${HAVE_X11}" = "yes"; then
2494   if test "${with_jpeg}" != "no"; then
2495     dnl Checking for jpeglib.h can lose because of a redefinition of
2496     dnl  HAVE_STDLIB_H.
2497     AC_CHECK_HEADER(jerror.h,
2498       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2499   fi
2500
2501   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2502   if test "${HAVE_JPEG}" = "yes"; then
2503     AC_DEFINE(HAVE_JPEG)
2504     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2505         [#include <jpeglib.h>
2506          version=JPEG_LIB_VERSION
2507 ],
2508         [AC_DEFINE(HAVE_JPEG)],
2509         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2510         HAVE_JPEG=no])
2511   fi
2512   if test "${HAVE_JPEG}" = "yes"; then
2513     LIBJPEG=-ljpeg
2514   fi
2515 fi
2516 AC_SUBST(LIBJPEG)
2517
2518 ### Use -lpng if available, unless `--with-png=no'.
2519 HAVE_PNG=no
2520 LIBPNG=
2521 if test "${HAVE_X11}" = "yes"; then
2522   if test "${with_png}" != "no"; then
2523     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2524     # in /usr/include/libpng.
2525     AC_CHECK_HEADERS(png.h libpng/png.h, break)
2526     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2527       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2528     fi
2529   fi
2530
2531   if test "${HAVE_PNG}" = "yes"; then
2532     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2533     LIBPNG="-lpng -lz -lm"
2534
2535     AC_CHECK_DECL(png_longjmp,
2536       [],
2537       [AC_DEFINE(PNG_DEPSTRUCT, [],
2538          [Define to empty to suppress deprecation warnings when building
2539           with --enable-gcc-warnings and with libpng versions before 1.5,
2540           which lack png_longjmp.])],
2541       [[#ifdef HAVE_LIBPNG_PNG_H
2542         # include <libpng/png.h>
2543         #else
2544         # include <png.h>
2545         #endif
2546       ]])
2547   fi
2548 fi
2549 AC_SUBST(LIBPNG)
2550
2551 ### Use -ltiff if available, unless `--with-tiff=no'.
2552 HAVE_TIFF=no
2553 LIBTIFF=
2554 if test "${HAVE_X11}" = "yes"; then
2555   if test "${with_tiff}" != "no"; then
2556     AC_CHECK_HEADER(tiffio.h,
2557       [tifflibs="-lz -lm"
2558       # At least one tiff package requires the jpeg library.
2559       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2560       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2561   fi
2562
2563   if test "${HAVE_TIFF}" = "yes"; then
2564     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2565     dnl FIXME -lz -lm, as per libpng?
2566     LIBTIFF=-ltiff
2567   fi
2568 fi
2569 AC_SUBST(LIBTIFF)
2570
2571 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2572 HAVE_GIF=no
2573 LIBGIF=
2574 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2575   AC_CHECK_HEADER(gif_lib.h,
2576 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2577 # Earlier versions can crash Emacs.
2578     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2579
2580   if test "$HAVE_GIF" = yes; then
2581     LIBGIF=-lgif
2582   elif test "$HAVE_GIF" = maybe; then
2583 # If gif_lib.h but no libgif, try libungif.
2584     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2585     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2586   fi
2587
2588   if test "${HAVE_GIF}" = "yes"; then
2589     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2590   fi
2591 fi
2592 AC_SUBST(LIBGIF)
2593
2594 dnl Check for required libraries.
2595 if test "${HAVE_X11}" = "yes"; then
2596   MISSING=""
2597   WITH_NO=""
2598   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2599     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2600   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2601     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2602   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2603     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2604   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2605     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2606   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2607     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2608
2609   if test "X${MISSING}" != X; then
2610     AC_MSG_ERROR([The following required libraries were not found:
2611     $MISSING
2612 Maybe some development libraries/packages are missing?
2613 If you don't want to link with them give
2614     $WITH_NO
2615 as options to configure])
2616   fi
2617 fi
2618
2619 ### Use -lgpm if available, unless `--with-gpm=no'.
2620 HAVE_GPM=no
2621 LIBGPM=
2622 if test "${with_gpm}" != "no"; then
2623   AC_CHECK_HEADER(gpm.h,
2624     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2625
2626   if test "${HAVE_GPM}" = "yes"; then
2627     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2628     LIBGPM=-lgpm
2629   fi
2630 fi
2631 AC_SUBST(LIBGPM)
2632
2633 dnl Check for malloc/malloc.h on darwin
2634 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2635
2636 GNUSTEP_CFLAGS=
2637 ### Use NeXTstep API to implement GUI.
2638 if test "${HAVE_NS}" = "yes"; then
2639   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2640   if test "${NS_IMPL_COCOA}" = "yes"; then
2641     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2642   fi
2643   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2644     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2645     # See also .m.o rule in Makefile.in */
2646     # FIXME: are all these flags really needed?  Document here why.  */
2647     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2648     ## Extra CFLAGS applied to src/*.m files.
2649     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2650   fi
2651   # We also have mouse menus.
2652   HAVE_MENUS=yes
2653   OTHER_FILES=ns-app
2654 fi
2655
2656
2657 ### Use session management (-lSM -lICE) if available
2658 HAVE_X_SM=no
2659 LIBXSM=
2660 if test "${HAVE_X11}" = "yes"; then
2661   AC_CHECK_HEADER(X11/SM/SMlib.h,
2662     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2663
2664   if test "${HAVE_X_SM}" = "yes"; then
2665     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2666     LIBXSM="-lSM -lICE"
2667     case "$LIBS" in
2668       *-lSM*) ;;
2669       *)      LIBS="$LIBXSM $LIBS" ;;
2670     esac
2671   fi
2672 fi
2673 AC_SUBST(LIBXSM)
2674
2675 ### Use libxml (-lxml2) if available
2676 HAVE_LIBXML2=no
2677 if test "${with_xml2}" != "no"; then
2678   ### I'm not sure what the version number should be, so I just guessed.
2679   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2680   if test "${HAVE_LIBXML2}" = "yes"; then
2681     LIBS="$LIBXML2_LIBS $LIBS"
2682     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2683     if test "${HAVE_LIBXML2}" = "yes"; then
2684       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2685     else
2686       LIBXML2_LIBS=""
2687       LIBXML2_CFLAGS=""
2688     fi
2689   fi
2690 fi
2691 AC_SUBST(LIBXML2_LIBS)
2692 AC_SUBST(LIBXML2_CFLAGS)
2693
2694 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2695 AC_CACHE_CHECK(whether netdb declares h_errno,
2696                emacs_cv_netdb_declares_h_errno,
2697 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2698   [[return h_errno;]])],
2699   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2700 if test $emacs_cv_netdb_declares_h_errno = yes; then
2701   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2702 fi
2703
2704 # sqrt and other floating-point functions such as fmod and frexp
2705 # are found in -lm on most systems.
2706 AC_CHECK_LIB(m, sqrt)
2707
2708 # Check for mail-locking functions in a "mail" library.  Probably this should
2709 # have the same check as for liblockfile below.
2710 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2711 if test $have_mail = yes; then
2712   LIBS_MAIL=-lmail
2713   LIBS="$LIBS_MAIL $LIBS"
2714   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2715 else
2716   LIBS_MAIL=
2717 fi
2718 dnl Debian, at least:
2719 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2720 if test $have_lockfile = yes; then
2721    LIBS_MAIL=-llockfile
2722    LIBS="$LIBS_MAIL $LIBS"
2723    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2724 else
2725 # If we have the shared liblockfile, assume we must use it for mail
2726 # locking (e.g. Debian).  If we couldn't link against liblockfile
2727 # (no liblockfile.a installed), ensure that we don't need to.
2728   dnl This works for files generally, not just executables.
2729   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2730   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2731                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2732   if test $ac_cv_prog_liblockfile = yes; then
2733     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2734 This probably means that movemail could lose mail.
2735 There may be a `development' package to install containing liblockfile.])
2736   fi
2737 fi
2738 AC_CHECK_HEADERS_ONCE(maillock.h)
2739 AC_SUBST(LIBS_MAIL)
2740
2741 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2742 ## interlock access to the mail spool.  The alternative is a lock file named
2743 ## /usr/spool/mail/$USER.lock.
2744 mail_lock=no
2745 case "$opsys" in
2746   aix4-2) mail_lock="lockf" ;;
2747
2748   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2749
2750   ## On GNU/Linux systems, both methods are used by various mail programs.
2751   ## I assume most people are using newer mailers that have heard of flock.
2752   ## Change this if you need to.
2753   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2754   ## configure gets the right answers, and that means *NOT* using flock.
2755   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2756   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2757   ## Debian maintainer hasn't provided a clean fix for Emacs.
2758   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2759   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2760   ## correct logic.  -- fx
2761   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2762   ## liblockfile is a Free Software replacement for libmail, used on
2763   ## Debian systems and elsewhere. -rfr.
2764   gnu-*)
2765     mail_lock="flock"
2766     if test $have_mail = yes || test $have_lockfile = yes; then
2767       test $ac_cv_header_maillock_h = yes && mail_lock=no
2768     fi
2769     ;;
2770 esac
2771
2772 BLESSMAIL_TARGET=
2773 case "$mail_lock" in
2774   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2775
2776   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2777
2778   *) BLESSMAIL_TARGET="need-blessmail" ;;
2779 esac
2780 AC_SUBST(BLESSMAIL_TARGET)
2781
2782
2783 AC_CHECK_FUNCS(gethostname \
2784 closedir getrusage get_current_dir_name \
2785 lrand48 setsid \
2786 fpathconf select euidaccess getpagesize setlocale \
2787 utimes getrlimit setrlimit setpgid getcwd shutdown getaddrinfo \
2788 __fpending strsignal setitimer \
2789 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2790 gai_strerror mkstemp getline getdelim fsync sync \
2791 difftime posix_memalign \
2792 getpwent endpwent getgrent endgrent \
2793 touchlock \
2794 cfmakeraw cfsetspeed copysign __executable_start)
2795
2796 dnl getwd appears to be buggy on SVR4.2, so we don't use it.
2797 if test $opsys = unixware; then
2798   dnl In case some other test ends up checking for getwd.
2799   AC_DEFINE(BROKEN_GETWD, 1, [Define if getwd should not be used.])
2800 else
2801   AC_CHECK_FUNCS(getwd)
2802 fi
2803
2804 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
2805 ## has a broken `rint' in some library versions including math library
2806 ## version number A.09.05.
2807 ## You can fix the math library by installing patch number PHSS_4630.
2808 ## But we can fix it more reliably for Emacs by just not using rint.
2809 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
2810 case $opsys in
2811    hpux*) : ;;
2812    *) AC_CHECK_FUNCS(random rint) ;;
2813 esac
2814
2815 dnl Cannot use AC_CHECK_FUNCS
2816 AC_CACHE_CHECK([for __builtin_unwind_init],
2817                emacs_cv_func___builtin_unwind_init,
2818 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2819                 emacs_cv_func___builtin_unwind_init=yes,
2820                 emacs_cv_func___builtin_unwind_init=no)])
2821 if test $emacs_cv_func___builtin_unwind_init = yes; then
2822   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2823             [Define to 1 if you have the `__builtin_unwind_init' function.])
2824 fi
2825
2826 AC_CHECK_HEADERS_ONCE(sys/un.h)
2827
2828 AC_FUNC_FSEEKO
2829
2830 AC_FUNC_GETPGRP
2831
2832 # UNIX98 PTYs.
2833 AC_CHECK_FUNCS(grantpt)
2834
2835 # PTY-related GNU extensions.
2836 AC_CHECK_FUNCS(getpt posix_openpt)
2837
2838 # Check this now, so that we will NOT find the above functions in ncurses.
2839 # That is because we have not set up to link ncurses in lib-src.
2840 # It's better to believe a function is not available
2841 # than to expect to find it in ncurses.
2842 # Also we need tputs and friends to be able to build at all.
2843 AC_MSG_CHECKING([for library containing tputs])
2844 # Run a test program that contains a call to tputs, a call that is
2845 # never executed.  This tests whether a pre-'main' dynamic linker
2846 # works with the library.  It's too much trouble to actually call
2847 # tputs in the test program, due to portability hassles.  When
2848 # cross-compiling, assume the test program will run if it links.
2849 AC_DEFUN([tputs_link_source], [
2850   AC_LANG_SOURCE(
2851      [[extern void tputs (const char *, int, int (*)(int));
2852        int main (int argc, char **argv)
2853        {
2854           if (argc == 10000)
2855             tputs (argv[0], 0, 0);
2856           return 0;
2857        }]])
2858 ])
2859 # Maybe curses should be tried earlier?
2860 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2861 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2862   OLIBS=$LIBS
2863   if test -z "$tputs_library"; then
2864     LIBS_TERMCAP=
2865     msg='none required'
2866   else
2867     LIBS_TERMCAP=-l$tputs_library
2868     msg=$LIBS_TERMCAP
2869     LIBS="$LIBS_TERMCAP $LIBS"
2870   fi
2871   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2872     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2873   LIBS=$OLIBS
2874   if test "X$msg" != Xno; then
2875     break
2876   fi
2877 done
2878 AC_MSG_RESULT([$msg])
2879 if test "X$msg" = Xno; then
2880   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2881 The following libraries were tried (in order):
2882   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2883 Please try installing whichever of these libraries is most appropriate
2884 for your system, together with its header files.
2885 For example, a libncurses-dev(el) or similar package.])
2886 fi
2887
2888 ## Use termcap instead of terminfo?
2889 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2890 TERMINFO=yes
2891 ## FIXME?  In the cases below where we unconditionally set
2892 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2893 ## if that was found above to have tputs.
2894 ## Should we use the gnu* logic everywhere?
2895 case "$opsys" in
2896   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2897   ##  The ncurses library has been moved out of the System framework in
2898   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2899   ##  option to use it.
2900   darwin) LIBS_TERMCAP="-lncurses" ;;
2901
2902   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2903
2904   freebsd)
2905     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2906     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2907     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2908 [[#if __FreeBSD_version < 400000
2909 fail;
2910 #endif
2911 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2912
2913     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2914
2915     if test $emacs_cv_freebsd_terminfo = yes; then
2916       LIBS_TERMCAP="-lncurses"
2917     else
2918       TERMINFO=no
2919       LIBS_TERMCAP="-ltermcap"
2920     fi
2921     ;;
2922
2923   netbsd)
2924     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2925       TERMINFO=no
2926       LIBS_TERMCAP="-ltermcap"
2927     fi
2928     ;;
2929
2930   openbsd) LIBS_TERMCAP="-lncurses" ;;
2931
2932   ## hpux: Make sure we get select from libc rather than from libcurses
2933   ##  because libcurses on HPUX 10.10 has a broken version of select.
2934   ##  We used to use -lc -lcurses, but this may be cleaner.
2935   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2936   # set that way, now it uses the default).  Isn't this a contradiction?
2937   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2938
2939 esac
2940
2941 TERMCAP_OBJ=tparam.o
2942 if test $TERMINFO = yes; then
2943   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2944   TERMCAP_OBJ=terminfo.o
2945 fi
2946 AC_SUBST(LIBS_TERMCAP)
2947 AC_SUBST(TERMCAP_OBJ)
2948
2949
2950 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2951 # On Darwin, res_init appears not to be useful: see bug#562 and
2952 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
2953 resolv=no
2954
2955 if test $opsys != darwin; then
2956
2957   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2958 #include <arpa/nameser.h>
2959 #include <resolv.h>]],
2960     [[return res_init();]])],
2961     have_res_init=yes, have_res_init=no)
2962   if test "$have_res_init" = no; then
2963     OLIBS="$LIBS"
2964     LIBS="$LIBS -lresolv"
2965     AC_MSG_CHECKING(for res_init with -lresolv)
2966     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2967 #include <arpa/nameser.h>
2968 #include <resolv.h>]],
2969       [[return res_init();]])],
2970       have_res_init=yes, have_res_init=no)
2971     AC_MSG_RESULT($have_res_init)
2972     if test "$have_res_init" = yes ; then
2973       resolv=yes
2974     fi
2975     LIBS="$OLIBS"
2976   fi
2977
2978   if test "$have_res_init" = yes; then
2979     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2980   fi
2981 fi                              dnl !darwin
2982
2983 # Do we need the Hesiod library to provide the support routines?
2984 dnl FIXME?  Should we be skipping this on Darwin too?
2985 LIBHESIOD=
2986 if test "$with_hesiod" != no ; then
2987   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2988   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2989      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2990                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2991   if test "$resolv" = yes ; then
2992     RESOLVLIB=-lresolv
2993   else
2994     RESOLVLIB=
2995   fi
2996   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2997         hesiod=yes, :, $RESOLVLIB)])
2998
2999   if test x"$hesiod" = xyes; then
3000     AC_DEFINE(HAVE_LIBHESIOD, 1,
3001               [Define to 1 if you have the hesiod library (-lhesiod).])
3002     LIBHESIOD=-lhesiod
3003   fi
3004 fi
3005 AC_SUBST(LIBHESIOD)
3006
3007 # Do we need libresolv (due to res_init or Hesiod)?
3008 if test "$resolv" = yes && test $opsys != darwin; then
3009   AC_DEFINE(HAVE_LIBRESOLV, 1,
3010             [Define to 1 if you have the resolv library (-lresolv).])
3011   LIBRESOLV=-lresolv
3012 else
3013   LIBRESOLV=
3014 fi
3015 AC_SUBST(LIBRESOLV)
3016
3017 # These tell us which Kerberos-related libraries to use.
3018 COM_ERRLIB=
3019 CRYPTOLIB=
3020 KRB5LIB=
3021 DESLIB=
3022 KRB4LIB=
3023
3024 if test "${with_kerberos}" != no; then
3025   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3026   if test $have_com_err = yes; then
3027     COM_ERRLIB=-lcom_err
3028     LIBS="$COM_ERRLIB $LIBS"
3029     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
3030   fi
3031   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3032   if test $have_crypto = yes; then
3033     CRYPTOLIB=-lcrypto
3034     LIBS="$CRYPTOLIB $LIBS"
3035     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
3036   fi
3037   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3038   if test $have_k5crypto = yes; then
3039     CRYPTOLIB=-lk5crypto
3040     LIBS="$CRYPTOLIB $LIBS"
3041     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
3042   fi
3043   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3044   if test $have_krb5=yes; then
3045     KRB5LIB=-lkrb5
3046     LIBS="$KRB5LIB $LIBS"
3047     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
3048   fi
3049   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3050   if test "${with_kerberos5}" = no; then
3051     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3052     if test $have_des425 = yes; then
3053       DESLIB=-ldes425
3054       LIBS="$DESLIB $LIBS"
3055       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
3056     else
3057       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3058       if test $have_des = yes; then
3059         DESLIB=-ldes
3060         LIBS="$DESLIB $LIBS"
3061         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
3062       fi
3063     fi
3064     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3065     if test $have_krb4 = yes; then
3066       KRB4LIB=-lkrb4
3067       LIBS="$KRB4LIB $LIBS"
3068       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
3069     else
3070       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3071       if test $have_krb = yes; then
3072         KRB4LIB=-lkrb
3073         LIBS="$KRB4LIB $LIBS"
3074         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3075       fi
3076     fi
3077   fi
3078
3079   if test "${with_kerberos5}" != no; then
3080     AC_CHECK_HEADERS(krb5.h,
3081       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3082                         [#include <krb5.h>])])
3083   else
3084     AC_CHECK_HEADERS(des.h,,
3085                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3086                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3087     AC_CHECK_HEADERS(krb.h,,
3088                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3089                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3090   fi
3091   AC_CHECK_HEADERS(com_err.h)
3092 fi
3093
3094 AC_SUBST(COM_ERRLIB)
3095 AC_SUBST(CRYPTOLIB)
3096 AC_SUBST(KRB5LIB)
3097 AC_SUBST(DESLIB)
3098 AC_SUBST(KRB4LIB)
3099
3100 AC_CHECK_FUNCS_ONCE(tzset)
3101 AC_MSG_CHECKING(whether localtime caches TZ)
3102 AC_CACHE_VAL(emacs_cv_localtime_cache,
3103 [if test x$ac_cv_func_tzset = xyes; then
3104 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3105 char TZ_GMT0[] = "TZ=GMT0";
3106 char TZ_PST8[] = "TZ=PST8";
3107 main()
3108 {
3109   time_t now = time ((time_t *) 0);
3110   int hour_GMT0, hour_unset;
3111   if (putenv (TZ_GMT0) != 0)
3112     exit (1);
3113   hour_GMT0 = localtime (&now)->tm_hour;
3114   unsetenv("TZ");
3115   hour_unset = localtime (&now)->tm_hour;
3116   if (putenv (TZ_PST8) != 0)
3117     exit (1);
3118   if (localtime (&now)->tm_hour == hour_GMT0)
3119     exit (1);
3120   unsetenv("TZ");
3121   if (localtime (&now)->tm_hour != hour_unset)
3122     exit (1);
3123   exit (0);
3124 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3125 [# If we have tzset, assume the worst when cross-compiling.
3126 emacs_cv_localtime_cache=yes])
3127 else
3128         # If we lack tzset, report that localtime does not cache TZ,
3129         # since we can't invalidate the cache if we don't have tzset.
3130         emacs_cv_localtime_cache=no
3131 fi])dnl
3132 AC_MSG_RESULT($emacs_cv_localtime_cache)
3133 if test $emacs_cv_localtime_cache = yes; then
3134   AC_DEFINE(LOCALTIME_CACHE, 1,
3135             [Define to 1 if localtime caches TZ.])
3136 fi
3137
3138 ok_so_far=yes
3139 AC_CHECK_FUNC(socket, , ok_so_far=no)
3140 if test $ok_so_far = yes; then
3141   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3142 fi
3143 if test $ok_so_far = yes; then
3144   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3145 fi
3146 if test $ok_so_far = yes; then
3147 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3148   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3149             [Define to 1 if you have inet sockets.])
3150 fi
3151
3152 if test -f /usr/lpp/X11/bin/smt.exp; then
3153   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3154             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3155 fi
3156
3157 AC_MSG_CHECKING(whether system supports dynamic ptys)
3158 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3159   AC_MSG_RESULT(yes)
3160   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3161 else
3162   AC_MSG_RESULT(no)
3163 fi
3164
3165 AC_FUNC_FORK
3166
3167 AC_CHECK_FUNCS(snprintf)
3168
3169 dnl Adapted from Haible's version.
3170 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3171   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3172     [[char* cs = nl_langinfo(CODESET);]])],
3173     emacs_cv_langinfo_codeset=yes,
3174     emacs_cv_langinfo_codeset=no)
3175   ])
3176 if test $emacs_cv_langinfo_codeset = yes; then
3177   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3178     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3179 fi
3180
3181 AC_TYPE_MBSTATE_T
3182
3183 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3184   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3185                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3186 if test "$emacs_cv_c_restrict_arr" = yes; then
3187   AC_DEFINE(__restrict_arr, __restrict,
3188     [Define to compiler's equivalent of C99 restrict keyword in array
3189      declarations.  Define as empty for no equivalent.])
3190 fi
3191
3192 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3193 dnl how the tty code is related to POSIX and/or other versions of termios.
3194 dnl The following looks like a useful start.
3195 dnl
3196 dnl AC_SYS_POSIX_TERMIOS
3197 dnl if test $ac_cv_sys_posix_termios = yes; then
3198 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3199 dnl                                and macros for terminal control.])
3200 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3201 dnl fi
3202
3203 dnl Turned on June 1996 supposing nobody will mind it.
3204 AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3205   in the full name stands for the login id.])
3206
3207 dnl Every platform that uses configure (ie every non-MS platform)
3208 dnl supports this.  There is a create-lockfiles option you can
3209 dnl customize if you do not want the lock files to be written.
3210 dnl So it is not clear that this #define still needs to exist.
3211 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3212   so that Emacs can tell instantly when you try to modify a file that
3213   someone else has modified in his/her Emacs.])
3214
3215 dnl Everybody supports this, except MS.
3216 dnl Seems like the kind of thing we should be testing for, though.
3217 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3218 AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3219
3220 dnl Everybody supports this, except MS-DOS.
3221 dnl Seems like the kind of thing we should be testing for, though.
3222 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3223 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3224   4.2-compatible sockets.])
3225
3226 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3227
3228 AC_DEFINE(NULL_DEVICE, ["/dev/null"], [Name of the file to open to get
3229   a null file, or a data sink.])
3230
3231 AC_DEFINE(SEPCHAR, [':'], [Character that separates PATH elements.])
3232
3233 dnl Everybody supports this, except MS-DOS.
3234 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3235
3236 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3237
3238
3239 AC_DEFINE(DIRECTORY_SEP, ['/'],
3240   [Character that separates directories in a file name.])
3241
3242 dnl Only used on MS platforms.
3243 AH_TEMPLATE(DEVICE_SEP, [Character that separates a device in a file name.])
3244
3245 AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3246   [Returns true if character is a device separator.])
3247
3248 AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3249   [Returns true if character is a directory separator.])
3250
3251 dnl On MS, this also accepts IS_DEVICE_SEP.
3252 AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3253   [Returns true if character is any form of separator.])
3254
3255
3256 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3257
3258 case $opsys in
3259   aix4-2)
3260     dnl Unfortunately without libXmu we cannot support EditRes.
3261     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3262       AC_DEFINE(NO_EDITRES, 1)
3263     fi
3264     ;;
3265
3266   hpux*)
3267     dnl Assar Westerlund <assar@sics.se> says this is necessary for
3268     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3269     AC_DEFINE(NO_EDITRES, 1)
3270     ;;
3271 esac
3272
3273
3274 case $opsys in
3275   irix6-5 | sol2* | unixware )
3276     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
3277     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
3278     dnl need the constant to dimension an array.  So wire in the appropriate
3279     dnl value here.
3280     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
3281     ;;
3282 esac
3283
3284 emacs_broken_SIGIO=no
3285
3286 case $opsys in
3287   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3288   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3289   hpux* | irix6-5 | openbsd | sol2* | unixware )
3290     emacs_broken_SIGIO=yes
3291     ;;
3292
3293   aix4-2)
3294     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
3295     dnl the way this system works, libc functions that return malloced
3296     dnl memory use the libc malloc implementation. Calling xfree or
3297     dnl xrealloc on the results of such functions results in a crash.
3298     dnl
3299     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
3300     dnl but that does not currently work on this system.
3301     dnl
3302     dnl It is possible to completely override the malloc implementation on
3303     dnl AIX, but that involves putting the malloc functions in a shared
3304     dnl library and setting the MALLOCTYPE environment variable to point to
3305     dnl that shared library.
3306     dnl
3307     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
3308     dnl to avoid a crash just use the Emacs implementation for that function.
3309     dnl
3310     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
3311     dnl of this file, so that we do not check for get_current_dir_name
3312     dnl on AIX.  But that might be fragile if something else ends
3313     dnl up testing for get_current_dir_name as a dependency.
3314     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
3315       get_current_dir_name should not be used.])
3316     ;;
3317
3318   freebsd)
3319     dnl Circumvent a bug in FreeBSD.  In the following sequence of
3320     dnl writes/reads on a PTY, read(2) returns bogus data:
3321     dnl
3322     dnl write(2)  1022 bytes
3323     dnl write(2)   954 bytes, get EAGAIN
3324     dnl read(2)   1024 bytes in process_read_output
3325     dnl read(2)     11 bytes in process_read_output
3326     dnl
3327     dnl That is, read(2) returns more bytes than have ever been written
3328     dnl successfully.  The 1033 bytes read are the 1022 bytes written
3329     dnl successfully after processing (for example with CRs added if the
3330     dnl terminal is set up that way which it is here).  The same bytes will
3331     dnl be seen again in a later read(2), without the CRs.
3332     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
3333       work around an issue when reading from a PTY.])
3334     ;;
3335 esac
3336
3337 case $opsys in
3338   gnu-* | sol2-10 )
3339     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3340     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3341   ;;
3342 esac
3343
3344 case $opsys in
3345   darwin | freebsd | netbsd | openbsd )
3346     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
3347       close a pty to make it a controlling terminal (it is already a
3348       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
3349   ;;
3350 esac
3351
3352 dnl FIXME Surely we can test for this rather than hard-code it.
3353 case $opsys in
3354   netbsd | openbsd) sound_device="/dev/audio" ;;
3355   *) sound_device="/dev/dsp" ;;
3356 esac
3357
3358 dnl Used in sound.c
3359 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
3360   [Name of the default sound device.])
3361
3362
3363 dnl Emacs can read input using SIGIO and buffering characters itself,
3364 dnl or using CBREAK mode and making C-g cause SIGINT.
3365 dnl The choice is controlled by the variable interrupt_input.
3366 dnl
3367 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
3368 dnl
3369 dnl Emacs uses the presence of the USABLE_SIGIO macro
3370 dnl to indicate whether or not signal-driven I/O is possible.  It uses
3371 dnl INTERRUPT_INPUT to decide whether to use it by default.
3372 dnl
3373 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
3374 dnl CBREAK mode has two disadvantages
3375 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
3376 dnl I hear that in system V this problem does not exist.
3377 dnl 2) Control-G causes output to be discarded.
3378 dnl I do not know whether this can be fixed in system V.
3379 dnl
3380 dnl Another method of doing input is planned but not implemented.
3381 dnl It would have Emacs fork off a separate process
3382 dnl to read the input and send it to the true Emacs process
3383 dnl through a pipe.
3384 case $opsys in
3385   darwin | gnu-linux | gnu-kfreebsd )
3386     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
3387   ;;
3388 esac
3389
3390
3391 dnl If the system's imake configuration file defines `NeedWidePrototypes'
3392 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
3393 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
3394 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
3395 dnl taking float or double parameters.
3396 case $opsys in
3397   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
3398     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
3399       file defines `NeedWidePrototypes' as `NO'.])
3400   ;;
3401 esac
3402
3403
3404 dnl Used in process.c, this must be a loop, even if it only runs once.
3405 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
3406 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
3407 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
3408 dnl trying suffixes 0-16.
3409 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
3410   first PTY, if PTYs are supported.])
3411 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
3412 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
3413   end of a PTY, if non-standard.])
3414 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
3415   end of a PTY, if non-standard.])
3416
3417 case $opsys in
3418   aix4-2 )
3419     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
3420     dnl You allocate a pty by opening /dev/ptc to get the master side.
3421     dnl To get the name of the slave side, you just ttyname() the master side.
3422     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
3423     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
3424     ;;
3425
3426   cygwin )
3427     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3428     dnl multi-line AC_DEFINEs are hard. :(
3429     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (0)])
3430     AC_DEFINE(PTY_NAME_SPRINTF, [])
3431     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3432     ;;
3433
3434   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
3435   darwin )
3436     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3437     dnl Not used, because PTY_ITERATION is defined.
3438     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3439     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
3440     dnl But we don't have to block SIGCHLD because it is blocked in the
3441     dnl implementation of grantpt.
3442     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (0)])
3443     AC_DEFINE(PTY_NAME_SPRINTF, [])
3444     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3445     ;;
3446
3447   gnu | openbsd )
3448     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3449     ;;
3450
3451   gnu-linux | gnu-kfreebsd | freebsd | netbsd )
3452     dnl if HAVE_GRANTPT
3453     if test "x$ac_cv_func_grantpt" = xyes; then
3454       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
3455       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3456       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
3457       dnl to prevent sigchld_handler from intercepting the child's death.
3458       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3459       dnl if HAVE_POSIX_OPENPT
3460       if test "x$ac_cv_func_posix_openpt" = xyes; then
3461         AC_DEFINE(PTY_OPEN, [fd = posix_openpt (O_RDWR | O_NOCTTY)])
3462         AC_DEFINE(PTY_NAME_SPRINTF, [])
3463       dnl if HAVE_GETPT
3464       elif test "x$ac_cv_func_getpt" = xyes; then
3465         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
3466         AC_DEFINE(PTY_NAME_SPRINTF, [])
3467       else
3468         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3469       fi
3470     else
3471       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3472     fi
3473     ;;
3474
3475   hpux*)
3476     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3477     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
3478     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
3479     ;;
3480
3481   irix6-5 )
3482     dnl It looks like this cannot be right, because it is not a loop.
3483     dnl However, process.c actually does this:
3484     dnl # ifndef __sgi
3485     dnl   continue;
3486     dnl # else
3487     dnl   return -1;
3488     dnl # endif
3489     dnl which presumably makes it OK, since irix == sgi (?).
3490     dnl FIXME it seems like this special treatment is unnecessary?
3491     dnl Why can't irix use a single-trip loop like eg cygwin?
3492     AC_DEFINE(PTY_ITERATION, [])
3493     dnl Not used, because PTY_ITERATION is defined.
3494     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
3495     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
3496     dnl No need to get the pty name at all.
3497     AC_DEFINE(PTY_NAME_SPRINTF, [])
3498     dnl No need to use sprintf to get the tty name--we get that from _getpty.
3499     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3500     ;;
3501
3502   sol2* )
3503     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
3504     dnl from intercepting that death.  If any child but grantpt's should die
3505     dnl within, it should be caught after sigrelse(2).
3506     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3507     ;;
3508
3509   unixware )
3510     dnl Comments are as per sol2*.
3511     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3512     ;;
3513 esac
3514
3515
3516 case $opsys in
3517   sol2* | unixware )
3518     dnl This change means that we don't loop through allocate_pty too
3519     dnl many times in the (rare) event of a failure.
3520     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
3521     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3522     dnl Push various streams modules onto a PTY channel.  Used in process.c.
3523     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
3524     ;;
3525 esac
3526
3527
3528 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
3529 "typing" a signal character on the pty.])
3530
3531 case $opsys in
3532   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
3533   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
3534   aix4-2 | cygwin | gnu | irix6-5 | freebsd | netbsd | openbsd )
3535     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3536     ;;
3537
3538   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
3539   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
3540   gnu-linux | gnu-kfreebsd )
3541
3542     AC_MSG_CHECKING([for signals via characters])
3543     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3544 #include <linux/version.h>
3545 #if LINUX_VERSION_CODE < 0x20400
3546 # error "Linux version too old"
3547 #endif
3548       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
3549
3550     AC_MSG_RESULT([$emacs_signals_via_chars])
3551     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3552     ;;
3553 esac
3554
3555
3556 dnl Used in dispnew.c
3557 AH_TEMPLATE(PENDING_OUTPUT_COUNT, [Number of chars of output in the
3558   buffer of a stdio stream.])
3559
3560 AC_MSG_CHECKING([whether we are using the GNU C library])
3561 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3562 #include <features.h>
3563 #ifndef __GNU_LIBRARY__
3564 # error "this is not the GNU C library"
3565 #endif
3566   ]], [[]])], emacs_glibc=yes, emacs_glibc=no)
3567 AC_MSG_RESULT([$emacs_glibc])
3568
3569 if test $emacs_glibc = yes; then
3570
3571   emacs_pending_output=unknown
3572
3573   case $opsys in
3574     gnu | gnu-linux | gnu-kfreebsd )
3575       AC_MSG_CHECKING([for style of pending output formalism])
3576       dnl In autoconf 2.67 and later, we could use a single test
3577       dnl since the preprocessed output is accessible in "conftest.i".
3578       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3579 #include <stdio.h>
3580 #if !defined (_IO_STDIO_H) && !defined (_STDIO_USES_IOSTREAM)
3581 # error "stdio definitions not found"
3582 #endif
3583         ]], [[]])], emacs_pending_output=new, [])
3584
3585       if test $emacs_pending_output = unknown; then
3586         case $opsys in
3587           gnu-linux | gnu-kfreebsd)
3588             AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3589 #include <stdio.h>
3590 #ifndef __UCLIBC__
3591 # error "not using uclibc"
3592 #endif
3593             ]], [[]])], emacs_pending_output=uclibc, emacs_pending_output=old)
3594             ;;
3595         esac
3596       fi
3597
3598       AC_MSG_RESULT([$emacs_pending_output])
3599
3600       case $emacs_pending_output in
3601         new)
3602           dnl New C libio names.
3603           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3604             [((FILE)->_IO_write_ptr - (FILE)->_IO_write_base)])
3605           ;;
3606         uclibc)
3607           dnl Using the uClibc library.
3608           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3609             [((FILE)->__bufpos - (FILE)->__bufstart)])
3610           ;;
3611         old)
3612           dnl Old C++ iostream names.
3613           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3614             [((FILE)->_pptr - (FILE)->_pbase)])
3615           ;;
3616       esac
3617     ;;
3618   esac                          dnl opsys
3619
3620   if test $emacs_pending_output = unknown; then
3621     AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__bufp - (FILE)->__buffer)])
3622   fi
3623
3624 else                            dnl !emacs_glibc
3625
3626   case $opsys in
3627     cygwin | darwin | freebsd | netbsd | openbsd )
3628       AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_p - (FILE)->_bf._base)])
3629       ;;
3630
3631     unixware)
3632       AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__ptr - (FILE)->__base)])
3633       ;;
3634
3635     *)
3636       dnl HAVE_STDIO_EXT_H && HAVE___FPENDING
3637       if test x$ac_cv_header_stdio_ext_h = xyes && \
3638         test x$ac_cv_func___fpending = xyes; then
3639         AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [__fpending (FILE)])
3640         AC_DEFINE(DISPNEW_NEEDS_STDIO_EXT, 1,
3641           [Define if dispnew.c should include stdio_ext.h.])
3642       else
3643         AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_ptr - (FILE)->_base)])
3644       fi
3645       ;;
3646   esac
3647 fi                              dnl emacs_glibc
3648
3649
3650 dnl Used in vm-limit.c
3651 AH_TEMPLATE(DATA_START, [Address of the start of the data segment.])
3652 dnl Used in lisp.h, emacs.c, mem-limits.h
3653 dnl NEWS.18 describes this as "a number which contains
3654 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
3655 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
3656 stored in a Lisp_Object.])
3657 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
3658
3659 case $opsys in
3660   gnu)
3661     dnl libc defines data_start.
3662     AC_DEFINE(DATA_START, [({ extern int data_start; (char *) &data_start; })])
3663     ;;
3664
3665   hpux*)
3666     dnl The data segment on this machine always starts at address 0x40000000.
3667     AC_DEFINE(DATA_START, [0x40000000])
3668     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
3669     ;;
3670   irix6-5)
3671     AC_DEFINE(DATA_START, [0x10000000])
3672     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
3673     ;;
3674 esac
3675
3676
3677 AH_TEMPLATE(ULIMIT_BREAK_VALUE, [Undocumented.])
3678 AH_TEMPLATE(TAB3, [Undocumented.])
3679
3680 case $opsys in
3681   darwin) AC_DEFINE(TAB3, OXTABS) ;;
3682
3683   gnu | freebsd | netbsd | openbsd )
3684     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
3685     AC_DEFINE(TAB3, OXTABS)
3686     ;;
3687
3688   gnu-linux | gnu-kfreebsd )
3689     dnl libc-linux/sysdeps/linux/i386/ulimit.c says that due to shared
3690     dnl library, we cannot get the maximum address for brk.
3691     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3692 #ifndef __i386__
3693 # error "not i386"
3694 #endif
3695       ]], [[]])], AC_DEFINE(ULIMIT_BREAK_VALUE, [(32*1024*1024)]), [])
3696
3697     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3698 #ifndef __ia64__
3699 # error "not ia64"
3700 #endif
3701       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
3702         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (0)],
3703         [Mark a secondary stack, like the register stack on the ia64.]), [])
3704     ;;
3705
3706   hpux*)
3707     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
3708       run_time_remap; for HPUX.])
3709     ;;
3710
3711   irix6-5)
3712     dnl Ulimit(UL_GMEMLIM) is busted...
3713     AC_DEFINE(ULIMIT_BREAK_VALUE, [0x14000000])
3714     ;;
3715 esac
3716
3717
3718 dnl These won't be used automatically yet.  We also need to know, at least,
3719 dnl that the stack is continuous.
3720 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
3721   registers relevant for conservative garbage collection in the jmp_buf.])
3722
3723 AH_TEMPLATE(GC_MARK_STACK, [Define to GC_USE_GCPROS_AS_BEFORE if
3724   conservative garbage collection is not known to work.])
3725
3726
3727 case $opsys in
3728   aix4-2 | hpux* | unixware)
3729     dnl Conservative garbage collection has not been tested, so for now
3730     dnl play it safe and stick with the old-fashioned way of marking.
3731     AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE])
3732     ;;
3733
3734   dnl Not all the architectures are tested, but there are Debian packages
3735   dnl for SCM and/or Guile on them, so the technique must work.  See also
3736   dnl comments in alloc.c concerning setjmp and gcc.
3737   dnl Fixme: it's probably safe to just use the GCC conditional below.
3738   gnu-linux | gnu-kfreebsd )
3739     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3740 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
3741   || defined __alpha__ || defined __mips__ || defined __s390__ \
3742   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
3743   || defined __ia64__ || defined __sh__
3744 /* ok */
3745 #else
3746 # error "setjmp not known to work on this arch"
3747 #endif
3748     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1),
3749       AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE]) )
3750     ;;
3751 esac
3752
3753
3754 if test x$GCC = xyes; then
3755    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
3756    AC_DEFINE(GC_SETJMP_WORKS, 1)
3757 else
3758   case $opsys in
3759     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
3760     freebsd | netbsd | openbsd | irix6-5 | sol2* )
3761       AC_DEFINE(GC_SETJMP_WORKS, 1)
3762       ;;
3763   esac
3764 fi                              dnl GCC?
3765
3766 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
3767   [AC_LINK_IFELSE(
3768      [AC_LANG_PROGRAM(
3769        [[#include <setjmp.h>
3770        ]],
3771        [[jmp_buf j;
3772          if (! _setjmp (j))
3773            _longjmp (j, 1);]])],
3774      [emacs_cv_func__setjmp=yes],
3775      [emacs_cv_func__setjmp=no])])
3776 if test $emacs_cv_func__setjmp = no; then
3777   AC_DEFINE([_setjmp], [setjmp],
3778     [Define to setjmp if _setjmp and _longjmp do not work.  See _longjmp.])
3779   AC_DEFINE([_longjmp], [longjmp],
3780     [Define to longjmp if _setjmp and _longjmp do not work.
3781      Because longjmp may alter signal masks, callers of _longjmp
3782      should not assume that it leaves signal masks alone.])
3783 fi
3784
3785 case $opsys in
3786   sol2* | unixware )
3787     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
3788     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
3789     dnl and this is all we need.
3790     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
3791     ;;
3792 esac
3793
3794
3795 case $opsys in
3796   hpux* | sol2* )
3797     dnl Used in xfaces.c.
3798     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
3799       some systems, where it requires time.h.])
3800     ;;
3801 esac
3802
3803
3804 dnl Define symbols to identify the version of Unix this is.
3805 dnl Define all the symbols that apply correctly.
3806 AH_TEMPLATE(BSD4_2, [Define if the system is compatible with BSD 4.2.])
3807 AH_TEMPLATE(BSD_SYSTEM, [Define if the system is compatible with BSD 4.2.])
3808 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
3809 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
3810 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
3811 AH_TEMPLATE(USG5, [Define if the system is compatible with System V.])
3812 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
3813
3814 case $opsys in
3815   aix4-2)
3816     AC_DEFINE(USG, [])
3817     AC_DEFINE(USG5, [])
3818     dnl This symbol should be defined on AIX Version 3  ???????
3819     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3820 #ifndef _AIX
3821 # error "_AIX not defined"
3822 #endif
3823     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
3824     ;;
3825
3826   cygwin)
3827     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
3828     ;;
3829
3830   darwin)
3831     dnl BSD4_3 and BSD4_4 are already defined in sys/param.h.
3832     AC_DEFINE(BSD4_2, [])
3833     AC_DEFINE(BSD_SYSTEM, [])
3834     dnl More specific than the above two.  We cannot use __APPLE__ as this
3835     dnl may not be defined on non-OSX Darwin, and we cannot define DARWIN
3836     dnl here because Panther and lower CoreFoundation.h uses DARWIN to
3837     dnl distinguish OS X from pure Darwin.
3838     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
3839     ;;
3840
3841   freebsd)
3842     AC_DEFINE(BSD4_2, [])
3843     dnl Hack to avoid calling AC_PREPROC_IFELSE multiple times.
3844     dnl Would not be needed with autoconf >= 2.67, where the
3845     dnl preprocessed output is accessible in "conftest.i".
3846     AC_DEFINE(BSD_SYSTEM_AHB, 1, [Define if AH_BOTTOM should change BSD_SYSTEM.])
3847     ;;
3848
3849   gnu | netbsd | openbsd )
3850     AC_DEFINE(BSD4_2, [])
3851     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3852 #ifndef BSD_SYSTEM
3853 # error "BSD_SYSTEM not defined"
3854 #endif
3855     ]], [[]])], [], AC_DEFINE(BSD_SYSTEM, 43) )
3856     ;;
3857
3858   gnu-linux | gnu-kfreebsd )
3859     AC_DEFINE(USG, [])
3860     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
3861     ;;
3862
3863   hpux*)
3864     AC_DEFINE(USG, [])
3865     AC_DEFINE(USG5, [])
3866     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
3867     ;;
3868
3869   irix6-5)
3870     AC_DEFINE(USG, [])
3871     AC_DEFINE(USG5, [])
3872     AC_DEFINE(USG5_4, [])
3873     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
3874     ;;
3875
3876   sol2*)
3877     AC_DEFINE(USG, [])
3878     AC_DEFINE(USG5, [])
3879     AC_DEFINE(USG5_4, [])
3880     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
3881     ;;
3882
3883   unixware)
3884     AC_DEFINE(USG, [])
3885     AC_DEFINE(USG5, [])
3886     AC_DEFINE(USG5_4, [])
3887     ;;
3888 esac
3889
3890 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
3891   [case $opsys in
3892      aix4-2)
3893        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
3894        emacs_cv_usable_FIONREAD=no
3895        ;;
3896
3897      *)
3898        AC_COMPILE_IFELSE(
3899          [AC_LANG_PROGRAM([[#include <sys/types.h>
3900                             #include <sys/ioctl.h>
3901                             #ifdef USG5_4
3902                             # include <sys/filio.h>
3903                             #endif
3904                           ]],
3905                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
3906          [emacs_cv_usable_FIONREAD=yes],
3907          [emacs_cv_usable_FIONREAD=no])
3908        ;;
3909    esac])
3910 if test $emacs_cv_usable_FIONREAD = yes; then
3911   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
3912
3913   if test $emacs_broken_SIGIO = no; then
3914     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
3915       [AC_COMPILE_IFELSE(
3916          [AC_LANG_PROGRAM([[#include <fcntl.h>
3917                             #include <signal.h>
3918                           ]],
3919                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
3920          [emacs_cv_usable_SIGIO=yes],
3921          [emacs_cv_usable_SIGIO=no])],
3922       [emacs_cv_usable_SIGIO=yes],
3923       [emacs_cv_usable_SIGIO=no])
3924     if test $emacs_cv_usable_SIGIO = yes; then
3925       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
3926     fi
3927   fi
3928 fi
3929
3930
3931 case $opsys in
3932   dnl Emacs supplies its own malloc, but glib (part of Gtk+) calls
3933   dnl memalign and on Cygwin, that becomes the Cygwin-supplied memalign.
3934   dnl As malloc is not the Cygwin malloc, the Cygwin memalign always
3935   dnl returns ENOSYS.  A workaround is to set G_SLICE=always-malloc. */
3936   cygwin)
3937     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
3938       G_SLICE environment variable to "always-malloc" at startup, if
3939       using GTK.])
3940     ;;
3941
3942   hpux11)
3943     dnl See comments in sysdep.c:sys_signal.
3944     dnl SA_RESTART resets the timeout of `select' on hpux11.
3945     dnl Defining BROKEN_SA_RESTART is not the same as undef'ing SA_RESTART.
3946     AC_DEFINE(BROKEN_SA_RESTART, 1, [Define if SA_RESTART should only
3947       be used in batch mode.])
3948     dnl It works to open the pty's tty in the parent (Emacs), then
3949     dnl close and reopen it in the child.
3950     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
3951       works to open a pty's tty in the parent process, then close and
3952       reopen it in the child.])
3953     ;;
3954
3955   irix6-5)
3956     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
3957       use VSUSP instead of VSWTCH.])
3958     AC_DEFINE(SETPGRP_RELEASES_CTTY, 1, [Define if process.c:child_setup
3959       should not call setpgrp.])
3960     ;;
3961
3962   sol2-10)
3963     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
3964       on Solaris.])
3965     ;;
3966 esac
3967
3968 # Set up the CFLAGS for real compilation, so we can substitute it.
3969 CFLAGS="$REAL_CFLAGS"
3970 CPPFLAGS="$REAL_CPPFLAGS"
3971
3972 ## Hack to detect a buggy GCC version.
3973 if test "x$GCC" = xyes \
3974    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3975    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3976    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3977    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3978 fi
3979
3980 version=$PACKAGE_VERSION
3981
3982 ### Specify what sort of things we'll be editing into Makefile and config.h.
3983 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3984 AC_SUBST(version)
3985 AC_SUBST(configuration)
3986 ## Unused?
3987 AC_SUBST(canonical)
3988 AC_SUBST(srcdir)
3989 AC_SUBST(prefix)
3990 AC_SUBST(exec_prefix)
3991 AC_SUBST(bindir)
3992 AC_SUBST(datadir)
3993 AC_SUBST(sharedstatedir)
3994 AC_SUBST(libexecdir)
3995 AC_SUBST(mandir)
3996 AC_SUBST(infodir)
3997 AC_SUBST(lispdir)
3998 AC_SUBST(leimdir)
3999 AC_SUBST(standardlisppath)
4000 AC_SUBST(locallisppath)
4001 AC_SUBST(lisppath)
4002 AC_SUBST(x_default_search_path)
4003 AC_SUBST(etcdir)
4004 AC_SUBST(archlibdir)
4005 AC_SUBST(docdir)
4006 AC_SUBST(bitmapdir)
4007 AC_SUBST(gamedir)
4008 AC_SUBST(gameuser)
4009 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4010 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4011 ## end of LIBX_BASE, but nothing ever set it.
4012 AC_SUBST(LD_SWITCH_X_SITE)
4013 AC_SUBST(C_SWITCH_X_SITE)
4014 AC_SUBST(GNUSTEP_CFLAGS)
4015 AC_SUBST(CFLAGS)
4016 ## Used in lwlib/Makefile.in.
4017 AC_SUBST(X_TOOLKIT_TYPE)
4018 AC_SUBST(ns_appdir)
4019 AC_SUBST(ns_appbindir)
4020 AC_SUBST(ns_appresdir)
4021 AC_SUBST(ns_appsrc)
4022 AC_SUBST(GNU_OBJC_CFLAGS)
4023 AC_SUBST(OTHER_FILES)
4024
4025 if test -n "${term_header}"; then
4026     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4027         [Define to the header for the built-in window system.])
4028 fi
4029
4030 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4031                    [Define to the canonical Emacs configuration name.])
4032 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
4033                    [Define to the options passed to configure.])
4034 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4035   define this to include extra configuration information.])
4036
4037 XMENU_OBJ=
4038 XOBJ=
4039 FONT_OBJ=
4040 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4041   AC_DEFINE(HAVE_X_WINDOWS, 1,
4042             [Define to 1 if you want to use the X window system.])
4043   XMENU_OBJ=xmenu.o
4044   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o xgselect.o"
4045   FONT_OBJ=xfont.o
4046   if test "$HAVE_XFT" = "yes"; then
4047     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4048   elif test "$HAVE_FREETYPE" = "yes"; then
4049     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4050   fi
4051   AC_SUBST(FONT_OBJ)
4052 fi
4053 AC_SUBST(XMENU_OBJ)
4054 AC_SUBST(XOBJ)
4055 AC_SUBST(FONT_OBJ)
4056
4057 WIDGET_OBJ=
4058 MOTIF_LIBW=
4059 if test "${USE_X_TOOLKIT}" != "none" ; then
4060   WIDGET_OBJ=widget.o
4061   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4062   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4063     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4064   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4065     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4066     MOTIF_LIBW=-lXm
4067     case "$opsys" in
4068       gnu-linux)
4069         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4070         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4071         ;;
4072
4073       unixware)
4074         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4075         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4076         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4077         ;;
4078
4079       aix4-2)
4080         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4081         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4082         ;;
4083     esac
4084     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4085   fi
4086 fi
4087 AC_SUBST(WIDGET_OBJ)
4088
4089 TOOLKIT_LIBW=
4090 case "$USE_X_TOOLKIT" in
4091   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4092   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4093   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4094 esac
4095 AC_SUBST(TOOLKIT_LIBW)
4096
4097 if test "$USE_X_TOOLKIT" = "none"; then
4098   LIBXT_OTHER="\$(LIBXSM)"
4099   OLDXMENU_TARGET="really-oldXMenu"
4100 else
4101   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4102   OLDXMENU_TARGET="really-lwlib"
4103 fi
4104 AC_SUBST(LIBXT_OTHER)
4105
4106 ## The X Menu stuff is present in the X10 distribution, but missing
4107 ## from X11.  If we have X10, just use the installed library;
4108 ## otherwise, use our own copy.
4109 if test "${HAVE_X11}" = "yes" ; then
4110   AC_DEFINE(HAVE_X11, 1,
4111             [Define to 1 if you want to use version 11 of X windows.
4112              Otherwise, Emacs expects to use version 10.])
4113
4114   if test "$USE_X_TOOLKIT" = "none"; then
4115     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
4116   else
4117     OLDXMENU="\${lwlibdir}/liblw.a"
4118   fi
4119   LIBXMENU="\$(OLDXMENU)"
4120   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4121   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
4122 else
4123   ## For a syntactically valid Makefile; not actually used for anything.
4124   ## See comments in src/Makefile.in.
4125   OLDXMENU=nothing
4126   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
4127   if test "${HAVE_X_WINDOWS}" = "yes"; then
4128     LIBXMENU="-lXMenu"
4129   else
4130     LIBXMENU=
4131   fi
4132   LIBX_OTHER=
4133   OLDXMENU_DEPS=
4134 fi
4135
4136 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
4137   OLDXMENU_TARGET=
4138   OLDXMENU=nothing
4139   LIBXMENU=
4140   OLDXMENU_DEPS=
4141 fi
4142
4143 AC_SUBST(OLDXMENU_TARGET)
4144 AC_SUBST(OLDXMENU)
4145 AC_SUBST(LIBXMENU)
4146 AC_SUBST(LIBX_OTHER)
4147 AC_SUBST(OLDXMENU_DEPS)
4148
4149 if test "${HAVE_MENUS}" = "yes" ; then
4150   AC_DEFINE(HAVE_MENUS, 1,
4151             [Define to 1 if you have mouse menus.
4152              (This is automatic if you use X, but the option to specify it remains.)
4153              It is also defined with other window systems that support xmenu.c.])
4154 fi
4155
4156 if test "${GNU_MALLOC}" = "yes" ; then
4157   AC_DEFINE(GNU_MALLOC, 1,
4158             [Define to 1 if you want to use the GNU memory allocator.])
4159 fi
4160
4161 RALLOC_OBJ=
4162 if test "${REL_ALLOC}" = "yes" ; then
4163   AC_DEFINE(REL_ALLOC, 1,
4164             [Define REL_ALLOC if you want to use the relocating allocator for
4165              buffer space.])
4166
4167   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4168 fi
4169 AC_SUBST(RALLOC_OBJ)
4170
4171 if test "$opsys" = "cygwin"; then
4172   CYGWIN_OBJ="sheap.o"
4173   ## Cygwin differs because of its unexec().
4174   PRE_ALLOC_OBJ=
4175   POST_ALLOC_OBJ=lastfile.o
4176 else
4177   CYGWIN_OBJ=
4178   PRE_ALLOC_OBJ=lastfile.o
4179   POST_ALLOC_OBJ=
4180 fi
4181 AC_SUBST(CYGWIN_OBJ)
4182 AC_SUBST(PRE_ALLOC_OBJ)
4183 AC_SUBST(POST_ALLOC_OBJ)
4184
4185 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4186 # it temporarily reverts them to their pre-pkg-config values,
4187 # because gnulib needs to work with both src (which uses the
4188 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4189 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4190 # and it therefore needs to run in an environment where LIBS does not
4191 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4192 # for some package unrelated to lib-src.
4193 SAVE_CFLAGS=$CFLAGS
4194 SAVE_LIBS=$LIBS
4195 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4196 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4197 gl_ASSERT_NO_GNULIB_POSIXCHECK
4198 gl_ASSERT_NO_GNULIB_TESTS
4199 gl_INIT
4200 CFLAGS=$SAVE_CFLAGS
4201 LIBS=$SAVE_LIBS
4202
4203 case "$opsys" in
4204   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4205
4206   darwin)
4207    ## The -headerpad option tells ld (see man page) to leave room at the
4208    ## end of the header for adding load commands.  Needed for dumping.
4209    ## 0x690 is the total size of 30 segment load commands (at 56
4210    ## each); under Cocoa 31 commands are required.
4211    if test "$HAVE_NS" = "yes"; then
4212      libs_nsgui="-framework AppKit"
4213      headerpad_extra=6C8
4214    else
4215      libs_nsgui=
4216      headerpad_extra=690
4217    fi
4218    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4219
4220    ## This is here because src/Makefile.in did some extra fiddling around
4221    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
4222    ##   #ifndef LD_SWITCH_SYSTEM
4223    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
4224    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
4225    ## not using gcc, darwin.
4226    ## Because this was done in src/Makefile.in, the resulting part of
4227    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
4228    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
4229    ## rather than LD_SWITCH_SYSTEM.
4230    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4231      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4232    ;;
4233
4234   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4235   ## find X at run-time.
4236   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4237   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4238   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4239   ## had different values in configure (in ac_link) and src/Makefile.in.
4240   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4241   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4242
4243   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4244 esac
4245
4246 if test "$NS_IMPL_GNUSTEP" = "yes"; then
4247   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
4248 fi
4249
4250 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4251
4252
4253 LD_FIRSTFLAG=
4254 ORDINARY_LINK=
4255 case "$opsys" in
4256   ## gnu: GNU needs its own crt0.
4257   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
4258
4259   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
4260   ## library search parth, i.e. it won't search /usr/lib for libc and
4261   ## friends.  Using -nostartfiles instead avoids this problem, and
4262   ## will also work on earlier NetBSD releases.
4263   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
4264
4265   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
4266   ##   MkLinux/LinuxPPC needs this.
4267   ## s390x-* only supports opsys = gnu-linux so it can be added here.
4268   gnu-*)
4269     case "$canonical" in
4270       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
4271     esac
4272     ;;
4273 esac
4274
4275
4276 if test "x$ORDINARY_LINK" = "xyes"; then
4277
4278   LD_FIRSTFLAG=""
4279   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
4280
4281 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
4282 ## freebsd, gnu-* not on powerpc*|s390x*.
4283 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
4284
4285   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
4286   ## places that are difficult to figure out at make time.  Fortunately,
4287   ## these same versions allow you to pass arbitrary flags on to the
4288   ## linker, so there is no reason not to use it as a linker.
4289   ##
4290   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
4291   ## searching for libraries in its internal directories, so we have to
4292   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
4293   LD_FIRSTFLAG="-nostdlib"
4294 fi
4295
4296 ## FIXME? What setting of EDIT_LDFLAGS should this have?
4297 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
4298
4299 AC_SUBST(LD_FIRSTFLAG)
4300
4301
4302 ## FIXME? The logic here is not precisely the same as that above.
4303 ## There is no check here for a pre-defined LD_FIRSTFLAG.
4304 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
4305 LIB_GCC=
4306 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
4307
4308   case "$opsys" in
4309     freebsd|netbsd|openbsd) LIB_GCC= ;;
4310
4311     gnu-*)
4312       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
4313       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
4314       case $host_cpu in
4315       arm*)
4316         LIB_GCC="-lgcc_s"
4317         ;;
4318       *)
4319         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
4320         ## immediately undefine it again and redefine it to empty.
4321         ## Was the C_SWITCH_X_SITE part really necessary?
4322 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
4323         LIB_GCC=
4324         ;;
4325       esac
4326       ;;
4327
4328     ## Ask GCC where to find libgcc.a.
4329     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
4330   esac
4331 fi                              dnl if $GCC
4332 AC_SUBST(LIB_GCC)
4333
4334 ## Common for all window systems
4335 if test "$window_system" != "none"; then
4336   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4337   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
4338   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4339 fi
4340
4341 AC_SUBST(WINDOW_SYSTEM_OBJ)
4342
4343 AH_TOP([/* GNU Emacs site configuration template file.
4344
4345 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
4346   Free Software Foundation, Inc.
4347
4348 This file is part of GNU Emacs.
4349
4350 GNU Emacs is free software: you can redistribute it and/or modify
4351 it under the terms of the GNU General Public License as published by
4352 the Free Software Foundation, either version 3 of the License, or
4353 (at your option) any later version.
4354
4355 GNU Emacs is distributed in the hope that it will be useful,
4356 but WITHOUT ANY WARRANTY; without even the implied warranty of
4357 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4358 GNU General Public License for more details.
4359
4360 You should have received a copy of the GNU General Public License
4361 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4362
4363
4364 /* No code in Emacs #includes config.h twice, but some bits of code
4365    intended to work with other packages as well (like gmalloc.c)
4366    think they can include it as many times as they like.  */
4367 #ifndef EMACS_CONFIG_H
4368 #define EMACS_CONFIG_H
4369 ])dnl
4370
4371 AH_BOTTOM([#include <conf_post.h>
4372
4373 #endif /* EMACS_CONFIG_H */
4374
4375 /*
4376 Local Variables:
4377 mode: c
4378 End:
4379 */
4380 ])dnl
4381
4382 #### Report on what we decided to do.
4383 #### Report GTK as a toolkit, even if it doesn't use Xt.
4384 #### It makes printing result more understandable as using GTK sets
4385 #### toolkit_scroll_bars to yes by default.
4386 if test "${HAVE_GTK}" = "yes"; then
4387   USE_X_TOOLKIT=GTK
4388 fi
4389
4390 echo "
4391 Configured for \`${canonical}'.
4392
4393   Where should the build process find the source code?    ${srcdir}
4394   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4395   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4396   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4397   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4398   What window system should Emacs use?                    ${window_system}
4399   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4400
4401 if test -n "${x_includes}"; then
4402 echo "  Where do we find X Windows header files?                ${x_includes}"
4403 else
4404 echo "  Where do we find X Windows header files?                Standard dirs"
4405 fi
4406 if test -n "${x_libraries}"; then
4407 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4408 else
4409 echo "  Where do we find X Windows libraries?                   Standard dirs"
4410 fi
4411
4412 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4413 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4414 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4415 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4416 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4417 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4418 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4419 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4420
4421 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4422 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4423 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4424 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4425 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4426 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4427 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4428
4429 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4430 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4431 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4432 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4433
4434 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
4435 echo
4436
4437 if test -n "${EMACSDATA}"; then
4438    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
4439 fi
4440 if test -n "${EMACSDOC}"; then
4441    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
4442 fi
4443
4444 echo
4445
4446 if test "$HAVE_NS" = "yes"; then
4447    echo
4448    echo "You must run \"${MAKE-make} install\" in order to test the built application.
4449 The installed application will go to nextstep/Emacs.app and can be
4450 run or moved from there."
4451    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
4452       echo "The application will be fully self-contained."
4453     else
4454       echo "The lisp resources for the application will be installed under ${prefix}.
4455 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
4456 to run if these resources are not installed."
4457    fi
4458    echo
4459 fi
4460
4461 if test "${opsys}" = "cygwin"; then
4462   case `uname -r` in
4463     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
4464            echo
4465            ;;
4466   esac
4467 fi
4468
4469 # Remove any trailing slashes in these variables.
4470 [test "${prefix}" != NONE &&
4471   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
4472 test "${exec_prefix}" != NONE &&
4473   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
4474
4475 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
4476 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
4477 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
4478 dnl (else you get "no `Makefile.am' found for any configure output").
4479 dnl This will work, but you get a config.status that is not quite right
4480 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
4481 dnl That doesn't have any obvious consequences for Emacs, but on the whole
4482 dnl it seems better to just live with the duplication.
4483 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
4484
4485 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
4486        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
4487        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
4488        leim/Makefile])
4489
4490 dnl test/ is not present in release tarfiles.
4491 opt_makefile=test/automated/Makefile
4492
4493 if test -f $srcdir/${opt_makefile}.in; then
4494   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4495   dnl Again, it's best not to use a variable.  Though you can add
4496   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
4497   AC_CONFIG_FILES([test/automated/Makefile])
4498 fi
4499
4500
4501 dnl admin/ may or may not be present.
4502 opt_makefile=admin/unidata/Makefile
4503
4504 if test -f $srcdir/${opt_makefile}.in; then
4505   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4506   AC_CONFIG_FILES([admin/unidata/Makefile])
4507 fi
4508
4509
4510 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
4511
4512 AC_SUBST(SUBDIR_MAKEFILES_IN)
4513
4514 dnl Make the necessary directories, if they don't exist.
4515 AC_CONFIG_COMMANDS([mkdirs], [
4516 for dir in etc lisp ; do
4517   test -d ${dir} || mkdir ${dir}
4518 done
4519 ])
4520
4521 dnl You might wonder (I did) why epaths.h is generated by running make,
4522 dnl rather than just letting configure generate it from epaths.in.
4523 dnl One reason is that the various paths are not fully expanded (see above);
4524 dnl eg gamedir=${prefix}/var/games/emacs.
4525 dnl Secondly, the GNU Coding standards require that one should be able
4526 dnl to run `make prefix=/some/where/else' and override the values set
4527 dnl by configure.  This also explains the `move-if-change' test and
4528 dnl the use of force in the `epaths-force' rule in Makefile.in.
4529 AC_CONFIG_COMMANDS([epaths], [
4530 echo creating src/epaths.h
4531 ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
4532 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
4533
4534 AC_CONFIG_COMMANDS([gdbinit], [
4535 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
4536   echo creating src/.gdbinit
4537   echo source $srcdir/src/.gdbinit > src/.gdbinit
4538 fi
4539 ])
4540
4541 AC_OUTPUT