lisp/gnus/gnus-notifications.el

   1 ;; gnus-notifications.el -- Send notification on new message in Gnus
   2
   3 ;; Copyright (C) 2012-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Julien Danjou <julien@danjou.info>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This implements notifications using `notifications-notify' on new
  26 ;; messages received.
  27 ;; Use (add-hook 'gnus-after-getting-new-news-hook 'gnus-notifications)
  28 ;; to get notifications just after getting the new news.
  29
  30 ;;; Code:
  31
  32 (ignore-errors
  33   (require 'notifications))
  34 (require 'gnus-sum)
  35 (require 'gnus-group)
  36 (require 'gnus-int)
  37 (require 'gnus-art)
  38 (require 'gnus-util)
  39 (ignore-errors
  40   (require 'google-contacts))        ; Optional
  41 (require 'gnus-fun)
  42
  43 (defgroup gnus-notifications nil
  44   "Send notifications on new message in Gnus."
  45   :version "24.3"
  46   :group 'gnus)
  47
  48 (defcustom gnus-notifications-use-google-contacts t
  49   "Use Google Contacts to retrieve photo."
  50   :type 'boolean
  51   :group 'gnus-notifications)
  52
  53 (defcustom gnus-notifications-use-gravatar t
  54   "Use Gravatar to retrieve photo."
  55   :type 'boolean
  56   :group 'gnus-notifications)
  57
  58 (defcustom gnus-notifications-minimum-level 1
  59   "Minimum group level the message should have to be notified.
  60 Any message in a group that has a greater value than this will
  61 not get notifications."
  62   :type 'integer
  63   :group 'gnus-notifications)
  64
  65 (defcustom gnus-notifications-timeout nil
  66   "Timeout used for notifications sent via `notifications-notify'."
  67   :type '(choice (const :tag "Server default" nil)
  68                  (integer :tag "Milliseconds"))
  69   :group 'gnus-notifications)
  70
  71 (defvar gnus-notifications-sent nil
  72   "Notifications already sent.")
  73
  74 (defvar gnus-notifications-id-to-msg nil
  75   "Map notifications ids to messages.")
  76
  77 (defun gnus-notifications-action (id key)
  78   (when (string= key "read")
  79     (let ((group-article (assoc id gnus-notifications-id-to-msg)))
  80       (when group-article
  81         (let ((group (cadr group-article))
  82               (article (nth 2 group-article)))
  83           (gnus-fetch-group group (list article)))))))
  84
  85 (defun gnus-notifications-notify (from subject photo-file)
  86   "Send a notification about a new mail.
  87 Return a notification id if any, or t on success."
  88   (if (fboundp 'notifications-notify)
  89       (gnus-funcall-no-warning
  90        'notifications-notify
  91        :title from
  92        :body subject
  93        :actions '("read" "Read")
  94        :on-action 'gnus-notifications-action
  95        :app-icon (or photo-file
  96                      (gnus-funcall-no-warning
  97                       'image-search-load-path "gnus/gnus.png"))
  98        :app-name "Gnus"
  99        :category "email.arrived"
 100        :timeout gnus-notifications-timeout)
 101     (message "New message from %s: %s" from subject)
 102     ;; Don't return an id
 103     t))
 104
 105 (declare-function gravatar-retrieve-synchronously "gravatar.el"
 106                   (mail-address))
 107
 108 (defun gnus-notifications-get-photo (mail-address)
 109   "Get photo for mail address."
 110   (let ((google-photo (when (and gnus-notifications-use-google-contacts
 111                                  (fboundp 'google-contacts-get-photo))
 112                         (ignore-errors
 113                           (gnus-funcall-no-warning
 114                            'google-contacts-get-photo mail-address)))))
 115     (if google-photo
 116         google-photo
 117       (when gnus-notifications-use-gravatar
 118         (let ((gravatar (ignore-errors
 119                           (gravatar-retrieve-synchronously mail-address))))
 120           (if (eq gravatar 'error)
 121               nil
 122             (plist-get (cdr gravatar) :data)))))))
 123
 124 (defun gnus-notifications-get-photo-file (mail-address)
 125   "Get a temporary file with an image for MAIL-ADDRESS.
 126 You have to delete the temporary image yourself using
 127 `delete-image'.
 128
 129 Returns nil if no image found."
 130   (let ((photo (gnus-notifications-get-photo mail-address)))
 131     (when photo
 132       (let ((photo-file (make-temp-file "gnus-notifications-photo-"))
 133             (coding-system-for-write 'binary))
 134         (with-temp-file photo-file
 135           (insert photo))
 136         photo-file))))
 137
 138 ;;;###autoload
 139 (defun gnus-notifications ()
 140   "Send a notification on new message.
 141 This check for new messages that are in group with a level lower
 142 or equal to `gnus-notifications-minimum-level' and send a
 143 notification using `notifications-notify' for it.
 144
 145 This is typically a function to add in
 146 `gnus-after-getting-new-news-hook'"
 147   (dolist (entry gnus-newsrc-alist)
 148     (let ((group (car entry)))
 149       ;; Check that the group level is less than
 150       ;; `gnus-notifications-minimum-level' and the the group has unread
 151       ;; messages.
 152       (when (and (<= (gnus-group-level group) gnus-notifications-minimum-level)
 153                  (let ((unread (gnus-group-unread group)))
 154                    (and (numberp unread)
 155                         (> unread 0))))
 156         ;; Each group should have an entry in the `gnus-notifications-sent'
 157         ;; alist. If not, we add one at this time.
 158         (let ((group-notifications (or (assoc group gnus-notifications-sent)
 159                                        ;; Nothing, add one and return it.
 160                                        (assoc group
 161                                               (add-to-list
 162                                                'gnus-notifications-sent
 163                                                (cons group nil))))))
 164           (dolist (article (gnus-list-of-unread-articles group))
 165             ;; Check if the article already has been notified
 166             (unless (memq article (cdr group-notifications))
 167               (with-current-buffer nntp-server-buffer
 168                 (gnus-request-head article group)
 169                 (article-decode-encoded-words) ; to decode mail addresses, subjects, etc
 170                 (let* ((address-components (mail-extract-address-components
 171                                             (or (mail-fetch-field "From") "")))
 172                        (address (cadr address-components)))
 173                   ;; Ignore mails from ourselves
 174                   (unless (and gnus-ignored-from-addresses
 175                                address
 176                                (gnus-string-match-p gnus-ignored-from-addresses
 177                                                     address))
 178                     (let* ((photo-file (gnus-notifications-get-photo-file address))
 179                            (notification-id (gnus-notifications-notify
 180                                              (or (car address-components) address)
 181                                              (mail-fetch-field "Subject")
 182                                              photo-file)))
 183                       (when notification-id
 184                         ;; Register that we did notify this message
 185                         (setcdr group-notifications (cons article (cdr group-notifications)))
 186                         (unless (eq notification-id t)
 187                           ;; Register the notification id for later actions
 188                           (add-to-list 'gnus-notifications-id-to-msg (list notification-id group article))))
 189                       (when photo-file
 190                         (delete-file photo-file)))))))))))))
 191
 192 (provide 'gnus-notifications)
 193
 194 ;;; gnus-notifications.el ends here