configure.in

   1 dnl This is an autoconf script.
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 AC_PREREQ(2.0)dnl
   6 AC_INIT(src/lisp.h)
   7 AC_CONFIG_HEADER(src/config.h)
   8
   9 bindir='${exec_prefix}/bin'
  10 datadir='${prefix}/share'
  11 sharedstatedir='${prefix}/com'
  12 libexecdir='${exec_prefix}/libexec'
  13 mandir='${prefix}/man/man1'
  14 infodir='${prefix}/info'
  15 lispdir='${datadir}/emacs/${version}/lisp'
  16 locallisppath='${datadir}/emacs/site-lisp'
  17 lisppath='${locallisppath}:${lispdir}'
  18 etcdir='${datadir}/emacs/${version}/etc'
  19 lockdir='${sharedstatedir}/emacs/lock'
  20 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  21 docdir='${datadir}/emacs/${version}/etc'
  22
  23 AC_ARG_WITH(gcc,
  24 [  --with-gcc              Use GCC to compile Emacs])
  25 AC_ARG_WITH(x-toolkit,
  26 [  --with-x-toolkit=KIT    Use an X toolkit (KIT = yes/lucid/athena/motif)],
  27 [         case "${withval}" in
  28             y | ye | yes )      val=athena ;;
  29             n | no )            val=no  ;;
  30             l | lu | luc | luci | lucid )       val=lucid ;;
  31             a | at | ath | athe | athena )      val=athena ;;
  32             m | mo | mot | moti | motif )       val=motif ;;
  33 dnl These don't currently work.
  34 dnl         o | op | ope | open | open- | open-l | open-lo \
  35 dnl             | open-loo | open-look )        val=open-look ;;
  36             * )
  37 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
  38 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
  39 AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
  40 which is \`yes', \`no', \`lucid', \`athena', or \`motif'.
  41 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
  42             ;;
  43           esac
  44           with_x_toolkit=$val
  45 ])
  46
  47 #### Make srcdir absolute, if it isn't already.  It's important to
  48 #### avoid running the path through pwd unnecessary, since pwd can
  49 #### give you automounter prefixes, which can go away.  We do all this
  50 #### so Emacs can find its files when run uninstalled.
  51 case "${srcdir}" in
  52   /* ) ;;
  53   . )
  54     ## We may be able to use the $PWD environment variable to make this
  55     ## absolute.  But sometimes PWD is inaccurate.
  56     if test "${PWD}" != "" && test "`(cd ${PWD} ; sh -c pwd)`" = "`pwd`"  ;
  57     then
  58       srcdir="$PWD"
  59     else
  60       srcdir="`(cd ${srcdir}; pwd)`"
  61     fi
  62   ;;
  63   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
  64 esac
  65
  66 #### Check if the source directory already has a configured system in it.
  67 if test `pwd` != `(cd ${srcdir} && pwd)` \
  68    && test -f "${srcdir}/src/config.h" ; then
  69   AC_MSG_WARN([The directory tree \`${srcdir}' is being used
  70    as a build directory right now; it has been configured in its own
  71    right.  To configure in another directory as well, you MUST
  72    use GNU make.  If you do not have GNU make, then you must
  73    now do \`make distclean' in ${srcdir},
  74    and then run $0 again.])
  75
  76 changequote(, )dnl
  77   extrasub='/^VPATH[     ]*=/c\
  78 changequote([, ])dnl
  79 vpath %.c $(srcdir)\
  80 vpath %.h $(srcdir)\
  81 vpath %.y $(srcdir)\
  82 vpath %.l $(srcdir)\
  83 vpath %.s $(srcdir)\
  84 vpath %.in $(srcdir)'
  85 fi
  86
  87 #### Given the configuration name, set machfile and opsysfile to the
  88 #### names of the m/*.h and s/*.h files we should use.
  89
  90 ### Canonicalize the configuration name.
  91
  92 AC_CANONICAL_HOST
  93 canonical=$host
  94 configuration=$host_alias
  95
  96 changequote(, )dnl
  97
  98 ### If you add support for a new configuration, add code to this
  99 ### switch statement to recognize your configuration name and select
 100 ### the appropriate operating system and machine description files.
 101
 102 ### You would hope that you could choose an m/*.h file pretty much
 103 ### based on the machine portion of the configuration name, and an s-
 104 ### file based on the operating system portion.  However, it turns out
 105 ### that each m/*.h file is pretty manufacturer-specific - for
 106 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
 107 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
 108 ### machines.  So we basically have to have a special case for each
 109 ### configuration name.
 110 ###
 111 ### As far as handling version numbers on operating systems is
 112 ### concerned, make sure things will fail in a fixable way.  If
 113 ### /etc/MACHINES doesn't say anything about version numbers, be
 114 ### prepared to handle anything reasonably.  If version numbers
 115 ### matter, be sure /etc/MACHINES says something about it.
 116 ###
 117 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 118 ### "System V Release 4"; he writes, "The old convention encouraged
 119 ### confusion between `system' and `release' levels'."
 120
 121 machine='' opsys='' unported=no
 122 case "${canonical}" in
 123
 124   ## NetBSD ports
 125   *-*-netbsd* )
 126     opsys=netbsd
 127     case "${canonical}" in
 128       i[345]86-*-netbsd*) machine=intel386 ;;
 129       m68k-*-netbsd*)
 130                         # This is somewhat bogus.
 131                         machine=hp9000s300 ;;
 132       mips-*-netbsd*)   machine=pmax ;;
 133       ns32k-*-netbsd*)  machine=ns32000 ;;
 134       sparc-*-netbsd*)  machine=sparc ;;
 135     esac
 136   ;;
 137
 138   ## Acorn RISCiX:
 139   arm-acorn-riscix1.1* )
 140     machine=acorn opsys=riscix1-1
 141   ;;
 142   arm-acorn-riscix1.2* | arm-acorn-riscix )
 143     machine=acorn opsys=riscix1-2
 144   ;;
 145
 146   ## Alliant machines
 147   ## Strictly speaking, we need the version of the alliant operating
 148   ## system to choose the right machine file, but currently the
 149   ## configuration name doesn't tell us enough to choose the right
 150   ## one; we need to give alliants their own operating system name to
 151   ## do this right.  When someone cares, they can help us.
 152   fx80-alliant-* )
 153     machine=alliant4 opsys=bsd4-2
 154   ;;
 155   i860-alliant-* )
 156     machine=alliant-2800 opsys=bsd4-3
 157   ;;
 158
 159   alpha-dec-osf* )
 160     machine=alpha opsys=osf1
 161   ;;
 162
 163   ## Altos 3068
 164   m68*-altos-sysv* )
 165     machine=altos opsys=usg5-2
 166   ;;
 167
 168   ## Amdahl UTS
 169   580-amdahl-sysv* )
 170     machine=amdahl opsys=usg5-2-2
 171   ;;
 172
 173   ## Appallings - I mean, Apollos - running Domain
 174   m68*-apollo* )
 175     machine=apollo opsys=bsd4-2
 176   ;;
 177
 178   ## AT&T 3b2, 3b5, 3b15, 3b20
 179   we32k-att-sysv* )
 180     machine=att3b opsys=usg5-2-2
 181   ;;
 182
 183   ## AT&T 3b1 - The Mighty Unix PC!
 184   m68*-att-sysv* )
 185     machine=7300 opsys=usg5-2-2
 186   ;;
 187
 188   ## Bull dpx20
 189   rs6000-bull-bosx* )
 190     machine=ibmrs6000 opsys=aix3-2
 191   ;;
 192
 193   ## Bull dpx2
 194   m68*-bull-sysv3* )
 195     machine=dpx2 opsys=usg5-3
 196   ;;
 197
 198   ## Bull sps7
 199   m68*-bull-sysv2* )
 200     machine=sps7 opsys=usg5-2
 201   ;;
 202
 203   ## CCI 5/32, 6/32 -- see "Tahoe".
 204
 205   ## Celerity
 206   ## I don't know what configuration name to use for this; config.sub
 207   ## doesn't seem to know anything about it.  Hey, Celerity users, get
 208   ## in touch with us!
 209   celerity-celerity-bsd* )
 210     machine=celerity opsys=bsd4-2
 211   ;;
 212
 213   ## Clipper
 214   ## What operating systems does this chip run that Emacs has been
 215   ## tested on?
 216   clipper-* )
 217     machine=clipper
 218     ## We'll use the catch-all code at the bottom to guess the
 219     ## operating system.
 220   ;;
 221
 222   ## Convex
 223   *-convex-bsd* | *-convex-convexos* )
 224     machine=convex opsys=bsd4-3
 225     ## Prevents suprious white space in makefiles - d.m.cooke@larc.nasa.gov
 226     NON_GNU_CPP="cc -E -P"
 227   ;;
 228
 229   ## Cubix QBx/386
 230   i[345]86-cubix-sysv* )
 231     machine=intel386 opsys=usg5-3
 232   ;;
 233
 234   ## Cydra 5
 235   cydra*-cydrome-sysv* )
 236     machine=cydra5 opsys=usg5-3
 237   ;;
 238
 239   ## Data General AViiON Machines
 240   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
 241     machine=aviion opsys=dgux5-4r3
 242   ;;
 243   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
 244     machine=aviion opsys=dgux5-4r2
 245   ;;
 246   m88k-dg-dgux* )
 247     machine=aviion opsys=dgux
 248   ;;
 249
 250   ## DECstations
 251   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 252     machine=pmax opsys=bsd4-2
 253   ;;
 254   mips-dec-ultrix* | mips-dec-bsd* )
 255     machine=pmax opsys=bsd4-3
 256   ;;
 257   mips-dec-osf* )
 258     machine=pmax opsys=osf1
 259   ;;
 260
 261   ## Motorola Delta machines
 262   m68k-motorola-sysv* | m68000-motorola-sysv* )
 263     machine=delta opsys=usg5-3
 264     if test -z "`type gnucc | grep 'not found'`"
 265     then CC=gnucc
 266     else
 267       if test -z "`type gcc | grep 'not found'`"
 268       then CC=gcc
 269       else CC=cc
 270       fi
 271     fi
 272   ;;
 273   m88k-motorola-sysv4* )
 274     machine=delta88k opsys=usg5-4
 275   ;;
 276   m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
 277     machine=delta88k opsys=usg5-3
 278   ;;
 279
 280   ## Dual machines
 281   m68*-dual-sysv* )
 282     machine=dual opsys=usg5-2
 283   ;;
 284   m68*-dual-uniplus* )
 285     machine=dual opsys=unipl5-2
 286   ;;
 287
 288   ## Elxsi 6400
 289   elxsi-elxsi-sysv* )
 290     machine=elxsi opsys=usg5-2
 291   ;;
 292
 293   ## Encore machines
 294   ns16k-encore-bsd* )
 295     machine=ns16000 opsys=umax
 296   ;;
 297
 298   ## The GEC 93 - apparently, this port isn't really finished yet.
 299
 300   ## Gould Power Node and NP1
 301   pn-gould-bsd4.2* )
 302     machine=gould opsys=bsd4-2
 303   ;;
 304   pn-gould-bsd4.3* )
 305     machine=gould opsys=bsd4-3
 306   ;;
 307   np1-gould-bsd* )
 308     machine=gould-np1 opsys=bsd4-3
 309   ;;
 310
 311   ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
 312   ## as far as Emacs is concerned).
 313   m88k-harris-cxux* )
 314     # Build needs to be different on 7.0 and later releases
 315     case "`uname -r`" in
 316        [56].[0-9] ) machine=nh4000 opsys=cxux ;;
 317        [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
 318     esac
 319   ;;
 320   ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
 321   m68k-harris-cxux* )
 322     machine=nh3000 opsys=cxux
 323   ;;
 324
 325   ## Honeywell XPS100
 326   xps*-honeywell-sysv* )
 327     machine=xps100 opsys=usg5-2
 328   ;;
 329
 330   ## HP 9000 series 200 or 300
 331   m68*-hp-bsd* )
 332     machine=hp9000s300 opsys=bsd4-3
 333   ;;
 334   ## HP/UX 7, 8 and 9 are supported on these machines.
 335   m68*-hp-hpux* )
 336     case "`uname -r`" in
 337       ## Someone's system reports A.B8.05 for this.
 338       ## I wonder what other possibilities there are.
 339       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 340       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 341       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 342       *) machine=hp9000s300 opsys=hpux ;;
 343     esac
 344   ;;
 345
 346   ## HP 9000 series 700 and 800, running HP/UX
 347   hppa*-hp-hpux7* )
 348     machine=hp800 opsys=hpux
 349   ;;
 350   hppa*-hp-hpux8* )
 351     machine=hp800 opsys=hpux8
 352   ;;
 353   hppa*-hp-hpux9shr* )
 354     machine=hp800 opsys=hpux9shr
 355   ;;
 356   hppa*-hp-hpux9* )
 357     machine=hp800 opsys=hpux9
 358   ;;
 359
 360   ## HP 9000 series 700 and 800, running HP/UX
 361   hppa*-hp-hpux* )
 362     ## Cross-compilation?  Nah!
 363     case "`uname -r`" in
 364       ## Someone's system reports A.B8.05 for this.
 365       ## I wonder what other possibilities there are.
 366       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 367       *.08.* ) machine=hp800 opsys=hpux8 ;;
 368       *.09.* ) machine=hp800 opsys=hpux9 ;;
 369       *) machine=hp800 opsys=hpux ;;
 370     esac
 371   ;;
 372
 373   ## Orion machines
 374   orion-orion-bsd* )
 375     machine=orion opsys=bsd4-2
 376   ;;
 377   clipper-orion-bsd* )
 378     machine=orion105 opsys=bsd4-2
 379   ;;
 380
 381   ## IBM machines
 382   i[345]86-ibm-aix1.1* )
 383     machine=ibmps2-aix opsys=usg5-2-2
 384   ;;
 385   i[345]86-ibm-aix1.[23]* | i[345]86-ibm-aix* )
 386     machine=ibmps2-aix opsys=usg5-3
 387   ;;
 388   i370-ibm-aix*)
 389     machine=ibm370aix opsys=usg5-3
 390   ;;
 391   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 392     machine=ibmrs6000 opsys=aix3-1
 393   ;;
 394   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 395     machine=ibmrs6000 opsys=aix3-2-5
 396   ;;
 397   rs6000-ibm-aix* | powerpc-ibm-aix* )
 398     machine=ibmrs6000 opsys=aix3-2
 399   ;;
 400   romp-ibm-bsd4.3* )
 401     machine=ibmrt opsys=bsd4-3
 402   ;;
 403   romp-ibm-bsd4.2* )
 404     machine=ibmrt opsys=bsd4-2
 405   ;;
 406   romp-ibm-aos4.3* )
 407     machine=ibmrt opsys=bsd4-3
 408   ;;
 409   romp-ibm-aos4.2* )
 410     machine=ibmrt opsys=bsd4-2
 411   ;;
 412   romp-ibm-aos* )
 413     machine=ibmrt opsys=bsd4-3
 414   ;;
 415   romp-ibm-bsd* )
 416     machine=ibmrt opsys=bsd4-3
 417   ;;
 418   romp-ibm-aix* )
 419     machine=ibmrt-aix opsys=usg5-2-2
 420   ;;
 421
 422   ## Integrated Solutions `Optimum V'
 423   m68*-isi-bsd4.2* )
 424     machine=isi-ov opsys=bsd4-2
 425   ;;
 426   m68*-isi-bsd4.3* )
 427     machine=isi-ov opsys=bsd4-3
 428   ;;
 429
 430   ## Intel 386 machines where we do care about the manufacturer
 431   i[345]86-intsys-sysv* )
 432     machine=is386 opsys=usg5-2-2
 433   ;;
 434
 435   ## Prime EXL
 436   i[345]86-prime-sysv* )
 437     machine=i386 opsys=usg5-3
 438   ;;
 439
 440   ## Sequent Symmetry running Dynix
 441   i[345]86-sequent-bsd* )
 442     machine=symmetry opsys=bsd4-3
 443   ;;
 444
 445   ## Sequent Symmetry running DYNIX/ptx
 446   ## Use the old cpp rather than the newer ANSI one.
 447   i[345]86-sequent-ptx* )
 448     machine=sequent-ptx opsys=ptx
 449     NON_GNU_CPP="/lib/cpp"
 450   ;;
 451
 452   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 453   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 454   i[345]86-ncr-sysv* )
 455     machine=intel386 opsys=usg5-4-2
 456   ;;
 457
 458   ## Intel 860
 459   i860-*-sysv4* )
 460     machine=i860 opsys=usg5-4
 461     NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
 462     NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
 463   ;;
 464
 465   ## Masscomp machines
 466   m68*-masscomp-rtu* )
 467     machine=masscomp opsys=rtu
 468   ;;
 469
 470   ## Megatest machines
 471   m68*-megatest-bsd* )
 472     machine=mega68 opsys=bsd4-2
 473   ;;
 474
 475   ## Workstations sold by MIPS
 476   ## This is not necessarily all workstations using the MIPS processor -
 477   ## Irises are produced by SGI, and DECstations by DEC.
 478
 479   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 480   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 481   ## it gives for choosing between the alternatives seems to be "Use
 482   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 483   ## the BSD world."  I'll assume that these are instructions for
 484   ## handling two odd situations, and that every other situation
 485   ## should use mips.h and usg5-2-2, they being listed first.
 486   mips-mips-usg* )
 487     machine=mips4
 488     ## Fall through to the general code at the bottom to decide on the OS.
 489   ;;
 490   mips-mips-riscos4* )
 491     machine=mips4 opsys=bsd4-3
 492     NON_GNU_CC="cc -systype bsd43"
 493     NON_GNU_CPP="cc -systype bsd43 -E"
 494   ;;
 495   mips-mips-bsd* )
 496     machine=mips opsys=bsd4-3
 497   ;;
 498   mips-mips-* )
 499     machine=mips opsys=usg5-2-2
 500   ;;
 501
 502   ## NeXT
 503   m68*-next-* | i[345]86-next-* )
 504     machine=next opsys=mach2
 505   ;;
 506
 507   ## The complete machine from National Semiconductor
 508   ns32k-ns-genix* )
 509     machine=ns32000 opsys=usg5-2
 510   ;;
 511
 512   ## NCR machines
 513   m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
 514     machine=tower32 opsys=usg5-2-2
 515   ;;
 516   m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
 517     machine=tower32v3 opsys=usg5-3
 518   ;;
 519
 520   ## Nixdorf Targon 31
 521   m68*-nixdorf-sysv* )
 522     machine=targon31 opsys=usg5-2-2
 523   ;;
 524
 525   ## Nu (TI or LMI)
 526   m68*-nu-sysv* )
 527     machine=nu opsys=usg5-2
 528   ;;
 529
 530   ## Plexus
 531   m68*-plexus-sysv* )
 532     machine=plexus opsys=usg5-2
 533   ;;
 534
 535   ## Pyramid machines
 536   ## I don't really have any idea what sort of processor the Pyramid has,
 537   ## so I'm assuming it is its own architecture.
 538   pyramid-pyramid-bsd* )
 539     machine=pyramid opsys=bsd4-2
 540   ;;
 541
 542   ## Sequent Balance
 543   ns32k-sequent-bsd4.2* )
 544     machine=sequent opsys=bsd4-2
 545   ;;
 546   ns32k-sequent-bsd4.3* )
 547     machine=sequent opsys=bsd4-3
 548   ;;
 549
 550   ## Siemens Nixdorf
 551   mips-siemens-sysv* )
 552     machine=mips-siemens opsys=usg5-4
 553     NON_GNU_CC=/usr/ccs/bin/cc
 554     NON_GNU_CPP=/usr/ccs/lib/cpp
 555   ;;
 556
 557   ## Silicon Graphics machines
 558   ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
 559   m68*-sgi-iris3.5* )
 560     machine=irist opsys=iris3-5
 561   ;;
 562   m68*-sgi-iris3.6* | m68*-sgi-iris*)
 563     machine=irist opsys=iris3-6
 564   ;;
 565   ## Iris 4D
 566   mips-sgi-irix3* )
 567     machine=iris4d opsys=irix3-3
 568   ;;
 569   mips-sgi-irix5* )
 570     machine=iris4d opsys=irix5-0
 571   ;;
 572   mips-sgi-irix4* | mips-sgi-irix* )
 573     machine=iris4d opsys=irix4-0
 574   ;;
 575
 576   ## SONY machines
 577   m68*-sony-bsd4.2* )
 578     machine=news opsys=bsd4-2
 579   ;;
 580   m68*-sony-bsd4.3* )
 581     machine=news opsys=bsd4-3
 582   ;;
 583   m68*-sony-newsos3* | m68*-sony-news3*)
 584     machine=news opsys=bsd4-3
 585   ;;
 586   mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
 587     machine=news-risc opsys=bsd4-3
 588   ;;
 589   mips-sony-news* )
 590     machine=news-risc opsys=newsos5
 591   ;;
 592
 593   ## Stride
 594   m68*-stride-sysv* )
 595     machine=stride opsys=usg5-2
 596   ;;
 597
 598   ## Suns
 599   *-sun-sunos* | *-sun-bsd* | *-sun-solaris* | i[345]86-*-solaris2* | i[345]86-*-sunos5* )
 600     case "${canonical}" in
 601       m68*-sunos1* )    machine=sun1 ;;
 602       m68*-sunos2* )    machine=sun2 ;;
 603       m68* )            machine=sun3 ;;
 604       i[345]86-sun-sunos[34]* ) machine=sun386 ;;
 605       i[345]86-*-* )     machine=intel386 ;;
 606       sparc* )          machine=sparc ;;
 607       * )               unported=yes ;;
 608     esac
 609     case "${canonical}" in
 610       ## The Sun386 didn't get past 4.0.
 611       i[345]86-*-sunos4   ) opsys=sunos4-0 ;;
 612       *-sunos4.0*         ) opsys=sunos4-0 ;;
 613       *-sunos4.1.3*       ) opsys=sunos4-1-3
 614                 NON_GCC_TEST_OPTIONS=-Bstatic
 615                 GCC_TEST_OPTIONS=-static
 616                 ;;
 617       *-sunos4shr*        ) opsys=sunos4shr ;;
 618       *-sunos4* | *-sunos ) opsys=sunos4-1
 619                 NON_GCC_TEST_OPTIONS=-Bstatic
 620                 GCC_TEST_OPTIONS=-static
 621                 ;;
 622       *-sunos5.3* | *-solaris2.3* )
 623                 opsys=sol2-3
 624                 NON_GNU_CPP=/usr/ccs/lib/cpp
 625                 ;;
 626       *-sunos5.4* | *-solaris2.4* )
 627                 opsys=sol2-4
 628                 NON_GNU_CPP=/usr/ccs/lib/cpp
 629                 ;;
 630       *-sunos5* | *-solaris* )
 631                 opsys=sol2
 632                 NON_GNU_CPP=/usr/ccs/lib/cpp
 633                 ;;
 634       *                   ) opsys=bsd4-2   ;;
 635     esac
 636   ;;
 637
 638   ## Tadpole 68k
 639   m68*-tadpole-sysv* )
 640     machine=tad68k opsys=usg5-3
 641   ;;
 642
 643   ## Tahoe machines
 644   tahoe-tahoe-bsd4.2* )
 645     machine=tahoe opsys=bsd4-2
 646   ;;
 647   tahoe-tahoe-bsd4.3* )
 648     machine=tahoe opsys=bsd4-3
 649   ;;
 650
 651   ## Tandem Integrity S2
 652   mips-tandem-sysv* )
 653     machine=tandem-s2 opsys=usg5-3
 654   ;;
 655
 656   ## Tektronix XD88
 657   m88k-tektronix-sysv3* )
 658   machine=tekxd88 opsys=usg5-3
 659   ;;
 660
 661   ## Tektronix 16000 box (6130?)
 662   ns16k-tektronix-bsd* )
 663     machine=ns16000 opsys=bsd4-2
 664   ;;
 665   ## Tektronix 4300
 666   ## src/m/tek4300.h hints that this is a m68k machine.
 667   m68*-tektronix-bsd* )
 668     machine=tek4300 opsys=bsd4-3
 669   ;;
 670
 671   ## Titan P2 or P3
 672   ## We seem to have lost the machine-description file titan.h!
 673   titan-titan-sysv* )
 674     machine=titan opsys=usg5-3
 675   ;;
 676
 677   ## Ustation E30 (SS5E)
 678   m68*-unisys-uniplus* )
 679     machine=ustation opsystem=unipl5-2
 680   ;;
 681
 682   ## Vaxen.
 683   vax-dec-* )
 684     machine=vax
 685     case "${canonical}" in
 686       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 687       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 688       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 689       *-bsd386* | *-bsdi* )                             opsys=bsd386 ;;
 690       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 691       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 692       *-vms* )                                          opsys=vms ;;
 693       * )                                               unported=yes
 694     esac
 695   ;;
 696
 697   ## Whitechapel MG1
 698   ns16k-whitechapel-* )
 699     machine=mg1
 700     ## We don't know what sort of OS runs on these; we'll let the
 701     ## operating system guessing code below try.
 702   ;;
 703
 704   ## Wicat
 705   m68*-wicat-sysv* )
 706     machine=wicat opsys=usg5-2
 707   ;;
 708
 709   ## Intel 386 machines where we don't care about the manufacturer
 710   i[345]86-*-* )
 711     machine=intel386
 712     case "${canonical}" in
 713       *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
 714       *-isc2.2* )               opsys=isc2-2 ;;
 715       *-isc4.0* )               opsys=isc4-0 ;;
 716       *-isc* )                  opsys=isc3-0 ;;
 717       *-esix5* )                opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
 718       *-esix* )                 opsys=esix ;;
 719       *-xenix* )                opsys=xenix ;;
 720       *-linux* )                opsys=linux ;;
 721       *-sco3.2v4* )             opsys=sco4 ; NON_GNU_CPP=/lib/cpp  ;;
 722       *-bsd386* | *-bsdi* )     opsys=bsd386 ;;
 723       *-386bsd* )               opsys=386bsd ;;
 724       *-freebsd* )              opsys=freebsd ;;
 725       *-nextstep* )             opsys=mach2 ;;
 726       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 727     esac
 728   ;;
 729
 730   * )
 731     unported=yes
 732   ;;
 733 esac
 734
 735 ### If the code above didn't choose an operating system, just choose
 736 ### an operating system based on the configuration name.  You really
 737 ### only want to use this when you have no idea what the right
 738 ### operating system is; if you know what operating systems a machine
 739 ### runs, it's cleaner to make it explicit in the case statement
 740 ### above.
 741 if test x"${opsys}" = x; then
 742   case "${canonical}" in
 743     *-gnu* )                            opsys=gnu ;;
 744     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 745     *-bsd4.2 )                          opsys=bsd4-2 ;;
 746     *-bsd4.3 )                          opsys=bsd4-3 ;;
 747     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 748     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 749     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 750     *-sysv3 | *-sysvr3 )                opsys=usg5-3 ;;
 751     *-sysv4 | *-sysvr4 )                opsys=usg5-4 ;;
 752     *-sysv4.1 | *-sysvr4.1 )
 753         NON_GNU_CPP=/usr/lib/cpp
 754         opsys=usg5-4 ;;
 755     *-sysv4.2 | *-sysvr4.2 )            opsys=usg5-4-2 ;;
 756     * )
 757       unported=yes
 758     ;;
 759   esac
 760 fi
 761
 762 changequote([, ])dnl
 763
 764 if test $unported = yes; then
 765   AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
 766 Check \`etc/MACHINES' for recognized configuration names.])
 767 fi
 768
 769 machfile="m/${machine}.h"
 770 opsysfile="s/${opsys}.h"
 771
 772
 773 #### Choose a compiler.
 774 test -n "$CC" && cc_specified=yes
 775
 776 case ${with_gcc} in
 777   "yes" ) CC="gcc" GCC=yes ;;
 778   "no"  ) : ${CC=cc} ;;
 779   * ) AC_PROG_CC
 780 esac
 781
 782 # On Suns, sometimes $CPP names a directory.
 783 if test -n "$CPP" && test -d "$CPP"; then
 784   CPP=
 785 fi
 786
 787 #### Some systems specify a CPP to use unless we are using GCC.
 788 #### Now that we know whether we are using GCC, we can decide whether
 789 #### to use that one.
 790 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 791 then
 792   CPP="$NON_GNU_CPP"
 793 fi
 794
 795 #### Some systems specify a CC to use unless we are using GCC.
 796 #### Now that we know whether we are using GCC, we can decide whether
 797 #### to use that one.
 798 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 799   test x$cc_specified != xyes
 800 then
 801   CC="$NON_GNU_CC"
 802 fi
 803
 804 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 805 then
 806   CC="$CC $GCC_TEST_OPTIONS"
 807 fi
 808
 809 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 810 then
 811   CC="$CC $NON_GCC_TEST_OPTIONS"
 812 fi
 813
 814 #### Some other nice autoconf tests.  If you add a test here which
 815 #### should make an entry in src/config.h, don't forget to add an
 816 #### #undef clause to src/config.h.in for autoconf to modify.
 817
 818 dnl checks for programs
 819 AC_PROG_LN_S
 820 AC_PROG_CPP
 821 AC_PROG_INSTALL
 822 AC_PROG_YACC
 823
 824 dnl checks for Unix variants
 825 AC_AIX
 826
 827 dnl checks for header files
 828 AC_CHECK_HEADERS(sys/timeb.h sys/time.h unistd.h utime.h)
 829 AC_HEADER_STDC
 830 AC_HEADER_TIME
 831 AC_DECL_SYS_SIGLIST
 832
 833 dnl Some systems have utime.h but don't declare the struct anyplace.
 834 AC_MSG_CHECKING(for struct utimbuf)
 835 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
 836 #include <sys/time.h>
 837 #include <time.h>
 838 #else
 839 #ifdef HAVE_SYS_TIME_H
 840 #include <sys/time.h>
 841 #else
 842 #include <time.h>
 843 #endif
 844 #endif
 845 #ifdef HAVE_UTIME_H
 846 #include <utime.h>
 847 #endif], [static struct utimbuf x; x.actime = x.modtime;],
 848   [AC_MSG_RESULT(yes)
 849    AC_DEFINE(HAVE_STRUCT_UTIMBUF)],
 850   AC_MSG_RESULT(no))
 851
 852 dnl checks for typedefs
 853 AC_TYPE_SIGNAL
 854
 855 AC_MSG_CHECKING(for struct timeval)
 856 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
 857 #include <sys/time.h>
 858 #include <time.h>
 859 #else
 860 #ifdef HAVE_SYS_TIME_H
 861 #include <sys/time.h>
 862 #else
 863 #include <time.h>
 864 #endif
 865 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
 866   [AC_MSG_RESULT(yes)
 867    AC_DEFINE(HAVE_TIMEVAL)],
 868   AC_MSG_RESULT(no))
 869
 870 dnl checks for structure members
 871 AC_STRUCT_TM
 872 AC_STRUCT_TIMEZONE
 873
 874 dnl checks for compiler characteristics
 875 AC_C_CONST
 876
 877 dnl check for Make feature
 878 AC_PROG_MAKE_SET
 879
 880 dnl checks for operating system services
 881 AC_SYS_LONG_FILE_NAMES
 882
 883 #### Choose a window system.
 884
 885 AC_PATH_X
 886 if test "$no_x" = yes; then
 887   window_system=none
 888 else
 889   window_system=x11
 890 fi
 891
 892 test "${x_libraries}" != NONE && LD_SWITCH_X_SITE="-L${x_libraries}"
 893 test "${x_libraries}" != NONE && LD_SWITCH_X_SITE_AUX="-R${x_libraries}"
 894 test "${x_includes}" != NONE && C_SWITCH_X_SITE="-I${x_includes}"
 895
 896 if test x"${x_includes}" = x; then
 897   bitmapdir=/usr/include/X11/bitmaps
 898 else
 899   bitmapdir="${x_includes}/bitmaps"
 900 fi
 901
 902 case "${window_system}" in
 903   x11 )
 904     HAVE_X_WINDOWS=yes
 905     HAVE_X11=yes
 906     case "${with_x_toolkit}" in
 907       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
 908       motif ) USE_X_TOOLKIT=MOTIF ;;
 909 dnl      open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
 910       * ) USE_X_TOOLKIT=none ;;
 911     esac
 912   ;;
 913   none )
 914     HAVE_X_WINDOWS=no
 915     HAVE_X11=no
 916     USE_X_TOOLKIT=none
 917   ;;
 918 esac
 919 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
 920
 921 ### If we're using X11, we should use the X menu package.
 922 HAVE_X_MENU=no
 923 case ${HAVE_X11} in
 924   yes ) HAVE_X_MENU=yes ;;
 925 esac
 926
 927 #### Extract some information from the operating system and machine files.
 928
 929 AC_CHECKING([the machine- and system-dependent files to find out
 930  - which libraries the lib-src programs will want, and
 931  - whether the GNU malloc routines are usable])
 932
 933 ### First figure out CFLAGS (which we use for running the compiler here)
 934 ### and REAL_CFLAGS (which we use for real compilation).
 935 ### The two are the same except on a few systems, where they are made
 936 ### different to work around various lossages.  For example,
 937 ### GCC 2.5 on Linux needs them to be different because it treats -g
 938 ### as implying static linking.
 939
 940 ### If the CFLAGS env var is specified, we use that value
 941 ### instead of the default.
 942
 943 ### It's not important that this name contain the PID; you can't run
 944 ### two configures in the same directory and have anything work
 945 ### anyway.
 946 tempcname="conftest.c"
 947
 948 echo '
 949 #include "'${srcdir}'/src/'${opsysfile}'"
 950 #include "'${srcdir}'/src/'${machfile}'"
 951 #ifndef LIBS_MACHINE
 952 #define LIBS_MACHINE
 953 #endif
 954 #ifndef LIBS_SYSTEM
 955 #define LIBS_SYSTEM
 956 #endif
 957 #ifndef C_SWITCH_SYSTEM
 958 #define C_SWITCH_SYSTEM
 959 #endif
 960 #ifndef C_SWITCH_MACHINE
 961 #define C_SWITCH_MACHINE
 962 #endif
 963 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 964 configure___ c_switch_system=C_SWITCH_SYSTEM
 965 configure___ c_switch_machine=C_SWITCH_MACHINE
 966
 967 #ifndef LIB_X11_LIB
 968 #define LIB_X11_LIB -lX11
 969 #endif
 970
 971 #ifndef LIBX11_MACHINE
 972 #define LIBX11_MACHINE
 973 #endif
 974
 975 #ifndef LIBX11_SYSTEM
 976 #define LIBX11_SYSTEM
 977 #endif
 978 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
 979
 980 #ifdef UNEXEC
 981 configure___ unexec=UNEXEC
 982 #else
 983 configure___ unexec=unexec.o
 984 #endif
 985
 986 #ifdef SYSTEM_MALLOC
 987 configure___ system_malloc=yes
 988 #else
 989 configure___ system_malloc=no
 990 #endif
 991
 992 #ifndef C_DEBUG_SWITCH
 993 #define C_DEBUG_SWITCH -g
 994 #endif
 995
 996 #ifndef C_OPTIMIZE_SWITCH
 997 #define C_OPTIMIZE_SWITCH -O
 998 #endif
 999
1000 #ifdef THIS_IS_CONFIGURE
1001
1002 /* Get the CFLAGS for tests in configure.  */
1003 #ifdef __GNUC__
1004 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${CFLAGS}'
1005 #else
1006 configure___ CFLAGS=C_DEBUG_SWITCH '${CFLAGS}'
1007 #endif
1008
1009 #else /* not THIS_IS_CONFIGURE */
1010
1011 /* Get the CFLAGS for real compilation.  */
1012 #ifdef __GNUC__
1013 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${CFLAGS}'
1014 #else
1015 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${CFLAGS}'
1016 #endif
1017
1018 #endif /* not THIS_IS_CONFIGURE */
1019 ' > ${tempcname}
1020
1021 # The value of CPP is a quoted variable reference, so we need to do this
1022 # to get its actual value...
1023 CPP=`eval "echo $CPP"`
1024 changequote(, )dnl
1025 eval `${CPP} -Isrc ${tempcname} \
1026        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1027 if test "x$CFLAGS" = x; then
1028   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1029          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1030 else
1031   REAL_CFLAGS="$CFLAGS"
1032 fi
1033 changequote([, ])dnl
1034 rm ${tempcname}
1035
1036 ### Compute the unexec source name from the object name.
1037 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1038
1039 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1040 # Assume not, until told otherwise.
1041 GNU_MALLOC=yes
1042 if test "${system_malloc}" = "yes"; then
1043   GNU_MALLOC=no
1044   GNU_MALLOC_reason="
1045   (The GNU allocators don't work with this system configuration.)"
1046 fi
1047
1048 if test x"${REL_ALLOC}" = x; then
1049   REL_ALLOC=${GNU_MALLOC}
1050 fi
1051
1052 LISP_FLOAT_TYPE=yes
1053
1054
1055 #### Add the libraries to LIBS and check for some functions.
1056
1057 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1058 LIBS="$libsrc_libs"
1059
1060 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1061 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1062 AC_CHECK_LIB(dnet, dnet_ntoa)
1063 dnl This causes -lresolv to get used in subsequent tests,
1064 dnl which causes failures on some systems such as HPUX 9.
1065 dnl AC_CHECK_LIB(resolv, gethostbyname)
1066
1067 dnl FIXME replace main with a function we actually want from this library.
1068 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1069
1070 AC_MSG_CHECKING(for XFree86)
1071 if test -d /usr/X386/include; then
1072   HAVE_XFREE386=yes
1073   : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1074 else
1075   HAVE_XFREE386=no
1076 fi
1077 AC_MSG_RESULT($HAVE_XFREE386)
1078
1079 # We change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1080 # for the tests that follow.
1081
1082 if test "${HAVE_X11}" = "yes"; then
1083   DEFS="$C_SWITCH_X_SITE $DEFS"
1084   LIBS="$LD_SWITCH_X_SITE $LIBX $LIBS"
1085   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1086   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1087 XScreenNumberOfScreen XSetWMProtocols)
1088 fi
1089
1090 if test "${USE_X_TOOLKIT}" != "none"; then
1091   AC_MSG_CHECKING(X11 toolkit version)
1092   AC_TRY_LINK([#include <X11/Intrinsic.h>],
1093 [#if XtSpecificationRelease < 6
1094 fail;
1095 #endif
1096 ], [AC_MSG_RESULT(6)
1097     AC_DEFINE(HAVE_X11XTR6)],
1098    [AC_MSG_RESULT(not 6)])
1099 fi
1100
1101 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1102 AC_MSG_CHECKING(whether netdb declarares h_errno)
1103 AC_TRY_LINK([#include <netdb.h>],
1104 [int
1105 foo ()
1106 {
1107   return h_errno;
1108 }
1109 ], [AC_MSG_RESULT(yes)
1110     AC_DEFINE(HAVE_H_ERRNO)],
1111    [AC_MSG_RESULT(no)])
1112
1113 AC_FUNC_ALLOCA
1114
1115 # logb and frexp are found in -lm on most systems.
1116 AC_CHECK_LIB(m, logb)
1117 AC_CHECK_FUNCS(gettimeofday gethostname dup2 rename closedir mkdir rmdir \
1118 random lrand48 bcopy bcmp logb frexp fmod drem ftime res_init setsid \
1119 strerror fpathconf select mktime eaccess getpagesize)
1120
1121 ok_so_far=yes
1122 AC_CHECK_FUNC(socket, , ok_so_far=no)
1123 if test $ok_so_far = yes; then
1124   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
1125 fi
1126 if test $ok_so_far = yes; then
1127   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
1128 fi
1129 if test $ok_so_far = yes; then
1130   AC_DEFINE(HAVE_INET_SOCKETS)
1131 fi
1132
1133 if test -f /usr/lpp/X11/bin/smt.exp; then
1134   AC_DEFINE(HAVE_AIX_SMT_EXP)
1135 fi
1136
1137 # Set up the CFLAGS for real compilation, so we can substitute it.
1138 CFLAGS="$REAL_CFLAGS"
1139
1140 changequote(, )dnl
1141 #### Find out which version of Emacs this is.
1142 version=`grep 'defconst[         ]*emacs-version' ${srcdir}/lisp/version.el \
1143          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
1144 changequote([, ])dnl
1145 if test x"${version}" = x; then
1146   AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
1147 fi
1148
1149 ### Specify what sort of things we'll be editing into Makefile and config.h.
1150 ### Use configuration here uncanonicalized to avoid exceeding size limits.
1151 AC_SUBST(version)
1152 AC_SUBST(configuration)
1153 AC_SUBST(canonical)
1154 AC_SUBST(srcdir)
1155 AC_SUBST(prefix)
1156 AC_SUBST(exec_prefix)
1157 AC_SUBST(bindir)
1158 AC_SUBST(datadir)
1159 AC_SUBST(sharedstatedir)
1160 AC_SUBST(libexecdir)
1161 AC_SUBST(mandir)
1162 AC_SUBST(infodir)
1163 AC_SUBST(lispdir)
1164 AC_SUBST(locallisppath)
1165 AC_SUBST(lisppath)
1166 AC_SUBST(etcdir)
1167 AC_SUBST(lockdir)
1168 AC_SUBST(archlibdir)
1169 AC_SUBST(docdir)
1170 AC_SUBST(bitmapdir)
1171 AC_SUBST(c_switch_system)
1172 AC_SUBST(c_switch_machine)
1173 AC_SUBST(LD_SWITCH_X_SITE)
1174 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1175 AC_SUBST(C_SWITCH_X_SITE)
1176 AC_SUBST(CFLAGS)
1177 AC_SUBST(X_TOOLKIT_TYPE)
1178 AC_SUBST(machfile)
1179 AC_SUBST(opsysfile)
1180
1181 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}")
1182 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${config_options}")
1183 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}")
1184 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
1185 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
1186 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
1187 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE})
1188 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC})
1189
1190 if test "${HAVE_X_WINDOWS}" = "yes" ; then
1191   AC_DEFINE(HAVE_X_WINDOWS)
1192 fi
1193 if test "${USE_X_TOOLKIT}" != "none" ; then
1194   AC_DEFINE(USE_X_TOOLKIT)
1195 fi
1196 if test "${HAVE_X11}" = "yes" ; then
1197   AC_DEFINE(HAVE_X11)
1198 fi
1199 if test "${HAVE_XFREE386}" = "yes" ; then
1200   AC_DEFINE(HAVE_XFREE386)
1201 fi
1202 if test "${HAVE_X_MENU}" = "yes" ; then
1203   AC_DEFINE(HAVE_X_MENU)
1204 fi
1205 if test "${GNU_MALLOC}" = "yes" ; then
1206   AC_DEFINE(GNU_MALLOC)
1207 fi
1208 if test "${REL_ALLOC}" = "yes" ; then
1209   AC_DEFINE(REL_ALLOC)
1210 fi
1211 if test "${LISP_FLOAT_TYPE}" = "yes" ; then
1212   AC_DEFINE(LISP_FLOAT_TYPE)
1213 fi
1214
1215 #### Report on what we decided to do.
1216 echo "
1217
1218 Configured for \`${canonical}'.
1219
1220   Where should the build process find the source code?    ${srcdir}
1221   What operating system and machine description files should Emacs use?
1222         \`${opsysfile}' and \`${machfile}'
1223   What compiler should emacs be built with?               ${CC} ${CFLAGS}
1224   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
1225   Should Emacs use the relocating allocator for buffers?  ${REL_ALLOC}
1226   What window system should Emacs use?                    ${window_system}
1227   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}${x_includes+
1228   Where do we find X Windows header files?                }${x_includes}${x_libraries+
1229   Where do we find X Windows libraries?                   }${x_libraries}
1230
1231 "
1232
1233 # Remove any trailing slashes in these variables.
1234 changequote(, )dnl
1235 test "${prefix}" != NONE &&
1236   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
1237 test "${exec_prefix}" != NONE &&
1238   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
1239 changequote([, ])dnl
1240
1241 AC_OUTPUT(Makefile lib-src/Makefile.in oldXMenu/Makefile \
1242         lwlib/Makefile src/Makefile.in, [
1243
1244 ### Make the necessary directories, if they don't exist.
1245 for dir in ./src ./lib-src ./cpp ./oldXMenu ./lwlib ./etc ; do
1246   if test ! -d ${dir}; then
1247     mkdir ${dir}
1248   fi
1249 done
1250
1251 # Build src/Makefile from ${srcdir}/src/Makefile.in.  This must be done
1252 # after src/config.h is built, since we rely on that file.
1253
1254 changequote(, )dnl The horror, the horror.
1255 # Now get this: Some word that is part of the ${srcdir} directory name
1256 # or the ${configuration} value might, just might, happen to be an
1257 # identifier like `sun4' or `i386' or something, and be predefined by
1258 # the C preprocessor to some helpful value like 1, or maybe the empty
1259 # string.  Needless to say consequent macro substitutions are less
1260 # than conducive to the makefile finding the correct directory.
1261 undefs="`echo $top_srcdir $configuration $canonical |
1262 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
1263     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
1264 `"
1265 changequote([, ])dnl
1266
1267 echo creating lib-src/Makefile
1268 ( cd lib-src
1269   rm -f junk.c junk1.c junk2.c
1270   sed -e '/start of cpp stuff/q' \
1271       < Makefile.in > junk1.c
1272   sed -e '1,/start of cpp stuff/d'\
1273       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1274       < Makefile.in > junk.c
1275   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1276       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1277   cat junk1.c junk2.c > Makefile.new
1278   rm -f junk.c junk1.c junk2.c
1279   chmod 444 Makefile.new
1280   mv -f Makefile.new Makefile
1281 )
1282
1283 echo creating src/Makefile
1284 ( cd src
1285   rm -f junk.c junk1.c junk2.c
1286   sed -e '/start of cpp stuff/q' \
1287       < Makefile.in > junk1.c
1288   sed -e '1,/start of cpp stuff/d'\
1289       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1290       < Makefile.in > junk.c
1291   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1292       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1293   cat junk1.c junk2.c > Makefile.new
1294   rm -f junk.c junk1.c junk2.c
1295   chmod 444 Makefile.new
1296   mv -f Makefile.new Makefile
1297 )
1298 ], [CPP="$CPP" CPPFLAGS="$CPPFLAGS"])