lisp/org/org-rmail.el

   1 ;;; org-rmail.el --- Support for links to Rmail messages from within Org-mode
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 6.16
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27
  28 ;; This file implements links to Rmail messages from within Org-mode.
  29 ;; Org-mode loads this module by default - if this is not what you want,
  30 ;; configure the variable `org-modules'.
  31
  32 ;;; Code:
  33
  34 (require 'org)
  35
  36 ;; Declare external functions and variables
  37 (declare-function rmail-narrow-to-non-pruned-header "rmail" ())
  38 (declare-function rmail-show-message "rmail" (&optional n no-summary))
  39 (declare-function rmail-what-message "rmail" ())
  40 (defvar rmail-current-message)
  41
  42 ;; Install the link type
  43 (org-add-link-type "rmail" 'org-rmail-open)
  44 (add-hook 'org-store-link-functions 'org-rmail-store-link)
  45
  46 ;; Implementation
  47 (defun org-rmail-store-link ()
  48   "Store a link to an Rmail folder or message."
  49   (when (or (eq major-mode 'rmail-mode)
  50             (eq major-mode 'rmail-summary-mode))
  51     (save-window-excursion
  52       (save-restriction
  53         (when (eq major-mode 'rmail-summary-mode)
  54           (rmail-show-message rmail-current-message))
  55         (rmail-narrow-to-non-pruned-header)
  56         (let* ((folder buffer-file-name)
  57                (message-id (mail-fetch-field "message-id"))
  58                (from (mail-fetch-field "from"))
  59                (to (mail-fetch-field "to"))
  60                (subject (mail-fetch-field "subject"))
  61                desc link)
  62           (org-store-link-props
  63            :type "rmail" :from from :to to
  64            :subject subject :message-id message-id)
  65           (setq message-id (org-remove-angle-brackets message-id))
  66           (setq desc (org-email-link-description))
  67           (setq link (org-make-link "rmail:" folder "#" message-id))
  68           (org-add-link-props :link link :description desc)
  69           (rmail-show-message rmail-current-message)
  70           link)))))
  71
  72 (defun org-rmail-open (path)
  73   "Follow an Rmail message link to the specified PATH."
  74   (let (folder article)
  75     (if (not (string-match "\\`\\([^#]+\\)\\(#\\(.*\\)\\)?" path))
  76         (error "Error in Rmail link"))
  77     (setq folder (match-string 1 path)
  78           article (match-string 3 path))
  79     (org-rmail-follow-link folder article)))
  80
  81 (defun org-rmail-follow-link (folder article)
  82   "Follow an Rmail link to FOLDER and ARTICLE."
  83   (require 'rmail)
  84   (setq article (org-add-angle-brackets article))
  85   (let (message-number)
  86     (save-excursion
  87       (save-window-excursion
  88         (rmail (if (string= folder "RMAIL") rmail-file-name folder))
  89         (setq message-number
  90               (save-restriction
  91                 (widen)
  92                 (goto-char (point-max))
  93                 (if (re-search-backward
  94                      (concat "^Message-ID:\\s-+" (regexp-quote
  95                                                   (or article "")))
  96                      nil t)
  97                     (rmail-what-message))))))
  98     (if message-number
  99         (progn
 100           (rmail (if (string= folder "RMAIL") rmail-file-name folder))
 101           (rmail-show-message message-number)
 102           message-number)
 103       (error "Message not found"))))
 104
 105 (provide 'org-rmail)
 106
 107 ;; arch-tag: c6cf4a8b-6639-4b7f-821f-bdf10746b173
 108
 109 ;;; org-rmail.el ends here