m4/stdalign.m4

   1 # Check for stdalign.h that conforms to C11.
   2
   3 dnl Copyright 2011-2013 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 # Prepare for substituting <stdalign.h> if it is not supported.
   9
  10 AC_DEFUN([gl_STDALIGN_H],
  11 [
  12   AC_CACHE_CHECK([for working stdalign.h],
  13     [gl_cv_header_working_stdalign_h],
  14     [AC_COMPILE_IFELSE(
  15        [AC_LANG_PROGRAM(
  16           [[#include <stdalign.h>
  17             #include <stddef.h>
  18
  19             /* Test that alignof yields a result consistent with offsetof.
  20                This catches GCC bug 52023
  21                <http://gcc.gnu.org/bugzilla/show_bug.cgi?id=52023>.  */
  22             #ifdef __cplusplus
  23                template <class t> struct alignof_helper { char a; t b; };
  24             # define ao(type) offsetof (alignof_helper<type>, b)
  25             #else
  26             # define ao(type) offsetof (struct { char a; type b; }, b)
  27             #endif
  28             char test_double[ao (double) % _Alignof (double) == 0 ? 1 : -1];
  29             char test_long[ao (long int) % _Alignof (long int) == 0 ? 1 : -1];
  30             char test_alignof[alignof (double) == _Alignof (double) ? 1 : -1];
  31
  32             /* Test _Alignas only on platforms where gnulib can help.  */
  33             #if \
  34                 ((defined __cplusplus && 201103 <= __cplusplus) \
  35                  || __GNUC__ || __IBMC__ || __IBMCPP__ || __ICC \
  36                  || 0x5110 <= __SUNPRO_C || 1300 <= _MSC_VER)
  37               struct alignas_test { char c; char alignas (8) alignas_8; };
  38               char test_alignas[offsetof (struct alignas_test, alignas_8) == 8
  39                                 ? 1 : -1];
  40             #endif
  41           ]])],
  42        [gl_cv_header_working_stdalign_h=yes],
  43        [gl_cv_header_working_stdalign_h=no])])
  44
  45   if test $gl_cv_header_working_stdalign_h = yes; then
  46     STDALIGN_H=''
  47   else
  48     STDALIGN_H='stdalign.h'
  49   fi
  50
  51   AC_SUBST([STDALIGN_H])
  52   AM_CONDITIONAL([GL_GENERATE_STDALIGN_H], [test -n "$STDALIGN_H"])
  53 ])