lisp/saveplace.el

   1 ;;; saveplace.el --- automatically save place in files
   2
   3 ;; Copyright (C) 1993-1994, 2001-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Karl Fogel <kfogel@red-bean.com>
   6 ;; Maintainer: FSF
   7 ;; Created: July, 1993
   8 ;; Keywords: bookmarks, placeholders
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Automatically save place in files, so that visiting them later
  28 ;; (even during a different Emacs session) automatically moves point
  29 ;; to the saved position, when the file is first found.  Uses the
  30 ;; value of buffer-local variable save-place to determine whether to
  31 ;; save position or not.
  32 ;;
  33 ;; Thanks to Stefan Schoef, who sent a patch with the
  34 ;; `save-place-version-control' stuff in it.
  35
  36 ;;; Code:
  37
  38 ;; this is what I was using during testing:
  39 ;; (define-key ctl-x-map "p" 'toggle-save-place-globally)
  40
  41 (defgroup save-place nil
  42   "Automatically save place in files."
  43   :group 'data)
  44
  45
  46 (defvar save-place-alist nil
  47   "Alist of saved places to go back to when revisiting files.
  48 Each element looks like (FILENAME . POSITION);
  49 visiting file FILENAME goes automatically to position POSITION
  50 rather than the beginning of the buffer.
  51 This alist is saved between Emacs sessions.")
  52
  53 (defcustom save-place nil
  54   "Non-nil means automatically save place in each file.
  55 This means when you visit a file, point goes to the last place
  56 where it was when you previously visited the same file.
  57 This variable is automatically buffer-local.
  58
  59 If you wish your place in any file to always be automatically
  60 saved, set this to t using the Customize facility, or put the
  61 following code in your init file:
  62
  63 \(setq-default save-place t)
  64 \(require 'saveplace)"
  65   :type 'boolean
  66   :require 'saveplace
  67   :group 'save-place)
  68
  69 (make-variable-buffer-local 'save-place)
  70
  71 (defcustom save-place-file (locate-user-emacs-file "places" ".emacs-places")
  72   "Name of the file that records `save-place-alist' value."
  73   :type 'file
  74   :group 'save-place)
  75
  76 (defcustom save-place-version-control nil
  77   "Controls whether to make numbered backups of master save-place file.
  78 It can have four values: t, nil, `never', and `nospecial'.  The first
  79 three have the same meaning that they do for the variable
  80 `version-control', and the final value `nospecial' means just use the
  81 value of `version-control'."
  82   :type '(radio (const :tag "Unconditionally" t)
  83                 (const :tag "For VC Files" nil)
  84                 (const never)
  85                 (const :tag "Use value of `version-control'" nospecial))
  86   :group 'save-place)
  87
  88 (defvar save-place-loaded nil
  89   "Non-nil means that the `save-place-file' has been loaded.")
  90
  91 (defcustom save-place-limit 400
  92   "Maximum number of entries to retain in the list; nil means no limit."
  93   :version "24.1"                       ; nil -> 400
  94   :type '(choice (integer :tag "Entries" :value 1)
  95                  (const :tag "No Limit" nil))
  96   :group 'save-place)
  97
  98 (defcustom save-place-forget-unreadable-files t
  99   "Non-nil means forget place in unreadable files.
 100
 101 The filenames in `save-place-alist' that do not match
 102 `save-place-skip-check-regexp' are filtered through
 103 `file-readable-p'. if nil, their alist entries are removed.
 104
 105 You may do this anytime by calling the complementary function,
 106 `save-place-forget-unreadable-files'.  When this option is turned on,
 107 this happens automatically before saving `save-place-alist' to
 108 `save-place-file'."
 109   :type 'boolean :group 'save-place)
 110
 111 (defcustom save-place-save-skipped t
 112   "If non-nil, remember files matching `save-place-skip-check-regexp'.
 113
 114 When filtering `save-place-alist' for unreadable files, some will not
 115 be checked, based on said regexp, and instead saved or forgotten based
 116 on this flag."
 117   :type 'boolean :group 'save-place)
 118
 119 (defcustom save-place-skip-check-regexp
 120   ;; thanks to ange-ftp-name-format
 121   "\\`/\\(?:cdrom\\|floppy\\|mnt\\|\\(?:[^@/:]*@\\)?[^@/:]*[^@/:.]:\\)"
 122   "Regexp whose file names shall not be checked for readability.
 123
 124 When forgetting unreadable files, file names matching this regular
 125 expression shall not be checked for readability, but instead be
 126 subject to `save-place-save-skipped'.
 127
 128 Files for which such a check may be inconvenient include those on
 129 removable and network volumes."
 130   :type 'regexp :group 'save-place)
 131
 132 (defcustom save-place-ignore-files-regexp
 133   "\\(?:COMMIT_EDITMSG\\|hg-editor-[[:alnum:]]+\\.txt\\|svn-commit\\.tmp\\|bzr_log\\.[[:alnum:]]+\\)$"
 134   "Regexp matching files for which no position should be recorded.
 135 Useful for temporary file such as commit message files that are
 136 automatically created by the VCS.  If set to nil, this feature is
 137 disabled, i.e., the position is recorded for all files."
 138   :version "24.1"
 139   :type 'regexp :group 'save-place)
 140
 141 (defun toggle-save-place (&optional parg)
 142   "Toggle whether to save your place in this file between sessions.
 143 If this mode is enabled, point is recorded when you kill the buffer
 144 or exit Emacs.  Visiting this file again will go to that position,
 145 even in a later Emacs session.
 146
 147 If called with a prefix arg, the mode is enabled if and only if
 148 the argument is positive.
 149
 150 To save places automatically in all files, put this in your init
 151 file:
 152
 153 \(setq-default save-place t\)"
 154   (interactive "P")
 155   (if (not buffer-file-name)
 156       (message "Buffer `%s' not visiting a file" (buffer-name))
 157     (if (and save-place (or (not parg) (<= parg 0)))
 158         (progn
 159           (message "No place will be saved in this file")
 160           (setq save-place nil))
 161       (message "Place will be saved")
 162       (setq save-place t))))
 163
 164 (defun save-place-to-alist ()
 165   ;; put filename and point in a cons box and then cons that onto the
 166   ;; front of the save-place-alist, if save-place is non-nil.
 167   ;; Otherwise, just delete that file from the alist.
 168   ;; first check to make sure alist has been loaded in from the master
 169   ;; file.  If not, do so, then feel free to modify the alist.  It
 170   ;; will be saved again when Emacs is killed.
 171   (or save-place-loaded (load-save-place-alist-from-file))
 172   (let ((item (or buffer-file-name
 173                   (and dired-directory (expand-file-name dired-directory)))))
 174     (when (and item
 175                (or (not save-place-ignore-files-regexp)
 176                    (not (string-match save-place-ignore-files-regexp
 177                                       item))))
 178       (let ((cell (assoc item save-place-alist))
 179             (position (if (not (eq major-mode 'hexl-mode))
 180                           (point)
 181                         (with-no-warnings
 182                           (1+ (hexl-current-address))))))
 183         (if cell
 184             (setq save-place-alist (delq cell save-place-alist)))
 185         (if (and save-place
 186                  (not (= position 1)))  ;; Optimize out the degenerate case.
 187             (setq save-place-alist
 188                   (cons (cons item position)
 189                         save-place-alist)))))))
 190
 191 (defun save-place-forget-unreadable-files ()
 192   "Remove unreadable files from `save-place-alist'.
 193 For each entry in the alist, if `file-readable-p' returns nil for the
 194 filename, remove the entry.  Save the new alist \(as the first pair
 195 may have changed\) back to `save-place-alist'."
 196   (interactive)
 197   ;; the following was adapted from an in-place filtering function,
 198   ;; `filter-mod', used in the original.
 199   (unless (null save-place-alist)       ;says it better than `when'
 200     ;; first, check all except first
 201     (let ((fmprev save-place-alist) (fmcur (cdr save-place-alist)))
 202       (while fmcur                      ;not null
 203         ;; a value is only saved when it becomes FMPREV.
 204         (if (if (string-match save-place-skip-check-regexp (caar fmcur))
 205                 save-place-save-skipped
 206               (file-readable-p (caar fmcur)))
 207             (setq fmprev fmcur)
 208           (setcdr fmprev (cdr fmcur)))
 209         (setq fmcur (cdr fmcur))))
 210     ;; test first pair, keep it if OK, otherwise 2nd element, which
 211     ;; may be '()
 212     (unless (if (string-match save-place-skip-check-regexp
 213                               (caar save-place-alist))
 214                 save-place-save-skipped
 215               (file-readable-p (caar save-place-alist)))
 216       (setq save-place-alist (cdr save-place-alist)))))
 217
 218 (defun save-place-alist-to-file ()
 219   (let ((file (expand-file-name save-place-file))
 220         (coding-system-for-write 'utf-8))
 221     (with-current-buffer (get-buffer-create " *Saved Places*")
 222       (delete-region (point-min) (point-max))
 223       (when save-place-forget-unreadable-files
 224         (save-place-forget-unreadable-files))
 225       (insert (format ";;; -*- coding: %s -*-\n"
 226                       (symbol-name coding-system-for-write)))
 227       (let ((print-length nil)
 228             (print-level nil))
 229         (pp save-place-alist (current-buffer)))
 230       (let ((version-control
 231              (cond
 232               ((null save-place-version-control) nil)
 233               ((eq 'never save-place-version-control) 'never)
 234               ((eq 'nospecial save-place-version-control) version-control)
 235               (t
 236                t))))
 237         (condition-case nil
 238             ;; Don't use write-file; we don't want this buffer to visit it.
 239             (write-region (point-min) (point-max) file)
 240           (file-error (message "Saving places: can't write %s" file)))
 241         (kill-buffer (current-buffer))))))
 242
 243 (defun load-save-place-alist-from-file ()
 244   (if (not save-place-loaded)
 245       (progn
 246         (setq save-place-loaded t)
 247         (let ((file (expand-file-name save-place-file)))
 248           ;; make sure that the alist does not get overwritten, and then
 249           ;; load it if it exists:
 250           (if (file-readable-p file)
 251               ;; don't want to use find-file because we have been
 252               ;; adding hooks to it.
 253               (with-current-buffer (get-buffer-create " *Saved Places*")
 254                 (delete-region (point-min) (point-max))
 255                 (insert-file-contents file)
 256                 (goto-char (point-min))
 257                 (setq save-place-alist
 258                       ;; This is with-demoted-errors, but we want to
 259                       ;; mention save-place in any error message.
 260                       (condition-case err
 261                         (car (read-from-string
 262                               (buffer-substring (point-min) (point-max))))
 263                         (error (message "Error reading save-place-file: %S" err)
 264                                nil)))
 265
 266                 ;; If there is a limit, and we're over it, then we'll
 267                 ;; have to truncate the end of the list:
 268                 (if save-place-limit
 269                     (if (<= save-place-limit 0)
 270                         ;; Zero gets special cased.  I'm not thrilled
 271                         ;; with this, but the loop for >= 1 is tight.
 272                         (setq save-place-alist nil)
 273                       ;; Else the limit is >= 1, so enforce it by
 274                       ;; counting and then `setcdr'ing.
 275                       (let ((s save-place-alist)
 276                             (count 1))
 277                         (while s
 278                           (if (>= count save-place-limit)
 279                               (setcdr s nil)
 280                             (setq count (1+ count)))
 281                           (setq s (cdr s))))))
 282
 283                 (kill-buffer (current-buffer))))
 284           nil))))
 285
 286 (defun save-places-to-alist ()
 287   ;; go through buffer-list, saving places to alist if save-place is
 288   ;; non-nil, deleting them from alist if it is nil.
 289   (let ((buf-list (buffer-list)))
 290     (while buf-list
 291       ;; put this into a save-excursion in case someone is counting on
 292       ;; another function in kill-emacs-hook to act on the last buffer
 293       ;; they were in:
 294       (with-current-buffer (car buf-list)
 295         ;; save-place checks buffer-file-name too, but we can avoid
 296         ;; overhead of function call by checking here too.
 297         (and buffer-file-name (save-place-to-alist))
 298         (setq buf-list (cdr buf-list))))))
 299
 300 (defun save-place-find-file-hook ()
 301   (or save-place-loaded (load-save-place-alist-from-file))
 302   (let ((cell (assoc buffer-file-name save-place-alist)))
 303     (if cell
 304         (progn
 305           (or revert-buffer-in-progress-p
 306               (goto-char (cdr cell)))
 307           ;; and make sure it will be saved again for later
 308           (setq save-place t)))))
 309
 310 (defun save-place-dired-hook ()
 311   "Position the point in a dired buffer."
 312   (or save-place-loaded (load-save-place-alist-from-file))
 313   (let ((cell (assoc (expand-file-name dired-directory) save-place-alist)))
 314     (if cell
 315         (progn
 316           (or revert-buffer-in-progress-p
 317               (goto-char (cdr cell)))
 318           ;; and make sure it will be saved again for later
 319           (setq save-place t)))))
 320
 321 (defun save-place-kill-emacs-hook ()
 322   ;; First update the alist.  This loads the old save-place-file if nec.
 323   (save-places-to-alist)
 324   ;; Now save the alist in the file, if we have ever loaded the file
 325   ;; (including just now).
 326   (if save-place-loaded
 327       (save-place-alist-to-file)))
 328
 329 (add-hook 'find-file-hook 'save-place-find-file-hook t)
 330
 331 (add-hook 'dired-initial-point-hook 'save-place-dired-hook)
 332 (unless noninteractive
 333   (add-hook 'kill-emacs-hook 'save-place-kill-emacs-hook))
 334
 335 (add-hook 'kill-buffer-hook 'save-place-to-alist)
 336
 337 (provide 'saveplace) ; why not...
 338
 339 ;;; saveplace.el ends here