lisp/mail/mail-utils.el

   1 ;;; mail-utils.el --- utility functions used both by rmail and rnews
   2
   3 ;; Copyright (C) 1985, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
   4 ;;   2009, 2010  Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: mail, news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Utility functions for mail and netnews handling.  These handle fine
  27 ;; points of header parsing.
  28
  29 ;;; Code:
  30
  31 ;;; We require lisp-mode to make sure that lisp-mode-syntax-table has
  32 ;;; been initialized.
  33 (require 'lisp-mode)
  34
  35 ;;;###autoload
  36 (defcustom mail-use-rfc822 nil
  37   "If non-nil, use a full, hairy RFC822 parser on mail addresses.
  38 Otherwise, (the default) use a smaller, somewhat faster, and
  39 often correct parser."
  40   :type 'boolean
  41   :group 'mail)
  42
  43 ;; Returns t if file FILE is an Rmail file.
  44 ;;;###autoload
  45 (defun mail-file-babyl-p (file)
  46   "Return non-nil if FILE is a Babyl file."
  47   (with-temp-buffer
  48     (insert-file-contents file nil 0 100)
  49     (looking-at "BABYL OPTIONS:")))
  50
  51 (defun mail-string-delete (string start end)
  52   "Returns a string containing all of STRING except the part
  53 from START (inclusive) to END (exclusive)."
  54   (if (null end) (substring string 0 start)
  55     (concat (substring string 0 start)
  56             (substring string end nil))))
  57
  58 ;;;###autoload
  59 (defun mail-quote-printable (string &optional wrapper)
  60   "Convert a string to the \"quoted printable\" Q encoding.
  61 If the optional argument WRAPPER is non-nil,
  62 we add the wrapper characters =?ISO-8859-1?Q?....?=."
  63   (let ((i 0) (result ""))
  64     (save-match-data
  65       (while (string-match "[?=\"\200-\377]" string i)
  66         (setq result
  67               (concat result (substring string i (match-beginning 0))
  68                       (upcase (format "=%02x"
  69                                       (aref string (match-beginning 0))))))
  70         (setq i (match-end 0)))
  71       (if wrapper
  72           (concat "=?ISO-8859-1?Q?"
  73                   result (substring string i)
  74                   "?=")
  75         (concat result (substring string i))))))
  76
  77 ;;;###autoload
  78 (defun mail-quote-printable-region (beg end &optional wrapper)
  79   "Convert the region to the \"quoted printable\" Q encoding.
  80 If the optional argument WRAPPER is non-nil,
  81 we add the wrapper characters =?ISO-8859-1?Q?....?=."
  82   (interactive "r\nP")
  83   (save-match-data
  84     (save-excursion
  85       (goto-char beg)
  86       (save-restriction
  87         (narrow-to-region beg end)
  88         (while (re-search-forward "[?=\"\200-\377]" nil t)
  89           (replace-match (upcase (format "=%02x" (preceding-char)))
  90                          t t))
  91         (when wrapper
  92           (goto-char beg)
  93           (insert "=?ISO-8859-1?Q?")
  94           (goto-char end)
  95           (insert "?="))))))
  96
  97 (defun mail-unquote-printable-hexdigit (char)
  98   (setq char (upcase char))
  99   (if (>= char ?A)
 100       (+ (- char ?A) 10)
 101     (- char ?0)))
 102
 103 ;;;###autoload
 104 (defun mail-unquote-printable (string &optional wrapper)
 105   "Undo the \"quoted printable\" encoding.
 106 If the optional argument WRAPPER is non-nil,
 107 we expect to find and remove the wrapper characters =?ISO-8859-1?Q?....?=."
 108   (save-match-data
 109     (and wrapper
 110          (string-match "\\`=\\?ISO-8859-1\\?Q\\?\\([^?]*\\)\\?" string)
 111          (setq string (match-string 1 string)))
 112     (let ((i 0) strings)
 113       (while (string-match "=\\(..\\|\n\\)" string i)
 114         (setq strings (cons (substring string i (match-beginning 0)) strings))
 115         (unless (= (aref string (match-beginning 1)) ?\n)
 116           (setq strings
 117                 (cons (make-string 1
 118                                    (+ (* 16 (mail-unquote-printable-hexdigit
 119                                              (aref string (match-beginning 1))))
 120                                       (mail-unquote-printable-hexdigit
 121                                        (aref string (1+ (match-beginning 1))))))
 122                       strings)))
 123         (setq i (match-end 0)))
 124       (apply 'concat (nreverse (cons (substring string i) strings))))))
 125
 126 ;;;###autoload
 127 (defun mail-unquote-printable-region (beg end &optional wrapper noerror
 128                                           unibyte)
 129   "Undo the \"quoted printable\" encoding in buffer from BEG to END.
 130 If the optional argument WRAPPER is non-nil,
 131 we expect to find and remove the wrapper characters =?ISO-8859-1?Q?....?=.
 132 If NOERROR is non-nil, return t if successful.
 133 If UNIBYTE is non-nil, insert converted characters as unibyte.
 134 That is useful if you are going to character code decoding afterward,
 135 as Rmail does."
 136   ;; FIXME: `unibyte' should always be non-nil, and the iso-latin-1
 137   ;; specific handling should be removed (or moved elsewhere and generalized).
 138   (interactive "r\nP")
 139   (let (failed)
 140     (save-match-data
 141       (save-excursion
 142         (save-restriction
 143           (narrow-to-region beg end)
 144           (goto-char (point-min))
 145           (when (and wrapper
 146                      (looking-at "\\`=\\?ISO-8859-1\\?Q\\?\\([^?]*\\)\\?"))
 147             (delete-region (match-end 1) end)
 148             (delete-region (point) (match-beginning 1)))
 149           (while (re-search-forward "=\\(\\([0-9A-F][0-9A-F]\\)\\|[=\n]\\|..\\)" nil t)
 150             (goto-char (match-end 0))
 151             (cond ((= (char-after (match-beginning 1)) ?\n)
 152                    (replace-match ""))
 153                   ((= (char-after (match-beginning 1)) ?=)
 154                    (replace-match "="))
 155                   ((match-beginning 2)
 156                    (let ((char (+ (* 16 (mail-unquote-printable-hexdigit
 157                                          (char-after (match-beginning 2))))
 158                                   (mail-unquote-printable-hexdigit
 159                                    (char-after (1+ (match-beginning 2)))))))
 160                      (if unibyte
 161                          (progn
 162                            (replace-match "")
 163                            ;; insert-byte will insert this as a
 164                            ;; corresponding eight-bit character.
 165                            (insert-byte char 1))
 166                        (replace-match (make-string 1 char) t t))))
 167                   (noerror
 168                    (setq failed t))
 169                   (t
 170                    (error "Malformed MIME quoted-printable message"))))
 171           (not failed))))))
 172
 173 (eval-when-compile (require 'rfc822))
 174
 175 (defun mail-strip-quoted-names (address)
 176   "Delete comments and quoted strings in an address list ADDRESS.
 177 Also delete leading/trailing whitespace and replace FOO <BAR> with just BAR.
 178 Return a modified address list."
 179   (if (null address)
 180       nil
 181     (if mail-use-rfc822
 182         (progn (require 'rfc822)
 183                (mapconcat 'identity (rfc822-addresses address) ", "))
 184       (let (pos)
 185
 186        ;; Detect nested comments.
 187        (if (string-match "[ \t]*(\\([^)\\]\\|\\\\.\\|\\\\\n\\)*(" address)
 188            ;; Strip nested comments.
 189            (with-current-buffer (get-buffer-create " *temp*")
 190              (erase-buffer)
 191              (insert address)
 192              (set-syntax-table lisp-mode-syntax-table)
 193              (goto-char 1)
 194              (while (search-forward "(" nil t)
 195                (forward-char -1)
 196                (skip-chars-backward " \t")
 197                (delete-region (point)
 198                               (save-excursion
 199                                 (condition-case ()
 200                                     (forward-sexp 1)
 201                                   (error (goto-char (point-max))))
 202                                   (point))))
 203              (setq address (buffer-string))
 204              (erase-buffer))
 205          ;; Strip non-nested comments an easier way.
 206          (while (setq pos (string-match
 207                             ;; This doesn't hack rfc822 nested comments
 208                             ;;  `(xyzzy (foo) whinge)' properly.  Big deal.
 209                             "[ \t]*(\\([^)\\]\\|\\\\.\\|\\\\\n\\)*)"
 210                             address))
 211            (setq address (replace-match "" nil nil address 0))))
 212
 213        ;; strip surrounding whitespace
 214        (string-match "\\`[ \t\n]*" address)
 215        (setq address (substring address
 216                                 (match-end 0)
 217                                 (string-match "[ \t\n]*\\'" address
 218                                               (match-end 0))))
 219
 220        ;; strip `quoted' names (This is supposed to hack `"Foo Bar" <bar@host>')
 221        (setq pos 0)
 222        (while (setq pos (string-match
 223                           "\\([ \t]?\\)\\([ \t]*\"\\([^\"\\]\\|\\\\.\\|\\\\\n\\)*\"[ \t\n]*\\)"
 224                           address pos))
 225          ;; If the next thing is "@", we have "foo bar"@host.  Leave it.
 226          (if (and (> (length address) (match-end 0))
 227                   (= (aref address (match-end 0)) ?@))
 228              (setq pos (match-end 0))
 229            ;; Otherwise discard the "..." part.
 230            (setq address (replace-match "" nil nil address 2))))
 231        ;; If this address contains <...>, replace it with just
 232        ;; the part between the <...>.
 233        (while (setq pos (string-match "\\(,\\s-*\\|\\`\\)\\([^,]*<\\([^>,:]*\\)>[^,]*\\)\\(\\s-*,\\|\\'\\)"
 234                                       address))
 235          (setq address (replace-match (match-string 3 address)
 236                                       nil 'literal address 2)))
 237        address))))
 238
 239 ;;; The following piece of ugliness is legacy code.  The name was an
 240 ;;; unfortunate choice --- a flagrant violation of the Emacs Lisp
 241 ;;; coding conventions.  `mail-dont-reply-to' would have been
 242 ;;; infinitely better.  Also, `rmail-dont-reply-to-names' might have
 243 ;;; been better named `mail-dont-reply-to-names' and sourced from this
 244 ;;; file instead of in rmail.el.  Yuck.  -pmr
 245 (defun rmail-dont-reply-to (destinations)
 246   "Prune addresses from DESTINATIONS, a list of recipient addresses.
 247 All addresses matching `rmail-dont-reply-to-names' are removed from
 248 the comma-separated list.  The pruned list is returned."
 249   (if (null rmail-dont-reply-to-names)
 250       (setq rmail-dont-reply-to-names
 251             (concat (if rmail-default-dont-reply-to-names
 252                         (concat rmail-default-dont-reply-to-names "\\|")
 253                       "")
 254                     (if (and user-mail-address
 255                              (not (equal user-mail-address user-login-name)))
 256                         ;; Anchor the login name and email address so
 257                         ;; that we don't match substrings: if the
 258                         ;; login name is "foo", we shouldn't match
 259                         ;; "barfoo@baz.com".
 260                         (concat "\\`"
 261                                 (regexp-quote user-mail-address)
 262                                 "\\'\\|")
 263                       "")
 264                     (concat "\\`" (regexp-quote user-login-name) "@"))))
 265   ;; Split up DESTINATIONS and match each element separately.
 266   (let ((start-pos 0) (cur-pos 0)
 267         (case-fold-search t))
 268     (while start-pos
 269       (setq cur-pos (string-match "[,\"]" destinations cur-pos))
 270       (if (and cur-pos (equal (match-string 0 destinations) "\""))
 271           ;; Search for matching quote.
 272           (let ((next-pos (string-match "\"" destinations (1+ cur-pos))))
 273             (if next-pos
 274                 (setq cur-pos (1+ next-pos))
 275               ;; If the open-quote has no close-quote,
 276               ;; delete the open-quote to get something well-defined.
 277               ;; This case is not valid, but it can happen if things
 278               ;; are weird elsewhere.
 279               (setq destinations (concat (substring destinations 0 cur-pos)
 280                                     (substring destinations (1+ cur-pos))))
 281               (setq cur-pos start-pos)))
 282         (let* ((address (substring destinations start-pos cur-pos))
 283                (naked-address (mail-strip-quoted-names address)))
 284           (if (string-match rmail-dont-reply-to-names naked-address)
 285               (setq destinations (concat (substring destinations 0 start-pos)
 286                                     (and cur-pos (substring destinations
 287                                                             (1+ cur-pos))))
 288                     cur-pos start-pos)
 289             (setq cur-pos (and cur-pos (1+ cur-pos))
 290                   start-pos cur-pos))))))
 291   ;; get rid of any trailing commas
 292   (let ((pos (string-match "[ ,\t\n]*\\'" destinations)))
 293     (if pos
 294         (setq destinations (substring destinations 0 pos))))
 295   ;; remove leading spaces. they bother me.
 296   (if (string-match "\\(\\s \\|,\\)*" destinations)
 297       (substring destinations (match-end 0))
 298     destinations))
 299
 300 \f
 301 ;;;###autoload
 302 (defun mail-fetch-field (field-name &optional last all list)
 303   "Return the value of the header field whose type is FIELD-NAME.
 304 If second arg LAST is non-nil, use the last field of type FIELD-NAME.
 305 If third arg ALL is non-nil, concatenate all such fields with commas between.
 306 If 4th arg LIST is non-nil, return a list of all such fields.
 307 The buffer should be narrowed to just the header, else false
 308 matches may be returned from the message body."
 309   (save-excursion
 310     (goto-char (point-min))
 311     (let ((case-fold-search t)
 312           (name (concat "^" (regexp-quote field-name) "[ \t]*:[ \t]*")))
 313       (if (or all list)
 314           (let ((value (if all "")))
 315             (while (re-search-forward name nil t)
 316               (let ((opoint (point)))
 317                 (while (progn (forward-line 1)
 318                               (looking-at "[ \t]")))
 319                 ;; Back up over newline, then trailing spaces or tabs
 320                 (forward-char -1)
 321                 (skip-chars-backward " \t" opoint)
 322                 (if list
 323                     (setq value (cons (buffer-substring-no-properties
 324                                        opoint (point))
 325                                       value))
 326                   (setq value (concat value
 327                                       (if (string= value "") "" ", ")
 328                                       (buffer-substring-no-properties
 329                                        opoint (point)))))))
 330             (if list
 331                 value
 332               (and (not (string= value "")) value)))
 333         (if (re-search-forward name nil t)
 334             (progn
 335               (if last (while (re-search-forward name nil t)))
 336               (let ((opoint (point)))
 337                 (while (progn (forward-line 1)
 338                               (looking-at "[ \t]")))
 339                 ;; Back up over newline, then trailing spaces or tabs
 340                 (forward-char -1)
 341                 (skip-chars-backward " \t" opoint)
 342                 (buffer-substring-no-properties opoint (point)))))))))
 343 \f
 344 ;; Parse a list of tokens separated by commas.
 345 ;; It runs from point to the end of the visible part of the buffer.
 346 ;; Whitespace before or after tokens is ignored,
 347 ;; but whitespace within tokens is kept.
 348 (defun mail-parse-comma-list ()
 349   (let (accumulated
 350         beg)
 351     (skip-chars-forward " \t\n")
 352     (while (not (eobp))
 353       (setq beg (point))
 354       (skip-chars-forward "^,")
 355       (skip-chars-backward " \t\n")
 356       (setq accumulated
 357             (cons (buffer-substring-no-properties beg (point))
 358                   accumulated))
 359       (skip-chars-forward "^,")
 360       (skip-chars-forward ", \t\n"))
 361     accumulated))
 362
 363 (defun mail-comma-list-regexp (labels)
 364   (let (pos)
 365     (setq pos (or (string-match "[^ \t]" labels) 0))
 366     ;; Remove leading and trailing whitespace.
 367     (setq labels (substring labels pos (string-match "[ \t]*$" labels pos)))
 368     ;; Change each comma to \|, and flush surrounding whitespace.
 369     (while (setq pos (string-match "[ \t]*,[ \t]*" labels))
 370       (setq labels
 371             (concat (substring labels 0 pos)
 372                     "\\|"
 373                     (substring labels (match-end 0))))))
 374   labels)
 375 \f
 376 (defun mail-rfc822-time-zone (time)
 377   (let* ((sec (or (car (current-time-zone time)) 0))
 378          (absmin (/ (abs sec) 60)))
 379     (format "%c%02d%02d" (if (< sec 0) ?- ?+) (/ absmin 60) (% absmin 60))))
 380
 381 (defun mail-rfc822-date ()
 382   (let* ((time (current-time))
 383          (s (current-time-string time)))
 384     (string-match "[^ ]+ +\\([^ ]+\\) +\\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)" s)
 385     (concat (substring s (match-beginning 2) (match-end 2)) " "
 386             (substring s (match-beginning 1) (match-end 1)) " "
 387             (substring s (match-beginning 4) (match-end 4)) " "
 388             (substring s (match-beginning 3) (match-end 3)) " "
 389             (mail-rfc822-time-zone time))))
 390
 391 (defun mail-mbox-from ()
 392   "Return an mbox \"From \" line for the current message.
 393 The buffer should be narrowed to just the header."
 394   (let ((from (or (mail-fetch-field "from")
 395                   (mail-fetch-field "really-from")
 396                   (mail-fetch-field "sender")
 397                   "unknown"))
 398         (date (mail-fetch-field "date")))
 399     (format "From %s %s\n" (mail-strip-quoted-names from)
 400             (or (and date
 401                      (ignore-errors
 402                       (current-time-string (date-to-time date))))
 403                 (current-time-string)))))
 404
 405 (provide 'mail-utils)
 406
 407 ;; arch-tag: b24aec2f-fd65-4ceb-9e39-3cc2827036fd
 408 ;;; mail-utils.el ends here