build-aux/update-copyright

   1 eval '(exit $?0)' && eval 'exec perl -wS -0777 -pi "$0" "$@"'
   2   & eval 'exec perl -wS -0777 -pi "$0" $argv:q'
   3     if 0;
   4 # Update an FSF copyright year list to include the current year.
   5
   6 my $VERSION = '2016-01-12.23:13'; # UTC
   7
   8 # Copyright (C) 2009-2017 Free Software Foundation, Inc.
   9 #
  10 # This program is free software: you can redistribute it and/or modify
  11 # it under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3, or (at your option)
  13 # any later version.
  14 #
  15 # This program is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 # Written by Jim Meyering and Joel E. Denny
  24
  25 # The arguments to this script should be names of files that contain
  26 # copyright statements to be updated.  The copyright holder's name
  27 # defaults to "Free Software Foundation, Inc." but may be changed to
  28 # any other name by using the "UPDATE_COPYRIGHT_HOLDER" environment
  29 # variable.
  30 #
  31 # For example, you might wish to use the update-copyright target rule
  32 # in maint.mk from gnulib's maintainer-makefile module.
  33 #
  34 # Iff a copyright statement is recognized in a file and the final
  35 # year is not the current year, then the statement is updated for the
  36 # new year and it is reformatted to:
  37 #
  38 #   1. Fit within 72 columns.
  39 #   2. Convert 2-digit years to 4-digit years by prepending "19".
  40 #   3. Expand copyright year intervals.  (See "Environment variables"
  41 #      below.)
  42 #
  43 # A warning is printed for every file for which no copyright
  44 # statement is recognized.
  45 #
  46 # Each file's copyright statement must be formatted correctly in
  47 # order to be recognized.  For example, each of these is fine:
  48 #
  49 #   Copyright @copyright{} 1990-2005, 2007-2009 Free Software
  50 #   Foundation, Inc.
  51 #
  52 #   # Copyright (C) 1990-2005, 2007-2009 Free Software
  53 #   # Foundation, Inc.
  54 #
  55 #   /*
  56 #    * Copyright &copy; 90,2005,2007-2009
  57 #    * Free Software Foundation, Inc.
  58 #    */
  59 #
  60 # However, the following format is not recognized because the line
  61 # prefix changes after the first line:
  62 #
  63 #   ## Copyright (C) 1990-2005, 2007-2009 Free Software
  64 #   #  Foundation, Inc.
  65 #
  66 # However, any correctly formatted copyright statement following
  67 # a non-matching copyright statements would be recognized.
  68 #
  69 # The exact conditions that a file's copyright statement must meet
  70 # to be recognized are:
  71 #
  72 #   1. It is the first copyright statement that meets all of the
  73 #      following conditions.  Subsequent copyright statements are
  74 #      ignored.
  75 #   2. Its format is "Copyright (C)", then a list of copyright years,
  76 #      and then the name of the copyright holder.
  77 #   3. The "(C)" takes one of the following forms or is omitted
  78 #      entirely:
  79 #
  80 #        A. (C)
  81 #        B. (c)
  82 #        C. @copyright{}
  83 #        D. &copy;
  84 #
  85 #   4. The "Copyright" appears at the beginning of a line, except that it
  86 #      may be prefixed by any sequence (e.g., a comment) of no more than
  87 #      5 characters -- including white space.
  88 #   5. Iff such a prefix is present, the same prefix appears at the
  89 #      beginning of each remaining line within the FSF copyright
  90 #      statement.  There is one exception in order to support C-style
  91 #      comments: if the first line's prefix contains nothing but
  92 #      whitespace surrounding a "/*", then the prefix for all subsequent
  93 #      lines is the same as the first line's prefix except with each of
  94 #      "/" and possibly "*" replaced by a " ".  The replacement of "*"
  95 #      by " " is consistent throughout all subsequent lines.
  96 #   6. Blank lines, even if preceded by the prefix, do not appear
  97 #      within the FSF copyright statement.
  98 #   7. Each copyright year is 2 or 4 digits, and years are separated by
  99 #      commas or dashes.  Whitespace may appear after commas.
 100 #
 101 # Environment variables:
 102 #
 103 #   1. If UPDATE_COPYRIGHT_FORCE=1, a recognized FSF copyright statement
 104 #      is reformatted even if it does not need updating for the new
 105 #      year.  If unset or set to 0, only updated FSF copyright
 106 #      statements are reformatted.
 107 #   2. If UPDATE_COPYRIGHT_USE_INTERVALS=1, every series of consecutive
 108 #      copyright years (such as 90, 1991, 1992-2007, 2008) in a
 109 #      reformatted FSF copyright statement is collapsed to a single
 110 #      interval (such as 1990-2008).  If unset or set to 0, all existing
 111 #      copyright year intervals in a reformatted FSF copyright statement
 112 #      are expanded instead.
 113 #      If UPDATE_COPYRIGHT_USE_INTERVALS=2, convert a sequence with gaps
 114 #      to the minimal containing range.  For example, convert
 115 #      2000, 2004-2007, 2009 to 2000-2009.
 116 #   3. For testing purposes, you can set the assumed current year in
 117 #      UPDATE_COPYRIGHT_YEAR.
 118 #   4. The default maximum line length for a copyright line is 72.
 119 #      Set UPDATE_COPYRIGHT_MAX_LINE_LENGTH to use a different length.
 120 #   5. Set UPDATE_COPYRIGHT_HOLDER if the copyright holder is other
 121 #      than "Free Software Foundation, Inc.".
 122
 123 use strict;
 124 use warnings;
 125
 126 my $copyright_re = 'Copyright';
 127 my $circle_c_re = '(?:\([cC]\)|@copyright\{}|\\\\\(co|&copy;)';
 128 my $holder = $ENV{UPDATE_COPYRIGHT_HOLDER};
 129 $holder ||= 'Free Software Foundation, Inc.';
 130 my $prefix_max = 5;
 131 my $margin = $ENV{UPDATE_COPYRIGHT_MAX_LINE_LENGTH};
 132 !$margin || $margin !~ m/^\d+$/
 133   and $margin = 72;
 134
 135 my $tab_width = 8;
 136
 137 my $this_year = $ENV{UPDATE_COPYRIGHT_YEAR};
 138 if (!$this_year || $this_year !~ m/^\d{4}$/)
 139   {
 140     my ($sec, $min, $hour, $mday, $month, $year) = localtime (time ());
 141     $this_year = $year + 1900;
 142   }
 143
 144 # Unless the file consistently uses "\r\n" as the EOL, use "\n" instead.
 145 my $eol = /(?:^|[^\r])\n/ ? "\n" : "\r\n";
 146
 147 my $leading;
 148 my $prefix;
 149 my $ws_re;
 150 my $stmt_re;
 151 while (/(^|\n)(.{0,$prefix_max})$copyright_re/g)
 152   {
 153     $leading = "$1$2";
 154     $prefix = $2;
 155     if ($prefix =~ /^(\s*\/)\*(\s*)$/)
 156       {
 157         $prefix =~ s,/, ,;
 158         my $prefix_ws = $prefix;
 159         $prefix_ws =~ s/\*/ /; # Only whitespace.
 160         if (/\G(?:[^*\n]|\*[^\/\n])*\*?\n$prefix_ws/)
 161           {
 162             $prefix = $prefix_ws;
 163           }
 164       }
 165     $ws_re = '[ \t\r\f]'; # \s without \n
 166     $ws_re =
 167       "(?:$ws_re*(?:$ws_re|\\n" . quotemeta($prefix) . ")$ws_re*)";
 168     my $holder_re = $holder;
 169     $holder_re =~ s/\s/$ws_re/g;
 170     my $stmt_remainder_re =
 171       "(?:$ws_re$circle_c_re)?"
 172       . "$ws_re(?:(?:\\d\\d)?\\d\\d(?:,$ws_re?|-))*"
 173       . "((?:\\d\\d)?\\d\\d)$ws_re$holder_re";
 174     if (/\G$stmt_remainder_re/)
 175       {
 176         $stmt_re =
 177           quotemeta($leading) . "($copyright_re$stmt_remainder_re)";
 178         last;
 179       }
 180   }
 181 if (defined $stmt_re)
 182   {
 183     /$stmt_re/ or die; # Should never die.
 184     my $stmt = $1;
 185     my $final_year_orig = $2;
 186
 187     # Handle two-digit year numbers like "98" and "99".
 188     my $final_year = $final_year_orig;
 189     $final_year <= 99
 190       and $final_year += 1900;
 191
 192     if ($final_year != $this_year)
 193       {
 194         # Update the year.
 195         $stmt =~ s/\b$final_year_orig\b/$final_year, $this_year/;
 196       }
 197     if ($final_year != $this_year || $ENV{'UPDATE_COPYRIGHT_FORCE'})
 198       {
 199         # Normalize all whitespace including newline-prefix sequences.
 200         $stmt =~ s/$ws_re/ /g;
 201
 202         # Put spaces after commas.
 203         $stmt =~ s/, ?/, /g;
 204
 205         # Convert 2-digit to 4-digit years.
 206         $stmt =~ s/(\b\d\d\b)/19$1/g;
 207
 208         # Make the use of intervals consistent.
 209         if (!$ENV{UPDATE_COPYRIGHT_USE_INTERVALS})
 210           {
 211             $stmt =~ s/(\d{4})-(\d{4})/join(', ', $1..$2)/eg;
 212           }
 213         else
 214           {
 215             $stmt =~
 216               s/
 217                 (\d{4})
 218                 (?:
 219                   (,\ |-)
 220                   ((??{
 221                     if    ($2 eq '-') { '\d{4}'; }
 222                     elsif (!$3)       { $1 + 1;  }
 223                     else              { $3 + 1;  }
 224                   }))
 225                 )+
 226               /$1-$3/gx;
 227
 228             # When it's 2, emit a single range encompassing all year numbers.
 229             $ENV{UPDATE_COPYRIGHT_USE_INTERVALS} == 2
 230               and $stmt =~ s/\b(\d{4})\b.*\b(\d{4})\b/$1-$2/;
 231           }
 232
 233         # Format within margin.
 234         my $stmt_wrapped;
 235         my $text_margin = $margin - length($prefix);
 236         if ($prefix =~ /^(\t+)/)
 237           {
 238             $text_margin -= length($1) * ($tab_width - 1);
 239           }
 240         while (length $stmt)
 241           {
 242             if (($stmt =~ s/^(.{1,$text_margin})(?: |$)//)
 243                 || ($stmt =~ s/^([\S]+)(?: |$)//))
 244               {
 245                 my $line = $1;
 246                 $stmt_wrapped .= $stmt_wrapped ? "$eol$prefix" : $leading;
 247                 $stmt_wrapped .= $line;
 248               }
 249             else
 250               {
 251                 # Should be unreachable, but we don't want an infinite
 252                 # loop if it can be reached.
 253                 die;
 254               }
 255           }
 256
 257         # Replace the old copyright statement.
 258         s/$stmt_re/$stmt_wrapped/;
 259       }
 260   }
 261 else
 262   {
 263     print STDERR "$ARGV: warning: copyright statement not found\n";
 264   }
 265
 266 # Local variables:
 267 # mode: perl
 268 # indent-tabs-mode: nil
 269 # eval: (add-hook 'write-file-hooks 'time-stamp)
 270 # time-stamp-start: "my $VERSION = '"
 271 # time-stamp-format: "%:y-%02m-%02d.%02H:%02M"
 272 # time-stamp-time-zone: "UTC0"
 273 # time-stamp-end: "'; # UTC"
 274 # End: