lisp/emacs-lisp/derived.el

   1 ;;; derived.el --- allow inheritance of major modes
   2 ;; (formerly mode-clone.el)
   3
   4 ;; Copyright (C) 1993, 1994, 1999, 2001, 2002, 2003, 2004, 2005, 2006,
   5 ;;   2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   6
   7 ;; Author: David Megginson (dmeggins@aix1.uottawa.ca)
   8 ;; Maintainer: FSF
   9 ;; Keywords: extensions
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 \f
  26 ;;; Commentary:
  27
  28 ;; GNU Emacs is already, in a sense, object oriented -- each object
  29 ;; (buffer) belongs to a class (major mode), and that class defines
  30 ;; the relationship between messages (input events) and methods
  31 ;; (commands) by means of a keymap.
  32 ;;
  33 ;; The only thing missing is a good scheme of inheritance.  It is
  34 ;; possible to simulate a single level of inheritance with generous
  35 ;; use of hooks and a bit of work -- sgml-mode, for example, also runs
  36 ;; the hooks for text-mode, and keymaps can inherit from other keymaps
  37 ;; -- but generally, each major mode ends up reinventing the wheel.
  38 ;; Ideally, someone should redesign all of Emacs's major modes to
  39 ;; follow a more conventional object-oriented system: when defining a
  40 ;; new major mode, the user should need only to name the existing mode
  41 ;; it is most similar to, then list the (few) differences.
  42 ;;
  43 ;; In the mean time, this package offers most of the advantages of
  44 ;; full inheritance with the existing major modes.  The macro
  45 ;; `define-derived-mode' allows the user to make a variant of an existing
  46 ;; major mode, with its own keymap.  The new mode will inherit the key
  47 ;; bindings of its parent, and will, in fact, run its parent first
  48 ;; every time it is called.  For example, the commands
  49 ;;
  50 ;;  (define-derived-mode hypertext-mode text-mode "Hypertext"
  51 ;;    "Major mode for hypertext.\n\n\\{hypertext-mode-map}"
  52 ;;    (setq case-fold-search nil))
  53 ;;
  54 ;;  (define-key hypertext-mode-map [down-mouse-3] 'do-hyper-link)
  55 ;;
  56 ;; will create a function `hypertext-mode' with its own (sparse)
  57 ;; keymap `hypertext-mode-map.'  The command M-x hypertext-mode will
  58 ;; perform the following actions:
  59 ;;
  60 ;; - run the command (text-mode) to get its default setup
  61 ;; - replace the current keymap with 'hypertext-mode-map,' which will
  62 ;;   inherit from 'text-mode-map'.
  63 ;; - replace the current syntax table with
  64 ;;   'hypertext-mode-syntax-table', which will borrow its defaults
  65 ;;   from the current text-mode-syntax-table.
  66 ;; - replace the current abbrev table with
  67 ;;   'hypertext-mode-abbrev-table', which will borrow its defaults
  68 ;;   from the current text-mode-abbrev table
  69 ;; - change the mode line to read "Hypertext"
  70 ;; - assign the value 'hypertext-mode' to the 'major-mode' variable
  71 ;; - run the body of commands provided in the macro -- in this case,
  72 ;;   set the local variable `case-fold-search' to nil.
  73 ;;
  74 ;; The advantages of this system are threefold.  First, text mode is
  75 ;; untouched -- if you had added the new keystroke to `text-mode-map,'
  76 ;; possibly using hooks, you would have added it to all text buffers
  77 ;; -- here, it appears only in hypertext buffers, where it makes
  78 ;; sense.  Second, it is possible to build even further, and make
  79 ;; a derived mode from a derived mode.  The commands
  80 ;;
  81 ;;   (define-derived-mode html-mode hypertext-mode "HTML")
  82 ;;   [various key definitions]
  83 ;;
  84 ;; will add a new major mode for HTML with very little fuss.
  85 ;;
  86 ;; Note also the function `derived-mode-p' which can tell if the current
  87 ;; mode derives from another.  In a hypertext-mode, buffer, for example,
  88 ;; (derived-mode-p 'text-mode) would return non-nil.  This should always
  89 ;; be used in place of (eq major-mode 'text-mode).
  90 \f
  91 ;;; Code:
  92
  93 (eval-when-compile (require 'cl))
  94
  95 ;;; PRIVATE: defsubst must be defined before they are first used
  96
  97 (defsubst derived-mode-hook-name (mode)
  98   "Construct a mode-hook name based on a MODE name."
  99   (intern (concat (symbol-name mode) "-hook")))
 100
 101 (defsubst derived-mode-map-name (mode)
 102   "Construct a map name based on a MODE name."
 103   (intern (concat (symbol-name mode) "-map")))
 104
 105 (defsubst derived-mode-syntax-table-name (mode)
 106   "Construct a syntax-table name based on a MODE name."
 107   (intern (concat (symbol-name mode) "-syntax-table")))
 108
 109 (defsubst derived-mode-abbrev-table-name (mode)
 110   "Construct an abbrev-table name based on a MODE name."
 111   (intern (concat (symbol-name mode) "-abbrev-table")))
 112
 113 ;; PUBLIC: define a new major mode which inherits from an existing one.
 114
 115 ;;;###autoload
 116 (defmacro define-derived-mode (child parent name &optional docstring &rest body)
 117   "Create a new mode as a variant of an existing mode.
 118
 119 The arguments to this command are as follow:
 120
 121 CHILD:     the name of the command for the derived mode.
 122 PARENT:    the name of the command for the parent mode (e.g. `text-mode')
 123            or nil if there is no parent.
 124 NAME:      a string which will appear in the status line (e.g. \"Hypertext\")
 125 DOCSTRING: an optional documentation string--if you do not supply one,
 126            the function will attempt to invent something useful.
 127 BODY:      forms to execute just before running the
 128            hooks for the new mode.  Do not use `interactive' here.
 129
 130 BODY can start with a bunch of keyword arguments.  The following keyword
 131   arguments are currently understood:
 132 :group GROUP
 133         Declare the customization group that corresponds to this mode.
 134         The command `customize-mode' uses this.
 135 :syntax-table TABLE
 136         Use TABLE instead of the default.
 137         A nil value means to simply use the same syntax-table as the parent.
 138 :abbrev-table TABLE
 139         Use TABLE instead of the default.
 140         A nil value means to simply use the same abbrev-table as the parent.
 141
 142 Here is how you could define LaTeX-Thesis mode as a variant of LaTeX mode:
 143
 144   (define-derived-mode LaTeX-thesis-mode LaTeX-mode \"LaTeX-Thesis\")
 145
 146 You could then make new key bindings for `LaTeX-thesis-mode-map'
 147 without changing regular LaTeX mode.  In this example, BODY is empty,
 148 and DOCSTRING is generated by default.
 149
 150 On a more complicated level, the following command uses `sgml-mode' as
 151 the parent, and then sets the variable `case-fold-search' to nil:
 152
 153   (define-derived-mode article-mode sgml-mode \"Article\"
 154     \"Major mode for editing technical articles.\"
 155     (setq case-fold-search nil))
 156
 157 Note that if the documentation string had been left out, it would have
 158 been generated automatically, with a reference to the keymap.
 159
 160 The new mode runs the hook constructed by the function
 161 `derived-mode-hook-name'.
 162
 163 See Info node `(elisp)Derived Modes' for more details."
 164   (declare (debug (&define name symbolp sexp [&optional stringp]
 165                            [&rest keywordp sexp] def-body))
 166            (doc-string 4))
 167
 168   (when (and docstring (not (stringp docstring)))
 169     ;; Some trickiness, since what appears to be the docstring may really be
 170     ;; the first element of the body.
 171     (push docstring body)
 172     (setq docstring nil))
 173
 174   (when (eq parent 'fundamental-mode) (setq parent nil))
 175
 176   (let ((map (derived-mode-map-name child))
 177         (syntax (derived-mode-syntax-table-name child))
 178         (abbrev (derived-mode-abbrev-table-name child))
 179         (declare-abbrev t)
 180         (declare-syntax t)
 181         (hook (derived-mode-hook-name child))
 182         (group nil))
 183
 184     ;; Process the keyword args.
 185     (while (keywordp (car body))
 186       (case (pop body)
 187         (:group (setq group (pop body)))
 188         (:abbrev-table (setq abbrev (pop body)) (setq declare-abbrev nil))
 189         (:syntax-table (setq syntax (pop body)) (setq declare-syntax nil))
 190         (t (pop body))))
 191
 192     (setq docstring (derived-mode-make-docstring
 193                      parent child docstring syntax abbrev))
 194
 195     `(progn
 196        (unless (get ',hook 'variable-documentation)
 197          (put ',hook 'variable-documentation
 198               (purecopy ,(format "Hook run when entering %s mode.
 199 No problems result if this variable is not bound.
 200 `add-hook' automatically binds it.  (This is true for all hook variables.)"
 201                        name))))
 202        (unless (boundp ',map)
 203          (put ',map 'definition-name ',child))
 204        (defvar ,map (make-sparse-keymap))
 205        (unless (get ',map 'variable-documentation)
 206          (put ',map 'variable-documentation
 207               (purecopy ,(format "Keymap for `%s'." child))))
 208        ,(if declare-syntax
 209             `(progn
 210                (unless (boundp ',syntax)
 211                  (put ',syntax 'definition-name ',child))
 212                (defvar ,syntax (make-syntax-table))
 213                (unless (get ',syntax 'variable-documentation)
 214                  (put ',syntax 'variable-documentation
 215                       (purecopy ,(format "Syntax table for `%s'." child))))))
 216        ,(if declare-abbrev
 217             `(progn
 218                (put ',abbrev 'definition-name ',child)
 219                (defvar ,abbrev
 220                  (progn (define-abbrev-table ',abbrev nil) ,abbrev))
 221                (unless (get ',abbrev 'variable-documentation)
 222                  (put ',abbrev 'variable-documentation
 223                       (purecopy ,(format "Abbrev table for `%s'." child))))))
 224        (put ',child 'derived-mode-parent ',parent)
 225        ,(if group `(put ',child 'custom-mode-group ,group))
 226
 227        (defun ,child ()
 228          ,docstring
 229          (interactive)
 230                                         ; Run the parent.
 231          (delay-mode-hooks
 232
 233           (,(or parent 'kill-all-local-variables))
 234                                         ; Identify the child mode.
 235           (setq major-mode (quote ,child))
 236           (setq mode-name ,name)
 237                                         ; Identify special modes.
 238           ,(when parent
 239              `(progn
 240                 (if (get (quote ,parent) 'mode-class)
 241                     (put (quote ,child) 'mode-class
 242                          (get (quote ,parent) 'mode-class)))
 243                                         ; Set up maps and tables.
 244                 (unless (keymap-parent ,map)
 245                   ;; It would probably be better to set the keymap's parent
 246                   ;; at the toplevel rather than inside the mode function,
 247                   ;; but this is not easy for at least the following reasons:
 248                   ;; - the parent (and its keymap) may not yet be loaded.
 249                   ;; - the parent's keymap name may be called something else
 250                   ;;   than <parent>-mode-map.
 251                   (set-keymap-parent ,map (current-local-map)))
 252                 ,(when declare-syntax
 253                    `(let ((parent (char-table-parent ,syntax)))
 254                       (unless (and parent
 255                                    (not (eq parent (standard-syntax-table))))
 256                         (set-char-table-parent ,syntax (syntax-table)))))))
 257
 258           (use-local-map ,map)
 259           ,(when syntax `(set-syntax-table ,syntax))
 260           ,(when abbrev `(setq local-abbrev-table ,abbrev))
 261                                         ; Splice in the body (if any).
 262           ,@body
 263           )
 264          ;; Run the hooks, if any.
 265          (run-mode-hooks ',hook)))))
 266
 267 ;; PUBLIC: find the ultimate class of a derived mode.
 268
 269 (defun derived-mode-class (mode)
 270   "Find the class of a major MODE.
 271 A mode's class is the first ancestor which is NOT a derived mode.
 272 Use the `derived-mode-parent' property of the symbol to trace backwards.
 273 Since major-modes might all derive from `fundamental-mode', this function
 274 is not very useful."
 275   (while (get mode 'derived-mode-parent)
 276     (setq mode (get mode 'derived-mode-parent)))
 277   mode)
 278 (make-obsolete 'derived-mode-class 'derived-mode-p "22.1")
 279
 280 \f
 281 ;;; PRIVATE
 282
 283 (defun derived-mode-make-docstring (parent child &optional
 284                                            docstring syntax abbrev)
 285   "Construct a docstring for a new mode if none is provided."
 286
 287   (let ((map (derived-mode-map-name child))
 288         (hook (derived-mode-hook-name child)))
 289
 290     (unless (stringp docstring)
 291       ;; Use a default docstring.
 292       (setq docstring
 293             (if (null parent)
 294                 (format "Major-mode.
 295 Uses keymap `%s', abbrev table `%s' and syntax-table `%s'." map abbrev syntax)
 296               (format "Major mode derived from `%s' by `define-derived-mode'.
 297 It inherits all of the parent's attributes, but has its own keymap,
 298 abbrev table and syntax table:
 299
 300   `%s', `%s' and `%s'
 301
 302 which more-or-less shadow %s's corresponding tables."
 303                       parent map abbrev syntax parent))))
 304
 305     (unless (string-match (regexp-quote (symbol-name hook)) docstring)
 306       ;; Make sure the docstring mentions the mode's hook.
 307       (setq docstring
 308             (concat docstring
 309                     (if (null parent)
 310                         "\n\nThis mode "
 311                       (concat
 312                        "\n\nIn addition to any hooks its parent mode "
 313                        (if (string-match (regexp-quote (format "`%s'" parent))
 314                                          docstring) nil
 315                          (format "`%s' " parent))
 316                        "might have run,\nthis mode "))
 317                     (format "runs the hook `%s'" hook)
 318                     ", as the final step\nduring initialization.")))
 319
 320     (unless (string-match "\\\\[{[]" docstring)
 321       ;; And don't forget to put the mode's keymap.
 322       (setq docstring (concat docstring "\n\n\\{" (symbol-name map) "}")))
 323
 324     docstring))
 325
 326 \f
 327 ;;; OBSOLETE
 328 ;; The functions below are only provided for backward compatibility with
 329 ;; code byte-compiled with versions of derived.el prior to Emacs-21.
 330
 331 (defsubst derived-mode-setup-function-name (mode)
 332   "Construct a setup-function name based on a MODE name."
 333   (intern (concat (symbol-name mode) "-setup")))
 334
 335 \f
 336 ;; Utility functions for defining a derived mode.
 337
 338 ;;;###autoload
 339 (defun derived-mode-init-mode-variables (mode)
 340   "Initialize variables for a new MODE.
 341 Right now, if they don't already exist, set up a blank keymap, an
 342 empty syntax table, and an empty abbrev table -- these will be merged
 343 the first time the mode is used."
 344
 345   (if (boundp (derived-mode-map-name mode))
 346       t
 347     (eval `(defvar ,(derived-mode-map-name mode)
 348                (make-sparse-keymap)
 349                ,(format "Keymap for %s." mode)))
 350     (put (derived-mode-map-name mode) 'derived-mode-unmerged t))
 351
 352   (if (boundp (derived-mode-syntax-table-name mode))
 353       t
 354     (eval `(defvar ,(derived-mode-syntax-table-name mode)
 355              ;; Make a syntax table which doesn't specify anything
 356              ;; for any char.  Valid data will be merged in by
 357              ;; derived-mode-merge-syntax-tables.
 358              (make-char-table 'syntax-table nil)
 359              ,(format "Syntax table for %s." mode)))
 360     (put (derived-mode-syntax-table-name mode) 'derived-mode-unmerged t))
 361
 362   (if (boundp (derived-mode-abbrev-table-name mode))
 363       t
 364     (eval `(defvar ,(derived-mode-abbrev-table-name mode)
 365              (progn
 366                (define-abbrev-table (derived-mode-abbrev-table-name mode) nil)
 367                (make-abbrev-table))
 368              ,(format "Abbrev table for %s." mode)))))
 369 \f
 370 ;; Utility functions for running a derived mode.
 371
 372 (defun derived-mode-set-keymap (mode)
 373   "Set the keymap of the new MODE, maybe merging with the parent."
 374   (let* ((map-name (derived-mode-map-name mode))
 375          (new-map (eval map-name))
 376          (old-map (current-local-map)))
 377     (and old-map
 378          (get map-name 'derived-mode-unmerged)
 379          (derived-mode-merge-keymaps old-map new-map))
 380     (put map-name 'derived-mode-unmerged nil)
 381     (use-local-map new-map)))
 382
 383 (defun derived-mode-set-syntax-table (mode)
 384   "Set the syntax table of the new MODE, maybe merging with the parent."
 385   (let* ((table-name (derived-mode-syntax-table-name mode))
 386          (old-table (syntax-table))
 387          (new-table (eval table-name)))
 388     (if (get table-name 'derived-mode-unmerged)
 389         (derived-mode-merge-syntax-tables old-table new-table))
 390     (put table-name 'derived-mode-unmerged nil)
 391     (set-syntax-table new-table)))
 392
 393 (defun derived-mode-set-abbrev-table (mode)
 394   "Set the abbrev table for MODE if it exists.
 395 Always merge its parent into it, since the merge is non-destructive."
 396   (let* ((table-name (derived-mode-abbrev-table-name mode))
 397          (old-table local-abbrev-table)
 398          (new-table (eval table-name)))
 399     (derived-mode-merge-abbrev-tables old-table new-table)
 400     (setq local-abbrev-table new-table)))
 401
 402 (defun derived-mode-run-hooks (mode)
 403    "Run the mode hook for MODE."
 404    (let ((hooks-name (derived-mode-hook-name mode)))
 405      (if (boundp hooks-name)
 406          (run-hooks hooks-name))))
 407
 408 ;; Functions to merge maps and tables.
 409
 410 (defun derived-mode-merge-keymaps (old new)
 411   "Merge an OLD keymap into a NEW one.
 412 The old keymap is set to be the last cdr of the new one, so that there will
 413 be automatic inheritance."
 414   ;; ?? Can this just use `set-keymap-parent'?
 415   (let ((tail new))
 416     ;; Scan the NEW map for prefix keys.
 417     (while (consp tail)
 418       (and (consp (car tail))
 419            (let* ((key (vector (car (car tail))))
 420                   (subnew (lookup-key new key))
 421                   (subold (lookup-key old key)))
 422              ;; If KEY is a prefix key in both OLD and NEW, merge them.
 423              (and (keymapp subnew) (keymapp subold)
 424                   (derived-mode-merge-keymaps subold subnew))))
 425       (and (vectorp (car tail))
 426            ;; Search a vector of ASCII char bindings for prefix keys.
 427            (let ((i (1- (length (car tail)))))
 428              (while (>= i 0)
 429                (let* ((key (vector i))
 430                       (subnew (lookup-key new key))
 431                       (subold (lookup-key old key)))
 432                  ;; If KEY is a prefix key in both OLD and NEW, merge them.
 433                  (and (keymapp subnew) (keymapp subold)
 434                       (derived-mode-merge-keymaps subold subnew)))
 435                (setq i (1- i)))))
 436       (setq tail (cdr tail))))
 437   (setcdr (nthcdr (1- (length new)) new) old))
 438
 439 (defun derived-mode-merge-syntax-tables (old new)
 440   "Merge an OLD syntax table into a NEW one.
 441 Where the new table already has an entry, nothing is copied from the old one."
 442   (set-char-table-parent new old))
 443
 444 ;; Merge an old abbrev table into a new one.
 445 ;; This function requires internal knowledge of how abbrev tables work,
 446 ;; presuming that they are obarrays with the abbrev as the symbol, the expansion
 447 ;; as the value of the symbol, and the hook as the function definition.
 448 (defun derived-mode-merge-abbrev-tables (old new)
 449   (if old
 450       (mapatoms
 451        (lambda (symbol)
 452          (or (intern-soft (symbol-name symbol) new)
 453              (define-abbrev new (symbol-name symbol)
 454                (symbol-value symbol) (symbol-function symbol))))
 455        old)))
 456
 457 (provide 'derived)
 458
 459 ;; arch-tag: 630be248-47d1-4f02-afa0-8207de0ebea0
 460 ;;; derived.el ends here