lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000, 2001
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile
  28   (require 'cl)
  29   ;; Warning suppression -- can't require x-win in batch:
  30   (autoload 'xw-defined-colors "x-win"))
  31
  32 (require 'cus-face)
  33
  34 \f
  35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  36 ;;; Font selection.
  37 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  38
  39 (defgroup font-selection nil
  40   "Influencing face font selection."
  41   :group 'faces)
  42
  43
  44 (defcustom face-font-selection-order
  45   '(:width :height :weight :slant)
  46   "*A list specifying how face font selection chooses fonts.
  47 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  48 must appear once in the list, and the list must not contain any other
  49 elements.  Font selection tries to find a best matching font for
  50 those face attributes first that appear first in the list.  For
  51 example, if `:slant' appears before `:height', font selection first
  52 tries to find a font with a suitable slant, even if this results in
  53 a font height that isn't optimal."
  54   :tag "Font selection order."
  55   :type '(list symbol symbol symbol symbol)
  56   :group 'font-selection
  57   :set #'(lambda (symbol value)
  58            (set-default symbol value)
  59            (internal-set-font-selection-order value)))
  60
  61
  62 ;; This is defined originally in xfaces.c.
  63 (defcustom face-font-family-alternatives
  64   '(("courier" "fixed")
  65     ("helv" "helvetica" "arial" "fixed"))
  66   "*Alist of alternative font family names.
  67 Each element has the the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  68 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  69 ALTERNATIVE2 etc."
  70   :tag "Alternative font families to try."
  71   :type '(repeat (repeat string))
  72   :group 'font-selection
  73   :set #'(lambda (symbol value)
  74            (set-default symbol value)
  75            (internal-set-alternative-font-family-alist value)))
  76
  77
  78 ;; This is defined originally in xfaces.c.
  79 (defcustom face-font-registry-alternatives
  80   '(("gb2312.1980" "gb2312.80&gb8565.88" "gbk*")
  81     ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  82     ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  83     ("muletibetan-2" "muletibetan-0"))
  84   "*Alist of alternative font registry names.
  85 Each element has the the form (REGISTRY ALTERNATIVE1 ALTERNATIVE2 ...).
  86 If fonts of registry REGISTRY can be loaded, font selection
  87 tries to find a best matching font among all fonts of registry
  88 REGISTRY, ALTERNATIVE1, ALTERNATIVE2, and etc."
  89   :tag "Alternative font registries to try."
  90   :type '(repeat (repeat string))
  91   :version "21.1"
  92   :group 'font-selection
  93   :set #'(lambda (symbol value)
  94            (set-default symbol value)
  95            (internal-set-alternative-font-registry-alist value)))
  96
  97
  98 \f
  99 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 100 ;;; Creation, copying.
 101 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 102
 103
 104 (defun face-list ()
 105   "Return a list of all defined face names."
 106   (mapcar #'car face-new-frame-defaults))
 107
 108
 109 ;;; ### If not frame-local initialize by what X resources?
 110
 111 (defun make-face (face &optional no-init-from-resources)
 112   "Define a new face with name FACE, a symbol.
 113 NO-INIT-FROM-RESOURCES non-nil means don't initialize frame-local
 114 variants of FACE from X resources.  (X resources recognized are found
 115 in the global variable `face-x-resources'.)  If FACE is already known
 116 as a face, leave it unmodified.  Value is FACE."
 117   (interactive "SMake face: ")
 118   (unless (facep face)
 119     ;; Make frame-local faces (this also makes the global one).
 120     (dolist (frame (frame-list))
 121       (internal-make-lisp-face face frame))
 122     ;; Add the face to the face menu.
 123     (when (fboundp 'facemenu-add-new-face)
 124       (facemenu-add-new-face face))
 125     ;; Define frame-local faces for all frames from X resources.
 126     (unless no-init-from-resources
 127       (make-face-x-resource-internal face)))
 128   face)
 129
 130
 131 (defun make-empty-face (face)
 132   "Define a new, empty face with name FACE.
 133 If the face already exists, it is left unmodified.  Value is FACE."
 134   (interactive "SMake empty face: ")
 135   (make-face face 'no-init-from-resources))
 136
 137
 138 (defun copy-face (old-face new-face &optional frame new-frame)
 139   "Define a face just like OLD-FACE, with name NEW-FACE.
 140
 141 If NEW-FACE already exists as a face, it is modified to be like
 142 OLD-FACE.  If it doesn't already exist, it is created.
 143
 144 If the optional argument FRAME is given as a frame,  NEW-FACE is
 145 changed on FRAME only.
 146 If FRAME is t, the frame-independent default specification for OLD-FACE
 147 is copied to NEW-FACE.
 148 If FRAME is nil, copying is done for the frame-independent defaults
 149 and for each existing frame.
 150
 151 If the optional fourth argument NEW-FRAME is given,
 152 copy the information from face OLD-FACE on frame FRAME
 153 to NEW-FACE on frame NEW-FRAME."
 154   (let ((inhibit-quit t))
 155     (if (null frame)
 156         (progn
 157           (dolist (frame (frame-list))
 158             (copy-face old-face new-face frame))
 159           (copy-face old-face new-face t))
 160       (internal-copy-lisp-face old-face new-face frame new-frame))
 161     new-face))
 162
 163
 164 \f
 165 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 166 ;;; Obsolete functions
 167 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 168
 169 ;; The functions in this section are defined because Lisp packages use
 170 ;; them, despite the prefix `internal-' suggesting that they are
 171 ;; private to the face implementation.
 172
 173 (defun internal-find-face (name &optional frame)
 174   "Retrieve the face named NAME.
 175 Return nil if there is no such face.
 176 If the optional argument FRAME is given, this gets the face NAME for
 177 that frame; otherwise, it uses the selected frame.
 178 If FRAME is the symbol t, then the global, non-frame face is returned.
 179 If NAME is already a face, it is simply returned.
 180
 181 This function is defined for compatibility with Emacs 20.2.  It
 182 should not be used anymore."
 183   (facep name))
 184 (make-obsolete 'internal-find-face 'facep "21.1")
 185
 186
 187 (defun internal-get-face (name &optional frame)
 188   "Retrieve the face named NAME; error if there is none.
 189 If the optional argument FRAME is given, this gets the face NAME for
 190 that frame; otherwise, it uses the selected frame.
 191 If FRAME is the symbol t, then the global, non-frame face is returned.
 192 If NAME is already a face, it is simply returned.
 193
 194 This function is defined for compatibility with Emacs 20.2.  It
 195 should not be used anymore."
 196   (or (internal-find-face name frame)
 197       (check-face name)))
 198 (make-obsolete 'internal-get-face "See `facep' and `check-face'." "21.1")
 199
 200 \f
 201 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 202 ;;; Predicates, type checks.
 203 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 204
 205 (defun facep (face)
 206   "Return non-nil if FACE is a face name."
 207   (internal-lisp-face-p face))
 208
 209
 210 (defun check-face (face)
 211   "Signal an error if FACE doesn't name a face.
 212 Value is FACE."
 213   (unless (facep face)
 214     (error "Not a face: %s" face))
 215   face)
 216
 217
 218 ;; The ID returned is not to be confused with the internally used IDs
 219 ;; of realized faces.  The ID assigned to Lisp faces is used to
 220 ;; support faces in display table entries.
 221
 222 (defun face-id (face &optional frame)
 223   "Return the interNal ID of face with name FACE.
 224 If optional argument FRAME is nil or omitted, use the selected frame."
 225   (check-face face)
 226   (get face 'face))
 227
 228
 229 (defun face-equal (face1 face2 &optional frame)
 230   "Non-nil if faces FACE1 and FACE2 are equal.
 231 Faces are considered equal if all their attributes are equal.
 232 If the optional argument FRAME is given, report on face FACE in that frame.
 233 If FRAME is t, report on the defaults for face FACE (for new frames).
 234 If FRAME is omitted or nil, use the selected frame."
 235   (internal-lisp-face-equal-p face1 face2 frame))
 236
 237
 238 (defun face-differs-from-default-p (face &optional frame)
 239   "Non-nil if FACE displays differently from the default face.
 240 If the optional argument FRAME is given, report on face FACE in that frame.
 241 If FRAME is t, report on the defaults for face FACE (for new frames).
 242 If FRAME is omitted or nil, use the selected frame.
 243 A face is considered to be ``the same'' as the default face if it is
 244 actually specified in the same way (equal attributes) or if it is
 245 fully-unspecified, and thus inherits the attributes of any face it
 246 is displayed on top of."
 247   (cond ((eq frame t) (setq frame nil))
 248         ((null frame) (setq frame (selected-frame))))
 249   (let* ((v1 (internal-lisp-face-p face frame))
 250          (n (if v1 (length v1) 0))
 251          (v2 (internal-lisp-face-p 'default frame))
 252          (i 1))
 253     (unless v1
 254       (error "Not a face: %S" face))
 255     (while (and (< i n)
 256                 (or (eq 'unspecified (aref v1 i))
 257                     (equal (aref v1 i) (aref v2 i))))
 258       (setq i (1+ i)))
 259     (< i n)))
 260
 261
 262 (defun face-nontrivial-p (face &optional frame)
 263   "True if face FACE has some non-nil attribute.
 264 If the optional argument FRAME is given, report on face FACE in that frame.
 265 If FRAME is t, report on the defaults for face FACE (for new frames).
 266 If FRAME is omitted or nil, use the selected frame."
 267   (not (internal-lisp-face-empty-p face frame)))
 268
 269
 270 \f
 271 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 272 ;;; Setting face attributes from X resources.
 273 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 274
 275 (defcustom face-x-resources
 276   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 277     (:width (".attributeWidth" . "Face.AttributeWidth"))
 278     (:height (".attributeHeight" . "Face.AttributeHeight"))
 279     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 280     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 281     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 282     (:background (".attributeBackground" . "Face.AttributeBackground"))
 283     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 284     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 285     (:box (".attributeBox" . "Face.AttributeBox"))
 286     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 287     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 288     (:stipple
 289      (".attributeStipple" . "Face.AttributeStipple")
 290      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 291     (:bold (".attributeBold" . "Face.AttributeBold"))
 292     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 293     (:font (".attributeFont" . "Face.AttributeFont"))
 294     (:inherit (".attributeInherit" . "Face.AttributeInherit")))
 295   "*List of X resources and classes for face attributes.
 296 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 297 the name of a face attribute, and each ENTRY is a cons of the form
 298 (RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 299 X resource class for the attribute."
 300   :type '(repeat (cons symbol (repeat (cons string string))))
 301   :group 'faces)
 302
 303
 304 (defun set-face-attribute-from-resource (face attribute resource class frame)
 305   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 306 Value is the attribute value specified by the resource, or nil
 307 if not present.  This function displays a message if the resource
 308 specifies an invalid attribute."
 309   (let* ((face-name (face-name face))
 310          (value (internal-face-x-get-resource (concat face-name resource)
 311                                               class frame)))
 312     (when value
 313       (condition-case ()
 314           (internal-set-lisp-face-attribute-from-resource
 315            face attribute (downcase value) frame)
 316         (error
 317          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 318                   face-name frame attribute value))))
 319     value))
 320
 321
 322 (defun set-face-attributes-from-resources (face frame)
 323   "Set attributes of FACE from X resources for FRAME."
 324   (when (memq (framep frame) '(x w32 mac))
 325     (dolist (definition face-x-resources)
 326       (let ((attribute (car definition)))
 327         (dolist (entry (cdr definition))
 328           (set-face-attribute-from-resource face attribute (car entry)
 329                                             (cdr entry) frame))))))
 330
 331
 332 (defun make-face-x-resource-internal (face &optional frame)
 333   "Fill frame-local FACE on FRAME from X resources.
 334 FRAME nil or not specified means do it for all frames."
 335   (if (null frame)
 336       (dolist (frame (frame-list))
 337         (set-face-attributes-from-resources face frame))
 338     (set-face-attributes-from-resources face frame)))
 339
 340
 341 \f
 342 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 343 ;;; Retrieving face attributes.
 344 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 345
 346 (defun face-name (face)
 347   "Return the name of face FACE."
 348   (symbol-name (check-face face)))
 349
 350
 351 (defun face-attribute (face attribute &optional frame)
 352   "Return the value of FACE's ATTRIBUTE on FRAME.
 353 If the optional argument FRAME is given, report on face FACE in that frame.
 354 If FRAME is t, report on the defaults for face FACE (for new frames).
 355 If FRAME is omitted or nil, use the selected frame."
 356   (internal-get-lisp-face-attribute face attribute frame))
 357
 358
 359 (defun face-foreground (face &optional frame)
 360   "Return the foreground color name of FACE, or nil if unspecified.
 361 If the optional argument FRAME is given, report on face FACE in that frame.
 362 If FRAME is t, report on the defaults for face FACE (for new frames).
 363 If FRAME is omitted or nil, use the selected frame."
 364   (let ((value (internal-get-lisp-face-attribute face :foreground frame)))
 365     (if (eq value 'unspecified)
 366         nil
 367       value)))
 368
 369
 370 (defun face-background (face &optional frame)
 371   "Return the background color name of FACE, or nil if unspecified.
 372 If the optional argument FRAME is given, report on face FACE in that frame.
 373 If FRAME is t, report on the defaults for face FACE (for new frames).
 374 If FRAME is omitted or nil, use the selected frame."
 375   (let ((value (internal-get-lisp-face-attribute face :background frame)))
 376     (if (eq value 'unspecified)
 377         nil
 378       value)))
 379
 380
 381 (defun face-stipple (face &optional frame)
 382  "Return the stipple pixmap name of FACE, or nil if unspecified.
 383 If the optional argument FRAME is given, report on face FACE in that frame.
 384 If FRAME is t, report on the defaults for face FACE (for new frames).
 385 If FRAME is omitted or nil, use the selected frame."
 386   (let ((value (internal-get-lisp-face-attribute face :stipple frame)))
 387     (if (eq value 'unspecified)
 388         nil
 389       value)))
 390
 391
 392 (defalias 'face-background-pixmap 'face-stipple)
 393
 394
 395 (defun face-underline-p (face &optional frame)
 396  "Return non-nil if FACE is underlined.
 397 If the optional argument FRAME is given, report on face FACE in that frame.
 398 If FRAME is t, report on the defaults for face FACE (for new frames).
 399 If FRAME is omitted or nil, use the selected frame."
 400  (eq (face-attribute face :underline frame) t))
 401
 402
 403 (defun face-inverse-video-p (face &optional frame)
 404  "Return non-nil if FACE is in inverse video on FRAME.
 405 If the optional argument FRAME is given, report on face FACE in that frame.
 406 If FRAME is t, report on the defaults for face FACE (for new frames).
 407 If FRAME is omitted or nil, use the selected frame."
 408  (eq (face-attribute face :inverse-video frame) t))
 409
 410
 411 (defun face-bold-p (face &optional frame)
 412   "Return non-nil if the font of FACE is bold on FRAME.
 413 If the optional argument FRAME is given, report on face FACE in that frame.
 414 If FRAME is t, report on the defaults for face FACE (for new frames).
 415 If FRAME is omitted or nil, use the selected frame.
 416 Use `face-attribute' for finer control."
 417   (let ((bold (face-attribute face :weight frame)))
 418     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 419
 420
 421 (defun face-italic-p (face &optional frame)
 422   "Return non-nil if the font of FACE is italic on FRAME.
 423 If the optional argument FRAME is given, report on face FACE in that frame.
 424 If FRAME is t, report on the defaults for face FACE (for new frames).
 425 If FRAME is omitted or nil, use the selected frame.
 426 Use `face-attribute' for finer control."
 427   (let ((italic (face-attribute face :slant frame)))
 428     (memq italic '(italic oblique))))
 429
 430
 431 \f
 432 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 433 ;;; Face documentation.
 434 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 435
 436 (defun face-documentation (face)
 437   "Get the documentation string for FACE."
 438   (get face 'face-documentation))
 439
 440
 441 (defun set-face-documentation (face string)
 442   "Set the documentation string for FACE to STRING."
 443   ;; Perhaps the text should go in DOC.
 444   (put face 'face-documentation (purecopy string)))
 445
 446
 447 (defalias 'face-doc-string 'face-documentation)
 448 (defalias 'set-face-doc-string 'set-face-documentation)
 449
 450
 451 \f
 452 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 453 ;; Setting face attributes.
 454 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 455
 456
 457 (defun set-face-attribute (face frame &rest args)
 458   "Set attributes of FACE on FRAME from ARGS.
 459
 460 FRAME nil means change attributes on all frames.  FRAME t means change
 461 the default for new frames (this is done automatically each time an
 462 attribute is changed on all frames).
 463
 464 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 465 face attribute name.  All attributes can be set to `unspecified';
 466 this fact is not further mentioned below.
 467
 468 The following attributes are recognized:
 469
 470 `:family'
 471
 472 VALUE must be a string specifying the font family, e.g. ``courier'',
 473 or a fontset alias name.  If a font family is specified, wild-cards `*'
 474 and `?' are allowed.
 475
 476 `:width'
 477
 478 VALUE specifies the relative proportionate width of the font to use.
 479 It must be one of the symbols `ultra-condensed', `extra-condensed',
 480 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 481 `extra-expanded', or `ultra-expanded'.
 482
 483 `:height'
 484
 485 VALUE must be either an integer specifying the height of the font to use
 486 in 1/10 pt, a floating point number specifying the amount by which to
 487 scale any underlying face, or a function, which is called with the old
 488 height (from the underlying face), and should return the new height.
 489
 490 `:weight'
 491
 492 VALUE specifies the weight of the font to use.  It must be one of the
 493 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 494 `semi-light', `light', `extra-light', `ultra-light'.
 495
 496 `:slant'
 497
 498 VALUE specifies the slant of the font to use.  It must be one of the
 499 symbols `italic', `oblique', `normal', `reverse-italic', or
 500 `reverse-oblique'.
 501
 502 `:foreground', `:background'
 503
 504 VALUE must be a color name, a string.
 505
 506 `:underline'
 507
 508 VALUE specifies whether characters in FACE should be underlined.  If
 509 VALUE is t, underline with foreground color of the face.  If VALUE is
 510 a string, underline with that color.  If VALUE is nil, explicitly
 511 don't underline.
 512
 513 `:overline'
 514
 515 VALUE specifies whether characters in FACE should be overlined.  If
 516 VALUE is t, overline with foreground color of the face.  If VALUE is a
 517 string, overline with that color.  If VALUE is nil, explicitly don't
 518 overline.
 519
 520 `:strike-through'
 521
 522 VALUE specifies whether characters in FACE should be drawn with a line
 523 striking through them.  If VALUE is t, use the foreground color of the
 524 face.  If VALUE is a string, strike-through with that color.  If VALUE
 525 is nil, explicitly don't strike through.
 526
 527 `:box'
 528
 529 VALUE specifies whether characters in FACE should have a box drawn
 530 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 531 VALUE is t, draw a box with lines of width 1 in the foreground color
 532 of the face.  If VALUE is a string, the string must be a color name,
 533 and the box is drawn in that color with a line width of 1.  Otherwise,
 534 VALUE must be a property list of the form `(:line-width WIDTH
 535 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 536 the property list, a default value will be used for the value, as
 537 specified below.  WIDTH specifies the width of the lines to draw; it
 538 defaults to 1.  If WIDTH is negative, the absolute value is the width
 539 of the lines, and draw top/bottom lines inside the characters area,
 540 not around it.  COLOR is the name of the color to draw in, default is
 541 the foreground color of the face for simple boxes, and the background
 542 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 543 should be draw.  If STYLE is `released-button', draw a box looking
 544 like a released 3D button.  If STYLE is `pressed-button' draw a box
 545 that appears like a pressed button.  If STYLE is nil, the default if
 546 the property list doesn't contain a style specification, draw a 2D
 547 box.
 548
 549 `:inverse-video'
 550
 551 VALUE specifies whether characters in FACE should be displayed in
 552 inverse video.  VALUE must be one of t or nil.
 553
 554 `:stipple'
 555
 556 If VALUE is a string, it must be the name of a file of pixmap data.
 557 The directories listed in the `x-bitmap-file-path' variable are
 558 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 559 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 560 is a string containing the raw bits of the bitmap.  VALUE nil means
 561 explicitly don't use a stipple pattern.
 562
 563 For convenience, attributes `:family', `:width', `:height', `:weight',
 564 and `:slant' may also be set in one step from an X font name:
 565
 566 `:font'
 567
 568 Set font-related face attributes from VALUE.  VALUE must be a valid
 569 XLFD font name.  If it is a font name pattern, the first matching font
 570 will be used.
 571
 572 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 573 be used to specify that a bold or italic font should be used.  VALUE
 574 must be t or nil in that case.  A value of `unspecified' is not allowed.
 575
 576 `:inherit'
 577
 578 VALUE is the name of a face from which to inherit attributes, or a list
 579 of face names.  Attributes from inherited faces are merged into the face
 580 like an underlying face would be, with higher priority than underlying faces."
 581   (let ((where (if (null frame) 0 frame)))
 582     (setq args (purecopy args))
 583     (while args
 584       (internal-set-lisp-face-attribute face (car args)
 585                                         (purecopy (cadr args))
 586                                         where)
 587       (setq args (cdr (cdr args))))))
 588
 589
 590 (defun make-face-bold (face &optional frame noerror)
 591   "Make the font of FACE be bold, if possible.
 592 FRAME nil or not specified means change face on all frames.
 593 Argument NOERROR is ignored and retained for compatibility.
 594 Use `set-face-attribute' for finer control of the font weight."
 595   (interactive (list (read-face-name "Make which face bold ")))
 596   (set-face-attribute face frame :weight 'bold))
 597
 598
 599 (defun make-face-unbold (face &optional frame noerror)
 600   "Make the font of FACE be non-bold, if possible.
 601 FRAME nil or not specified means change face on all frames.
 602 Argument NOERROR is ignored and retained for compatibility."
 603   (interactive (list (read-face-name "Make which face non-bold ")))
 604   (set-face-attribute face frame :weight 'normal))
 605
 606
 607 (defun make-face-italic (face &optional frame noerror)
 608   "Make the font of FACE be italic, if possible.
 609 FRAME nil or not specified means change face on all frames.
 610 Argument NOERROR is ignored and retained for compatibility.
 611 Use `set-face-attribute' for finer control of the font slant."
 612   (interactive (list (read-face-name "Make which face italic ")))
 613   (set-face-attribute face frame :slant 'italic))
 614
 615
 616 (defun make-face-unitalic (face &optional frame noerror)
 617   "Make the font of FACE be non-italic, if possible.
 618 FRAME nil or not specified means change face on all frames.
 619 Argument NOERROR is ignored and retained for compatibility."
 620   (interactive (list (read-face-name "Make which face non-italic ")))
 621   (set-face-attribute face frame :slant 'normal))
 622
 623
 624 (defun make-face-bold-italic (face &optional frame noerror)
 625   "Make the font of FACE be bold and italic, if possible.
 626 FRAME nil or not specified means change face on all frames.
 627 Argument NOERROR is ignored and retained for compatibility.
 628 Use `set-face-attribute' for finer control of font weight and slant."
 629   (interactive (list (read-face-name "Make which face bold-italic: ")))
 630   (set-face-attribute face frame :weight 'bold :slant 'italic))
 631
 632
 633 (defun set-face-font (face font &optional frame)
 634   "Change font-related attributes of FACE to those of FONT (a string).
 635 FRAME nil or not specified means change face on all frames.
 636 This sets the attributes `:family', `:width', `:height', `:weight',
 637 and `:slant'.  When called interactively, prompt for the face and font."
 638   (interactive (read-face-and-attribute :font))
 639   (set-face-attribute face frame :font font))
 640
 641
 642 ;; Implementation note: Emulating gray background colors with a
 643 ;; stipple pattern is now part of the face realization process, and is
 644 ;; done in C depending on the frame on which the face is realized.
 645
 646 (defun set-face-background (face color &optional frame)
 647   "Change the background color of face FACE to COLOR (a string).
 648 FRAME nil or not specified means change face on all frames.
 649 When called interactively, prompt for the face and color."
 650   (interactive (read-face-and-attribute :background))
 651   (set-face-attribute face frame :background (or color 'unspecified)))
 652
 653
 654 (defun set-face-foreground (face color &optional frame)
 655   "Change the foreground color of face FACE to COLOR (a string).
 656 FRAME nil or not specified means change face on all frames.
 657 When called interactively, prompt for the face and color."
 658   (interactive (read-face-and-attribute :foreground))
 659   (set-face-attribute face frame :foreground (or color 'unspecified)))
 660
 661
 662 (defun set-face-stipple (face stipple &optional frame)
 663   "Change the stipple pixmap of face FACE to STIPPLE.
 664 FRAME nil or not specified means change face on all frames.
 665 STIPPLE should be a string, the name of a file of pixmap data.
 666 The directories listed in the `x-bitmap-file-path' variable are searched.
 667
 668 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 669 where WIDTH and HEIGHT are the size in pixels,
 670 and DATA is a string, containing the raw bits of the bitmap."
 671   (interactive (read-face-and-attribute :stipple))
 672   (set-face-attribute face frame :stipple (or stipple 'unspecified)))
 673
 674
 675 (defun set-face-underline (face underline &optional frame)
 676   "Specify whether face FACE is underlined.
 677 UNDERLINE nil means FACE explicitly doesn't underline.
 678 UNDERLINE non-nil means FACE explicitly does underlining
 679 with the same of the foreground color.
 680 If UNDERLINE is a string, underline with the color named UNDERLINE.
 681 FRAME nil or not specified means change face on all frames.
 682 Use `set-face-attribute' to ``unspecify'' underlining."
 683   (interactive
 684    (let ((list (read-face-and-attribute :underline)))
 685      (list (car list) (eq (car (cdr list)) t))))
 686   (set-face-attribute face frame :underline underline))
 687
 688
 689 (defun set-face-underline-p (face underline-p &optional frame)
 690   "Specify whether face FACE is underlined.
 691 UNDERLINE-P nil means FACE explicitly doesn't underline.
 692 UNDERLINE-P non-nil means FACE explicitly does underlining.
 693 FRAME nil or not specified means change face on all frames.
 694 Use `set-face-attribute' to ``unspecify'' underlining."
 695   (interactive
 696    (let ((list (read-face-and-attribute :underline)))
 697      (list (car list) (eq (car (cdr list)) t))))
 698   (set-face-attribute face frame :underline underline-p))
 699
 700
 701 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 702   "Specify whether face FACE is in inverse video.
 703 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 704 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 705 FRAME nil or not specified means change face on all frames.
 706 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 707   (interactive
 708    (let ((list (read-face-and-attribute :inverse-video)))
 709      (list (car list) (eq (car (cdr list)) t))))
 710   (set-face-attribute face frame :inverse-video inverse-video-p))
 711
 712
 713 (defun set-face-bold-p (face bold-p &optional frame)
 714   "Specify whether face FACE is bold.
 715 BOLD-P non-nil means FACE should explicitly display bold.
 716 BOLD-P nil means FACE should explicitly display non-bold.
 717 FRAME nil or not specified means change face on all frames.
 718 Use `set-face-attribute' or `modify-face' for finer control."
 719   (if (null bold-p)
 720       (make-face-unbold face frame)
 721     (make-face-bold face frame)))
 722
 723
 724 (defun set-face-italic-p (face italic-p &optional frame)
 725   "Specify whether face FACE is italic.
 726 ITALIC-P non-nil means FACE should explicitly display italic.
 727 ITALIC-P nil means FACE should explicitly display non-italic.
 728 FRAME nil or not specified means change face on all frames.
 729 Use `set-face-attribute' or `modify-face' for finer control."
 730   (if (null italic-p)
 731       (make-face-unitalic face frame)
 732     (make-face-italic face frame)))
 733
 734
 735 (defalias 'set-face-background-pixmap 'set-face-stipple)
 736
 737
 738 (defun invert-face (face &optional frame)
 739   "Swap the foreground and background colors of FACE.
 740 FRAME nil or not specified means change face on all frames.
 741 If FACE specifies neither foreground nor background color,
 742 set its foreground and background to the background and foreground
 743 of the default face.  Value is FACE."
 744   (interactive (list (read-face-name "Invert face ")))
 745   (let ((fg (face-attribute face :foreground frame))
 746         (bg (face-attribute face :background frame)))
 747     (if (or fg bg)
 748         (set-face-attribute face frame :foreground bg :background fg)
 749       (set-face-attribute face frame
 750                           :foreground
 751                           (face-attribute 'default :background frame)
 752                           :background
 753                           (face-attribute 'default :foreground frame))))
 754   face)
 755
 756 \f
 757 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 758 ;;; Interactively modifying faces.
 759 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 760
 761 (defun read-face-name (prompt)
 762   "Read and return a face symbol, prompting with PROMPT.
 763 Value is a symbol naming a known face."
 764   (let ((face-list (mapcar #'(lambda (x) (cons (symbol-name x) x))
 765                            (face-list)))
 766         (def (thing-at-point 'symbol))
 767         face)
 768     (cond ((assoc def face-list)
 769            (setq prompt (concat prompt " (default " def "): ")))
 770           (t (setq def nil)
 771              (setq prompt (concat prompt ": "))))
 772     (while (equal "" (setq face (completing-read
 773                                  prompt face-list nil t nil nil def))))
 774     (intern face)))
 775
 776
 777 (defun face-valid-attribute-values (attribute &optional frame)
 778   "Return valid values for face attribute ATTRIBUTE.
 779 The optional argument FRAME is used to determine available fonts
 780 and colors.  If it is nil or not specified, the selected frame is
 781 used.  Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value
 782 out of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 783 an integer value."
 784   (let (valid)
 785     (setq valid
 786           (case attribute
 787             (:family
 788              (if window-system
 789                  (mapcar #'(lambda (x) (cons (car x) (car x)))
 790                          (x-font-family-list))
 791                ;; Only one font on TTYs.
 792                (list (cons "default" "default"))))
 793             ((:width :weight :slant :inverse-video)
 794              (mapcar #'(lambda (x) (cons (symbol-name x) x))
 795                      (internal-lisp-face-attribute-values attribute)))
 796             ((:underline :overline :strike-through :box)
 797              (if window-system
 798                  (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
 799                                 (internal-lisp-face-attribute-values attribute))
 800                         (mapcar #'(lambda (c) (cons c c))
 801                                 (x-defined-colors frame)))
 802                (mapcar #'(lambda (x) (cons (symbol-name x) x))
 803                        (internal-lisp-face-attribute-values attribute))))
 804             ((:foreground :background)
 805              (mapcar #'(lambda (c) (cons c c))
 806                      (defined-colors frame)))
 807             ((:height)
 808              'integerp)
 809             (:stipple
 810              (and (memq window-system '(x w32 mac))
 811                   (mapcar #'list
 812                           (apply #'nconc
 813                                  (mapcar (lambda (dir)
 814                                            (and (file-readable-p dir)
 815                                                 (file-directory-p dir)
 816                                                 (directory-files dir)))
 817                                          x-bitmap-file-path)))))
 818             (:inherit
 819              (cons '("none" . nil)
 820                    (mapcar #'(lambda (c) (cons (symbol-name c) c))
 821                            (face-list))))
 822             (t
 823              (error "Internal error"))))
 824     (if (and (listp valid) (not (memq attribute '(:inherit))))
 825         (nconc (list (cons "unspecified" 'unspecified)) valid)
 826       valid)))
 827
 828
 829
 830 (defvar face-attribute-name-alist
 831   '((:family . "font family")
 832     (:width . "character set width")
 833     (:height . "height in 1/10 pt")
 834     (:weight . "weight")
 835     (:slant . "slant")
 836     (:underline . "underline")
 837     (:overline . "overline")
 838     (:strike-through . "strike-through")
 839     (:box . "box")
 840     (:inverse-video . "inverse-video display")
 841     (:foreground . "foreground color")
 842     (:background . "background color")
 843     (:stipple . "background stipple")
 844     (:inherit . "inheritance"))
 845   "An alist of descriptive names for face attributes.
 846 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
 847 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
 848 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
 849
 850
 851 (defun face-descriptive-attribute-name (attribute)
 852   "Return a descriptive name for ATTRIBUTE."
 853   (cdr (assq attribute face-attribute-name-alist)))
 854
 855
 856 (defun face-read-string (face default name &optional completion-alist)
 857   "Interactively read a face attribute string value.
 858 FACE is the face whose attribute is read.  If non-nil, DEFAULT is the
 859 default string to return if no new value is entered.  NAME is a
 860 descriptive name of the attribute for prompting.  COMPLETION-ALIST is an
 861 alist of valid values, if non-nil.
 862
 863 Entering nothing accepts the default string DEFAULT.
 864 Value is the new attribute value."
 865   ;; Capitalize NAME (we don't use `capitalize' because that capitalizes
 866   ;; each word in a string separately).
 867   (setq name (concat (upcase (substring name 0 1)) (substring name 1)))
 868   (let* ((completion-ignore-case t)
 869          (value (completing-read
 870                  (if default
 871                      (format "%s for face `%s' (default %s): "
 872                              name face default)
 873                    (format "%s for face `%s': " name face))
 874                  completion-alist)))
 875     (if (equal value "") default value)))
 876
 877
 878 (defun face-read-integer (face default name)
 879   "Interactively read an integer face attribute value.
 880 FACE is the face whose attribute is read.  DEFAULT is the default
 881 value to return if no new value is entered.  NAME is a descriptive
 882 name of the attribute for prompting.  Value is the new attribute value."
 883   (let ((new-value
 884          (face-read-string face
 885                            (format "%s" default)
 886                            name
 887                            (list (cons "unspecified" 'unspecified)))))
 888     (cond ((equal new-value "unspecified")
 889            'unspecified)
 890           ((member new-value '("unspecified-fg" "unspecified-bg"))
 891            new-value)
 892           (t
 893            (string-to-int new-value)))))
 894
 895
 896 (defun read-face-attribute (face attribute &optional frame)
 897   "Interactively read a new value for FACE's ATTRIBUTE.
 898 Optional argument FRAME nil or unspecified means read an attribute value
 899 of a global face.  Value is the new attribute value."
 900   (let* ((old-value (face-attribute face attribute frame))
 901          (attribute-name (face-descriptive-attribute-name attribute))
 902          (valid (face-valid-attribute-values attribute frame))
 903          new-value)
 904     ;; Represent complex attribute values as strings by printing them
 905     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
 906     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
 907     ;; SHADOW)'.
 908     (when (and (or (eq attribute :stipple)
 909                    (eq attribute :box))
 910                (or (consp old-value)
 911                    (vectorp old-value)))
 912       (setq old-value (prin1-to-string old-value)))
 913     (cond ((listp valid)
 914            (let ((default
 915                    (or (car (rassoc old-value valid))
 916                        (format "%s" old-value))))
 917              (setq new-value
 918                    (face-read-string face default attribute-name valid))
 919              (if (equal new-value default)
 920                  ;; Nothing changed, so don't bother with all the stuff
 921                  ;; below.  In particular, this avoids a non-tty color
 922                  ;; from being canonicalized for a tty when the user
 923                  ;; just uses the default.
 924                  (setq new-value old-value)
 925                ;; Terminal frames can support colors that don't appear
 926                ;; explicitly in VALID, using color approximation code
 927                ;; in tty-colors.el.
 928                (when (and (memq attribute '(:foreground :background))
 929                           (not (memq window-system '(x w32 mac)))
 930                           (not (member new-value
 931                                        '("unspecified"
 932                                          "unspecified-fg" "unspecified-bg"))))
 933                  (setq new-value (car (tty-color-desc new-value frame))))
 934                (when (assoc new-value valid)
 935                  (setq new-value (cdr (assoc new-value valid)))))))
 936           ((eq valid 'integerp)
 937            (setq new-value (face-read-integer face old-value attribute-name)))
 938           (t (error "Internal error")))
 939     ;; Convert stipple and box value text we read back to a list or
 940     ;; vector if it looks like one.  This makes the assumption that a
 941     ;; pixmap file name won't start with an open-paren.
 942     (when (and (or (eq attribute :stipple)
 943                    (eq attribute :box))
 944                (stringp new-value)
 945                (string-match "^[[(]" new-value))
 946       (setq new-value (read new-value)))
 947     new-value))
 948
 949
 950 (defun read-face-font (face &optional frame)
 951   "Read the name of a font for FACE on FRAME.
 952 If optional argument FRAME Is nil or omitted, use the selected frame."
 953   (let ((completion-ignore-case t))
 954     (completing-read (format "Set font attributes of face `%s' from font: " face)
 955                      (mapcar 'list (x-list-fonts "*" nil frame)))))
 956
 957
 958 (defun read-all-face-attributes (face &optional frame)
 959   "Interactively read all attributes for FACE.
 960 If optional argument FRAME Is nil or omitted, use the selected frame.
 961 Value is a property list of attribute names and new values."
 962   (let (result)
 963     (dolist (attribute face-attribute-name-alist result)
 964       (setq result (cons (car attribute)
 965                          (cons (read-face-attribute face (car attribute) frame)
 966                                result))))))
 967
 968
 969 (defun modify-face (&optional frame)
 970   "Modify attributes of faces interactively.
 971 If optional argument FRAME is nil or omitted, modify the face used
 972 for newly created frame, i.e. the global face."
 973   (interactive)
 974   (let ((face (read-face-name "Modify face")))
 975     (apply #'set-face-attribute face frame
 976            (read-all-face-attributes face frame))))
 977
 978
 979 (defun read-face-and-attribute (attribute &optional frame)
 980   "Read face name and face attribute value.
 981 ATTRIBUTE is the attribute whose new value is read.
 982 FRAME nil or unspecified means read attribute value of global face.
 983 Value is a list (FACE NEW-VALUE) where FACE is the face read
 984 (a symbol), and NEW-VALUE is value read."
 985   (cond ((eq attribute :font)
 986          (let* ((prompt "Set font-related attributes of face")
 987                 (face (read-face-name prompt))
 988                 (font (read-face-font face frame)))
 989            (list face font)))
 990         (t
 991          (let* ((attribute-name (face-descriptive-attribute-name attribute))
 992                 (prompt (format "Set %s of face" attribute-name))
 993                 (face (read-face-name prompt))
 994                 (new-value (read-face-attribute face attribute frame)))
 995            (list face new-value)))))
 996
 997
 998 \f
 999 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1000 ;;; Listing faces.
1001 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1002
1003 (defvar list-faces-sample-text
1004   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
1005   "*Text string to display as the sample text for `list-faces-display'.")
1006
1007
1008 ;; The name list-faces would be more consistent, but let's avoid a
1009 ;; conflict with Lucid, which uses that name differently.
1010
1011 (defun list-faces-display ()
1012   "List all faces, using the same sample text in each.
1013 The sample text is a string that comes from the variable
1014 `list-faces-sample-text'."
1015   (interactive)
1016   (let ((faces (sort (face-list) #'string-lessp))
1017         (face nil)
1018         (frame (selected-frame))
1019         disp-frame window face-name)
1020     (with-output-to-temp-buffer "*Faces*"
1021       (save-excursion
1022         (set-buffer standard-output)
1023         (setq truncate-lines t)
1024         (insert
1025          (substitute-command-keys
1026           (concat
1027            "Use "
1028            (if (display-mouse-p) "\\[help-follow-mouse] or ")
1029            "\\[help-follow] on a face name to customize it\n"
1030            "or on its sample text for a decription of the face.\n\n")))
1031         (setq help-xref-stack nil)
1032         (while faces
1033           (setq face (car faces))
1034           (setq faces (cdr faces))
1035           (setq face-name (symbol-name face))
1036           (insert (format "%25s " face-name))
1037           ;; Hyperlink to a customization buffer for the face.  Using
1038           ;; the help xref mechanism may not be the best way.
1039           (save-excursion
1040             (save-match-data
1041               (search-backward face-name)
1042               (help-xref-button 0 (lambda (f)
1043                                     (if help-xref-stack
1044                                         (pop help-xref-stack))
1045                                     (customize-face f))
1046                                 face-name
1047                                 "mouse-2: customize this face")))
1048           (let ((beg (point)))
1049             (insert list-faces-sample-text)
1050             ;; Hyperlink to a help buffer for the face.
1051             (save-excursion
1052               (save-match-data
1053                 (search-backward list-faces-sample-text)
1054                 (help-xref-button 0 #'describe-face face
1055                                   "mouse-2: describe this face")))
1056             (insert "\n")
1057             (put-text-property beg (1- (point)) 'face face)
1058             ;; If the sample text has multiple lines, line up all of them.
1059             (goto-char beg)
1060             (forward-line 1)
1061             (while (not (eobp))
1062               (insert "                          ")
1063               (forward-line 1))))
1064         (goto-char (point-min)))
1065       (print-help-return-message))
1066     ;; If the *Faces* buffer appears in a different frame,
1067     ;; copy all the face definitions from FRAME,
1068     ;; so that the display will reflect the frame that was selected.
1069     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1070     (setq disp-frame (if window (window-frame window)
1071                        (car (frame-list))))
1072     (or (eq frame disp-frame)
1073         (let ((faces (face-list)))
1074           (while faces
1075             (copy-face (car faces) (car faces) frame disp-frame)
1076             (setq faces (cdr faces)))))))
1077
1078
1079 (defun describe-face (face &optional frame)
1080   "Display the properties of face FACE on FRAME.
1081 If the optional argument FRAME is given, report on face FACE in that frame.
1082 If FRAME is t, report on the defaults for face FACE (for new frames).
1083 If FRAME is omitted or nil, use the selected frame."
1084   (interactive (list (read-face-name "Describe face")))
1085   (let* ((attrs '((:family . "Family")
1086                   (:width . "Width")
1087                   (:height . "Height")
1088                   (:weight . "Weight")
1089                   (:slant . "Slant")
1090                   (:foreground . "Foreground")
1091                   (:background . "Background")
1092                   (:underline . "Underline")
1093                   (:overline . "Overline")
1094                   (:strike-through . "Strike-through")
1095                   (:box . "Box")
1096                   (:inverse-video . "Inverse")
1097                   (:stipple . "Stipple")
1098                   (:font . "Font or fontset")
1099                   (:inherit . "Inherit")))
1100         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1101                                         attrs))))
1102     (with-output-to-temp-buffer "*Help*"
1103       (save-excursion
1104         (set-buffer standard-output)
1105         (dolist (a attrs)
1106           (let ((attr (face-attribute face (car a) frame)))
1107             (insert (make-string (- max-width (length (cdr a))) ?\ )
1108                     (cdr a) ": " (format "%s" attr) "\n")))
1109         (insert "\nDocumentation:\n\n"
1110                 (or (face-documentation face)
1111                     "not documented as a face."))
1112         (let ((customize-label "customize"))
1113           (terpri)
1114           (terpri)
1115           (princ (concat "You can " customize-label " this face."))
1116           (with-current-buffer "*Help*"
1117             (save-excursion
1118               (re-search-backward
1119                (concat "\\(" customize-label "\\)") nil t)
1120               (help-xref-button 1 #'customize-face face
1121                                 "mouse-2, RET: customize face")))))
1122       (print-help-return-message)
1123       (with-current-buffer "*Help*"
1124         (help-setup-xref (list #'describe-face face) (interactive-p))
1125         (buffer-string)))))
1126 \f
1127 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1128 ;;; Face specifications (defface).
1129 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1130
1131 ;; Parameter FRAME Is kept for call compatibility to with previous
1132 ;; face implementation.
1133
1134 (defun face-attr-construct (face &optional frame)
1135   "Return a defface-style attribute list for FACE on FRAME.
1136 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1137 face attributes of FACE where ATTRIBUTE is the attribute name and
1138 VALUE is the specified value of that attribute."
1139   (let (result)
1140     (dolist (entry face-attribute-name-alist result)
1141       (let* ((attribute (car entry))
1142              (value (face-attribute face attribute)))
1143         (unless (eq value 'unspecified)
1144           (setq result (nconc (list attribute value) result)))))))
1145
1146
1147 (defun face-spec-set-match-display (display frame)
1148   "Non-nil if DISPLAY matches FRAME.
1149 DISPLAY is part of a spec such as can be used in `defface'.
1150 If FRAME is nil, the current FRAME is used."
1151   (let* ((conjuncts display)
1152          conjunct req options
1153          ;; t means we have succeeded against all the conjuncts in
1154          ;; DISPLAY that have been tested so far.
1155          (match t))
1156     (if (eq conjuncts t)
1157         (setq conjuncts nil))
1158     (while (and conjuncts match)
1159       (setq conjunct (car conjuncts)
1160             conjuncts (cdr conjuncts)
1161             req (car conjunct)
1162             options (cdr conjunct)
1163             match (cond ((eq req 'type)
1164                          (or (memq window-system options)
1165                              ;; FIXME: This should be revisited to use
1166                              ;; display-graphic-p, provided that the
1167                              ;; color selection depends on the number
1168                              ;; of supported colors, and all defface's
1169                              ;; are changed to look at number of colors
1170                              ;; instead of (type graphic) etc.
1171                              (and (null window-system)
1172                                   (memq 'tty options))
1173                              (and (memq 'motif options)
1174                                   (featurep 'motif))
1175                              (and (memq 'lucid options)
1176                                   (featurep 'x-toolkit)
1177                                   (not (featurep 'motif)))
1178                              (and (memq 'x-toolkit options)
1179                                   (featurep 'x-toolkit))))
1180                         ((eq req 'class)
1181                          (memq (frame-parameter frame 'display-type) options))
1182                         ((eq req 'background)
1183                          (memq (frame-parameter frame 'background-mode)
1184                                options))
1185                         (t (error "Unknown req `%S' with options `%S'"
1186                                   req options)))))
1187     match))
1188
1189
1190 (defun face-spec-choose (spec &optional frame)
1191   "Choose the proper attributes for FRAME, out of SPEC.
1192 If SPEC is nil, return nil."
1193   (unless frame
1194     (setq frame (selected-frame)))
1195   (let ((tail spec)
1196         result)
1197     (while tail
1198       (let* ((entry (pop tail))
1199              (display (car entry))
1200              (attrs (cdr entry)))
1201         (when (face-spec-set-match-display display frame)
1202           (setq result (if (listp (car attrs))
1203                            ;; Old-style entry, the attribute list is the
1204                            ;; first element.
1205                            (car attrs)
1206                          attrs)
1207                 tail nil))))
1208     result))
1209
1210
1211 (defun face-spec-reset-face (face &optional frame)
1212   "Reset all attributes of FACE on FRAME to unspecified."
1213   (let ((attrs face-attribute-name-alist))
1214     (while attrs
1215       (let ((attr-and-name (car attrs)))
1216         (set-face-attribute face frame (car attr-and-name) 'unspecified))
1217       (setq attrs (cdr attrs)))))
1218
1219
1220 (defun face-spec-set (face spec &optional frame)
1221   "Set FACE's attributes according to the first matching entry in SPEC.
1222 FRAME is the frame whose frame-local face is set.  FRAME nil means
1223 do it on all frames.  See `defface' for information about SPEC.
1224 If SPEC is nil, do nothing."
1225   (let ((attrs (face-spec-choose spec frame)))
1226     (when attrs
1227       (face-spec-reset-face face frame))
1228     (while attrs
1229       (let ((attribute (car attrs))
1230             (value (car (cdr attrs))))
1231         ;; Support some old-style attribute names and values.
1232         (case attribute
1233           (:bold (setq attribute :weight value (if value 'bold 'normal)))
1234           (:italic (setq attribute :slant value (if value 'italic 'normal)))
1235           ((:foreground :background)
1236            ;; Compatibility with 20.x.  Some bogus face specs seem to
1237            ;; exist containing things like `:foreground nil'.
1238            (if (null value) (setq value 'unspecified)))
1239           (t (unless (assq attribute face-x-resources)
1240                (setq attribute nil))))
1241         (when attribute
1242           (set-face-attribute face frame attribute value)))
1243       (setq attrs (cdr (cdr attrs))))))
1244
1245
1246 (defun face-attr-match-p (face attrs &optional frame)
1247   "Return t if attributes of FACE match values in plist ATTRS.
1248 Optional parameter FRAME is the frame whose definition of FACE
1249 is used.  If nil or omitted, use the selected frame."
1250   (unless frame
1251     (setq frame (selected-frame)))
1252   (let ((list face-attribute-name-alist)
1253         (match t))
1254     (while (and match (not (null list)))
1255       (let* ((attr (car (car list)))
1256              (specified-value
1257               (if (plist-member attrs attr)
1258                   (plist-get attrs attr)
1259                 'unspecified))
1260              (value-now (face-attribute face attr frame)))
1261         (setq match (equal specified-value value-now))
1262         (setq list (cdr list))))
1263     match))
1264
1265 (defun face-spec-match-p (face spec &optional frame)
1266   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1267   (face-attr-match-p face (face-spec-choose spec frame) frame))
1268
1269 (defsubst face-default-spec (face)
1270   "Return the default face-spec for FACE, ignoring any user customization.
1271 If there is no default for FACE, return nil."
1272   (get face 'face-defface-spec))
1273
1274 (defsubst face-user-default-spec (face)
1275   "Return the user's customized face-spec for FACE, or the default if none.
1276 If there is neither a user setting or a default for FACE, return nil."
1277   (or (get face 'saved-face)
1278       (face-default-spec face)))
1279
1280 \f
1281 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1282 ;;; Frame-type independent color support.
1283 ;;; We keep the old x-* names as aliases for back-compatibility.
1284 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1285
1286 (defun defined-colors (&optional frame)
1287   "Return a list of colors supported for a particular frame.
1288 The argument FRAME specifies which frame to try.
1289 The value may be different for frames on different display types.
1290 If FRAME doesn't support colors, the value is nil."
1291   (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1292       (xw-defined-colors frame)
1293     (mapcar 'car (tty-color-alist frame))))
1294 (defalias 'x-defined-colors 'defined-colors)
1295
1296 (defun color-defined-p (color &optional frame)
1297   "Return non-nil if color COLOR is supported on frame FRAME.
1298 If FRAME is omitted or nil, use the selected frame.
1299 If COLOR is the symbol `unspecified' or one of the strings
1300 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1301   (if (member color '(unspecified "unspecified-bg" "unspecified-fg"))
1302       nil
1303     (if (member (framep (or frame (selected-frame))) '(x w32 mac))
1304         (xw-color-defined-p color frame)
1305       (numberp (tty-color-translate color frame)))))
1306 (defalias 'x-color-defined-p 'color-defined-p)
1307
1308 (defun color-values (color &optional frame)
1309   "Return a description of the color named COLOR on frame FRAME.
1310 The value is a list of integer RGB values--\(RED GREEN BLUE\).
1311 These values appear to range from 0 65535; white is \(65535 65535 65535\).
1312 If FRAME is omitted or nil, use the selected frame.
1313 If FRAME cannot display COLOR, the value is nil.
1314 If COLOR is the symbol `unspecified' or one of the strings
1315 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1316   (if (member color '(unspecified "unspecified-fg" "unspecified-bg"))
1317       nil
1318     (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1319         (xw-color-values color frame)
1320       (tty-color-values color frame))))
1321 (defalias 'x-color-values 'color-values)
1322
1323 (defun display-color-p (&optional display)
1324   "Return t if DISPLAY supports color.
1325 The optional argument DISPLAY specifies which display to ask about.
1326 DISPLAY should be either a frame or a display name (a string).
1327 If omitted or nil, that stands for the selected frame's display."
1328   (if (memq (framep-on-display display) '(x w32 mac))
1329       (xw-display-color-p display)
1330     (tty-display-color-p display)))
1331 (defalias 'x-display-color-p 'display-color-p)
1332
1333 (defun display-grayscale-p (&optional display)
1334   "Return non-nil if frames on DISPLAY can display shades of gray."
1335   (let ((frame-type (framep-on-display display)))
1336     (cond
1337      ((memq frame-type '(x w32 mac))
1338       (x-display-grayscale-p display))
1339      (t
1340       (> (tty-color-gray-shades display) 2)))))
1341
1342 \f
1343 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1344 ;;; Background mode.
1345 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1346
1347 (defcustom frame-background-mode nil
1348   "*The brightness of the background.
1349 Set this to the symbol `dark' if your background color is dark, `light' if
1350 your background is light, or nil (default) if you want Emacs to
1351 examine the brightness for you.  Don't set this variable with `setq';
1352 this won't have the expected effect."
1353   :group 'faces
1354   :set #'(lambda (var value)
1355            (set-default var value)
1356            (mapc 'frame-set-background-mode (frame-list)))
1357   :initialize 'custom-initialize-changed
1358   :type '(choice (choice-item dark)
1359                  (choice-item light)
1360                  (choice-item :tag "default" nil)))
1361
1362
1363 (defun frame-set-background-mode (frame)
1364   "Set up display-dependent faces on FRAME.
1365 Display-dependent faces are those which have different definitions
1366 according to the `background-mode' and `display-type' frame parameters."
1367   (let* ((bg-resource
1368           (and window-system
1369                (x-get-resource ".backgroundMode" "BackgroundMode")))
1370          (bg-color (frame-parameter frame 'background-color))
1371          (bg-mode
1372           (cond (frame-background-mode)
1373                 (bg-resource
1374                  (intern (downcase bg-resource)))
1375                 ((and (null window-system) (null bg-color))
1376                  ;; No way to determine this automatically (?).
1377                  'dark)
1378                 ;; Unspecified frame background color can only happen
1379                 ;; on tty's.
1380                 ((member bg-color '(unspecified "unspecified-bg"))
1381                  'dark)
1382                 ((equal bg-color "unspecified-fg") ; inverted colors
1383                  'light)
1384                 ((>= (apply '+ (x-color-values bg-color frame))
1385                     ;; Just looking at the screen, colors whose
1386                     ;; values add up to .6 of the white total
1387                     ;; still look dark to me.
1388                     (* (apply '+ (x-color-values "white" frame)) .6))
1389                  'light)
1390                 (t 'dark)))
1391          (display-type
1392           (cond ((null window-system)
1393                  (if (tty-display-color-p frame) 'color 'mono))
1394                 ((x-display-color-p frame)
1395                  'color)
1396                 ((x-display-grayscale-p frame)
1397                  'grayscale)
1398                 (t 'mono)))
1399          (old-bg-mode
1400           (frame-parameter frame 'background-mode))
1401          (old-display-type
1402           (frame-parameter frame 'display-type)))
1403
1404     (unless (and (eq bg-mode old-bg-mode) (eq display-type old-display-type))
1405       (let ((locally-modified-faces nil))
1406         ;; Before modifying the frame parameters, we collect a list of
1407         ;; faces that don't match what their face-spec says they should
1408         ;; look like; we then avoid changing these faces below.  A
1409         ;; negative list is used on the assumption that most faces will
1410         ;; be unmodified, so we can avoid consing in the common case.
1411         (dolist (face (face-list))
1412           (when (not (face-spec-match-p face
1413                                         (face-user-default-spec face)
1414                                         (selected-frame)))
1415             (push face locally-modified-faces)))
1416         ;; Now change to the new frame parameters
1417         (modify-frame-parameters frame
1418                                  (list (cons 'background-mode bg-mode)
1419                                        (cons 'display-type display-type)))
1420         ;; For all named faces, choose face specs matching the new frame
1421         ;; parameters, unless they have been locally modified.
1422         (dolist (face (face-list))
1423           (unless (memq face locally-modified-faces)
1424             (face-spec-set face (face-user-default-spec face) frame)))))))
1425
1426 \f
1427 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1428 ;;; Frame creation.
1429 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1430
1431 (defun x-handle-named-frame-geometry (parameters)
1432   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1433 Value is the new parameter list."
1434   (let* ((name (or (cdr (assq 'name parameters))
1435                    (cdr (assq 'name default-frame-alist))))
1436          (x-resource-name name)
1437          (res-geometry (if name (x-get-resource "geometry" "Geometry"))))
1438     (when res-geometry
1439       (let ((parsed (x-parse-geometry res-geometry)))
1440         ;; If the resource specifies a position, call the position
1441         ;; and size "user-specified".
1442         (when (or (assq 'top parsed)
1443                   (assq 'left parsed))
1444           (setq parsed (append '((user-position . t) (user-size . t)) parsed)))
1445         ;; Put the geometry parameters at the end.  Copy
1446         ;; default-frame-alist so that they go after it.
1447         (setq parameters (append parameters default-frame-alist parsed))))
1448     parameters))
1449
1450
1451 (defun x-handle-reverse-video (frame parameters)
1452   "Handle the reverse-video frame parameter and X resource.
1453 `x-create-frame' does not handle this one."
1454   (when (cdr (or (assq 'reverse parameters)
1455                  (assq 'reverse default-frame-alist)
1456                  (let ((resource (x-get-resource "reverseVideo"
1457                                                  "ReverseVideo")))
1458                    (if resource
1459                        (cons nil (member (downcase resource)
1460                                          '("on" "true")))))))
1461       (let* ((params (frame-parameters frame))
1462              (bg (cdr (assq 'foreground-color params)))
1463              (fg (cdr (assq 'background-color params))))
1464         (modify-frame-parameters frame
1465                                  (list (cons 'foreground-color fg)
1466                                        (cons 'background-color bg)))
1467         (if (equal bg (cdr (assq 'border-color params)))
1468             (modify-frame-parameters frame
1469                                      (list (cons 'border-color fg))))
1470         (if (equal bg (cdr (assq 'mouse-color params)))
1471             (modify-frame-parameters frame
1472                                      (list (cons 'mouse-color fg))))
1473         (if (equal bg (cdr (assq 'cursor-color params)))
1474             (modify-frame-parameters frame
1475                                      (list (cons 'cursor-color fg)))))))
1476
1477
1478 (defun x-create-frame-with-faces (&optional parameters)
1479   "Create a frame from optional frame parameters PARAMETERS.
1480 Parameters not specified by PARAMETERS are taken from
1481 `default-frame-alist'.  If PARAMETERS specify a frame name,
1482 handle X geometry resources for that name.  If either PARAMETERS
1483 or `default-frame-alist' contains a `reverse' parameter, or
1484 the X resource ``reverseVideo'' is present, handle that.
1485 Value is the new frame created."
1486   (setq parameters (x-handle-named-frame-geometry parameters))
1487   (let ((visibility-spec (assq 'visibility parameters))
1488         (frame-list (frame-list))
1489         (frame (x-create-frame (cons '(visibility . nil) parameters)))
1490         success)
1491     (unwind-protect
1492         (progn
1493           (x-handle-reverse-video frame parameters)
1494           (frame-set-background-mode frame)
1495           (face-set-after-frame-default frame)
1496           (if (or (null frame-list) (null visibility-spec))
1497               (make-frame-visible frame)
1498             (modify-frame-parameters frame (list visibility-spec)))
1499           (setq success t))
1500       (unless success
1501         (delete-frame frame)))
1502     frame))
1503
1504
1505 (defun face-set-after-frame-default (frame)
1506   "Set frame-local faces of FRAME from face specs and resources.
1507 Initialize colors of certain faces from frame parameters."
1508   (dolist (face (face-list))
1509     (face-spec-set face (face-user-default-spec face) frame)
1510     (internal-merge-in-global-face face frame)
1511     (when (and (memq window-system '(x w32 mac))
1512                (or (not (boundp 'inhibit-default-face-x-resources))
1513                    (not (eq face 'default))))
1514       (make-face-x-resource-internal face frame)))
1515
1516   ;; Initialize attributes from frame parameters.
1517   (let ((params '((foreground-color default :foreground)
1518                   (background-color default :background)
1519                   (border-color border :background)
1520                   (cursor-color cursor :background)
1521                   (scroll-bar-foreground scroll-bar :foreground)
1522                   (scroll-bar-background scroll-bar :background)
1523                   (mouse-color mouse :background))))
1524     (dolist (param params)
1525       (let ((frame-param (frame-parameter frame (nth 0 param)))
1526             (face (nth 1 param))
1527             (attr (nth 2 param)))
1528         (when (and frame-param
1529                    ;; Don't override face attributes explicitly
1530                    ;; specified for new frames.
1531                    (eq (face-attribute face attr t) 'unspecified))
1532           (set-face-attribute face frame attr frame-param))))))
1533
1534
1535 (defun tty-handle-reverse-video (frame parameters)
1536   "Handle the reverse-video frame parameter for terminal frames."
1537   (when (cdr (or (assq 'reverse parameters)
1538                  (assq 'reverse default-frame-alist)))
1539     (if (null window-system)
1540         (setq inverse-video t))
1541     (let* ((params (frame-parameters frame))
1542            (bg (cdr (assq 'foreground-color params)))
1543            (fg (cdr (assq 'background-color params))))
1544       (modify-frame-parameters frame
1545                                (list (cons 'foreground-color fg)
1546                                      (cons 'background-color bg)))
1547       (if (equal bg (cdr (assq 'mouse-color params)))
1548           (modify-frame-parameters frame
1549                                    (list (cons 'mouse-color fg))))
1550       (if (equal bg (cdr (assq 'cursor-color params)))
1551           (modify-frame-parameters frame
1552                                    (list (cons 'cursor-color fg)))))))
1553
1554
1555 (defun tty-create-frame-with-faces (&optional parameters)
1556   "Create a frame from optional frame parameters PARAMETERS.
1557 Parameters not specified by PARAMETERS are taken from
1558 `default-frame-alist'.  If either PARAMETERS or `default-frame-alist'
1559 contains a `reverse' parameter, handle that.  Value is the new frame
1560 created."
1561   (let ((frame (make-terminal-frame parameters))
1562         success)
1563     (unwind-protect
1564         (progn
1565           (tty-handle-reverse-video frame (frame-parameters frame))
1566           (frame-set-background-mode frame)
1567           (face-set-after-frame-default frame)
1568           (setq success t))
1569       (unless success
1570         (delete-frame frame)))
1571     frame))
1572
1573
1574 ;; Called from C function init_display to initialize faces of the
1575 ;; dumped terminal frame on startup.
1576
1577 (defun tty-set-up-initial-frame-faces ()
1578   (let ((frame (selected-frame)))
1579     (frame-set-background-mode frame)
1580     (face-set-after-frame-default frame)))
1581
1582
1583
1584 \f
1585 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1586 ;;; Compatiblity with 20.2
1587 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1588
1589 ;; Update a frame's faces when we change its default font.
1590
1591 (defalias 'frame-update-faces 'ignore)
1592 (make-obsolete 'frame-update-faces "No longer necessary" "21.1")
1593
1594 ;; Update the colors of FACE, after FRAME's own colors have been
1595 ;; changed.
1596
1597 (defalias 'frame-update-face-colors 'frame-set-background-mode)
1598 (make-obsolete 'frame-update-face-colors 'frame-set-background-mode "21.1")
1599
1600 \f
1601 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1602 ;;; Standard faces.
1603 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1604
1605 (defgroup basic-faces nil
1606   "The standard faces of Emacs."
1607   :group 'faces)
1608
1609
1610 (defface default
1611   '((t nil))
1612   "Basic default face."
1613   :group 'basic-faces)
1614
1615
1616 (defface mode-line
1617   '((((type x w32 mac) (class color))
1618      (:box (:line-width -1 :style released-button)
1619            :background "grey75" :foreground "black"))
1620     (t
1621      (:inverse-video t)))
1622   "Basic mode line face."
1623   :version "21.1"
1624   :group 'modeline
1625   :group 'basic-faces)
1626
1627 ;; Make `modeline' an alias for `mode-line', for compatibility.
1628 (put 'modeline 'face-alias 'mode-line)
1629
1630 (defface header-line
1631   '((((type tty))
1632      ;; This used to be `:inverse-video t', but that doesn't look very
1633      ;; good when combined with inverse-video mode-lines and multiple
1634      ;; windows.  Underlining looks better, and is more consistent with
1635      ;; the window-system face variants, which deemphasize the
1636      ;; header-line in relation to the mode-line face.  If a terminal
1637      ;; can't underline, then the header-line will end up without any
1638      ;; highlighting; this may be too confusing in general, although it
1639      ;; happens to look good with the only current use of header-lines,
1640      ;; the info browser. XXX
1641      :underline t)
1642     (((class color grayscale) (background light))
1643      :inherit mode-line
1644      :background "grey90" :foreground "grey20"
1645      :box nil)
1646     (((class color grayscale) (background dark))
1647      :inherit mode-line
1648      :background "grey20" :foreground "grey90"
1649      :box nil)
1650     (((class mono) (background light))
1651      :inherit mode-line
1652      :background "white" :foreground "black"
1653      :inverse-video nil
1654      :box nil
1655      :underline t)
1656     (((class mono) (background dark))
1657      :inherit mode-line
1658      :background "black" :foreground "white"
1659      :inverse-video nil
1660      :box nil
1661      :underline t)
1662     (t
1663      :inverse-video t))
1664   "Basic header-line face."
1665   :version "21.1"
1666   :group 'basic-faces)
1667
1668
1669 (defface tool-bar
1670   '((((type x w32 mac) (class color))
1671      (:box (:line-width 1 :style released-button)
1672            :background "grey75" :foreground "black"))
1673     (((type x) (class mono))
1674      (:box (:line-width 1 :style released-button)
1675            :background "grey" :foreground "black"))
1676     (t
1677      ()))
1678   "Basic tool-bar face."
1679   :version "21.1"
1680   :group 'basic-faces)
1681
1682
1683 (defface region
1684   '((((type tty) (class color))
1685      (:background "blue" :foreground "white"))
1686     (((type tty) (class mono))
1687      (:inverse-video t))
1688     (((class color) (background dark))
1689      (:background "blue3"))
1690     (((class color) (background light))
1691      (:background "light goldenrod yellow"))
1692     (t (:background "gray")))
1693   "Basic face for highlighting the region."
1694   :version "21.1"
1695   :group 'basic-faces)
1696
1697
1698 (defface fringe
1699   '((((class color) (background light))
1700        (:background "grey95"))
1701       (((class color) (background dark))
1702        (:background "grey10"))
1703       (t
1704        (:background "gray")))
1705   "Basic face for the fringes to the left and right of windows under X."
1706   :version "21.1"
1707   :group 'frames
1708   :group 'basic-faces)
1709
1710
1711 (defface scroll-bar '()
1712   "Basic face for the scroll bar colors under X."
1713   :version "21.1"
1714   :group 'frames
1715   :group 'basic-faces)
1716
1717
1718 (defface menu
1719   '((((type tty))
1720      :inverse-video t)
1721     (((type x-toolkit))
1722      )
1723     (t
1724      :inverse-video t))
1725   "Basic menu face."
1726   :version "21.1"
1727   :group 'menu
1728   :group 'basic-faces)
1729
1730
1731 (defface border '()
1732   "Basic face for the frame border under X."
1733   :version "21.1"
1734   :group 'frames
1735   :group 'basic-faces)
1736
1737
1738 (defface cursor '()
1739   "Basic face for the cursor color under X."
1740   :version "21.1"
1741   :group 'cursor
1742   :group 'basic-faces)
1743
1744
1745 (defface mouse '()
1746   "Basic face for the mouse color under X."
1747   :version "21.1"
1748   :group 'mouse
1749   :group 'basic-faces)
1750
1751
1752 (defface bold '((t (:weight bold)))
1753   "Basic bold face."
1754   :group 'basic-faces)
1755
1756
1757 (defface italic '((t (:slant italic)))
1758   "Basic italic font."
1759   :group 'basic-faces)
1760
1761
1762 (defface bold-italic '((t (:weight bold :slant italic)))
1763   "Basic bold-italic face."
1764   :group 'basic-faces)
1765
1766
1767 (defface underline '((t (:underline t)))
1768   "Basic underlined face."
1769   :group 'basic-faces)
1770
1771
1772 (defface highlight
1773   '((((type tty) (class color))
1774      (:background "green"))
1775     (((class color) (background light))
1776      (:background "darkseagreen2"))
1777     (((class color) (background dark))
1778      (:background "darkolivegreen"))
1779     (t (:inverse-video t)))
1780   "Basic face for highlighting."
1781   :group 'basic-faces)
1782
1783
1784 (defface secondary-selection
1785   '((((type tty) (class color))
1786      (:background "cyan" :foreground "black"))
1787     (((class color) (background light))
1788      (:background "yellow"))
1789     (((class color) (background dark))
1790      (:background "SkyBlue4"))
1791     (t (:inverse-video t)))
1792   "Basic face for displaying the secondary selection."
1793   :group 'basic-faces)
1794
1795
1796 (defface fixed-pitch '((t (:family "courier")))
1797   "The basic fixed-pitch face."
1798   :group 'basic-faces)
1799
1800
1801 (defface variable-pitch '((t (:family "helv")))
1802   "The basic variable-pitch face."
1803   :group 'basic-faces)
1804
1805
1806 (defface trailing-whitespace
1807   '((((class color) (background light))
1808      (:background "red"))
1809     (((class color) (background dark))
1810      (:background "red"))
1811     (t (:inverse-video t)))
1812   "Basic face for highlighting trailing whitespace."
1813   :version "21.1"
1814   :group 'font-lock                     ; like `show-trailing-whitespace'
1815   :group 'basic-faces)
1816
1817
1818 \f
1819 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1820 ;;; Manipulating font names.
1821 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1822
1823 ;; This is here for compatibilty with Emacs 20.2.  For example,
1824 ;; international/fontset.el uses x-resolve-font-name.  The following
1825 ;; functions are not used in the face implementation itself.
1826
1827 (defvar x-font-regexp nil)
1828 (defvar x-font-regexp-head nil)
1829 (defvar x-font-regexp-weight nil)
1830 (defvar x-font-regexp-slant nil)
1831
1832 (defconst x-font-regexp-weight-subnum 1)
1833 (defconst x-font-regexp-slant-subnum 2)
1834 (defconst x-font-regexp-swidth-subnum 3)
1835 (defconst x-font-regexp-adstyle-subnum 4)
1836
1837 ;;; Regexps matching font names in "Host Portable Character Representation."
1838 ;;;
1839 (let ((-                "[-?]")
1840       (foundry          "[^-]+")
1841       (family           "[^-]+")
1842       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
1843 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
1844       (weight\?         "\\([^-]*\\)")                                  ; 1
1845       (slant            "\\([ior]\\)")                                  ; 2
1846 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
1847       (slant\?          "\\([^-]?\\)")                                  ; 2
1848 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
1849       (swidth           "\\([^-]*\\)")                                  ; 3
1850 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
1851       (adstyle          "\\([^-]*\\)")                                  ; 4
1852       (pixelsize        "[0-9]+")
1853       (pointsize        "[0-9][0-9]+")
1854       (resx             "[0-9][0-9]+")
1855       (resy             "[0-9][0-9]+")
1856       (spacing          "[cmp?*]")
1857       (avgwidth         "[0-9]+")
1858       (registry         "[^-]+")
1859       (encoding         "[^-]+")
1860       )
1861   (setq x-font-regexp
1862         (concat "\\`\\*?[-?*]"
1863                 foundry - family - weight\? - slant\? - swidth - adstyle -
1864                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
1865                 registry - encoding "\\*?\\'"
1866                 ))
1867   (setq x-font-regexp-head
1868         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
1869                 "\\([-*?]\\|\\'\\)"))
1870   (setq x-font-regexp-slant (concat - slant -))
1871   (setq x-font-regexp-weight (concat - weight -))
1872   nil)
1873
1874
1875 (defun x-resolve-font-name (pattern &optional face frame)
1876   "Return a font name matching PATTERN.
1877 All wildcards in PATTERN are instantiated.
1878 If PATTERN is nil, return the name of the frame's base font, which never
1879 contains wildcards.
1880 Given optional arguments FACE and FRAME, return a font which is
1881 also the same size as FACE on FRAME, or fail."
1882   (or (symbolp face)
1883       (setq face (face-name face)))
1884   (and (eq frame t)
1885        (setq frame nil))
1886   (if pattern
1887       ;; Note that x-list-fonts has code to handle a face with nil as its font.
1888       (let ((fonts (x-list-fonts pattern face frame 1)))
1889         (or fonts
1890             (if face
1891                 (if (string-match "\\*" pattern)
1892                     (if (null (face-font face))
1893                         (error "No matching fonts are the same height as the frame default font")
1894                       (error "No matching fonts are the same height as face `%s'" face))
1895                   (if (null (face-font face))
1896                       (error "Height of font `%s' doesn't match the frame default font"
1897                              pattern)
1898                     (error "Height of font `%s' doesn't match face `%s'"
1899                            pattern face)))
1900               (error "No fonts match `%s'" pattern)))
1901         (car fonts))
1902     (cdr (assq 'font (frame-parameters (selected-frame))))))
1903
1904
1905 (defun x-frob-font-weight (font which)
1906   (let ((case-fold-search t))
1907     (cond ((string-match x-font-regexp font)
1908            (concat (substring font 0
1909                               (match-beginning x-font-regexp-weight-subnum))
1910                    which
1911                    (substring font (match-end x-font-regexp-weight-subnum)
1912                               (match-beginning x-font-regexp-adstyle-subnum))
1913                    ;; Replace the ADD_STYLE_NAME field with *
1914                    ;; because the info in it may not be the same
1915                    ;; for related fonts.
1916                    "*"
1917                    (substring font (match-end x-font-regexp-adstyle-subnum))))
1918           ((string-match x-font-regexp-head font)
1919            (concat (substring font 0 (match-beginning 1)) which
1920                    (substring font (match-end 1))))
1921           ((string-match x-font-regexp-weight font)
1922            (concat (substring font 0 (match-beginning 1)) which
1923                    (substring font (match-end 1)))))))
1924 (make-obsolete 'x-frob-font-weight 'make-face-... "21.1")
1925
1926 (defun x-frob-font-slant (font which)
1927   (let ((case-fold-search t))
1928     (cond ((string-match x-font-regexp font)
1929            (concat (substring font 0
1930                               (match-beginning x-font-regexp-slant-subnum))
1931                    which
1932                    (substring font (match-end x-font-regexp-slant-subnum)
1933                               (match-beginning x-font-regexp-adstyle-subnum))
1934                    ;; Replace the ADD_STYLE_NAME field with *
1935                    ;; because the info in it may not be the same
1936                    ;; for related fonts.
1937                    "*"
1938                    (substring font (match-end x-font-regexp-adstyle-subnum))))
1939           ((string-match x-font-regexp-head font)
1940            (concat (substring font 0 (match-beginning 2)) which
1941                    (substring font (match-end 2))))
1942           ((string-match x-font-regexp-slant font)
1943            (concat (substring font 0 (match-beginning 1)) which
1944                    (substring font (match-end 1)))))))
1945 (make-obsolete 'x-frob-font-slant 'make-face-... "21.1")
1946
1947 (defun x-make-font-bold (font)
1948   "Given an X font specification, make a bold version of it.
1949 If that can't be done, return nil."
1950   (x-frob-font-weight font "bold"))
1951 (make-obsolete 'x-make-font-bold 'make-face-bold "21.1")
1952
1953 (defun x-make-font-demibold (font)
1954   "Given an X font specification, make a demibold version of it.
1955 If that can't be done, return nil."
1956   (x-frob-font-weight font "demibold"))
1957 (make-obsolete 'x-make-font-demibold 'make-face-bold "21.1")
1958
1959 (defun x-make-font-unbold (font)
1960   "Given an X font specification, make a non-bold version of it.
1961 If that can't be done, return nil."
1962   (x-frob-font-weight font "medium"))
1963 (make-obsolete 'x-make-font-unbold 'make-face-unbold "21.1")
1964
1965 (defun x-make-font-italic (font)
1966   "Given an X font specification, make an italic version of it.
1967 If that can't be done, return nil."
1968   (x-frob-font-slant font "i"))
1969 (make-obsolete 'x-make-font-italic 'make-face-italic "21.1")
1970
1971 (defun x-make-font-oblique (font) ; you say tomayto...
1972   "Given an X font specification, make an oblique version of it.
1973 If that can't be done, return nil."
1974   (x-frob-font-slant font "o"))
1975 (make-obsolete 'x-make-font-oblique 'make-face-italic "21.1")
1976
1977 (defun x-make-font-unitalic (font)
1978   "Given an X font specification, make a non-italic version of it.
1979 If that can't be done, return nil."
1980   (x-frob-font-slant font "r"))
1981 (make-obsolete 'x-make-font-unitalic 'make-face-unitalic "21.1")
1982
1983 (defun x-make-font-bold-italic (font)
1984   "Given an X font specification, make a bold and italic version of it.
1985 If that can't be done, return nil."
1986   (and (setq font (x-make-font-bold font))
1987        (x-make-font-italic font)))
1988 (make-obsolete 'x-make-font-bold-italic 'make-face-bold-italic "21.1")
1989
1990 (provide 'faces)
1991
1992 ;;; faces.el ends here