lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   5 ;;   Free Software Foundation, Inc.
   6
   7 ;; Maintainer: FSF
   8 ;; Keywords: help, internal
   9 ;; Package: emacs
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This file contains those help commands which are complicated, and
  29 ;; which may not be used in every session.  For example
  30 ;; `describe-function' will probably be heavily used when doing elisp
  31 ;; programming, but not if just editing C files.  Simpler help commands
  32 ;; are in help.el
  33
  34 ;;; Code:
  35
  36 ;; Functions
  37
  38 ;;;###autoload
  39 (defun describe-function (function)
  40   "Display the full documentation of FUNCTION (a symbol)."
  41   (interactive
  42    (let ((fn (function-called-at-point))
  43          (enable-recursive-minibuffers t)
  44          val)
  45      (setq val (completing-read (if fn
  46                                     (format "Describe function (default %s): " fn)
  47                                   "Describe function: ")
  48                                 obarray 'fboundp t nil nil
  49                                 (and fn (symbol-name fn))))
  50      (list (if (equal val "")
  51                fn (intern val)))))
  52   (if (null function)
  53       (message "You didn't specify a function")
  54     (help-setup-xref (list #'describe-function function)
  55                      (called-interactively-p 'interactive))
  56     (save-excursion
  57       (with-help-window (help-buffer)
  58         (prin1 function)
  59         ;; Use " is " instead of a colon so that
  60         ;; it is easier to get out the function name using forward-sexp.
  61         (princ " is ")
  62         (describe-function-1 function)
  63         (with-current-buffer standard-output
  64           ;; Return the text we displayed.
  65           (buffer-string))))))
  66
  67 (defun help-split-fundoc (docstring def)
  68   "Split a function DOCSTRING into the actual doc and the usage info.
  69 Return (USAGE . DOC) or nil if there's no usage info.
  70 DEF is the function whose usage we're looking for in DOCSTRING."
  71   ;; Functions can get the calling sequence at the end of the doc string.
  72   ;; In cases where `function' has been fset to a subr we can't search for
  73   ;; function's name in the doc string so we use `fn' as the anonymous
  74   ;; function name instead.
  75   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
  76     (cons (format "(%s%s"
  77                   ;; Replace `fn' with the actual function name.
  78                   (if (consp def) "anonymous" def)
  79                   (match-string 1 docstring))
  80           (substring docstring 0 (match-beginning 0)))))
  81
  82 (defun help-add-fundoc-usage (docstring arglist)
  83   "Add the usage info to DOCSTRING.
  84 If DOCSTRING already has a usage info, then just return it unchanged.
  85 The usage info is built from ARGLIST.  DOCSTRING can be nil.
  86 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
  87   (unless (stringp docstring) (setq docstring "Not documented"))
  88   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring) (eq arglist t))
  89       docstring
  90     (concat docstring
  91             (if (string-match "\n?\n\\'" docstring)
  92                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
  93               "\n\n")
  94             (if (and (stringp arglist)
  95                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
  96                 (concat "(fn" (match-string 1 arglist) ")")
  97               (format "%S" (help-make-usage 'fn arglist))))))
  98
  99 (defun help-function-arglist (def)
 100   ;; Handle symbols aliased to other symbols.
 101   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
 102   ;; If definition is a macro, find the function inside it.
 103   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
 104   (cond
 105    ((byte-code-function-p def) (aref def 0))
 106    ((eq (car-safe def) 'lambda) (nth 1 def))
 107    ((and (eq (car-safe def) 'autoload) (not (eq (nth 4 def) 'keymap)))
 108     "[Arg list not available until function definition is loaded.]")
 109    (t t)))
 110
 111 (defun help-make-usage (function arglist)
 112   (cons (if (symbolp function) function 'anonymous)
 113         (mapcar (lambda (arg)
 114                   (if (not (symbolp arg))
 115                       (if (and (consp arg) (symbolp (car arg)))
 116                           ;; CL style default values for optional args.
 117                           (cons (intern (upcase (symbol-name (car arg))))
 118                                 (cdr arg))
 119                         arg)
 120                     (let ((name (symbol-name arg)))
 121                       (if (string-match "\\`&" name) arg
 122                         (intern (upcase name))))))
 123                 arglist)))
 124
 125 ;; Could be this, if we make symbol-file do the work below.
 126 ;; (defun help-C-file-name (subr-or-var kind)
 127 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
 128 ;; KIND should be `var' for a variable or `subr' for a subroutine."
 129 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
 130 ;;               (subr-name subr-or-var))
 131 ;;             (if (eq kind 'var) 'defvar 'defun)))
 132 ;;;###autoload
 133 (defun help-C-file-name (subr-or-var kind)
 134   "Return the name of the C file where SUBR-OR-VAR is defined.
 135 KIND should be `var' for a variable or `subr' for a subroutine."
 136   (let ((docbuf (get-buffer-create " *DOC*"))
 137         (name (if (eq 'var kind)
 138                   (concat "V" (symbol-name subr-or-var))
 139                 (concat "F" (subr-name subr-or-var)))))
 140     (with-current-buffer docbuf
 141       (goto-char (point-min))
 142       (if (eobp)
 143           (insert-file-contents-literally
 144            (expand-file-name internal-doc-file-name doc-directory)))
 145       (let ((file (catch 'loop
 146                     (while t
 147                       (let ((pnt (search-forward (concat "\x1f" name "\n"))))
 148                         (re-search-backward "\x1fS\\(.*\\)")
 149                         (let ((file (match-string 1)))
 150                           (if (member file build-files)
 151                               (throw 'loop file)
 152                             (goto-char pnt))))))))
 153         (if (string-match "^ns.*\\(\\.o\\|obj\\)\\'" file)
 154             (setq file (replace-match ".m" t t file 1))
 155           (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 156               (setq file (replace-match ".c" t t file))))
 157         (if (string-match "\\.\\(c\\|m\\)\\'" file)
 158             (concat "src/" file)
 159           file)))))
 160
 161 (defcustom help-downcase-arguments nil
 162   "If non-nil, argument names in *Help* buffers are downcased."
 163   :type 'boolean
 164   :group 'help
 165   :version "23.2")
 166
 167 (defun help-highlight-arg (arg)
 168   "Highlight ARG as an argument name for a *Help* buffer.
 169 Return ARG in face `help-argument-name'; ARG is also downcased
 170 if the variable `help-downcase-arguments' is non-nil."
 171   (propertize (if help-downcase-arguments (downcase arg) arg)
 172               'face 'help-argument-name))
 173
 174 (defun help-do-arg-highlight (doc args)
 175   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 176     (modify-syntax-entry ?\- "w")
 177     (dolist (arg args doc)
 178       (setq doc (replace-regexp-in-string
 179                  ;; This is heuristic, but covers all common cases
 180                  ;; except ARG1-ARG2
 181                  (concat "\\<"                   ; beginning of word
 182                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 183                          "\\("
 184                          (regexp-quote arg)
 185                          "\\)"
 186                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 187                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 188                          "\\(?:-[{([<`\"].*?\\)?"; for ARG-{x}, (x), <x>, [x], `x'
 189                          "\\>")                  ; end of word
 190                  (help-highlight-arg arg)
 191                  doc t t 1)))))
 192
 193 (defun help-highlight-arguments (usage doc &rest args)
 194   (when usage
 195     (with-temp-buffer
 196       (insert usage)
 197       (goto-char (point-min))
 198       (let ((case-fold-search nil)
 199             (next (not (or args (looking-at "\\["))))
 200             (opt nil))
 201         ;; Make a list of all arguments
 202         (skip-chars-forward "^ ")
 203         (while next
 204           (or opt (not (looking-at " &")) (setq opt t))
 205           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 206               (setq next nil)
 207             (setq args (cons (match-string 2) args))
 208             (when (and opt (string= (match-string 1) "("))
 209               ;; A pesky CL-style optional argument with default value,
 210               ;; so let's skip over it
 211               (search-backward "(")
 212               (goto-char (scan-sexps (point) 1)))))
 213         ;; Highlight aguments in the USAGE string
 214         (setq usage (help-do-arg-highlight (buffer-string) args))
 215         ;; Highlight arguments in the DOC string
 216         (setq doc (and doc (help-do-arg-highlight doc args))))))
 217   ;; Return value is like the one from help-split-fundoc, but highlighted
 218   (cons usage doc))
 219
 220 ;; The following function was compiled from the former functions
 221 ;; `describe-simplify-lib-file-name' and `find-source-lisp-file' with
 222 ;; some excerpts from `describe-function-1' and `describe-variable'.
 223 ;; The only additional twists provided are (1) locate the defining file
 224 ;; for autoloaded functions, and (2) give preference to files in the
 225 ;; "install directory" (directories found via `load-path') rather than
 226 ;; to files in the "compile directory" (directories found by searching
 227 ;; the loaddefs.el file).  We autoload it because it's also used by
 228 ;; `describe-face' (instead of `describe-simplify-lib-file-name').
 229
 230 ;;;###autoload
 231 (defun find-lisp-object-file-name (object type)
 232   "Guess the file that defined the Lisp object OBJECT, of type TYPE.
 233 OBJECT should be a symbol associated with a function, variable, or face;
 234   alternatively, it can be a function definition.
 235 If TYPE is `defvar', search for a variable definition.
 236 If TYPE is `defface', search for a face definition.
 237 If TYPE is the value returned by `symbol-function' for a function symbol,
 238  search for a function definition.
 239
 240 The return value is the absolute name of a readable file where OBJECT is
 241 defined.  If several such files exist, preference is given to a file
 242 found via `load-path'.  The return value can also be `C-source', which
 243 means that OBJECT is a function or variable defined in C.  If no
 244 suitable file is found, return nil."
 245   (let* ((autoloaded (eq (car-safe type) 'autoload))
 246          (file-name (or (and autoloaded (nth 1 type))
 247                         (symbol-file
 248                          object (if (memq type (list 'defvar 'defface))
 249                                     type
 250                                   'defun)))))
 251     (cond
 252      (autoloaded
 253       ;; An autoloaded function: Locate the file since `symbol-function'
 254       ;; has only returned a bare string here.
 255       (setq file-name
 256             (locate-file file-name load-path '(".el" ".elc") 'readable)))
 257      ((and (stringp file-name)
 258            (string-match "[.]*loaddefs.el\\'" file-name))
 259       ;; An autoloaded variable or face.  Visit loaddefs.el in a buffer
 260       ;; and try to extract the defining file.  The following form is
 261       ;; from `describe-function-1' and `describe-variable'.
 262       (let ((location
 263              (condition-case nil
 264                  (find-function-search-for-symbol object nil file-name)
 265                (error nil))))
 266         (when (cdr location)
 267           (with-current-buffer (car location)
 268             (goto-char (cdr location))
 269             (when (re-search-backward
 270                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 271               (setq file-name
 272                     (locate-file
 273                      (file-name-sans-extension
 274                       (match-string-no-properties 1))
 275                      load-path '(".el" ".elc") 'readable))))))))
 276
 277     (cond
 278      ((and (not file-name) (subrp type))
 279       ;; A built-in function.  The form is from `describe-function-1'.
 280       (if (get-buffer " *DOC*")
 281           (help-C-file-name type 'subr)
 282         'C-source))
 283      ((and (not file-name) (symbolp object)
 284            (integerp (get object 'variable-documentation)))
 285       ;; A variable defined in C.  The form is from `describe-variable'.
 286       (if (get-buffer " *DOC*")
 287           (help-C-file-name object 'var)
 288         'C-source))
 289      ((not (stringp file-name))
 290       ;; If we don't have a file-name string by now, we lost.
 291       nil)
 292      ;; Now, `file-name' should have become an absolute file name.
 293      ;; For files loaded from ~/.emacs.elc, try ~/.emacs.
 294      ((let (fn)
 295         (and (string-equal file-name
 296                            (expand-file-name ".emacs.elc" "~"))
 297              (file-readable-p (setq fn (expand-file-name ".emacs" "~")))
 298              fn)))
 299      ;; When the Elisp source file can be found in the install
 300      ;; directory, return the name of that file.
 301      ((let ((lib-name
 302              (if (string-match "[.]elc\\'" file-name)
 303                  (substring-no-properties file-name 0 -1)
 304                file-name)))
 305         (or (and (file-readable-p lib-name) lib-name)
 306             ;; The library might be compressed.
 307             (and (file-readable-p (concat lib-name ".gz")) lib-name))))
 308      ((let* ((lib-name (file-name-nondirectory file-name))
 309              ;; The next form is from `describe-simplify-lib-file-name'.
 310              (file-name
 311               ;; Try converting the absolute file name to a library
 312               ;; name, convert that back to a file name and see if we
 313               ;; get the original one.  If so, they are equivalent.
 314               (if (equal file-name (locate-file lib-name load-path '("")))
 315                   (if (string-match "[.]elc\\'" lib-name)
 316                       (substring-no-properties lib-name 0 -1)
 317                     lib-name)
 318                 file-name))
 319              ;; The next three forms are from `find-source-lisp-file'.
 320              (elc-file (locate-file
 321                         (concat file-name
 322                                 (if (string-match "\\.el\\'" file-name)
 323                                     "c"
 324                                   ".elc"))
 325                         load-path nil 'readable))
 326              (str (when elc-file
 327                     (with-temp-buffer
 328                       (insert-file-contents-literally elc-file nil 0 256)
 329                       (buffer-string))))
 330              (src-file (and str
 331                             (string-match ";;; from file \\(.*\\.el\\)" str)
 332                             (match-string 1 str))))
 333         (and src-file (file-readable-p src-file) src-file))))))
 334
 335 (declare-function ad-get-advice-info "advice" (function))
 336
 337 ;;;###autoload
 338 (defun describe-function-1 (function)
 339   (let* ((advised (and (symbolp function) (featurep 'advice)
 340                        (ad-get-advice-info function)))
 341          ;; If the function is advised, use the symbol that has the
 342          ;; real definition, if that symbol is already set up.
 343          (real-function
 344           (or (and advised
 345                    (let ((origname (cdr (assq 'origname advised))))
 346                      (and (fboundp origname) origname)))
 347               function))
 348          ;; Get the real definition.
 349          (def (if (symbolp real-function)
 350                   (symbol-function real-function)
 351                 function))
 352          file-name string
 353          (beg (if (commandp def) "an interactive " "a "))
 354          (pt1 (with-current-buffer (help-buffer) (point)))
 355          errtype)
 356     (setq string
 357           (cond ((or (stringp def)
 358                      (vectorp def))
 359                  "a keyboard macro")
 360                 ((subrp def)
 361                  (if (eq 'unevalled (cdr (subr-arity def)))
 362                      (concat beg "special form")
 363                    (concat beg "built-in function")))
 364                 ((byte-code-function-p def)
 365                  (concat beg "compiled Lisp function"))
 366                 ((symbolp def)
 367                  (while (and (fboundp def)
 368                              (symbolp (symbol-function def)))
 369                    (setq def (symbol-function def)))
 370                  ;; Handle (defalias 'foo 'bar), where bar is undefined.
 371                  (or (fboundp def) (setq errtype 'alias))
 372                  (format "an alias for `%s'" def))
 373                 ((eq (car-safe def) 'lambda)
 374                  (concat beg "Lisp function"))
 375                 ((eq (car-safe def) 'macro)
 376                  "a Lisp macro")
 377                 ((eq (car-safe def) 'autoload)
 378                  (format "%s autoloaded %s"
 379                          (if (commandp def) "an interactive" "an")
 380                          (if (eq (nth 4 def) 'keymap) "keymap"
 381                            (if (nth 4 def) "Lisp macro" "Lisp function"))))
 382                 ((keymapp def)
 383                  (let ((is-full nil)
 384                        (elts (cdr-safe def)))
 385                    (while elts
 386                      (if (char-table-p (car-safe elts))
 387                          (setq is-full t
 388                                elts nil))
 389                      (setq elts (cdr-safe elts)))
 390                    (if is-full
 391                        "a full keymap"
 392                      "a sparse keymap")))
 393                 (t "")))
 394     (princ string)
 395     (if (eq errtype 'alias)
 396         (princ ",\nwhich is not defined.  Please make a bug report.")
 397       (with-current-buffer standard-output
 398         (save-excursion
 399           (save-match-data
 400             (when (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 401               (help-xref-button 1 'help-function def)))))
 402
 403       (setq file-name (find-lisp-object-file-name function def))
 404       (when file-name
 405         (princ " in `")
 406         ;; We used to add .el to the file name,
 407         ;; but that's completely wrong when the user used load-file.
 408         (princ (if (eq file-name 'C-source)
 409                    "C source code"
 410                  (file-name-nondirectory file-name)))
 411         (princ "'")
 412         ;; Make a hyperlink to the library.
 413         (with-current-buffer standard-output
 414           (save-excursion
 415             (re-search-backward "`\\([^`']+\\)'" nil t)
 416             (help-xref-button 1 'help-function-def function file-name))))
 417       (princ ".")
 418       (with-current-buffer (help-buffer)
 419         (fill-region-as-paragraph (save-excursion (goto-char pt1) (forward-line 0) (point))
 420                                   (point)))
 421       (terpri)(terpri)
 422       (when (commandp function)
 423         (let ((pt2 (with-current-buffer (help-buffer) (point)))
 424               (remapped (command-remapping function)))
 425           (unless (memq remapped '(ignore undefined))
 426             (let ((keys (where-is-internal
 427                          (or remapped function) overriding-local-map nil nil))
 428                   non-modified-keys)
 429               (if (and (eq function 'self-insert-command)
 430                        (vectorp (car-safe keys))
 431                        (consp (aref (car keys) 0)))
 432                   (princ "It is bound to many ordinary text characters.\n")
 433                 ;; Which non-control non-meta keys run this command?
 434                 (dolist (key keys)
 435                   (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 436                       (push key non-modified-keys)))
 437                 (when remapped
 438                   (princ "It is remapped to `")
 439                   (princ (symbol-name remapped))
 440                   (princ "'"))
 441
 442                 (when keys
 443                   (princ (if remapped ", which is bound to " "It is bound to "))
 444                   ;; If lots of ordinary text characters run this command,
 445                   ;; don't mention them one by one.
 446                   (if (< (length non-modified-keys) 10)
 447                       (princ (mapconcat 'key-description keys ", "))
 448                     (dolist (key non-modified-keys)
 449                       (setq keys (delq key keys)))
 450                     (if keys
 451                         (progn
 452                           (princ (mapconcat 'key-description keys ", "))
 453                           (princ ", and many ordinary text characters"))
 454                       (princ "many ordinary text characters"))))
 455                 (when (or remapped keys non-modified-keys)
 456                   (princ ".")
 457                   (terpri)))))
 458
 459           (with-current-buffer (help-buffer)
 460             (fill-region-as-paragraph pt2 (point))
 461             (unless (looking-back "\n\n")
 462               (terpri)))))
 463       ;; Note that list* etc do not get this property until
 464       ;; cl-hack-byte-compiler runs, after bytecomp is loaded.
 465       (when (and (symbolp function)
 466                  (eq (get function 'byte-compile)
 467                      'cl-byte-compile-compiler-macro))
 468         (princ "This function has a compiler macro")
 469         (let ((lib (get function 'compiler-macro-file)))
 470           (when (stringp lib)
 471             (princ (format " in `%s'" lib))
 472             (with-current-buffer standard-output
 473               (save-excursion
 474                 (re-search-backward "`\\([^`']+\\)'" nil t)
 475                 (help-xref-button 1 'help-function-cmacro function lib)))))
 476         (princ ".\n\n"))
 477       (let* ((advertised (gethash def advertised-signature-table t))
 478              (arglist (if (listp advertised)
 479                           advertised (help-function-arglist def)))
 480              (doc (documentation function))
 481              (usage (help-split-fundoc doc function)))
 482         (with-current-buffer standard-output
 483           ;; If definition is a keymap, skip arglist note.
 484           (unless (keymapp function)
 485             (if usage (setq doc (cdr usage)))
 486             (let* ((use (cond
 487                          ((and usage (not (listp advertised))) (car usage))
 488                          ((listp arglist)
 489                           (format "%S" (help-make-usage function arglist)))
 490                          ((stringp arglist) arglist)
 491                          ;; Maybe the arglist is in the docstring of a symbol
 492                          ;; this one is aliased to.
 493                          ((let ((fun real-function))
 494                             (while (and (symbolp fun)
 495                                         (setq fun (symbol-function fun))
 496                                         (not (setq usage (help-split-fundoc
 497                                                           (documentation fun)
 498                                                           function)))))
 499                             usage)
 500                           (car usage))
 501                          ((or (stringp def)
 502                               (vectorp def))
 503                           (format "\nMacro: %s" (format-kbd-macro def)))
 504                          (t "[Missing arglist.  Please make a bug report.]")))
 505                    (high (help-highlight-arguments use doc)))
 506               (let ((fill-begin (point)))
 507                 (insert (car high) "\n")
 508                 (fill-region fill-begin (point)))
 509               (setq doc (cdr high))))
 510           (let* ((obsolete (and
 511                             ;; function might be a lambda construct.
 512                             (symbolp function)
 513                             (get function 'byte-obsolete-info)))
 514                  (use (car obsolete)))
 515             (when obsolete
 516               (princ "\nThis function is obsolete")
 517               (when (nth 2 obsolete)
 518                 (insert (format " since %s" (nth 2 obsolete))))
 519               (insert (cond ((stringp use) (concat ";\n" use))
 520                             (use (format ";\nuse `%s' instead." use))
 521                             (t "."))
 522                       "\n"))
 523             (insert "\n"
 524                     (or doc "Not documented."))))))))
 525
 526 \f
 527 ;; Variables
 528
 529 ;;;###autoload
 530 (defun variable-at-point (&optional any-symbol)
 531   "Return the bound variable symbol found at or before point.
 532 Return 0 if there is no such symbol.
 533 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 534   (with-syntax-table emacs-lisp-mode-syntax-table
 535     (or (condition-case ()
 536             (save-excursion
 537               (or (not (zerop (skip-syntax-backward "_w")))
 538                   (eq (char-syntax (following-char)) ?w)
 539                   (eq (char-syntax (following-char)) ?_)
 540                   (forward-sexp -1))
 541               (skip-chars-forward "'")
 542               (let ((obj (read (current-buffer))))
 543                 (and (symbolp obj) (boundp obj) obj)))
 544           (error nil))
 545         (let* ((str (find-tag-default))
 546                (sym (if str (intern-soft str))))
 547           (if (and sym (or any-symbol (boundp sym)))
 548               sym
 549             (save-match-data
 550               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 551                 (setq sym (intern-soft (match-string 1 str)))
 552                 (and (or any-symbol (boundp sym)) sym)))))
 553         0)))
 554
 555 (defun describe-variable-custom-version-info (variable)
 556   (let ((custom-version (get variable 'custom-version))
 557         (cpv (get variable 'custom-package-version))
 558         (output nil))
 559     (if custom-version
 560         (setq output
 561               (format "This variable was introduced, or its default value was changed, in\nversion %s of Emacs.\n"
 562                       custom-version))
 563       (when cpv
 564         (let* ((package (car-safe cpv))
 565                (version (if (listp (cdr-safe cpv))
 566                             (car (cdr-safe cpv))
 567                           (cdr-safe cpv)))
 568                (pkg-versions (assq package customize-package-emacs-version-alist))
 569                (emacsv (cdr (assoc version pkg-versions))))
 570           (if (and package version)
 571               (setq output
 572                     (format (concat "This variable was introduced, or its default value was changed, in\nversion %s of the %s package"
 573                                     (if emacsv
 574                                         (format " that is part of Emacs %s" emacsv))
 575                                     ".\n")
 576                             version package))))))
 577     output))
 578
 579 ;;;###autoload
 580 (defun describe-variable (variable &optional buffer frame)
 581   "Display the full documentation of VARIABLE (a symbol).
 582 Returns the documentation as a string, also.
 583 If VARIABLE has a buffer-local value in BUFFER or FRAME
 584 \(default to the current buffer and current frame),
 585 it is displayed along with the global value."
 586   (interactive
 587    (let ((v (variable-at-point))
 588          (enable-recursive-minibuffers t)
 589          val)
 590      (setq val (completing-read (if (symbolp v)
 591                                     (format
 592                                      "Describe variable (default %s): " v)
 593                                   "Describe variable: ")
 594                                 obarray
 595                                 '(lambda (vv)
 596                                    (or (boundp vv)
 597                                        (get vv 'variable-documentation)))
 598                                 t nil nil
 599                                 (if (symbolp v) (symbol-name v))))
 600      (list (if (equal val "")
 601                v (intern val)))))
 602   (let (file-name)
 603     (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 604     (unless (frame-live-p frame) (setq frame (selected-frame)))
 605     (if (not (symbolp variable))
 606         (message "You did not specify a variable")
 607       (save-excursion
 608         (let ((valvoid (not (with-current-buffer buffer (boundp variable))))
 609               val val-start-pos locus)
 610           ;; Extract the value before setting up the output buffer,
 611           ;; in case `buffer' *is* the output buffer.
 612           (unless valvoid
 613             (with-selected-frame frame
 614               (with-current-buffer buffer
 615                 (setq val (symbol-value variable)
 616                       locus (variable-binding-locus variable)))))
 617           (help-setup-xref (list #'describe-variable variable buffer)
 618                            (called-interactively-p 'interactive))
 619           (with-help-window (help-buffer)
 620             (with-current-buffer buffer
 621               (prin1 variable)
 622               (setq file-name (find-lisp-object-file-name variable 'defvar))
 623
 624               (if file-name
 625                   (progn
 626                     (princ " is a variable defined in `")
 627                     (princ (if (eq file-name 'C-source)
 628                                "C source code"
 629                              (file-name-nondirectory file-name)))
 630                     (princ "'.\n")
 631                     (with-current-buffer standard-output
 632                       (save-excursion
 633                         (re-search-backward "`\\([^`']+\\)'" nil t)
 634                         (help-xref-button 1 'help-variable-def
 635                                           variable file-name)))
 636                     (if valvoid
 637                         (princ "It is void as a variable.")
 638                       (princ "Its ")))
 639                 (if valvoid
 640                     (princ " is void as a variable.")
 641                   (princ "'s "))))
 642             (unless valvoid
 643               (with-current-buffer standard-output
 644                 (setq val-start-pos (point))
 645                 (princ "value is ")
 646                 (let ((from (point)))
 647                   (terpri)
 648                   (pp val)
 649                   (if (< (point) (+ 68 (line-beginning-position 0)))
 650                       (delete-region from (1+ from))
 651                     (delete-region (1- from) from))
 652                   (let* ((sv (get variable 'standard-value))
 653                          (origval (and (consp sv)
 654                                        (condition-case nil
 655                                            (eval (car sv))
 656                                          (error :help-eval-error)))))
 657                     (when (and (consp sv)
 658                                (not (equal origval val))
 659                                (not (equal origval :help-eval-error)))
 660                       (princ "\nOriginal value was \n")
 661                       (setq from (point))
 662                       (pp origval)
 663                       (if (< (point) (+ from 20))
 664                           (delete-region (1- from) from)))))))
 665             (terpri)
 666             (when locus
 667               (if (bufferp locus)
 668                   (princ (format "%socal in buffer %s; "
 669                                  (if (get variable 'permanent-local)
 670                                      "Permanently l" "L")
 671                                  (buffer-name)))
 672                 (princ (format "It is a frame-local variable; ")))
 673               (if (not (default-boundp variable))
 674                   (princ "globally void")
 675                 (let ((val (default-value variable)))
 676                   (with-current-buffer standard-output
 677                     (princ "global value is ")
 678                     (terpri)
 679                     ;; Fixme: pp can take an age if you happen to
 680                     ;; ask for a very large expression.  We should
 681                     ;; probably print it raw once and check it's a
 682                     ;; sensible size before prettyprinting.  -- fx
 683                     (let ((from (point)))
 684                       (pp val)
 685                       ;; See previous comment for this function.
 686                       ;; (help-xref-on-pp from (point))
 687                       (if (< (point) (+ from 20))
 688                           (delete-region (1- from) from))))))
 689               (terpri))
 690
 691             ;; If the value is large, move it to the end.
 692             (with-current-buffer standard-output
 693               (when (> (count-lines (point-min) (point-max)) 10)
 694                 ;; Note that setting the syntax table like below
 695                 ;; makes forward-sexp move over a `'s' at the end
 696                 ;; of a symbol.
 697                 (set-syntax-table emacs-lisp-mode-syntax-table)
 698                 (goto-char val-start-pos)
 699                 ;; The line below previously read as
 700                 ;; (delete-region (point) (progn (end-of-line) (point)))
 701                 ;; which suppressed display of the buffer local value for
 702                 ;; large values.
 703                 (when (looking-at "value is") (replace-match ""))
 704                 (save-excursion
 705                   (insert "\n\nValue:")
 706                   (set (make-local-variable 'help-button-cache)
 707                        (point-marker)))
 708                 (insert "value is shown ")
 709                 (insert-button "below"
 710                                'action help-button-cache
 711                                'follow-link t
 712                                'help-echo "mouse-2, RET: show value")
 713                 (insert ".\n")))
 714             (terpri)
 715
 716             (let* ((alias (condition-case nil
 717                               (indirect-variable variable)
 718                             (error variable)))
 719                    (obsolete (get variable 'byte-obsolete-variable))
 720                    (use (car obsolete))
 721                    (safe-var (get variable 'safe-local-variable))
 722                    (doc (or (documentation-property variable 'variable-documentation)
 723                             (documentation-property alias 'variable-documentation)))
 724                    (extra-line nil))
 725               ;; Add a note for variables that have been make-var-buffer-local.
 726               (when (and (local-variable-if-set-p variable)
 727                          (or (not (local-variable-p variable))
 728                              (with-temp-buffer
 729                                (local-variable-if-set-p variable))))
 730                 (setq extra-line t)
 731                 (princ "  Automatically becomes buffer-local when set in any fashion.\n"))
 732
 733               ;; Mention if it's an alias
 734               (unless (eq alias variable)
 735                 (setq extra-line t)
 736                 (princ (format "  This variable is an alias for `%s'.\n" alias)))
 737
 738               (when obsolete
 739                 (setq extra-line t)
 740                 (princ "  This variable is obsolete")
 741                 (if (cdr obsolete) (princ (format " since %s" (cdr obsolete))))
 742                 (princ (cond ((stringp use) (concat ";\n  " use))
 743                              (use (format ";\n  use `%s' instead." (car obsolete)))
 744                              (t ".")))
 745                 (terpri))
 746
 747               (when (member (cons variable val) file-local-variables-alist)
 748                 (setq extra-line t)
 749                 (if (member (cons variable val) dir-local-variables-alist)
 750                     (let ((file (and (buffer-file-name)
 751                                      (not (file-remote-p (buffer-file-name)))
 752                                      (dir-locals-find-file (buffer-file-name)))))
 753                       (princ "  This variable is a directory local variable")
 754                       (when file
 755                         (princ (concat "\n  from the file \""
 756                                        (if (consp file)
 757                                            (car file)
 758                                          file)
 759                                        "\"")))
 760                       (princ ".\n"))
 761                   (princ "  This variable is a file local variable.\n")))
 762
 763               (when (memq variable ignored-local-variables)
 764                 (setq extra-line t)
 765                 (princ "  This variable is ignored when used as a file local \
 766 variable.\n"))
 767
 768               ;; Can be both risky and safe, eg auto-fill-function.
 769               (when (risky-local-variable-p variable)
 770                 (setq extra-line t)
 771                 (princ "  This variable is potentially risky when used as a \
 772 file local variable.\n")
 773                 (when (assq variable safe-local-variable-values)
 774                   (princ "  However, you have added it to \
 775 `safe-local-variable-values'.\n")))
 776
 777               (when safe-var
 778                 (setq extra-line t)
 779                 (princ "  This variable is safe as a file local variable ")
 780                 (princ "if its value\n  satisfies the predicate ")
 781                 (princ (if (byte-code-function-p safe-var)
 782                            "which is byte-compiled expression.\n"
 783                          (format "`%s'.\n" safe-var))))
 784
 785               (if extra-line (terpri))
 786               (princ "Documentation:\n")
 787               (with-current-buffer standard-output
 788                 (insert (or doc "Not documented as a variable."))))
 789
 790             ;; Make a link to customize if this variable can be customized.
 791             (when (custom-variable-p variable)
 792               (let ((customize-label "customize"))
 793                 (terpri)
 794                 (terpri)
 795                 (princ (concat "You can " customize-label " this variable."))
 796                 (with-current-buffer standard-output
 797                   (save-excursion
 798                     (re-search-backward
 799                      (concat "\\(" customize-label "\\)") nil t)
 800                     (help-xref-button 1 'help-customize-variable variable))))
 801               ;; Note variable's version or package version
 802               (let ((output (describe-variable-custom-version-info variable)))
 803                 (when output
 804                   (terpri)
 805                   (terpri)
 806                   (princ output))))
 807
 808             (with-current-buffer standard-output
 809               ;; Return the text we displayed.
 810               (buffer-string))))))))
 811
 812
 813 ;;;###autoload
 814 (defun describe-syntax (&optional buffer)
 815   "Describe the syntax specifications in the syntax table of BUFFER.
 816 The descriptions are inserted in a help buffer, which is then displayed.
 817 BUFFER defaults to the current buffer."
 818   (interactive)
 819   (setq buffer (or buffer (current-buffer)))
 820   (help-setup-xref (list #'describe-syntax buffer)
 821                    (called-interactively-p 'interactive))
 822   (with-help-window (help-buffer)
 823     (let ((table (with-current-buffer buffer (syntax-table))))
 824       (with-current-buffer standard-output
 825         (describe-vector table 'internal-describe-syntax-value)
 826         (while (setq table (char-table-parent table))
 827           (insert "\nThe parent syntax table is:")
 828           (describe-vector table 'internal-describe-syntax-value))))))
 829
 830 (defun help-describe-category-set (value)
 831   (insert (cond
 832            ((null value) "default")
 833            ((char-table-p value) "deeper char-table ...")
 834            (t (condition-case err
 835                   (category-set-mnemonics value)
 836                 (error "invalid"))))))
 837
 838 ;;;###autoload
 839 (defun describe-categories (&optional buffer)
 840   "Describe the category specifications in the current category table.
 841 The descriptions are inserted in a buffer, which is then displayed.
 842 If BUFFER is non-nil, then describe BUFFER's category table instead.
 843 BUFFER should be a buffer or a buffer name."
 844   (interactive)
 845   (setq buffer (or buffer (current-buffer)))
 846   (help-setup-xref (list #'describe-categories buffer)
 847                    (called-interactively-p 'interactive))
 848   (with-help-window (help-buffer)
 849     (let* ((table (with-current-buffer buffer (category-table)))
 850            (docs (char-table-extra-slot table 0)))
 851       (if (or (not (vectorp docs)) (/= (length docs) 95))
 852           (error "Invalid first extra slot in this category table\n"))
 853       (with-current-buffer standard-output
 854         (insert "Legend of category mnemonics (see the tail for the longer description)\n")
 855         (let ((pos (point)) (items 0) lines n)
 856           (dotimes (i 95)
 857             (if (aref docs i) (setq items (1+ items))))
 858           (setq lines (1+ (/ (1- items) 4)))
 859           (setq n 0)
 860           (dotimes (i 95)
 861             (let ((elt (aref docs i)))
 862               (when elt
 863                 (string-match ".*" elt)
 864                 (setq elt (match-string 0 elt))
 865                 (if (>= (length elt) 17)
 866                     (setq elt (concat (substring elt 0 14) "...")))
 867                 (if (< (point) (point-max))
 868                     (move-to-column (* 20 (/ n lines)) t))
 869                 (insert (+ i ?\s) ?: elt)
 870                 (if (< (point) (point-max))
 871                     (forward-line 1)
 872                   (insert "\n"))
 873                 (setq n (1+ n))
 874                 (if (= (% n lines) 0)
 875                     (goto-char pos))))))
 876         (goto-char (point-max))
 877         (insert "\n"
 878                 "character(s)\tcategory mnemonics\n"
 879                 "------------\t------------------")
 880         (describe-vector table 'help-describe-category-set)
 881         (insert "Legend of category mnemonics:\n")
 882         (dotimes (i 95)
 883           (let ((elt (aref docs i)))
 884             (when elt
 885               (if (string-match "\n" elt)
 886                   (setq elt (substring elt (match-end 0))))
 887               (insert (+ i ?\s) ": " elt "\n"))))
 888         (while (setq table (char-table-parent table))
 889           (insert "\nThe parent category table is:")
 890           (describe-vector table 'help-describe-category-set))))))
 891
 892 \f
 893 ;;; Replacements for old lib-src/ programs.  Don't seem especially useful.
 894
 895 ;; Replaces lib-src/digest-doc.c.
 896 ;;;###autoload
 897 (defun doc-file-to-man (file)
 898   "Produce an nroff buffer containing the doc-strings from the DOC file."
 899   (interactive (list (read-file-name "Name of DOC file: " doc-directory
 900                                      internal-doc-file-name t)))
 901   (or (file-readable-p file)
 902       (error "Cannot read file `%s'" file))
 903   (pop-to-buffer (generate-new-buffer "*man-doc*"))
 904   (setq buffer-undo-list t)
 905   (insert ".TH \"Command Summary for GNU Emacs\"\n"
 906           ".AU Richard M. Stallman\n")
 907   (insert-file-contents file)
 908   (let (notfirst)
 909     (while (search-forward "\x1f" nil 'move)
 910       (if (looking-at "S")
 911           (delete-region (1- (point)) (line-end-position))
 912         (delete-char -1)
 913         (if notfirst
 914             (insert "\n.DE\n")
 915           (setq notfirst t))
 916         (insert "\n.SH ")
 917         (insert (if (looking-at "F") "Function " "Variable "))
 918         (delete-char 1)
 919         (forward-line 1)
 920         (insert ".DS L\n"))))
 921   (insert "\n.DE\n")
 922   (setq buffer-undo-list nil)
 923   (nroff-mode))
 924
 925 ;; Replaces lib-src/sorted-doc.c.
 926 ;;;###autoload
 927 (defun doc-file-to-info (file)
 928   "Produce a texinfo buffer with sorted doc-strings from the DOC file."
 929   (interactive (list (read-file-name "Name of DOC file: " doc-directory
 930                                      internal-doc-file-name t)))
 931   (or (file-readable-p file)
 932       (error "Cannot read file `%s'" file))
 933   (let ((i 0) type name doc alist)
 934     (with-temp-buffer
 935       (insert-file-contents file)
 936       ;; The characters "@{}" need special treatment.
 937       (while (re-search-forward "[@{}]" nil t)
 938         (backward-char)
 939         (insert "@")
 940         (forward-char 1))
 941       (goto-char (point-min))
 942       (while (search-forward "\x1f" nil t)
 943         (unless (looking-at "S")
 944           (setq type (char-after)
 945                 name (buffer-substring (1+ (point)) (line-end-position))
 946                 doc (buffer-substring (line-beginning-position 2)
 947                                       (if (search-forward  "\x1f" nil 'move)
 948                                           (1- (point))
 949                                         (point)))
 950                 alist (cons (list name type doc) alist))
 951           (backward-char 1))))
 952     (pop-to-buffer (generate-new-buffer "*info-doc*"))
 953     (setq buffer-undo-list t)
 954     ;; Write the output header.
 955     (insert "\\input texinfo  @c -*-texinfo-*-\n"
 956             "@setfilename emacsdoc.info\n"
 957             "@settitle Command Summary for GNU Emacs\n"
 958             "@finalout\n"
 959             "\n@node Top\n"
 960             "@unnumbered Command Summary for GNU Emacs\n\n"
 961             "@table @asis\n\n"
 962             "@iftex\n"
 963             "@global@let@ITEM@item\n"
 964             "@def@item{@filbreak@vskip5pt@ITEM}\n"
 965             "@font@tensy cmsy10 scaled @magstephalf\n"
 966             "@font@teni cmmi10 scaled @magstephalf\n"
 967             "@def\\{{@tensy@char110}}\n" ; this backslash goes with cmr10
 968             "@def|{{@tensy@char106}}\n"
 969             "@def@{{{@tensy@char102}}\n"
 970             "@def@}{{@tensy@char103}}\n"
 971             "@def<{{@teni@char62}}\n"
 972             "@def>{{@teni@char60}}\n"
 973             "@chardef@@64\n"
 974             "@catcode43=12\n"
 975             "@tableindent-0.2in\n"
 976             "@end iftex\n")
 977     ;; Sort the array by name; within each name, by type (functions first).
 978     (setq alist (sort alist (lambda (e1 e2)
 979                               (if (string-equal (car e1) (car e2))
 980                                   (<= (cadr e1) (cadr e2))
 981                                 (string-lessp (car e1) (car e2))))))
 982     ;; Print each function.
 983     (dolist (e alist)
 984       (insert "\n@item "
 985               (if (char-equal (cadr e) ?\F) "Function" "Variable")
 986               " @code{" (car e) "}\n@display\n"
 987               (nth 2 e)
 988               "\n@end display\n")
 989       ;; Try to avoid a save size overflow in the TeX output routine.
 990       (if (zerop (setq i (% (1+ i) 100)))
 991           (insert "\n@end table\n@table @asis\n")))
 992     (insert "@end table\n"
 993             "@bye\n")
 994     (setq buffer-undo-list nil)
 995     (texinfo-mode)))
 996
 997 (provide 'help-fns)
 998
 999 ;;; help-fns.el ends here