lisp/pgg-pgp5.el

   1 ;;; pgg-pgp5.el --- PGP 5.* support for PGG.
   2
   3 ;; Copyright (C) 1999, 2000, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   5
   6 ;; Author: Daiki Ueno <ueno@unixuser.org>
   7 ;; Created: 1999/11/02
   8 ;; Keywords: PGP, OpenPGP
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Code:
  26
  27 (eval-when-compile
  28   (require 'cl)                         ; for pgg macros
  29   (require 'pgg))
  30
  31 (defgroup pgg-pgp5 ()
  32   "PGP 5.* interface."
  33   :group 'pgg)
  34
  35 (defcustom pgg-pgp5-pgpe-program "pgpe"
  36   "PGP 5.* 'pgpe' executable."
  37   :group 'pgg-pgp5
  38   :type 'string)
  39
  40 (defcustom pgg-pgp5-pgps-program "pgps"
  41   "PGP 5.* 'pgps' executable."
  42   :group 'pgg-pgp5
  43   :type 'string)
  44
  45 (defcustom pgg-pgp5-pgpk-program "pgpk"
  46   "PGP 5.* 'pgpk' executable."
  47   :group 'pgg-pgp5
  48   :type 'string)
  49
  50 (defcustom pgg-pgp5-pgpv-program "pgpv"
  51   "PGP 5.* 'pgpv' executable."
  52   :group 'pgg-pgp5
  53   :type 'string)
  54
  55 (defcustom pgg-pgp5-shell-file-name "/bin/sh"
  56   "File name to load inferior shells from.
  57 Bourne shell or its equivalent \(not tcsh) is needed for \"2>\"."
  58   :group 'pgg-pgp5
  59   :type 'string)
  60
  61 (defcustom pgg-pgp5-shell-command-switch "-c"
  62   "Switch used to have the shell execute its command line argument."
  63   :group 'pgg-pgp5
  64   :type 'string)
  65
  66 (defcustom pgg-pgp5-extra-args nil
  67   "Extra arguments for every PGP 5.* invocation."
  68   :group 'pgg-pgp5
  69   :type '(choice
  70           (const :tag "None" nil)
  71           (string :tag "Arguments")))
  72
  73 (defvar pgg-pgp5-user-id nil
  74   "PGP 5.* ID of your default identity.")
  75
  76 (defun pgg-pgp5-process-region (start end passphrase program args)
  77   (let* ((errors-file-name (pgg-make-temp-file "pgg-errors"))
  78          (args
  79           (append args
  80                   pgg-pgp5-extra-args
  81                   (list (concat "2>" errors-file-name))))
  82          (shell-file-name pgg-pgp5-shell-file-name)
  83          (shell-command-switch pgg-pgp5-shell-command-switch)
  84          (process-environment process-environment)
  85          (output-buffer pgg-output-buffer)
  86          (errors-buffer pgg-errors-buffer)
  87          (process-connection-type nil)
  88          process status exit-status)
  89     (with-current-buffer (get-buffer-create output-buffer)
  90       (buffer-disable-undo)
  91       (erase-buffer))
  92     (when passphrase
  93       (setenv "PGPPASSFD" "0"))
  94     (unwind-protect
  95         (progn
  96           (let ((coding-system-for-read 'binary)
  97                 (coding-system-for-write 'binary))
  98             (setq process
  99                   (apply #'funcall
 100                          #'start-process-shell-command "*PGP*" output-buffer
 101                          program args)))
 102           (set-process-sentinel process #'ignore)
 103           (when passphrase
 104             (process-send-string process (concat passphrase "\n")))
 105           (process-send-region process start end)
 106           (process-send-eof process)
 107           (while (eq 'run (process-status process))
 108             (accept-process-output process 5))
 109           (setq status (process-status process)
 110                 exit-status (process-exit-status process))
 111           (delete-process process)
 112           (with-current-buffer output-buffer
 113             (pgg-convert-lbt-region (point-min)(point-max) 'LF)
 114
 115             (if (memq status '(stop signal))
 116                 (error "%s exited abnormally: '%s'" program exit-status))
 117             (if (= 127 exit-status)
 118                 (error "%s could not be found" program))
 119
 120             (set-buffer (get-buffer-create errors-buffer))
 121             (buffer-disable-undo)
 122             (erase-buffer)
 123             (insert-file-contents errors-file-name)))
 124       (if (and process (eq 'run (process-status process)))
 125           (interrupt-process process))
 126       (condition-case nil
 127           (let ((delete-by-moving-to-trash nil))
 128             (delete-file errors-file-name))
 129         (file-error nil)))))
 130
 131 (defun pgg-pgp5-lookup-key (string &optional type)
 132   "Search keys associated with STRING."
 133   (let ((args (list "+language=en" "-l" string)))
 134     (with-current-buffer (get-buffer-create pgg-output-buffer)
 135       (buffer-disable-undo)
 136       (erase-buffer)
 137       (apply #'call-process pgg-pgp5-pgpk-program nil t nil args)
 138       (goto-char (point-min))
 139       (when (re-search-forward "^sec" nil t)
 140         (substring
 141          (nth 2 (split-string
 142                  (buffer-substring (match-end 0)(progn (end-of-line)(point)))))
 143          2)))))
 144
 145 (defun pgg-pgp5-encrypt-region (start end recipients &optional sign passphrase)
 146   "Encrypt the current region between START and END."
 147   (let* ((pgg-pgp5-user-id (or pgg-pgp5-user-id pgg-default-user-id))
 148          (passphrase (or passphrase
 149                          (when sign
 150                            (pgg-read-passphrase
 151                             (format "PGP passphrase for %s: "
 152                                     pgg-pgp5-user-id)
 153                             pgg-pgp5-user-id))))
 154          (args
 155           (append
 156            `("+NoBatchInvalidKeys=off" "-fat" "+batchmode=1"
 157              ,@(if (or recipients pgg-encrypt-for-me)
 158                    (apply #'append
 159                           (mapcar (lambda (rcpt)
 160                                     (list "-r"
 161                                           (concat "\"" rcpt "\"")))
 162                                   (append recipients
 163                                           (if pgg-encrypt-for-me
 164                                               (list pgg-pgp5-user-id)))))))
 165            (if sign '("-s" "-u" pgg-pgp5-user-id)))))
 166     (pgg-pgp5-process-region start end nil pgg-pgp5-pgpe-program args)
 167     (pgg-process-when-success nil)))
 168
 169 (defun pgg-pgp5-decrypt-region (start end &optional passphrase)
 170   "Decrypt the current region between START and END."
 171   (let* ((pgg-pgp5-user-id (or pgg-pgp5-user-id pgg-default-user-id))
 172          (passphrase
 173           (or passphrase
 174               (pgg-read-passphrase
 175                (format "PGP passphrase for %s: " pgg-pgp5-user-id)
 176                (pgg-pgp5-lookup-key pgg-pgp5-user-id 'encrypt))))
 177          (args
 178           '("+verbose=1" "+batchmode=1" "+language=us" "-f")))
 179     (pgg-pgp5-process-region start end passphrase pgg-pgp5-pgpv-program args)
 180     (pgg-process-when-success nil)))
 181
 182 (defun pgg-pgp5-sign-region (start end &optional clearsign passphrase)
 183   "Make detached signature from text between START and END."
 184   (let* ((pgg-pgp5-user-id (or pgg-pgp5-user-id pgg-default-user-id))
 185          (passphrase
 186           (or passphrase
 187               (pgg-read-passphrase
 188                (format "PGP passphrase for %s: " pgg-pgp5-user-id)
 189                (pgg-pgp5-lookup-key pgg-pgp5-user-id 'sign))))
 190          (args
 191           (list (if clearsign "-fat" "-fbat")
 192                 "+verbose=1" "+language=us" "+batchmode=1"
 193                 "-u" pgg-pgp5-user-id)))
 194     (pgg-pgp5-process-region start end passphrase pgg-pgp5-pgps-program args)
 195     (pgg-process-when-success
 196       (when (re-search-forward "^-+BEGIN PGP SIGNATURE" nil t);XXX
 197         (let ((packet
 198                (cdr (assq 2 (pgg-parse-armor-region
 199                              (progn (beginning-of-line 2)
 200                                     (point))
 201                              (point-max))))))
 202           (if pgg-cache-passphrase
 203               (pgg-add-passphrase-to-cache
 204                (cdr (assq 'key-identifier packet))
 205                passphrase)))))))
 206
 207 (defun pgg-pgp5-verify-region (start end &optional signature)
 208   "Verify region between START and END as the detached signature SIGNATURE."
 209   (let ((orig-file (pgg-make-temp-file "pgg"))
 210         (args '("+verbose=1" "+batchmode=1" "+language=us"))
 211         (orig-mode (default-file-modes)))
 212     (unwind-protect
 213         (progn
 214           (set-default-file-modes 448)
 215           (let ((coding-system-for-write 'binary)
 216                 jka-compr-compression-info-list jam-zcat-filename-list)
 217             (write-region start end orig-file)))
 218       (set-default-file-modes orig-mode))
 219     (when (stringp signature)
 220       (copy-file signature (setq signature (concat orig-file ".asc")))
 221       (setq args (append args (list signature))))
 222     (pgg-pgp5-process-region (point)(point) nil pgg-pgp5-pgpv-program args)
 223     (let ((delete-by-moving-to-trash nil))
 224       (delete-file orig-file))
 225     (if signature
 226         (let ((delete-by-moving-to-trash nil))
 227           (delete-file signature)))
 228     (with-current-buffer pgg-errors-buffer
 229       (goto-char (point-min))
 230       (if (re-search-forward "^Good signature" nil t)
 231           (progn
 232             (set-buffer pgg-output-buffer)
 233             (insert-buffer-substring pgg-errors-buffer)
 234             t)
 235         nil))))
 236
 237 (defun pgg-pgp5-insert-key ()
 238   "Insert public key at point."
 239   (let* ((pgg-pgp5-user-id (or pgg-pgp5-user-id pgg-default-user-id))
 240          (args
 241           (list "+verbose=1" "+batchmode=1" "+language=us" "-x"
 242                 (concat "\"" pgg-pgp5-user-id "\""))))
 243     (pgg-pgp5-process-region (point)(point) nil pgg-pgp5-pgpk-program args)
 244     (insert-buffer-substring pgg-output-buffer)))
 245
 246 (defun pgg-pgp5-snarf-keys-region (start end)
 247   "Add all public keys in region between START and END to the keyring."
 248   (let* ((pgg-pgp5-user-id (or pgg-pgp5-user-id pgg-default-user-id))
 249          (key-file (pgg-make-temp-file "pgg"))
 250          (args
 251           (list "+verbose=1" "+batchmode=1" "+language=us" "-a"
 252                 key-file)))
 253     (let ((coding-system-for-write 'raw-text-dos))
 254       (write-region start end key-file))
 255     (pgg-pgp5-process-region start end nil pgg-pgp5-pgpk-program args)
 256     (let ((delete-by-moving-to-trash nil))
 257       (delete-file key-file))
 258     (pgg-process-when-success nil)))
 259
 260 (provide 'pgg-pgp5)
 261
 262 ;; arch-tag: 3dbd1073-6b3a-466c-9f55-5c587ffa6d7b
 263 ;;; pgg-pgp5.el ends here