lisp/arc-mode.el

   1 ;;; arc-mode.el --- simple editing of archives
   2
   3 ;; Copyright (C) 1995, 1997, 1998 Free Software Foundation, Inc.
   4
   5 ;; Author: Morten Welinder <terra@diku.dk>
   6 ;; Keywords: archives msdog editing major-mode
   7 ;; Favourite-brand-of-beer: None, I hate beer.
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; NAMING: "arc" is short for "archive" and does not refer specifically
  29 ;; to files whose name end in ".arc"
  30 ;;
  31 ;; This code does not decode any files internally, although it does
  32 ;; understand the directory level of the archives.  For this reason,
  33 ;; you should expect this code to need more fiddling than tar-mode.el
  34 ;; (although it at present has fewer bugs :-)  In particular, I have
  35 ;; not tested this under Ms-Dog myself.
  36 ;; -------------------------------------
  37 ;; INTERACTION: arc-mode.el should play together with
  38 ;;
  39 ;; * ange-ftp.el: Remote archives (i.e., ones that ange-ftp has brought
  40 ;;                to you) are handled by doing all updates on a local
  41 ;;                copy.  When you make changes to a remote file the
  42 ;;                changes will first take effect when the archive buffer
  43 ;;                is saved.  You will be warned about this.
  44 ;;
  45 ;; * dos-fns.el:  (Part of Emacs 19).  You get automatic ^M^J <--> ^J
  46 ;;                conversion.
  47 ;;
  48 ;; arc-mode.el does not work well with crypt++.el; for the archives as
  49 ;; such this could be fixed (but wouldn't be useful) by declaring such
  50 ;; archives to be "remote".  For the members this is a general Emacs
  51 ;; problem that 19.29's file formats may fix.
  52 ;; -------------------------------------
  53 ;; ARCHIVE TYPES: Currently only the archives below are handled, but the
  54 ;; structure for handling just about anything is in place.
  55 ;;
  56 ;;                        Arc     Lzh     Zip     Zoo
  57 ;;                        --------------------------------
  58 ;; View listing           Intern  Intern  Intern  Intern
  59 ;; Extract member         Y       Y       Y       Y
  60 ;; Save changed member    Y       Y       Y       Y
  61 ;; Add new member         N       N       N       N
  62 ;; Delete member          Y       Y       Y       Y
  63 ;; Rename member          Y       Y       N       N
  64 ;; Chmod                  -       Y       Y       -
  65 ;; Chown                  -       Y       -       -
  66 ;; Chgrp                  -       Y       -       -
  67 ;;
  68 ;; Special thanks to Bill Brodie <wbrodie@panix.com> for very useful tips
  69 ;; on the first released version of this package.
  70 ;;
  71 ;; This code is partly based on tar-mode.el from Emacs.
  72 ;; -------------------------------------
  73 ;; ARCHIVE STRUCTURES:
  74 ;; (This is mostly for myself.)
  75 ;;
  76 ;; ARC         A series of (header,file).  No interactions among members.
  77 ;;
  78 ;; LZH         A series of (header,file).  Headers are checksummed.  No
  79 ;;             interaction among members.
  80 ;;
  81 ;; ZIP         A series of (lheader,fil) followed by a "central directory"
  82 ;;             which is a series of (cheader) followed by an end-of-
  83 ;;             central-dir record possibly followed by junk.  The e-o-c-d
  84 ;;             links to c-d.  cheaders link to lheaders which are basically
  85 ;;             cut-down versions of the cheaders.
  86 ;;
  87 ;; ZOO         An archive header followed by a series of (header,file).
  88 ;;             Each member header points to the next.  The archive is
  89 ;;             terminated by a bogus header with a zero next link.
  90 ;; -------------------------------------
  91 ;; HOOKS: `foo' means one the the supported archive types.
  92 ;;
  93 ;; archive-mode-hook
  94 ;; archive-foo-mode-hook
  95 ;; archive-extract-hooks
  96
  97 ;;; Code:
  98
  99 ;; -------------------------------------------------------------------------
 100 ;; Section: Configuration.
 101
 102 (defgroup archive nil
 103   "Simple editing of archives."
 104   :group 'data)
 105
 106 (defgroup archive-arc nil
 107   "ARC-specific options to archive."
 108   :group 'archive)
 109
 110 (defgroup archive-lzh nil
 111   "LZH-specific options to archive."
 112   :group 'archive)
 113
 114 (defgroup archive-zip nil
 115   "ZIP-specific options to archive."
 116   :group 'archive)
 117
 118 (defgroup archive-zoo nil
 119   "ZOO-specific options to archive."
 120   :group 'archive)
 121
 122 (defcustom archive-tmpdir
 123   (make-temp-name
 124    (expand-file-name (if (eq system-type 'ms-dos) "ar" "archive.tmp")
 125                      temporary-file-directory))
 126   "*Directory for temporary files made by arc-mode.el"
 127   :type 'directory
 128   :group 'archive)
 129
 130 (defcustom archive-remote-regexp "^/[^/:]*[^/:.]:"
 131   "*Regexp recognizing archive files names that are not local.
 132 A non-local file is one whose file name is not proper outside Emacs.
 133 A local copy of the archive will be used when updating."
 134   :type 'regexp
 135   :group 'archive)
 136
 137 (defcustom archive-extract-hooks nil
 138   "*Hooks to run when an archive member has been extracted."
 139   :type 'hook
 140   :group 'archive)
 141 ;; ------------------------------
 142 ;; Arc archive configuration
 143
 144 ;; We always go via a local file since there seems to be no reliable way
 145 ;; to extract to stdout without junk getting added.
 146 (defcustom archive-arc-extract
 147   '("arc" "x")
 148   "*Program and its options to run in order to extract an arc file member.
 149 Extraction should happen to the current directory.  Archive and member
 150 name will be added."
 151   :type '(list (string :tag "Program")
 152                 (repeat :tag "Options"
 153                         :inline t
 154                         (string :format "%v")))
 155   :group 'archive-arc)
 156
 157 (defcustom archive-arc-expunge
 158   '("arc" "d")
 159   "*Program and its options to run in order to delete arc file members.
 160 Archive and member names will be added."
 161   :type '(list (string :tag "Program")
 162                 (repeat :tag "Options"
 163                         :inline t
 164                         (string :format "%v")))
 165   :group 'archive-arc)
 166
 167 (defcustom archive-arc-write-file-member
 168   '("arc" "u")
 169   "*Program and its options to run in order to update an arc file member.
 170 Archive and member name will be added."
 171   :type '(list (string :tag "Program")
 172                 (repeat :tag "Options"
 173                         :inline t
 174                         (string :format "%v")))
 175   :group 'archive-arc)
 176 ;; ------------------------------
 177 ;; Lzh archive configuration
 178
 179 (defcustom archive-lzh-extract
 180   '("lha" "pq")
 181   "*Program and its options to run in order to extract an lzh file member.
 182 Extraction should happen to standard output.  Archive and member name will
 183 be added."
 184   :type '(list (string :tag "Program")
 185                 (repeat :tag "Options"
 186                         :inline t
 187                         (string :format "%v")))
 188   :group 'archive-lzh)
 189
 190 (defcustom archive-lzh-expunge
 191   '("lha" "d")
 192   "*Program and its options to run in order to delete lzh file members.
 193 Archive and member names will be added."
 194   :type '(list (string :tag "Program")
 195                 (repeat :tag "Options"
 196                         :inline t
 197                         (string :format "%v")))
 198   :group 'archive-lzh)
 199
 200 (defcustom archive-lzh-write-file-member
 201   '("lha" "a")
 202   "*Program and its options to run in order to update an lzh file member.
 203 Archive and member name will be added."
 204   :type '(list (string :tag "Program")
 205                 (repeat :tag "Options"
 206                         :inline t
 207                         (string :format "%v")))
 208   :group 'archive-lzh)
 209 ;; ------------------------------
 210 ;; Zip archive configuration
 211
 212 (defcustom archive-zip-use-pkzip (memq system-type '(ms-dos windows-nt))
 213   "*If non-nil then pkzip option are used instead of zip options.
 214 Only set to true for msdog systems!"
 215   :type 'boolean
 216   :group 'archive-zip)
 217
 218 (defcustom archive-zip-extract
 219   (if archive-zip-use-pkzip '("pkunzip" "-e" "-o-") '("unzip" "-qq" "-c"))
 220   "*Program and its options to run in order to extract a zip file member.
 221 Extraction should happen to standard output.  Archive and member name will
 222 be added.  If `archive-zip-use-pkzip' is non-nil then this program is
 223 expected to extract to a file junking the directory part of the name."
 224   :type '(list (string :tag "Program")
 225                 (repeat :tag "Options"
 226                         :inline t
 227                         (string :format "%v")))
 228   :group 'archive-zip)
 229
 230 ;; For several reasons the latter behaviour is not desirable in general.
 231 ;; (1) It uses more disk space.  (2) Error checking is worse or non-
 232 ;; existent.  (3) It tends to do funny things with other systems' file
 233 ;; names.
 234
 235 (defcustom archive-zip-expunge
 236   (if archive-zip-use-pkzip '("pkzip" "-d") '("zip" "-d" "-q"))
 237   "*Program and its options to run in order to delete zip file members.
 238 Archive and member names will be added."
 239   :type '(list (string :tag "Program")
 240                 (repeat :tag "Options"
 241                         :inline t
 242                         (string :format "%v")))
 243   :group 'archive-zip)
 244
 245 (defcustom archive-zip-update
 246   (if archive-zip-use-pkzip '("pkzip" "-u" "-P") '("zip" "-q"))
 247   "*Program and its options to run in order to update a zip file member.
 248 Options should ensure that specified directory will be put into the zip
 249 file.  Archive and member name will be added."
 250   :type '(list (string :tag "Program")
 251                 (repeat :tag "Options"
 252                         :inline t
 253                         (string :format "%v")))
 254   :group 'archive-zip)
 255
 256 (defcustom archive-zip-update-case
 257   (if archive-zip-use-pkzip archive-zip-update '("zip" "-q" "-k"))
 258   "*Program and its options to run in order to update a case fiddled zip member.
 259 Options should ensure that specified directory will be put into the zip file.
 260 Archive and member name will be added."
 261   :type '(list (string :tag "Program")
 262                 (repeat :tag "Options"
 263                         :inline t
 264                         (string :format "%v")))
 265   :group 'archive-zip)
 266
 267 (defcustom archive-zip-case-fiddle t
 268   "*If non-nil then zip file members may be down-cased.
 269 This case fiddling will only happen for members created by a system
 270 that uses caseless file names."
 271   :type 'boolean
 272   :group 'archive-zip)
 273 ;; ------------------------------
 274 ;; Zoo archive configuration
 275
 276 (defcustom archive-zoo-extract
 277   '("zoo" "xpq")
 278   "*Program and its options to run in order to extract a zoo file member.
 279 Extraction should happen to standard output.  Archive and member name will
 280 be added."
 281   :type '(list (string :tag "Program")
 282                 (repeat :tag "Options"
 283                         :inline t
 284                         (string :format "%v")))
 285   :group 'archive-zoo)
 286
 287 (defcustom archive-zoo-expunge
 288   '("zoo" "DqPP")
 289   "*Program and its options to run in order to delete zoo file members.
 290 Archive and member names will be added."
 291   :type '(list (string :tag "Program")
 292                 (repeat :tag "Options"
 293                         :inline t
 294                         (string :format "%v")))
 295   :group 'archive-zoo)
 296
 297 (defcustom archive-zoo-write-file-member
 298   '("zoo" "a")
 299   "*Program and its options to run in order to update a zoo file member.
 300 Archive and member name will be added."
 301   :type '(list (string :tag "Program")
 302                 (repeat :tag "Options"
 303                         :inline t
 304                         (string :format "%v")))
 305   :group 'archive-zoo)
 306 ;; -------------------------------------------------------------------------
 307 ;; Section: Variables
 308
 309 (defvar archive-subtype nil "*Symbol describing archive type.")
 310 (defvar archive-file-list-start nil "*Position of first contents line.")
 311 (defvar archive-file-list-end nil "*Position just after last contents line.")
 312 (defvar archive-proper-file-start nil "*Position of real archive's start.")
 313 (defvar archive-read-only nil "*Non-nil if the archive is read-only on disk.")
 314 (defvar archive-local-name nil "*Name of local copy of remote archive.")
 315 (defvar archive-mode-map nil "*Local keymap for archive mode listings.")
 316 (defvar archive-file-name-indent nil "*Column where file names start.")
 317
 318 (defvar archive-remote nil "*Non-nil if the archive is outside file system.")
 319 (make-variable-buffer-local 'archive-remote)
 320 (put 'archive-remote 'permanent-local t)
 321
 322 (defvar archive-member-coding-system nil "Coding-system of archive member.")
 323 (make-variable-buffer-local 'archive-member-coding-system)
 324
 325 (defvar archive-alternate-display nil
 326   "*Non-nil when alternate information is shown.")
 327 (make-variable-buffer-local 'archive-alternate-display)
 328 (put 'archive-alternate-display 'permanent-local t)
 329
 330 (defvar archive-superior-buffer nil "*In archive members, points to archive.")
 331 (put 'archive-superior-buffer 'permanent-local t)
 332
 333 (defvar archive-subfile-mode nil "*Non-nil in archive member buffers.")
 334 (make-variable-buffer-local 'archive-subfile-mode)
 335 (put 'archive-subfile-mode 'permanent-local t)
 336
 337 (defvar archive-files nil
 338   "Vector of file descriptors.
 339 Each descriptor is a vector of the form
 340  [EXT-FILE-NAME INT-FILE-NAME CASE-FIDDLED MODE ...]")
 341 (make-variable-buffer-local 'archive-files)
 342
 343 (defvar archive-lemacs
 344   (string-match "\\(Lucid\\|Xemacs\\)" emacs-version)
 345   "*Non-nil when running under under Lucid Emacs or Xemacs.")
 346 ;; -------------------------------------------------------------------------
 347 ;; Section: Support functions.
 348
 349 (defsubst archive-name (suffix)
 350   (intern (concat "archive-" (symbol-name archive-subtype) "-" suffix)))
 351
 352 (defun archive-l-e (str &optional len)
 353   "Convert little endian string/vector to integer.
 354 Alternatively, first argument may be a buffer position in the current buffer
 355 in which case a second argument, length, should be supplied."
 356   (if (stringp str)
 357       (setq len (length str))
 358     (setq str (buffer-substring str (+ str len))))
 359   (let ((result 0)
 360         (i 0))
 361     (while (< i len)
 362       (setq i (1+ i)
 363             result (+ (ash result 8) (aref str (- len i)))))
 364     result))
 365
 366 (defun archive-int-to-mode (mode)
 367   "Turn an integer like 0700 (i.e., 448) into a mode string like -rwx------."
 368   ;; FIXME: merge with tar-grind-file-mode.
 369   (string
 370     (if (zerop (logand  8192 mode))
 371         (if (zerop (logand 16384 mode)) ?- ?d)
 372       ?c) ; completeness
 373     (if (zerop (logand   256 mode)) ?- ?r)
 374     (if (zerop (logand   128 mode)) ?- ?w)
 375     (if (zerop (logand    64 mode))
 376         (if (zerop (logand  1024 mode)) ?- ?S)
 377       (if (zerop (logand  1024 mode)) ?x ?s))
 378     (if (zerop (logand    32 mode)) ?- ?r)
 379     (if (zerop (logand    16 mode)) ?- ?w)
 380     (if (zerop (logand     8 mode))
 381         (if (zerop (logand  2048 mode)) ?- ?S)
 382       (if (zerop (logand  2048 mode)) ?x ?s))
 383     (if (zerop (logand     4 mode)) ?- ?r)
 384     (if (zerop (logand     2 mode)) ?- ?w)
 385     (if (zerop (logand     1 mode)) ?- ?x)))
 386
 387 (defun archive-calc-mode (oldmode newmode &optional error)
 388   "From the integer OLDMODE and the string NEWMODE calculate a new file mode.
 389 NEWMODE may be an octal number including a leading zero in which case it
 390 will become the new mode.\n
 391 NEWMODE may also be a relative specification like \"og-rwx\" in which case
 392 OLDMODE will be modified accordingly just like chmod(2) would have done.\n
 393 If optional third argument ERROR is non-nil an error will be signaled if
 394 the mode is invalid.  If ERROR is nil then nil will be returned."
 395   (cond ((string-match "^0[0-7]*$" newmode)
 396          (let ((result 0)
 397                (len (length newmode))
 398                (i 1))
 399            (while (< i len)
 400              (setq result (+ (lsh result 3) (aref newmode i) (- ?0))
 401                    i (1+ i)))
 402            (logior (logand oldmode 65024) result)))
 403         ((string-match "^\\([agou]+\\)\\([---+=]\\)\\([rwxst]+\\)$" newmode)
 404          (let ((who 0)
 405                (result oldmode)
 406                (op (aref newmode (match-beginning 2)))
 407                (bits 0)
 408                (i (match-beginning 3)))
 409            (while (< i (match-end 3))
 410              (let ((rwx (aref newmode i)))
 411                (setq bits (logior bits (cond ((= rwx ?r)  292)
 412                                              ((= rwx ?w)  146)
 413                                              ((= rwx ?x)   73)
 414                                              ((= rwx ?s) 3072)
 415                                              ((= rwx ?t)  512)))
 416                      i (1+ i))))
 417            (while (< who (match-end 1))
 418              (let* ((whoc (aref newmode who))
 419                     (whomask (cond ((= whoc ?a) 4095)
 420                                    ((= whoc ?u) 1472)
 421                                    ((= whoc ?g) 2104)
 422                                    ((= whoc ?o)    7))))
 423                (if (= op ?=)
 424                    (setq result (logand result (lognot whomask))))
 425                (if (= op ?-)
 426                    (setq result (logand result (lognot (logand whomask bits))))
 427                  (setq result (logior result (logand whomask bits)))))
 428              (setq who (1+ who)))
 429            result))
 430         (t
 431          (if error
 432              (error "Invalid mode specification: %s" newmode)))))
 433
 434 (defun archive-dosdate (date)
 435   "Stringify dos packed DATE record."
 436   (let ((year (+ 1980 (logand (ash date -9) 127)))
 437         (month (logand (ash date -5) 15))
 438         (day (logand date 31)))
 439     (if (or (> month 12) (< month 1))
 440         ""
 441       (format "%2d-%s-%d"
 442               day
 443               (aref ["Jan" "Feb" "Mar" "Apr" "May" "Jun"
 444                      "Jul" "Aug" "Sep" "Oct" "Nov" "Dec"] (1- month))
 445               year))))
 446
 447 (defun archive-dostime (time)
 448   "Stringify dos packed TIME record."
 449   (let ((hour (logand (ash time -11) 31))
 450         (minute (logand (ash time -5) 53))
 451         (second (* 2 (logand time 31)))) ; 2 seconds resolution
 452     (format "%02d:%02d:%02d" hour minute second)))
 453
 454 ;;(defun archive-unixdate (low high)
 455 ;;  "Stringify unix (LOW HIGH) date."
 456 ;;  (let ((str (current-time-string (cons high low))))
 457 ;;    (format "%s-%s-%s"
 458 ;;          (substring str 8 9)
 459 ;;          (substring str 4 7)
 460 ;;          (substring str 20 24))))
 461
 462 ;;(defun archive-unixtime (low high)
 463 ;;  "Stringify unix (LOW HIGH) time."
 464 ;;  (let ((str (current-time-string (cons high low))))
 465 ;;    (substring str 11 19)))
 466
 467 (defun archive-get-lineno ()
 468   (if (>= (point) archive-file-list-start)
 469       (count-lines archive-file-list-start
 470                    (save-excursion (beginning-of-line) (point)))
 471     0))
 472
 473 (defun archive-get-descr (&optional noerror)
 474   "Return the descriptor vector for file at point.
 475 Does not signal an error if optional second argument NOERROR is non-nil."
 476   (let ((no (archive-get-lineno)))
 477     (if (and (>= (point) archive-file-list-start)
 478              (< no (length archive-files)))
 479         (let ((item (aref archive-files no)))
 480           (if (vectorp item)
 481               item
 482             (if (not noerror)
 483                 (error "Entry is not a regular member of the archive"))))
 484       (if (not noerror)
 485           (error "Line does not describe a member of the archive")))))
 486 ;; -------------------------------------------------------------------------
 487 ;; Section: the mode definition
 488
 489 ;;;###autoload
 490 (defun archive-mode (&optional force)
 491   "Major mode for viewing an archive file in a dired-like way.
 492 You can move around using the usual cursor motion commands.
 493 Letters no longer insert themselves.
 494 Type `e' to pull a file out of the archive and into its own buffer;
 495 or click mouse-2 on the file's line in the archive mode buffer.
 496
 497 If you edit a sub-file of this archive (as with the `e' command) and
 498 save it, the contents of that buffer will be saved back into the
 499 archive.
 500
 501 \\{archive-mode-map}"
 502   ;; This is not interactive because you shouldn't be turning this
 503   ;; mode on and off.  You can corrupt things that way.
 504   (if (zerop (buffer-size))
 505       ;; At present we cannot create archives from scratch
 506       (funcall default-major-mode)
 507     (if (and (not force) archive-files) nil
 508       (let* ((type (archive-find-type))
 509              (typename (capitalize (symbol-name type))))
 510         (kill-all-local-variables)
 511         (make-local-variable 'archive-subtype)
 512         (setq archive-subtype type)
 513
 514         ;; Buffer contains treated image of file before the file contents
 515         (make-local-variable 'revert-buffer-function)
 516         (setq revert-buffer-function 'archive-mode-revert)
 517         (auto-save-mode 0)
 518
 519         ;; Remote archives are not written by a hook.
 520         (if archive-remote nil
 521           (make-local-variable 'write-contents-hooks)
 522           (add-hook 'write-contents-hooks 'archive-write-file))
 523
 524         (make-local-variable 'require-final-newline)
 525         (setq require-final-newline nil)
 526         (make-local-variable 'local-enable-local-variables)
 527         (setq local-enable-local-variables nil)
 528
 529         ;; Prevent loss of data when saving the file.
 530         (make-local-variable 'file-precious-flag)
 531         (setq file-precious-flag t)
 532
 533         (make-local-variable 'archive-read-only)
 534         ;; Archives which are inside other archives and whose
 535         ;; names are invalid for this OS, can't be written.
 536         (setq archive-read-only
 537               (or (not (file-writable-p (buffer-file-name)))
 538                   (and archive-subfile-mode
 539                        (string-match file-name-invalid-regexp
 540                                      (aref archive-subfile-mode 0)))))
 541
 542         ;; Should we use a local copy when accessing from outside Emacs?
 543         (make-local-variable 'archive-local-name)
 544
 545         ;; An archive can contain another archive whose name is invalid
 546         ;; on local filesystem.  Treat such archives as remote.
 547         (or archive-remote
 548             (setq archive-remote
 549                   (or (string-match archive-remote-regexp (buffer-file-name))
 550                       (string-match file-name-invalid-regexp
 551                                     (buffer-file-name)))))
 552
 553         (setq major-mode 'archive-mode)
 554         (setq mode-name (concat typename "-Archive"))
 555         ;; Run archive-foo-mode-hook and archive-mode-hook
 556         (run-hooks (archive-name "mode-hook") 'archive-mode-hook)
 557         (use-local-map archive-mode-map))
 558
 559       (make-local-variable 'archive-proper-file-start)
 560       (make-local-variable 'archive-file-list-start)
 561       (make-local-variable 'archive-file-list-end)
 562       (make-local-variable 'archive-file-name-indent)
 563       (archive-summarize nil)
 564       (setq buffer-read-only t))))
 565
 566 ;; Archive mode is suitable only for specially formatted data.
 567 (put 'archive-mode 'mode-class 'special)
 568 ;; -------------------------------------------------------------------------
 569 ;; Section: Key maps
 570
 571 (if archive-mode-map nil
 572   (setq archive-mode-map (make-keymap))
 573   (suppress-keymap archive-mode-map)
 574   (define-key archive-mode-map " " 'archive-next-line)
 575   (define-key archive-mode-map "a" 'archive-alternate-display)
 576   ;;(define-key archive-mode-map "c" 'archive-copy)
 577   (define-key archive-mode-map "d" 'archive-flag-deleted)
 578   (define-key archive-mode-map "\C-d" 'archive-flag-deleted)
 579   (define-key archive-mode-map "e" 'archive-extract)
 580   (define-key archive-mode-map "f" 'archive-extract)
 581   (define-key archive-mode-map "\C-m" 'archive-extract)
 582   (define-key archive-mode-map "g" 'revert-buffer)
 583   (define-key archive-mode-map "h" 'describe-mode)
 584   (define-key archive-mode-map "m" 'archive-mark)
 585   (define-key archive-mode-map "n" 'archive-next-line)
 586   (define-key archive-mode-map "\C-n" 'archive-next-line)
 587   (define-key archive-mode-map [down] 'archive-next-line)
 588   (define-key archive-mode-map "o" 'archive-extract-other-window)
 589   (define-key archive-mode-map "p" 'archive-previous-line)
 590   (define-key archive-mode-map "q" 'quit-window)
 591   (define-key archive-mode-map "\C-p" 'archive-previous-line)
 592   (define-key archive-mode-map [up] 'archive-previous-line)
 593   (define-key archive-mode-map "r" 'archive-rename-entry)
 594   (define-key archive-mode-map "u" 'archive-unflag)
 595   (define-key archive-mode-map "\M-\C-?" 'archive-unmark-all-files)
 596   (define-key archive-mode-map "v" 'archive-view)
 597   (define-key archive-mode-map "x" 'archive-expunge)
 598   (define-key archive-mode-map "\177" 'archive-unflag-backwards)
 599   (define-key archive-mode-map "E" 'archive-extract-other-window)
 600   (define-key archive-mode-map "M" 'archive-chmod-entry)
 601   (define-key archive-mode-map "G" 'archive-chgrp-entry)
 602   (define-key archive-mode-map "O" 'archive-chown-entry)
 603
 604   (if archive-lemacs
 605       (progn
 606         ;; Not a nice "solution" but it'll have to do
 607         (define-key archive-mode-map "\C-xu" 'archive-undo)
 608         (define-key archive-mode-map "\C-_" 'archive-undo))
 609     (substitute-key-definition 'undo 'archive-undo
 610                                archive-mode-map global-map))
 611
 612   (define-key archive-mode-map
 613     (if archive-lemacs 'button2 [mouse-2]) 'archive-mouse-extract)
 614
 615   (if archive-lemacs
 616       ()                                ; out of luck
 617
 618     (define-key archive-mode-map [menu-bar immediate]
 619       (cons "Immediate" (make-sparse-keymap "Immediate")))
 620     (define-key archive-mode-map [menu-bar immediate alternate]
 621       '(menu-item "Alternate Display" archive-alternate-display
 622                   :enable (boundp (archive-name "alternate-display"))
 623                   :help "Toggle alternate file info display"))
 624     (define-key archive-mode-map [menu-bar immediate view]
 625       '(menu-item "View This File" archive-view
 626                   :help "Display file at cursor in View Mode"))
 627     (define-key archive-mode-map [menu-bar immediate display]
 628       '(menu-item "Display in Other Window" archive-display-other-window
 629                   :help "Display file at cursor in another window"))
 630     (define-key archive-mode-map [menu-bar immediate find-file-other-window]
 631       '(menu-item "Find in Other Window" archive-extract-other-window
 632                   :help "Edit file at cursor in another window"))
 633     (define-key archive-mode-map [menu-bar immediate find-file]
 634       '(menu-item "Find This File" archive-extract
 635                   :help "Extract file at cursor and edit it"))
 636
 637     (define-key archive-mode-map [menu-bar mark]
 638       (cons "Mark" (make-sparse-keymap "Mark")))
 639     (define-key archive-mode-map [menu-bar mark unmark-all]
 640       '(menu-item "Unmark All" archive-unmark-all-files
 641                   :help "Unmark all marked files"))
 642     (define-key archive-mode-map [menu-bar mark deletion]
 643       '(menu-item "Flag" archive-flag-deleted
 644                   :help "Flag file at cursor for deletion"))
 645     (define-key archive-mode-map [menu-bar mark unmark]
 646       '(menu-item "Unflag" archive-unflag
 647                   :help "Unmark file at cursor"))
 648     (define-key archive-mode-map [menu-bar mark mark]
 649       '(menu-item "Mark" archive-mark
 650                   :help "Mark file at cursor"))
 651
 652     (define-key archive-mode-map [menu-bar operate]
 653       (cons "Operate" (make-sparse-keymap "Operate")))
 654     (define-key archive-mode-map [menu-bar operate chown]
 655       '(menu-item "Change Owner..." archive-chown-entry
 656                   :enable (fboundp (archive-name "chown-entry"))
 657                   :help "Change owner of marked files"))
 658     (define-key archive-mode-map [menu-bar operate chgrp]
 659       '(menu-item "Change Group..." archive-chgrp-entry
 660                   :enable (fboundp (archive-name "chgrp-entry"))
 661                   :help "Change group ownership of marked files"))
 662     (define-key archive-mode-map [menu-bar operate chmod]
 663       '(menu-item "Change Mode..." archive-chmod-entry
 664                   :enable (fboundp (archive-name "chmod-entry"))
 665                   :help "Change mode (permissions) of marked files"))
 666     (define-key archive-mode-map [menu-bar operate rename]
 667       '(menu-item "Rename to..." archive-rename-entry
 668                   :enable (fboundp (archive-name "rename-entry"))
 669                   :help "Rename marked files"))
 670     ;;(define-key archive-mode-map [menu-bar operate copy]
 671     ;;  '(menu-item "Copy to..." archive-copy))
 672     (define-key archive-mode-map [menu-bar operate expunge]
 673       '(menu-item "Expunge Marked Files" archive-expunge
 674                   :help "Delete all flagged files from archive"))
 675   ))
 676
 677 (let* ((item1 '(archive-subfile-mode " Archive"))
 678        (items (list item1)))
 679   (or (member item1 minor-mode-alist)
 680       (setq minor-mode-alist (append items minor-mode-alist))))
 681 ;; -------------------------------------------------------------------------
 682 (defun archive-find-type ()
 683   (widen)
 684   (goto-char (point-min))
 685   ;; The funny [] here make it unlikely that the .elc file will be treated
 686   ;; as an archive by other software.
 687   (let (case-fold-search)
 688     (cond ((looking-at "[P]K\003\004") 'zip)
 689           ((looking-at "..-l[hz][0-9ds]-") 'lzh)
 690           ((looking-at "....................[\334]\247\304\375") 'zoo)
 691           ((and (looking-at "\C-z")     ; signature too simple, IMHO
 692                 (string-match "\\.[aA][rR][cC]$"
 693                               (or buffer-file-name (buffer-name))))
 694            'arc)
 695           (t (error "Buffer format not recognized")))))
 696 ;; -------------------------------------------------------------------------
 697 (defun archive-summarize (&optional shut-up)
 698   "Parse the contents of the archive file in the current buffer.
 699 Place a dired-like listing on the front;
 700 then narrow to it, so that only that listing
 701 is visible (and the real data of the buffer is hidden).
 702 Optional argument SHUT-UP, if non-nil, means don't print messages
 703 when parsing the archive."
 704   (widen)
 705   (set-buffer-multibyte nil)
 706   (let (buffer-read-only)
 707     (or shut-up
 708         (message "Parsing archive file..."))
 709     (buffer-disable-undo (current-buffer))
 710     (setq archive-files (funcall (archive-name "summarize")))
 711     (or shut-up
 712         (message "Parsing archive file...done."))
 713     (setq archive-proper-file-start (point-marker))
 714     (narrow-to-region (point-min) (point))
 715     (set-buffer-modified-p nil)
 716     (buffer-enable-undo))
 717   (goto-char archive-file-list-start)
 718   (archive-next-line 0))
 719
 720 (defun archive-resummarize ()
 721   "Recreate the contents listing of an archive."
 722   (let ((modified (buffer-modified-p))
 723         (no (archive-get-lineno))
 724         buffer-read-only)
 725     (widen)
 726     (delete-region (point-min) archive-proper-file-start)
 727     (archive-summarize t)
 728     (set-buffer-modified-p modified)
 729     (goto-char archive-file-list-start)
 730     (archive-next-line no)))
 731
 732 (defun archive-summarize-files (files)
 733   "Insert a description of a list of files annotated with proper mouse face."
 734   (setq archive-file-list-start (point-marker))
 735   (setq archive-file-name-indent (if files (aref (car files) 1) 0))
 736   ;; We don't want to do an insert for each element since that takes too
 737   ;; long when the archive -- which has to be moved in memory -- is large.
 738   (insert
 739    (apply
 740     (function concat)
 741     (mapcar
 742      (function
 743       (lambda (fil)
 744         ;; Using `concat' here copies the text also, so we can add
 745         ;; properties without problems.
 746         (let ((text (concat (aref fil 0) "\n")))
 747           (if archive-lemacs
 748               ()                        ; out of luck
 749             (add-text-properties
 750              (aref fil 1) (aref fil 2)
 751              '(mouse-face highlight
 752                help-echo "mouse-2: extract this file into a buffer")
 753              text))
 754           text)))
 755      files)))
 756   (setq archive-file-list-end (point-marker)))
 757
 758 (defun archive-alternate-display ()
 759   "Toggle alternative display.
 760 To avoid very long lines some archive mode don't show all information.
 761 This function changes the set of information shown for each files."
 762   (interactive)
 763   (setq archive-alternate-display (not archive-alternate-display))
 764   (archive-resummarize))
 765 ;; -------------------------------------------------------------------------
 766 ;; Section: Local archive copy handling
 767
 768 (defun archive-unique-fname (fname dir)
 769   "Make sure a file FNAME can be created uniquely in directory DIR.
 770
 771 If FNAME can be uniquely created in DIR, it is returned unaltered.
 772 If FNAME is something our underlying filesystem can't grok, or if another
 773 file by that name already exists in DIR, a unique new name is generated
 774 using `make-temp-file', and the generated name is returned."
 775   (let ((fullname (expand-file-name fname dir))
 776         (alien (string-match file-name-invalid-regexp fname)))
 777     (if (or alien (file-exists-p fullname))
 778         (make-temp-file
 779          (expand-file-name
 780           (if (and (fboundp 'msdos-long-file-names)
 781                    (not (msdos-long-file-names)))
 782               "am"
 783             "arc-mode.")
 784           dir))
 785       fullname)))
 786
 787 (defun archive-maybe-copy (archive)
 788   (let ((coding-system-for-write 'no-conversion))
 789     (if archive-remote
 790         (let ((start (point-max))
 791               ;; Sometimes ARCHIVE is invalid while its actual name, as
 792               ;; recorded in its parent archive, is not.  For example, an
 793               ;; archive bar.zip inside another archive foo.zip gets a name
 794               ;; "foo.zip:bar.zip", which is invalid on DOS/Windows.
 795               ;; So use the actual name if available.
 796               (archive-name
 797                (or (and archive-subfile-mode (aref archive-subfile-mode 0))
 798                    archive)))
 799           (make-directory archive-tmpdir t)
 800           (setq archive-local-name
 801                 (archive-unique-fname archive-name archive-tmpdir))
 802           (save-restriction
 803             (widen)
 804             (write-region start (point-max) archive-local-name nil 'nomessage))
 805           archive-local-name)
 806       (if (buffer-modified-p) (save-buffer))
 807       archive)))
 808
 809 (defun archive-maybe-update (unchanged)
 810   (if archive-remote
 811       (let ((name archive-local-name)
 812             (modified (buffer-modified-p))
 813             (coding-system-for-read 'no-conversion)
 814             (lno (archive-get-lineno))
 815             buffer-read-only)
 816         (if unchanged nil
 817           (setq archive-files nil)
 818           (erase-buffer)
 819           (insert-file-contents name)
 820           (archive-mode t)
 821           (goto-char archive-file-list-start)
 822           (archive-next-line lno))
 823         (archive-delete-local name)
 824         (if (not unchanged)
 825             (message
 826              "Buffer `%s' must be saved for changes to take effect"
 827              (buffer-name (current-buffer))))
 828         (set-buffer-modified-p (or modified (not unchanged))))))
 829
 830 (defun archive-delete-local (name)
 831   "Delete file NAME and its parents up to and including `archive-tmpdir'."
 832   (let ((again t)
 833         (top (directory-file-name (file-name-as-directory archive-tmpdir))))
 834     (condition-case nil
 835         (delete-file name)
 836       (error nil))
 837     (while again
 838       (setq name (directory-file-name (file-name-directory name)))
 839       (condition-case nil
 840           (delete-directory name)
 841         (error nil))
 842       (if (string= name top) (setq again nil)))))
 843 ;; -------------------------------------------------------------------------
 844 ;; Section: Member extraction
 845
 846 (defun archive-file-name-handler (op &rest args)
 847   (or (eq op 'file-exists-p)
 848       (let ((file-name-handler-alist nil))
 849         (apply op args))))
 850
 851 (defun archive-set-buffer-as-visiting-file (filename)
 852   "Set the current buffer as if it were visiting FILENAME."
 853   (save-excursion
 854     (goto-char (point-min))
 855     (let ((coding
 856            (or coding-system-for-read
 857                (and set-auto-coding-function
 858                     (save-excursion
 859                       (funcall set-auto-coding-function
 860                                filename (- (point-max) (point-min)))))
 861                ;; dos-w32.el defines find-operation-coding-system for
 862                ;; DOS/Windows systems which preserves the coding-system
 863                ;; of existing files.  We want it to act here as if the
 864                ;; extracted file existed.
 865                (let ((file-name-handler-alist
 866                       '(("" . archive-file-name-handler))))
 867                  (car (find-operation-coding-system 'insert-file-contents
 868                                                     filename t))))))
 869       (if (and (not coding-system-for-read)
 870                (not enable-multibyte-characters))
 871           (setq coding
 872                 (coding-system-change-text-conversion coding 'raw-text)))
 873       (if (and coding
 874                (not (eq coding 'no-conversion)))
 875           (decode-coding-region (point-min) (point-max) coding)
 876         (setq last-coding-system-used coding))
 877       (set-buffer-modified-p nil)
 878       (kill-local-variable 'buffer-file-coding-system)
 879       (after-insert-file-set-buffer-file-coding-system (- (point-max)
 880                                                           (point-min))))))
 881
 882 (defun archive-mouse-extract (event)
 883   "Extract a file whose name you click on."
 884   (interactive "e")
 885   (mouse-set-point event)
 886   (switch-to-buffer
 887    (save-excursion
 888      (archive-extract)
 889      (current-buffer))))
 890
 891 (defun archive-extract (&optional other-window-p)
 892   "In archive mode, extract this entry of the archive into its own buffer."
 893   (interactive)
 894   (let* ((view-p (eq other-window-p 'view))
 895          (descr (archive-get-descr))
 896          (ename (aref descr 0))
 897          (iname (aref descr 1))
 898          (archive-buffer (current-buffer))
 899          (arcdir default-directory)
 900          (archive (buffer-file-name))
 901          (arcname (file-name-nondirectory archive))
 902          (bufname (concat (file-name-nondirectory iname) " (" arcname ")"))
 903          (extractor (archive-name "extract"))
 904          ;; Members with file names which aren't valid for the
 905          ;; underlying filesystem, are treated as read-only.
 906          (read-only-p (or archive-read-only
 907                           view-p
 908                           (string-match file-name-invalid-regexp ename)))
 909          (buffer (get-buffer bufname))
 910          (just-created nil))
 911       (if buffer
 912           nil
 913         (setq archive (archive-maybe-copy archive))
 914         (setq buffer (get-buffer-create bufname))
 915         (setq just-created t)
 916         (save-excursion
 917           (set-buffer buffer)
 918           (setq buffer-file-name
 919                 (expand-file-name (concat arcname ":" iname)))
 920           (setq buffer-file-truename
 921                 (abbreviate-file-name buffer-file-name))
 922           ;; Set the default-directory to the dir of the superior buffer.
 923           (setq default-directory arcdir)
 924           (make-local-variable 'archive-superior-buffer)
 925           (setq archive-superior-buffer archive-buffer)
 926           (make-local-variable 'local-write-file-hooks)
 927           (add-hook 'local-write-file-hooks 'archive-write-file-member)
 928           (setq archive-subfile-mode descr)
 929           (if (and
 930                (null
 931                 (let (;; We may have to encode file name arguement for
 932                       ;; external programs.
 933                       (coding-system-for-write
 934                        (and enable-multibyte-characters
 935                             file-name-coding-system))
 936                       ;; We read an archive member by no-conversion at
 937                       ;; first, then decode appropriately by calling
 938                       ;; archive-set-buffer-as-visiting-file later.
 939                       (coding-system-for-read 'no-conversion))
 940                   (condition-case err
 941                       (if (fboundp extractor)
 942                           (funcall extractor archive ename)
 943                         (archive-*-extract archive ename
 944                                            (symbol-value extractor)))
 945                     (error
 946                      (ding (message "%s" (error-message-string err)))
 947                      nil))))
 948                just-created)
 949               (progn
 950                 (set-buffer-modified-p nil)
 951                 (kill-buffer buffer))
 952             (archive-set-buffer-as-visiting-file ename)
 953             (goto-char (point-min))
 954             (rename-buffer bufname)
 955             (setq buffer-read-only read-only-p)
 956             (setq buffer-undo-list nil)
 957             (set-buffer-modified-p nil)
 958             (setq buffer-saved-size (buffer-size))
 959             (normal-mode)
 960             ;; Just in case an archive occurs inside another archive.
 961             (if (eq major-mode 'archive-mode)
 962                 (progn
 963                   (setq archive-remote t)
 964                   (if read-only-p (setq archive-read-only t))
 965                   ;; We will write out the archive ourselves if it is
 966                   ;; part of another archive.
 967                   (remove-hook 'write-contents-hooks 'archive-write-file t)))
 968             (run-hooks 'archive-extract-hooks)
 969             (if archive-read-only
 970                 (message "Note: altering this archive is not implemented."))))
 971         (archive-maybe-update t))
 972       (or (not (buffer-name buffer))
 973           (progn
 974             (if view-p
 975                 (view-buffer buffer (and just-created 'kill-buffer))
 976               (if (eq other-window-p 'display)
 977                   (display-buffer buffer)
 978                 (if other-window-p
 979                     (switch-to-buffer-other-window buffer)
 980                   (switch-to-buffer buffer))))))))
 981
 982 (defun archive-*-extract (archive name command)
 983   (let* ((default-directory (file-name-as-directory archive-tmpdir))
 984          (tmpfile (expand-file-name (file-name-nondirectory name)
 985                                     default-directory))
 986          exit-status success)
 987     (make-directory (directory-file-name default-directory) t)
 988     (setq exit-status
 989           (apply 'call-process
 990                  (car command)
 991                  nil
 992                  nil
 993                  nil
 994                  (append (cdr command) (list archive name))))
 995     (cond ((and (numberp exit-status) (= exit-status 0))
 996            (if (not (file-exists-p tmpfile))
 997                (ding (message "`%s': no such file or directory" tmpfile))
 998              (insert-file-contents tmpfile)
 999              (setq success t)))
1000           ((numberp exit-status)
1001            (ding
1002             (message "`%s' exited with status %d" (car command) exit-status)))
1003           ((stringp exit-status)
1004            (ding (message "`%s' aborted: %s" (car command) exit-status)))
1005           (t
1006            (ding (message "`%s' failed" (car command)))))
1007     (archive-delete-local tmpfile)
1008     success))
1009
1010 (defun archive-extract-by-stdout (archive name command)
1011   (apply 'call-process
1012          (car command)
1013          nil
1014          t
1015          nil
1016          (append (cdr command) (list archive name))))
1017
1018 (defun archive-extract-other-window ()
1019   "In archive mode, find this member in another window."
1020   (interactive)
1021   (archive-extract t))
1022
1023 (defun archive-display-other-window ()
1024   "In archive mode, display this member in another window."
1025   (interactive)
1026   (archive-extract 'display))
1027
1028 (defun archive-view ()
1029   "In archive mode, view the member on this line."
1030   (interactive)
1031   (archive-extract 'view))
1032
1033 (defun archive-add-new-member (arcbuf name)
1034   "Add current buffer to the archive in ARCBUF naming it NAME."
1035   (interactive
1036    (list (get-buffer
1037           (read-buffer "Buffer containing archive: "
1038                        ;; Find first archive buffer and suggest that
1039                        (let ((bufs (buffer-list)))
1040                          (while (and bufs (not (eq (save-excursion
1041                                                      (set-buffer (car bufs))
1042                                                      major-mode)
1043                                                    'archive-mode)))
1044                            (setq bufs (cdr bufs)))
1045                          (if bufs
1046                              (car bufs)
1047                            (error "There are no archive buffers")))
1048                        t))
1049          (read-string "File name in archive: "
1050                       (if buffer-file-name
1051                           (file-name-nondirectory buffer-file-name)
1052                         ""))))
1053   (save-excursion
1054     (set-buffer arcbuf)
1055     (or (eq major-mode 'archive-mode)
1056         (error "Buffer is not an archive buffer"))
1057     (if archive-read-only
1058         (error "Archive is read-only")))
1059   (if (eq arcbuf (current-buffer))
1060       (error "An archive buffer cannot be added to itself"))
1061   (if (string= name "")
1062       (error "Archive members may not be given empty names"))
1063   (let ((func (save-excursion (set-buffer arcbuf)
1064                               (archive-name "add-new-member")))
1065         (membuf (current-buffer)))
1066     (if (fboundp func)
1067         (save-excursion
1068           (set-buffer arcbuf)
1069           (funcall func buffer-file-name membuf name))
1070       (error "Adding a new member is not supported for this archive type"))))
1071 ;; -------------------------------------------------------------------------
1072 ;; Section: IO stuff
1073
1074 (defun archive-write-file-member ()
1075   (save-excursion
1076     (save-restriction
1077       (message "Updating archive...")
1078       (widen)
1079       (let ((writer  (save-excursion (set-buffer archive-superior-buffer)
1080                                      (archive-name "write-file-member")))
1081             (archive (save-excursion (set-buffer archive-superior-buffer)
1082                                      (archive-maybe-copy (buffer-file-name)))))
1083         (if (fboundp writer)
1084             (funcall writer archive archive-subfile-mode)
1085           (archive-*-write-file-member archive
1086                                        archive-subfile-mode
1087                                        (symbol-value writer)))
1088         (set-buffer-modified-p nil)
1089         (message "Updating archive...done"))
1090       (set-buffer archive-superior-buffer)
1091       (if (not archive-remote) (revert-buffer) (archive-maybe-update nil))))
1092   ;; Restore the value of last-coding-system-used, so that basic-save-buffer
1093   ;; won't reset the coding-system of this archive member.
1094   (if (local-variable-p 'archive-member-coding-system)
1095       (setq last-coding-system-used archive-member-coding-system))
1096   t)
1097
1098 (defun archive-*-write-file-member (archive descr command)
1099   (let* ((ename (aref descr 0))
1100          (tmpfile (expand-file-name ename archive-tmpdir))
1101          (top (directory-file-name (file-name-as-directory archive-tmpdir)))
1102          (default-directory (file-name-as-directory top)))
1103     (unwind-protect
1104         (progn
1105           (make-directory (file-name-directory tmpfile) t)
1106           ;; If the member is itself an archive, write it without
1107           ;; the dired-like listing we created.
1108           (if (eq major-mode 'archive-mode)
1109               (archive-write-file tmpfile)
1110             (write-region (point-min) (point-max) tmpfile nil 'nomessage))
1111           ;; basic-save-buffer needs last-coding-system-used to have
1112           ;; the value used to write the file, so save it before any
1113           ;; further processing clobbers it (we restore it in
1114           ;; archive-write-file-member, above).
1115           (setq archive-member-coding-system last-coding-system-used)
1116           (if (aref descr 3)
1117               ;; Set the file modes, but make sure we can read it.
1118               (set-file-modes tmpfile (logior ?\400 (aref descr 3))))
1119           (if enable-multibyte-characters
1120               (setq ename
1121                     (encode-coding-string ename file-name-coding-system)))
1122           (let ((exitcode (apply 'call-process
1123                                  (car command)
1124                                  nil
1125                                  nil
1126                                  nil
1127                                  (append (cdr command) (list archive ename)))))
1128             (if (equal exitcode 0)
1129                 nil
1130               (error "Updating was unsuccessful (%S)" exitcode))))
1131       (archive-delete-local tmpfile))))
1132
1133 (defun archive-write-file (&optional file)
1134   (save-excursion
1135     (let ((coding-system-for-write 'no-conversion))
1136       (write-region archive-proper-file-start (point-max)
1137                     (or file buffer-file-name) nil t)
1138       (set-buffer-modified-p nil))
1139     t))
1140 ;; -------------------------------------------------------------------------
1141 ;; Section: Marking and unmarking.
1142
1143 (defun archive-flag-deleted (p &optional type)
1144   "In archive mode, mark this member to be deleted from the archive.
1145 With a prefix argument, mark that many files."
1146   (interactive "p")
1147   (or type (setq type ?D))
1148   (beginning-of-line)
1149   (let ((sign (if (>= p 0) +1 -1))
1150         (modified (buffer-modified-p))
1151         buffer-read-only)
1152     (while (not (zerop p))
1153       (if (archive-get-descr t)
1154           (progn
1155             (delete-char 1)
1156             (insert type)))
1157       (forward-line sign)
1158       (setq p (- p sign)))
1159     (set-buffer-modified-p modified))
1160   (archive-next-line 0))
1161
1162 (defun archive-unflag (p)
1163   "In archive mode, un-mark this member if it is marked to be deleted.
1164 With a prefix argument, un-mark that many files forward."
1165   (interactive "p")
1166   (archive-flag-deleted p ? ))
1167
1168 (defun archive-unflag-backwards (p)
1169   "In archive mode, un-mark this member if it is marked to be deleted.
1170 With a prefix argument, un-mark that many members backward."
1171   (interactive "p")
1172   (archive-flag-deleted (- p) ? ))
1173
1174 (defun archive-unmark-all-files ()
1175   "Remove all marks."
1176   (interactive)
1177   (let ((modified (buffer-modified-p))
1178         buffer-read-only)
1179     (save-excursion
1180       (goto-char archive-file-list-start)
1181       (while (< (point) archive-file-list-end)
1182         (or (= (following-char) ? )
1183             (progn (delete-char 1) (insert ? )))
1184         (forward-line 1)))
1185     (set-buffer-modified-p modified)))
1186
1187 (defun archive-mark (p)
1188   "In archive mode, mark this member for group operations.
1189 With a prefix argument, mark that many members.
1190 Use \\[archive-unmark-all-files] to remove all marks."
1191   (interactive "p")
1192   (archive-flag-deleted p ?*))
1193
1194 (defun archive-get-marked (mark &optional default)
1195   (let (files)
1196     (save-excursion
1197       (goto-char archive-file-list-start)
1198       (while (< (point) archive-file-list-end)
1199         (if (= (following-char) mark)
1200             (setq files (cons (archive-get-descr) files)))
1201         (forward-line 1)))
1202     (or (nreverse files)
1203         (and default
1204              (list (archive-get-descr))))))
1205 ;; -------------------------------------------------------------------------
1206 ;; Section: Operate
1207
1208 (defun archive-next-line (p)
1209   (interactive "p")
1210   (forward-line p)
1211   (or (eobp)
1212       (forward-char archive-file-name-indent)))
1213
1214 (defun archive-previous-line (p)
1215   (interactive "p")
1216   (archive-next-line (- p)))
1217
1218 (defun archive-chmod-entry (new-mode)
1219   "Change the protection bits associated with all marked or this member.
1220 The new protection bits can either be specified as an octal number or
1221 as a relative change like \"g+rw\" as for chmod(2)"
1222   (interactive "sNew mode (octal or relative): ")
1223   (if archive-read-only (error "Archive is read-only"))
1224   (let ((func (archive-name "chmod-entry")))
1225     (if (fboundp func)
1226         (progn
1227           (funcall func new-mode (archive-get-marked ?* t))
1228           (archive-resummarize))
1229       (error "Setting mode bits is not supported for this archive type"))))
1230
1231 (defun archive-chown-entry (new-uid)
1232   "Change the owner of all marked or this member."
1233   (interactive "nNew uid: ")
1234   (if archive-read-only (error "Archive is read-only"))
1235   (let ((func (archive-name "chown-entry")))
1236     (if (fboundp func)
1237         (progn
1238           (funcall func new-uid (archive-get-marked ?* t))
1239           (archive-resummarize))
1240       (error "Setting owner is not supported for this archive type"))))
1241
1242 (defun archive-chgrp-entry (new-gid)
1243   "Change the group of all marked or this member."
1244   (interactive "nNew gid: ")
1245   (if archive-read-only (error "Archive is read-only"))
1246   (let ((func (archive-name "chgrp-entry")))
1247     (if (fboundp func)
1248         (progn
1249           (funcall func new-gid (archive-get-marked ?* t))
1250           (archive-resummarize))
1251       (error "Setting group is not supported for this archive type"))))
1252
1253 (defun archive-expunge ()
1254   "Do the flagged deletions."
1255   (interactive)
1256   (let (files)
1257     (save-excursion
1258       (goto-char archive-file-list-start)
1259       (while (< (point) archive-file-list-end)
1260         (if (= (following-char) ?D)
1261             (setq files (cons (aref (archive-get-descr) 0) files)))
1262         (forward-line 1)))
1263     (setq files (nreverse files))
1264     (and files
1265          (or (not archive-read-only)
1266              (error "Archive is read-only"))
1267          (or (yes-or-no-p (format "Really delete %d member%s? "
1268                                   (length files)
1269                                   (if (null (cdr files)) "" "s")))
1270              (error "Operation aborted"))
1271          (let ((archive (archive-maybe-copy (buffer-file-name)))
1272                (expunger (archive-name "expunge")))
1273            (if (fboundp expunger)
1274                (funcall expunger archive files)
1275              (archive-*-expunge archive files (symbol-value expunger)))
1276            (archive-maybe-update nil)
1277            (if archive-remote
1278                (archive-resummarize)
1279              (revert-buffer))))))
1280
1281 (defun archive-*-expunge (archive files command)
1282   (apply 'call-process
1283          (car command)
1284          nil
1285          nil
1286          nil
1287          (append (cdr command) (cons archive files))))
1288
1289 (defun archive-rename-entry (newname)
1290   "Change the name associated with this entry in the tar file."
1291   (interactive "sNew name: ")
1292   (if archive-read-only (error "Archive is read-only"))
1293   (if (string= newname "")
1294       (error "Archive members may not be given empty names"))
1295   (let ((func (archive-name "rename-entry"))
1296         (descr (archive-get-descr)))
1297     (if (fboundp func)
1298         (progn
1299           (funcall func (buffer-file-name)
1300                    (if enable-multibyte-characters
1301                        (encode-coding-string newname file-name-coding-system)
1302                      newname)
1303                    descr)
1304           (archive-resummarize))
1305       (error "Renaming is not supported for this archive type"))))
1306
1307 ;; Revert the buffer and recompute the dired-like listing.
1308 (defun archive-mode-revert (&optional no-auto-save no-confirm)
1309   (let ((no (archive-get-lineno)))
1310     (setq archive-files nil)
1311     (let ((revert-buffer-function nil)
1312           (coding-system-for-read 'no-conversion))
1313       (set-buffer-multibyte nil)
1314       (revert-buffer t t))
1315     (archive-mode)
1316     (goto-char archive-file-list-start)
1317     (archive-next-line no)))
1318
1319 (defun archive-undo ()
1320   "Undo in an archive buffer.
1321 This doesn't recover lost files, it just undoes changes in the buffer itself."
1322   (interactive)
1323   (let (buffer-read-only)
1324     (undo)))
1325 ;; -------------------------------------------------------------------------
1326 ;; Section: Arc Archives
1327
1328 (defun archive-arc-summarize ()
1329   (let ((p 1)
1330         (totalsize 0)
1331         (maxlen 8)
1332         files
1333         visual)
1334     (while (and (< (+ p 29) (point-max))
1335                 (= (char-after p) ?\C-z)
1336                 (> (char-after (1+ p)) 0))
1337       (let* ((namefld (buffer-substring (+ p 2) (+ p 2 13)))
1338              (fnlen   (or (string-match "\0" namefld) 13))
1339              (efnname (substring namefld 0 fnlen))
1340              (csize   (archive-l-e (+ p 15) 4))
1341              (moddate (archive-l-e (+ p 19) 2))
1342              (modtime (archive-l-e (+ p 21) 2))
1343              (ucsize  (archive-l-e (+ p 25) 4))
1344              (fiddle  (string= efnname (upcase efnname)))
1345              (ifnname (if fiddle (downcase efnname) efnname))
1346              (text    (format "  %8d  %-11s  %-8s  %s"
1347                               ucsize
1348                               (archive-dosdate moddate)
1349                               (archive-dostime modtime)
1350                               ifnname)))
1351         (setq maxlen (max maxlen fnlen)
1352               totalsize (+ totalsize ucsize)
1353               visual (cons (vector text
1354                                    (- (length text) (length ifnname))
1355                                    (length text))
1356                            visual)
1357               files (cons (vector efnname ifnname fiddle nil (1- p))
1358                           files)
1359               p (+ p 29 csize))))
1360     (goto-char (point-min))
1361     (let ((dash (concat "- --------  -----------  --------  "
1362                         (make-string maxlen ?-)
1363                         "\n")))
1364       (insert "M   Length  Date         Time      File\n"
1365               dash)
1366       (archive-summarize-files (nreverse visual))
1367       (insert dash
1368               (format "  %8d                         %d file%s"
1369                       totalsize
1370                       (length files)
1371                       (if (= 1 (length files)) "" "s"))
1372               "\n"))
1373     (apply 'vector (nreverse files))))
1374
1375 (defun archive-arc-rename-entry (archive newname descr)
1376   (if (string-match "[:\\\\/]" newname)
1377       (error "File names in arc files may not contain a path"))
1378   (if (> (length newname) 12)
1379       (error "File names in arc files are limited to 12 characters"))
1380   (let ((name (concat newname (substring "\0\0\0\0\0\0\0\0\0\0\0\0\0"
1381                                          (length newname))))
1382         buffer-read-only)
1383     (save-restriction
1384       (save-excursion
1385         (widen)
1386         (set-buffer-multibyte nil)
1387         (goto-char (+ archive-proper-file-start (aref descr 4) 2))
1388         (delete-char 13)
1389         (insert name)))))
1390 ;; -------------------------------------------------------------------------
1391 ;; Section: Lzh Archives
1392
1393 (defun archive-lzh-summarize ()
1394   (let ((p 1)
1395         (totalsize 0)
1396         (maxlen 8)
1397         files
1398         visual)
1399     (while (progn (goto-char p)
1400                   (looking-at "\\(.\\|\n\\)\\(.\\|\n\\)-l[hz][0-9ds]-"))
1401       (let* ((hsize   (char-after p))
1402              (csize   (archive-l-e (+ p 7) 4))
1403              (ucsize  (archive-l-e (+ p 11) 4))
1404              (modtime (archive-l-e (+ p 15) 2))
1405              (moddate (archive-l-e (+ p 17) 2))
1406              (hdrlvl  (char-after (+ p 20)))
1407              (fnlen   (char-after (+ p 21)))
1408              (efnname (let ((str (buffer-substring (+ p 22) (+ p 22 fnlen))))
1409                         (if file-name-coding-system
1410                             (decode-coding-string str file-name-coding-system)
1411                           (string-as-multibyte str))))
1412              (fiddle  (string= efnname (upcase efnname)))
1413              (ifnname (if fiddle (downcase efnname) efnname))
1414              (width (string-width ifnname))
1415              (p2      (+ p 22 fnlen))
1416              (creator (if (>= (- hsize fnlen) 24) (char-after (+ p2 2)) 0))
1417              mode modestr uid gid text path prname
1418              )
1419         (if (= hdrlvl 0)
1420             (setq mode    (if (= creator ?U) (archive-l-e (+ p2 8) 2) ?\666)
1421                   uid     (if (= creator ?U) (archive-l-e (+ p2 10) 2))
1422                   gid     (if (= creator ?U) (archive-l-e (+ p2 12) 2)))
1423           (if (= creator ?U)
1424               (let* ((p3 (+ p2 3))
1425                      (hsize (archive-l-e p3 2))
1426                      (etype (char-after (+ p3 2))))
1427                 (while (not (= hsize 0))
1428                   (cond
1429                    ((= etype 2) (let ((i (+ p3 3)))
1430                                   (while (< i (+ p3 hsize))
1431                                     (setq path (concat path
1432                                                        (if (= (char-after i)
1433                                                               255)
1434                                                            "/"
1435                                                          (char-to-string
1436                                                           (char-after i)))))
1437                                     (setq i (1+ i)))))
1438                    ((= etype 80) (setq mode (archive-l-e (+ p3 3) 2)))
1439                    ((= etype 81) (progn (setq uid (archive-l-e (+ p3 3) 2))
1440                                         (setq gid (archive-l-e (+ p3 5) 2))))
1441                    )
1442                   (setq p3 (+ p3 hsize))
1443                   (setq hsize (archive-l-e p3 2))
1444                   (setq etype (char-after (+ p3 2)))))))
1445         (setq prname (if path (concat path ifnname) ifnname))
1446         (setq modestr (if mode (archive-int-to-mode mode) "??????????"))
1447         (setq text    (if archive-alternate-display
1448                           (format "  %8d  %5S  %5S  %s"
1449                                   ucsize
1450                                   (or uid "?")
1451                                   (or gid "?")
1452                                   ifnname)
1453                         (format "  %10s  %8d  %-11s  %-8s  %s"
1454                                 modestr
1455                                 ucsize
1456                                 (archive-dosdate moddate)
1457                                 (archive-dostime modtime)
1458                                 ifnname)))
1459         (setq maxlen (max maxlen width)
1460               totalsize (+ totalsize ucsize)
1461               visual (cons (vector text
1462                                    (- (length text) (length ifnname))
1463                                    (length text))
1464                            visual)
1465               files (cons (vector prname ifnname fiddle mode (1- p))
1466                           files)
1467               p (+ p hsize 2 csize))))
1468     (goto-char (point-min))
1469     (set-buffer-multibyte default-enable-multibyte-characters)
1470     (let ((dash (concat (if archive-alternate-display
1471                             "- --------  -----  -----  "
1472                           "- ----------  --------  -----------  --------  ")
1473                         (make-string maxlen ?-)
1474                         "\n"))
1475           (header (if archive-alternate-display
1476                        "M   Length    Uid    Gid  File\n"
1477                     "M   Filemode    Length  Date         Time      File\n"))
1478           (sumline (if archive-alternate-display
1479                        "  %8d                %d file%s"
1480                      "              %8d                         %d file%s")))
1481       (insert header dash)
1482       (archive-summarize-files (nreverse visual))
1483       (insert dash
1484               (format sumline
1485                       totalsize
1486                       (length files)
1487                       (if (= 1 (length files)) "" "s"))
1488               "\n"))
1489     (apply 'vector (nreverse files))))
1490
1491 (defconst archive-lzh-alternate-display t)
1492
1493 (defun archive-lzh-extract (archive name)
1494   (archive-extract-by-stdout archive name archive-lzh-extract))
1495
1496 (defun archive-lzh-resum (p count)
1497   (let ((sum 0))
1498     (while (> count 0)
1499       (setq count (1- count)
1500             sum (+ sum (char-after p))
1501             p (1+ p)))
1502     (logand sum 255)))
1503
1504 (defun archive-lzh-rename-entry (archive newname descr)
1505   (save-restriction
1506     (save-excursion
1507       (widen)
1508       (set-buffer-multibyte nil)
1509       (let* ((p        (+ archive-proper-file-start (aref descr 4)))
1510              (oldhsize (char-after p))
1511              (oldfnlen (char-after (+ p 21)))
1512              (newfnlen (length newname))
1513              (newhsize (+ oldhsize newfnlen (- oldfnlen)))
1514              buffer-read-only)
1515         (if (> newhsize 255)
1516             (error "The file name is too long"))
1517         (goto-char (+ p 21))
1518         (delete-char (1+ oldfnlen))
1519         (insert newfnlen newname)
1520         (goto-char p)
1521         (delete-char 2)
1522         (insert newhsize (archive-lzh-resum p newhsize))))))
1523
1524 (defun archive-lzh-ogm (newval files errtxt ofs)
1525   (save-restriction
1526     (save-excursion
1527       (widen)
1528       (set-buffer-multibyte nil)
1529       (while files
1530         (let* ((fil (car files))
1531                (p (+ archive-proper-file-start (aref fil 4)))
1532                (hsize   (char-after p))
1533                (fnlen   (char-after (+ p 21)))
1534                (p2      (+ p 22 fnlen))
1535                (creator (if (>= (- hsize fnlen) 24) (char-after (+ p2 2)) 0))
1536                buffer-read-only)
1537           (if (= creator ?U)
1538               (progn
1539                 (or (numberp newval)
1540                     (setq newval (funcall newval (archive-l-e (+ p2 ofs) 2))))
1541                 (goto-char (+ p2 ofs))
1542                 (delete-char 2)
1543                 (insert (logand newval 255) (lsh newval -8))
1544                 (goto-char (1+ p))
1545                 (delete-char 1)
1546                 (insert (archive-lzh-resum (1+ p) hsize)))
1547             (message "Member %s does not have %s field"
1548                      (aref fil 1) errtxt)))
1549         (setq files (cdr files))))))
1550
1551 (defun archive-lzh-chown-entry (newuid files)
1552   (archive-lzh-ogm newuid files "an uid" 10))
1553
1554 (defun archive-lzh-chgrp-entry (newgid files)
1555   (archive-lzh-ogm newgid files "a gid" 12))
1556
1557 (defun archive-lzh-chmod-entry (newmode files)
1558   (archive-lzh-ogm
1559    ;; This should work even though newmode will be dynamically accessed.
1560    (function (lambda (old) (archive-calc-mode old newmode t)))
1561    files "a unix-style mode" 8))
1562 ;; -------------------------------------------------------------------------
1563 ;; Section: Zip Archives
1564
1565 (defun archive-zip-summarize ()
1566   (goto-char (- (point-max) (- 22 18)))
1567   (search-backward-regexp "[P]K\005\006")
1568   (let ((p (1+ (archive-l-e (+ (point) 16) 4)))
1569         (maxlen 8)
1570         (totalsize 0)
1571         files
1572         visual)
1573     (while (string= "PK\001\002" (buffer-substring p (+ p 4)))
1574       (let* ((creator (char-after (+ p 5)))
1575              (method  (archive-l-e (+ p 10) 2))
1576              (modtime (archive-l-e (+ p 12) 2))
1577              (moddate (archive-l-e (+ p 14) 2))
1578              (ucsize  (archive-l-e (+ p 24) 4))
1579              (fnlen   (archive-l-e (+ p 28) 2))
1580              (exlen   (archive-l-e (+ p 30) 2))
1581              (fclen   (archive-l-e (+ p 32) 2))
1582              (lheader (archive-l-e (+ p 42) 4))
1583              (efnname (let ((str (buffer-substring (+ p 46) (+ p 46 fnlen))))
1584                         (if file-name-coding-system
1585                             (decode-coding-string str file-name-coding-system)
1586                           (string-as-multibyte str))))
1587              (isdir   (and (= ucsize 0)
1588                            (string= (file-name-nondirectory efnname) "")))
1589              (mode    (cond ((memq creator '(2 3)) ; Unix + VMS
1590                              (archive-l-e (+ p 40) 2))
1591                             ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1592                              (logior ?\444
1593                                      (if isdir (logior 16384 ?\111) 0)
1594                                      (if (zerop
1595                                           (logand 1 (char-after (+ p 38))))
1596                                          ?\222 0)))
1597                             (t nil)))
1598              (modestr (if mode (archive-int-to-mode mode) "??????????"))
1599              (fiddle  (and archive-zip-case-fiddle
1600                            (not (not (memq creator '(0 2 4 5 9))))
1601                            (string= (upcase efnname) efnname)))
1602              (ifnname (if fiddle (downcase efnname) efnname))
1603              (width (string-width ifnname))
1604              (text    (format "  %10s  %8d  %-11s  %-8s  %s"
1605                               modestr
1606                               ucsize
1607                               (archive-dosdate moddate)
1608                               (archive-dostime modtime)
1609                               ifnname)))
1610         (setq maxlen (max maxlen width)
1611               totalsize (+ totalsize ucsize)
1612               visual (cons (vector text
1613                                    (- (length text) (length ifnname))
1614                                    (length text))
1615                            visual)
1616               files (cons (if isdir
1617                               nil
1618                             (vector efnname ifnname fiddle mode
1619                                     (list (1- p) lheader)))
1620                           files)
1621               p (+ p 46 fnlen exlen fclen))))
1622     (goto-char (point-min))
1623     (let ((dash (concat "- ----------  --------  -----------  --------  "
1624                         (make-string maxlen ?-)
1625                         "\n")))
1626       (insert "M Filemode      Length  Date         Time      File\n"
1627               dash)
1628       (archive-summarize-files (nreverse visual))
1629       (insert dash
1630               (format "              %8d                         %d file%s"
1631                       totalsize
1632                       (length files)
1633                       (if (= 1 (length files)) "" "s"))
1634               "\n"))
1635     (apply 'vector (nreverse files))))
1636
1637 (defun archive-zip-extract (archive name)
1638   (if archive-zip-use-pkzip
1639       (archive-*-extract archive name archive-zip-extract)
1640     (archive-extract-by-stdout archive name archive-zip-extract)))
1641
1642 (defun archive-zip-write-file-member (archive descr)
1643   (archive-*-write-file-member
1644    archive
1645    descr
1646    (if (aref descr 2) archive-zip-update-case archive-zip-update)))
1647
1648 (defun archive-zip-chmod-entry (newmode files)
1649   (save-restriction
1650     (save-excursion
1651       (widen)
1652       (set-buffer-multibyte nil)
1653       (while files
1654         (let* ((fil (car files))
1655                (p (+ archive-proper-file-start (car (aref fil 4))))
1656                (creator (char-after (+ p 5)))
1657                (oldmode (aref fil 3))
1658                (newval  (archive-calc-mode oldmode newmode t))
1659                buffer-read-only)
1660           (cond ((memq creator '(2 3)) ; Unix + VMS
1661                  (goto-char (+ p 40))
1662                  (delete-char 2)
1663                  (insert (logand newval 255) (lsh newval -8)))
1664                 ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1665                  (goto-char (+ p 38))
1666                  (insert (logior (logand (char-after (point)) 254)
1667                                  (logand (logxor 1 (lsh newval -7)) 1)))
1668                  (delete-char 1))
1669                 (t (message "Don't know how to change mode for this member"))))
1670         (setq files (cdr files))))))
1671 ;; -------------------------------------------------------------------------
1672 ;; Section: Zoo Archives
1673
1674 (defun archive-zoo-summarize ()
1675   (let ((p (1+ (archive-l-e 25 4)))
1676         (maxlen 8)
1677         (totalsize 0)
1678         files
1679         visual)
1680     (while (and (string= "\334\247\304\375" (buffer-substring p (+ p 4)))
1681                 (> (archive-l-e (+ p 6) 4) 0))
1682       (let* ((next    (1+ (archive-l-e (+ p 6) 4)))
1683              (moddate (archive-l-e (+ p 14) 2))
1684              (modtime (archive-l-e (+ p 16) 2))
1685              (ucsize  (archive-l-e (+ p 20) 4))
1686              (namefld (buffer-substring (+ p 38) (+ p 38 13)))
1687              (dirtype (char-after (+ p 4)))
1688              (lfnlen  (if (= dirtype 2) (char-after (+ p 56)) 0))
1689              (ldirlen (if (= dirtype 2) (char-after (+ p 57)) 0))
1690              (fnlen   (or (string-match "\0" namefld) 13))
1691              (efnname (let ((str
1692                              (concat
1693                               (if (> ldirlen 0)
1694                                   (concat (buffer-substring
1695                                            (+ p 58 lfnlen)
1696                                            (+ p 58 lfnlen ldirlen -1))
1697                                           "/")
1698                                 "")
1699                               (if (> lfnlen 0)
1700                                   (buffer-substring (+ p 58)
1701                                                     (+ p 58 lfnlen -1))
1702                                 (substring namefld 0 fnlen)))))
1703                         (if file-name-coding-system
1704                             (decode-coding-string str file-name-coding-system)
1705                           (string-as-multibyte str))))
1706              (fiddle  (and (= lfnlen 0) (string= efnname (upcase efnname))))
1707              (ifnname (if fiddle (downcase efnname) efnname))
1708              (width (string-width ifnname))
1709              (text    (format "  %8d  %-11s  %-8s  %s"
1710                               ucsize
1711                               (archive-dosdate moddate)
1712                               (archive-dostime modtime)
1713                               ifnname)))
1714         (setq maxlen (max maxlen width)
1715               totalsize (+ totalsize ucsize)
1716               visual (cons (vector text
1717                                    (- (length text) (length ifnname))
1718                                    (length text))
1719                            visual)
1720               files (cons (vector efnname ifnname fiddle nil (1- p))
1721                           files)
1722               p next)))
1723     (goto-char (point-min))
1724     (let ((dash (concat "- --------  -----------  --------  "
1725                         (make-string maxlen ?-)
1726                         "\n")))
1727       (insert "M   Length  Date         Time      File\n"
1728               dash)
1729       (archive-summarize-files (nreverse visual))
1730       (insert dash
1731               (format "  %8d                         %d file%s"
1732                       totalsize
1733                       (length files)
1734                       (if (= 1 (length files)) "" "s"))
1735               "\n"))
1736     (apply 'vector (nreverse files))))
1737
1738 (defun archive-zoo-extract (archive name)
1739   (archive-extract-by-stdout archive name archive-zoo-extract))
1740 ;; -------------------------------------------------------------------------
1741 ;; This line was a mistake; it is kept now for compatibility.
1742 ;; rms  15 Oct 98
1743 (provide 'archive-mode)
1744
1745 (provide 'arc-mode)
1746
1747 ;;; arc-mode.el ends here