lisp/tooltip.el

   1 ;;; tooltip.el --- show tooltip windows
   2
   3 ;; Copyright (C) 1997, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Gerd Moellmann <gerd@acm.org>
   7 ;; Keywords: help c mouse tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (defvar comint-prompt-regexp)
  29
  30 (defgroup tooltip nil
  31   "Customization group for the `tooltip' package."
  32   :group 'help
  33   :group 'gud
  34   :group 'mouse
  35   :group 'tools
  36   :version "21.1"
  37   :tag "Tool Tips")
  38 \f
  39 ;;; Switching tooltips on/off
  40
  41 (define-minor-mode tooltip-mode
  42   "Toggle Tooltip mode.
  43 With ARG, turn Tooltip mode on if and only if ARG is positive.
  44 When this minor mode is enabled, Emacs displays help text
  45 in a pop-up window for buttons and menu items that you put the mouse on.
  46 \(However, if `tooltip-use-echo-area' is non-nil, this and
  47 all pop-up help appears in the echo area.)
  48
  49 When Tooltip mode is disabled, Emacs displays one line of
  50 the help text in the echo area, and does not make a pop-up window."
  51   :global t
  52   :init-value (not (or noninteractive
  53                        emacs-basic-display
  54                        (not (display-graphic-p))
  55                        (not (fboundp 'x-show-tip))))
  56   :initialize 'custom-initialize-safe-default
  57   :group 'tooltip
  58   (unless (or (null tooltip-mode) (fboundp 'x-show-tip))
  59     (error "Sorry, tooltips are not yet available on this system"))
  60   (if tooltip-mode
  61       (progn
  62         (add-hook 'pre-command-hook 'tooltip-hide)
  63         (add-hook 'tooltip-hook 'tooltip-help-tips))
  64     (unless (and (boundp 'gud-tooltip-mode) gud-tooltip-mode)
  65       (remove-hook 'pre-command-hook 'tooltip-hide))
  66     (remove-hook 'tooltip-hook 'tooltip-help-tips))
  67   (setq show-help-function
  68         (if tooltip-mode 'tooltip-show-help 'tooltip-show-help-non-mode)))
  69
  70 \f
  71 ;;; Customizable settings
  72
  73 (defcustom tooltip-delay 0.7
  74   "Seconds to wait before displaying a tooltip the first time."
  75   :type 'number
  76   :group 'tooltip)
  77
  78 (defcustom tooltip-short-delay 0.1
  79   "Seconds to wait between subsequent tooltips on different items."
  80   :type 'number
  81   :group 'tooltip)
  82
  83 (defcustom tooltip-recent-seconds 1
  84   "Display tooltips if changing tip items within this many seconds.
  85 Do so after `tooltip-short-delay'."
  86   :type 'number
  87   :group 'tooltip)
  88
  89 (defcustom tooltip-hide-delay 10
  90   "Hide tooltips automatically after this many seconds."
  91   :type 'number
  92   :group 'tooltip)
  93
  94 (defcustom tooltip-x-offset 5
  95   "X offset, in pixels, for the display of tooltips.
  96 The offset is the distance between the X position of the mouse and
  97 the left border of the tooltip window.  It must be chosen so that the
  98 tooltip window doesn't contain the mouse when it pops up, or it may
  99 interfere with clicking where you wish.
 100
 101 If `tooltip-frame-parameters' includes the `left' parameter,
 102 the value of `tooltip-x-offset' is ignored."
 103   :type 'integer
 104   :group 'tooltip)
 105
 106 (defcustom tooltip-y-offset +20
 107   "Y offset, in pixels, for the display of tooltips.
 108 The offset is the distance between the Y position of the mouse and
 109 the top border of the tooltip window.  It must be chosen so that the
 110 tooltip window doesn't contain the mouse when it pops up, or it may
 111 interfere with clicking where you wish.
 112
 113 If `tooltip-frame-parameters' includes the `top' parameter,
 114 the value of `tooltip-y-offset' is ignored."
 115   :type 'integer
 116   :group 'tooltip)
 117
 118 (defcustom tooltip-frame-parameters
 119   '((name . "tooltip")
 120     (internal-border-width . 2)
 121     (border-width . 1))
 122   "Frame parameters used for tooltips.
 123
 124 If `left' or `top' parameters are included, they specify the absolute
 125 position to pop up the tooltip."
 126   :type 'sexp
 127   :group 'tooltip)
 128
 129 (defface tooltip
 130   '((((class color))
 131      :background "lightyellow"
 132      :foreground "black"
 133      :inherit variable-pitch)
 134     (t
 135      :inherit variable-pitch))
 136   "Face for tooltips."
 137   :group 'tooltip
 138   :group 'basic-faces)
 139
 140 (defcustom tooltip-use-echo-area nil
 141   "Use the echo area instead of tooltip frames for help and GUD tooltips.
 142 To display multi-line help text in the echo area, set this to t
 143 and enable `tooltip-mode'."
 144   :type 'boolean
 145   :group 'tooltip)
 146
 147 \f
 148 ;;; Variables that are not customizable.
 149
 150 (defvar tooltip-hook nil
 151   "Functions to call to display tooltips.
 152 Each function is called with one argument EVENT which is a copy of
 153 the last mouse movement event that occurred.")
 154
 155 (defvar tooltip-timeout-id nil
 156   "The id of the timeout started when Emacs becomes idle.")
 157
 158 (defvar tooltip-last-mouse-motion-event nil
 159   "A copy of the last mouse motion event seen.")
 160
 161 (defvar tooltip-hide-time nil
 162   "Time when the last tooltip was hidden.")
 163
 164 (defvar gud-tooltip-mode) ;; Prevent warning.
 165
 166 ;;; Event accessors
 167
 168 (defun tooltip-event-buffer (event)
 169   "Return the buffer over which event EVENT occurred.
 170 This might return nil if the event did not occur over a buffer."
 171   (let ((window (posn-window (event-end event))))
 172     (and window (window-buffer window))))
 173
 174 \f
 175 ;;; Timeout for tooltip display
 176
 177 (defun tooltip-delay ()
 178   "Return the delay in seconds for the next tooltip."
 179   (if (and tooltip-hide-time
 180            (< (- (float-time) tooltip-hide-time) tooltip-recent-seconds))
 181       tooltip-short-delay
 182     tooltip-delay))
 183
 184 (defun tooltip-cancel-delayed-tip ()
 185   "Disable the tooltip timeout."
 186   (when tooltip-timeout-id
 187     (disable-timeout tooltip-timeout-id)
 188     (setq tooltip-timeout-id nil)))
 189
 190 (defun tooltip-start-delayed-tip ()
 191   "Add a one-shot timeout to call function `tooltip-timeout'."
 192   (setq tooltip-timeout-id
 193         (add-timeout (tooltip-delay) 'tooltip-timeout nil)))
 194
 195 (defun tooltip-timeout (object)
 196   "Function called when timer with id `tooltip-timeout-id' fires."
 197   (run-hook-with-args-until-success 'tooltip-hook
 198                                     tooltip-last-mouse-motion-event))
 199
 200 \f
 201 ;;; Displaying tips
 202
 203 (defun tooltip-set-param (alist key value)
 204   "Change the value of KEY in alist ALIST to VALUE.
 205 If there's no association for KEY in ALIST, add one, otherwise
 206 change the existing association.  Value is the resulting alist."
 207   (let ((param (assq key alist)))
 208     (if (consp param)
 209         (setcdr param value)
 210       (push (cons key value) alist))
 211     alist))
 212
 213 (declare-function x-show-tip "xfns.c"
 214                   (string &optional frame parms timeout dx dy))
 215
 216 (defun tooltip-show (text &optional use-echo-area)
 217   "Show a tooltip window displaying TEXT.
 218
 219 Text larger than `x-max-tooltip-size' is clipped.
 220
 221 If the alist in `tooltip-frame-parameters' includes `left' and `top'
 222 parameters, they determine the x and y position where the tooltip
 223 is displayed.  Otherwise, the tooltip pops at offsets specified by
 224 `tooltip-x-offset' and `tooltip-y-offset' from the current mouse
 225 position.
 226
 227 Optional second arg USE-ECHO-AREA non-nil means to show tooltip
 228 in echo area."
 229   (if use-echo-area
 230       (tooltip-show-help-non-mode text)
 231     (condition-case error
 232         (let ((params (copy-sequence tooltip-frame-parameters))
 233               (fg (face-attribute 'tooltip :foreground))
 234               (bg (face-attribute 'tooltip :background)))
 235           (when (stringp fg)
 236             (setq params (tooltip-set-param params 'foreground-color fg))
 237             (setq params (tooltip-set-param params 'border-color fg)))
 238           (when (stringp bg)
 239             (setq params (tooltip-set-param params 'background-color bg)))
 240           (x-show-tip (propertize text 'face 'tooltip)
 241                       (selected-frame)
 242                       params
 243                       tooltip-hide-delay
 244                       tooltip-x-offset
 245                       tooltip-y-offset))
 246       (error
 247        (message "Error while displaying tooltip: %s" error)
 248        (sit-for 1)
 249        (message "%s" text)))))
 250
 251 (declare-function x-hide-tip "xfns.c" ())
 252
 253 (defun tooltip-hide (&optional ignored-arg)
 254   "Hide a tooltip, if one is displayed.
 255 Value is non-nil if tooltip was open."
 256   (tooltip-cancel-delayed-tip)
 257   (when (x-hide-tip)
 258     (setq tooltip-hide-time (float-time))))
 259
 260 \f
 261 ;;; Debugger-related functions
 262
 263 (defun tooltip-identifier-from-point (point)
 264   "Extract the identifier at POINT, if any.
 265 Value is nil if no identifier exists at point.  Identifier extraction
 266 is based on the current syntax table."
 267   (save-excursion
 268     (goto-char point)
 269     (let ((start (progn (skip-syntax-backward "w_") (point))))
 270       (unless (looking-at "[0-9]")
 271         (skip-syntax-forward "w_")
 272         (when (> (point) start)
 273           (buffer-substring start (point)))))))
 274
 275 (defmacro tooltip-region-active-p ()
 276   "Value is non-nil if the region should override command actions."
 277   `(use-region-p))
 278
 279 (defun tooltip-expr-to-print (event)
 280   "Return an expression that should be printed for EVENT.
 281 If a region is active and the mouse is inside the region, print
 282 the region.  Otherwise, figure out the identifier around the point
 283 where the mouse is."
 284   (with-current-buffer (tooltip-event-buffer event)
 285     (let ((point (posn-point (event-end event))))
 286       (if (tooltip-region-active-p)
 287           (when (and (<= (region-beginning) point) (<= point (region-end)))
 288             (buffer-substring (region-beginning) (region-end)))
 289         (tooltip-identifier-from-point point)))))
 290
 291 (defun tooltip-process-prompt-regexp (process)
 292   "Return regexp matching the prompt of PROCESS at the end of a string.
 293 The prompt is taken from the value of `comint-prompt-regexp' in
 294 the buffer of PROCESS."
 295   (let ((prompt-regexp (with-current-buffer (process-buffer process)
 296                          comint-prompt-regexp)))
 297     (concat "\n*"
 298             ;; Most start with `^' but the one for `sdb' cannot be easily
 299             ;; stripped.  Code the prompt for `sdb' fixed here.
 300             (if (= (aref prompt-regexp 0) ?^)
 301                 (substring prompt-regexp 1)
 302               "\\*")
 303             "$")))
 304
 305 (defun tooltip-strip-prompt (process output)
 306   "Return OUTPUT with any prompt of PROCESS stripped from its end."
 307   (save-match-data
 308     (if (string-match (tooltip-process-prompt-regexp process) output)
 309         (substring output 0 (match-beginning 0))
 310       output)))
 311
 312 \f
 313 ;;; Tooltip help.
 314
 315 (defvar tooltip-help-message nil
 316   "The last help message received via `tooltip-show-help'.")
 317
 318 (defvar tooltip-previous-message nil
 319   "The previous content of the echo area.")
 320
 321 (defun tooltip-show-help-non-mode (help)
 322   "Function installed as `show-help-function' when tooltip is off."
 323   (when (and (not (window-minibuffer-p)) ;Don't overwrite minibuffer contents.
 324              ;; Don't know how to reproduce it in Elisp:
 325              ;; Don't overwrite a keystroke echo.
 326              ;; (NILP (echo_message_buffer) || ok_to_overwrite_keystroke_echo)
 327              (not cursor-in-echo-area)) ;Don't overwrite a prompt.
 328     (cond
 329      ((stringp help)
 330       (unless tooltip-previous-message
 331         (setq tooltip-previous-message (current-message)))
 332       (let ((message-truncate-lines t)
 333             (message-log-max nil))
 334         (message "%s" (replace-regexp-in-string "\n" ", " help))))
 335      ((stringp tooltip-previous-message)
 336       (let ((message-log-max nil))
 337         (message "%s" tooltip-previous-message)
 338         (setq tooltip-previous-message nil)))
 339      (t
 340       (message nil)))))
 341
 342
 343 (defun tooltip-show-help (msg)
 344   "Function installed as `show-help-function'.
 345 MSG is either a help string to display, or nil to cancel the display."
 346   (let ((previous-help tooltip-help-message))
 347     (setq tooltip-help-message msg)
 348     (cond ((null msg)
 349            ;; Cancel display.  This also cancels a delayed tip, if
 350            ;; there is one.
 351            (tooltip-hide))
 352           ((equal previous-help msg)
 353            ;; Same help as before (but possibly the mouse has moved).
 354            ;; Keep what we have.
 355            )
 356           (t
 357            ;; A different help.  Remove a previous tooltip, and
 358            ;; display a new one, with some delay.
 359            (tooltip-hide)
 360            (tooltip-start-delayed-tip)))))
 361
 362 (defun tooltip-help-tips (event)
 363   "Hook function to display a help tooltip.
 364 This is installed on the hook `tooltip-hook', which is run when
 365 the timer with id `tooltip-timeout-id' fires.
 366 Value is non-nil if this function handled the tip."
 367   (when (stringp tooltip-help-message)
 368     (tooltip-show tooltip-help-message tooltip-use-echo-area)
 369     t))
 370
 371 (provide 'tooltip)
 372
 373 ;; arch-tag: 3d61135e-4618-4a78-af28-183f6df5636f
 374 ;;; tooltip.el ends here