lisp/obsolete/mailpost.el

   1 ;;; mailpost.el --- RMAIL coupler to /usr/uci/post mailer
   2
   3 ;; This is in the public domain
   4 ;; since Delp distributed it in 1986 without a copyright notice.
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; Author: Gary Delp <delp@huey.Udel.Edu>
   9 ;; Maintainer: emacs-devel@gnu.org
  10 ;; Created: 13 Jan 1986
  11 ;; Keywords: mail
  12 ;; Obsolete-since: 24.3
  13
  14 ;;; Commentary:
  15
  16 ;; Yet another mail interface.  this for the rmail system to provide
  17 ;;  the missing sendmail interface on systems without /usr/lib/sendmail,
  18 ;;   but with /usr/uci/post.
  19
  20 ;;; Code:
  21
  22 (require 'mailalias)
  23 (require 'sendmail)
  24
  25 ;; (setq send-mail-function 'post-mail-send-it)
  26
  27 (defun post-mail-send-it ()
  28   "The MH -post interface for `rmail-mail' to call.
  29 To use it, include \"(setq send-mail-function 'post-mail-send-it)\" in
  30 site-init."
  31   (let ((errbuf (if mail-interactive
  32                     (generate-new-buffer " post-mail errors")
  33                   0))
  34         temfile
  35         (tembuf (generate-new-buffer " post-mail temp"))
  36         (case-fold-search nil)
  37         delimline
  38         (mailbuf (current-buffer)))
  39     (unwind-protect
  40         (with-current-buffer tembuf
  41           (erase-buffer)
  42           (insert-buffer-substring mailbuf)
  43           (goto-char (point-max))
  44           ;; require one newline at the end.
  45           (or (= (preceding-char) ?\n)
  46               (insert ?\n))
  47           ;; Change header-delimiter to be what post-mail expects.
  48           (mail-sendmail-undelimit-header)
  49           (setq delimline (point-marker))
  50           (if mail-aliases
  51               (expand-mail-aliases (point-min) delimline))
  52           (goto-char (point-min))
  53           ;; ignore any blank lines in the header
  54           (while (and (re-search-forward "\n\n\n*" delimline t)
  55                       (< (point) delimline))
  56             (replace-match "\n"))
  57           ;; Find and handle any FCC fields.
  58           (let ((case-fold-search t))
  59             (goto-char (point-min))
  60             (if (re-search-forward "^FCC:" delimline t)
  61                 (mail-do-fcc delimline))
  62             ;; If there is a From and no Sender, put it a Sender.
  63             (goto-char (point-min))
  64             (and (re-search-forward "^From:"  delimline t)
  65                  (not (save-excursion
  66                         (goto-char (point-min))
  67                         (re-search-forward "^Sender:" delimline t)))
  68                  (progn
  69                    (forward-line 1)
  70                    (insert "Sender: " (user-login-name) "\n")))
  71             ;; don't send out a blank subject line
  72             (goto-char (point-min))
  73             (if (re-search-forward "^Subject:[ \t]*\n" delimline t)
  74                 (replace-match ""))
  75             (if mail-interactive
  76                 (with-current-buffer errbuf
  77                   (erase-buffer))))
  78           (with-file-modes 384 (setq temfile (make-temp-file ",rpost")))
  79           (apply 'call-process
  80                  (append (list (if (boundp 'post-mail-program)
  81                                    post-mail-program
  82                                  "/usr/uci/lib/mh/post")
  83                                nil errbuf nil
  84                                "-nofilter" "-msgid")
  85                          (if mail-interactive '("-watch") '("-nowatch"))
  86                          (list temfile)))
  87           (if mail-interactive
  88               (with-current-buffer errbuf
  89                 (goto-char (point-min))
  90                 (while (re-search-forward "\n\n* *" nil t)
  91                   (replace-match "; "))
  92                 (if (not (zerop (buffer-size)))
  93                     (error "Sending...failed to %s"
  94                            (buffer-substring (point-min) (point-max)))))))
  95       (kill-buffer tembuf)
  96       (if (bufferp errbuf)
  97           (switch-to-buffer errbuf)))))
  98
  99 (provide 'mailpost)
 100
 101 ;;; mailpost.el ends here