lisp/cedet/cedet-global.el

   1 ;;; cedet-global.el --- GNU Global support for CEDET.
   2
   3 ;; Copyright (C) 2008-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric M. Ludlam <eric@siege-engine.com>
   6 ;; Package: cedet
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24 ;;
  25 ;; Basic support for calling GNU Global, and testing version numbers.
  26
  27 (declare-function inversion-check-version "inversion")
  28
  29 (defvar cedet-global-min-version "5.0"
  30   "Minimum version of GNU Global required.")
  31
  32 (defcustom cedet-global-command "global"
  33   "Command name for the GNU Global executable."
  34   :type 'string
  35   :group 'cedet)
  36
  37 (defcustom cedet-global-gtags-command "gtags"
  38   "Command name for the GNU Global gtags executable.
  39 GTAGS is used to create the tags table queried by the 'global' command."
  40   :type 'string
  41   :group 'cedet)
  42
  43 ;;; Code:
  44 (defun cedet-gnu-global-search (searchtext texttype type scope)
  45   "Perform a search with GNU Global, return the created buffer.
  46 SEARCHTEXT is text to find.
  47 TEXTTYPE is the type of text, such as 'regexp, 'string, 'tagname,
  48 'tagregexp, or 'tagcompletions.
  49 TYPE is the type of search, meaning that SEARCHTEXT is compared to
  50 filename, tagname (tags table), references (uses of a tag) , or
  51 symbol (uses of something not in the tag table.)
  52 SCOPE is the scope of the search, such as 'project or 'subdirs."
  53   (let ((flgs (cond ((eq type 'file)
  54                      "-a")
  55                     (t "-xa")))
  56         (scopeflgs (cond
  57                     ((eq scope 'project)
  58                      ""
  59                      )
  60                     ((eq scope 'target)
  61                      "l")))
  62         (stflag (cond ((or (eq texttype 'tagname)
  63                            (eq texttype 'tagregexp))
  64                        "")
  65                       ((eq texttype 'tagcompletions)
  66                        "c")
  67                       ((eq texttype 'regexp)
  68                        "g")
  69                       (t "r"))))
  70     (cedet-gnu-global-call (list (concat flgs scopeflgs stflag)
  71                                  searchtext))))
  72
  73 (defun cedet-gnu-global-call (flags)
  74   "Call GNU Global with the list of FLAGS."
  75   (let ((b (get-buffer-create "*CEDET Global*"))
  76         (cd default-directory))
  77     (with-current-buffer b
  78       (setq default-directory cd)
  79       (erase-buffer))
  80     (apply 'call-process cedet-global-command
  81            nil b nil
  82            flags)
  83     b))
  84
  85 (defun cedet-gnu-global-gtags-call (flags)
  86   "Create GNU Global TAGS using gtags with FLAGS."
  87   (let ((b (get-buffer-create "*CEDET Global gtags*"))
  88         (cd default-directory)
  89         )
  90     (with-current-buffer b
  91       (setq default-directory cd)
  92       (erase-buffer))
  93     (apply 'call-process cedet-global-gtags-command
  94            nil b nil
  95            flags)
  96     b))
  97
  98 (defun cedet-gnu-global-expand-filename (filename)
  99   "Expand the FILENAME with GNU Global.
 100 Return a fully qualified filename."
 101   (interactive "sFile: ")
 102   (let ((ans (with-current-buffer (cedet-gnu-global-call (list "-Pa" filename))
 103                (goto-char (point-min))
 104                (if (looking-at "global: ")
 105                    (error "GNU Global not available")
 106                  (split-string (buffer-string) "\n" t)))))
 107     (when (called-interactively-p 'interactive)
 108       (if ans
 109           (if (= (length ans) 1)
 110               (message "%s" (car ans))
 111             (message "%s + %d others" (car ans)
 112                      (length (cdr ans))))
 113         (error "No file found")))
 114     ans))
 115
 116 (defun cedet-gnu-global-show-root ()
 117   "Show the root of a GNU Global area under the current buffer."
 118   (interactive)
 119   (message "%s" (cedet-gnu-global-root)))
 120
 121 (defun cedet-gnu-global-root (&optional dir)
 122   "Return the root of any GNU Global scanned project.
 123 If a default starting DIR is not specified, the current buffer's
 124 `default-directory' is used."
 125   (let ((default-directory (or dir default-directory)))
 126     (with-current-buffer (cedet-gnu-global-call (list "-pq"))
 127       (goto-char (point-min))
 128       (when (not (eobp))
 129         (file-name-as-directory
 130          (buffer-substring (point) (point-at-eol)))))))
 131
 132 (defun cedet-gnu-global-version-check (&optional noerror)
 133   "Check the version of the installed GNU Global command.
 134 If optional programmatic argument NOERROR is non-nil,
 135 then instead of throwing an error if Global isn't available,
 136 return nil."
 137   (interactive)
 138   (require 'inversion)
 139   (let ((b (condition-case nil
 140                (cedet-gnu-global-call (list "--version"))
 141              (error nil)))
 142         (rev nil))
 143     (if (not b)
 144         (progn
 145           (when (called-interactively-p 'interactive)
 146             (message "GNU Global not found."))
 147           nil)
 148       (with-current-buffer b
 149         (goto-char (point-min))
 150         (re-search-forward "GNU GLOBAL \\([0-9.]+\\)" nil t)
 151         (setq rev (match-string 1))
 152         (if (inversion-check-version rev nil cedet-global-min-version)
 153             (if noerror
 154                 nil
 155               (error "Version of GNU Global is %s.  Need at least %s"
 156                      rev cedet-global-min-version))
 157           ;; Else, return TRUE, as in good enough.
 158           (when (called-interactively-p 'interactive)
 159             (message "GNU Global %s  - Good enough for CEDET." rev))
 160           t)))))
 161
 162 (defun cedet-gnu-global-scan-hits (buffer)
 163   "Scan all the hits from the GNU Global output BUFFER."
 164   (let ((hits nil)
 165         (r1 "^\\([^ ]+\\) +\\([0-9]+\\) \\([^ ]+\\) "))
 166     (with-current-buffer buffer
 167       (goto-char (point-min))
 168       (while (re-search-forward r1 nil t)
 169         (setq hits (cons (cons (string-to-number (match-string 2))
 170                                (match-string 3))
 171                          hits)))
 172       ;; Return the results
 173       (nreverse hits))))
 174
 175 (defun cedet-gnu-global-create/update-database (&optional dir)
 176   "Create a GNU Global database in DIR.
 177 If a database already exists, then just update it."
 178   (interactive "DDirectory: ")
 179   (let ((root (cedet-gnu-global-root dir)))
 180     (if root (setq dir root))
 181     (let ((default-directory dir))
 182       (cedet-gnu-global-gtags-call
 183        (when root
 184          '("-i");; Incremental update flag.
 185          )))))
 186
 187 (provide 'cedet-global)
 188
 189 ;;; cedet-global.el ends here