lisp/paren.el

   1 ;;; paren.el --- highlight matching paren.
   2
   3 ;; Copyright (C) 1993, 1996 Free Software Foundation, Inc.
   4
   5 ;; Author: rms@gnu.ai.mit.edu
   6 ;; Maintainer: FSF
   7 ;; Keywords: languages, faces
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Load this and it will display highlighting on whatever
  29 ;; paren matches the one before or after point.
  30
  31 ;;; Code:
  32
  33 (defgroup paren-showing nil
  34   "Showing (un)matching of parens and expressions."
  35   :prefix "show-paren-"
  36   :group 'paren-matching)
  37
  38 ;; This is the overlay used to highlight the matching paren.
  39 (defvar show-paren-overlay nil)
  40 ;; This is the overlay used to highlight the closeparen right before point.
  41 (defvar show-paren-overlay-1 nil)
  42
  43 (defcustom show-paren-mode nil
  44   "Toggle Show Paren mode.
  45 When Show Paren mode is enabled, any matching parenthesis is highlighted
  46 after `show-paren-delay' seconds of Emacs idle time.
  47 You must modify via \\[customize] for this variable to have an effect."
  48   :set (lambda (symbol value)
  49          (show-paren-mode (or value 0)))
  50   :initialize 'custom-initialize-default
  51   :type 'boolean
  52   :group 'paren-showing
  53   :require 'paren)
  54
  55 (defcustom show-paren-style 'parenthesis
  56   "*Style used when showing a matching paren.
  57 Valid styles are `parenthesis' (meaning show the matching paren),
  58 `expression' (meaning show the entire expression enclosed by the paren) and
  59 `mixed' (meaning show the matching paren if it is visible, and the expression
  60 otherwise)."
  61   :type '(choice (const parenthesis) (const expression) (const mixed))
  62   :group 'paren-showing)
  63
  64 (defcustom show-paren-delay
  65   (if (featurep 'lisp-float-type) (/ (float 1) (float 8)) 1)
  66   "*Time in seconds to delay before showing a matching paren."
  67   :type '(number :tag "seconds")
  68   :group 'paren-showing)
  69
  70 (defface show-paren-match-face
  71   '((((class color)) (:background "turquoise"))
  72     (((class grayscale)) (:background "gray"))
  73     (t (:reverse-video t)))
  74   "Show Paren mode face used for a matching paren."
  75   :group 'faces
  76   :group 'paren-showing)
  77
  78 (defface show-paren-mismatch-face
  79   '((((class color)) (:foreground "white" :background "purple"))
  80     (t (:reverse-video t)))
  81   "Show Paren mode face used for a mismatching paren."
  82   :group 'faces
  83   :group 'paren-showing)
  84
  85 (defvar show-paren-idle-timer nil)
  86
  87 ;;;###autoload
  88 (defun show-paren-mode (&optional arg)
  89   "Toggle Show Paren mode.
  90 With prefix ARG, turn Show Paren mode on if and only if ARG is positive.
  91 Returns the new status of Show Paren mode (non-nil means on).
  92
  93 When Show Paren mode is enabled, any matching parenthesis is highlighted
  94 in `show-paren-style' after `show-paren-delay' seconds of Emacs idle time."
  95   (interactive "P")
  96   (when window-system
  97     (let ((on-p (if arg
  98                     (> (prefix-numeric-value arg) 0)
  99                   (not show-paren-mode))))
 100       (setq blink-matching-paren-on-screen (not on-p))
 101       (when show-paren-idle-timer
 102         (cancel-timer show-paren-idle-timer))
 103       (if on-p
 104           (setq show-paren-idle-timer (run-with-idle-timer
 105                                        show-paren-delay t
 106                                        'show-paren-function))
 107         (and show-paren-overlay (overlay-buffer show-paren-overlay)
 108              (delete-overlay show-paren-overlay))
 109         (and show-paren-overlay-1 (overlay-buffer show-paren-overlay-1)
 110              (delete-overlay show-paren-overlay-1)))
 111       (setq show-paren-mode on-p))))
 112
 113 ;; Find the place to show, if there is one,
 114 ;; and show it until input arrives.
 115 (defun show-paren-function ()
 116   ;; Do nothing if no window system to display results with.
 117   ;; Do nothing if executing keyboard macro.
 118   ;; Do nothing if input is pending.
 119   (when window-system
 120     (let (pos dir mismatch face (oldpos (point)))
 121       (cond ((eq (char-syntax (preceding-char)) ?\))
 122              (setq dir -1))
 123             ((eq (char-syntax (following-char)) ?\()
 124              (setq dir 1)))
 125       ;;
 126       ;; Find the other end of the sexp.
 127       (when dir
 128         (save-excursion
 129           (save-restriction
 130             ;; Determine the range within which to look for a match.
 131             (when blink-matching-paren-distance
 132               (narrow-to-region
 133                (max (point-min) (- (point) blink-matching-paren-distance))
 134                (min (point-max) (+ (point) blink-matching-paren-distance))))
 135             ;; Scan across one sexp within that range.
 136             ;; Errors or nil mean there is a mismatch.
 137             (condition-case ()
 138                 (setq pos (scan-sexps (point) dir))
 139               (error (setq pos t mismatch t)))
 140             ;; If found a "matching" paren, see if it is the right
 141             ;; kind of paren to match the one we started at.
 142             (when (integerp pos)
 143               (let ((beg (min pos oldpos)) (end (max pos oldpos)))
 144                 (when (/= (char-syntax (char-after beg)) ?\$)
 145                   (setq mismatch
 146                         (not (eq (char-before end)
 147                                  ;; This can give nil.
 148                                  (matching-paren (char-after beg)))))))))))
 149       ;;
 150       ;; Highlight the other end of the sexp, or unhighlight if none.
 151       (if (not pos)
 152           (progn
 153             ;; If not at a paren that has a match,
 154             ;; turn off any previous paren highlighting.
 155             (and show-paren-overlay (overlay-buffer show-paren-overlay)
 156                  (delete-overlay show-paren-overlay))
 157             (and show-paren-overlay-1 (overlay-buffer show-paren-overlay-1)
 158                  (delete-overlay show-paren-overlay-1)))
 159         ;;
 160         ;; Use the correct face.
 161         (if mismatch
 162             (setq face 'show-paren-mismatch-face)
 163           (setq face 'show-paren-match-face))
 164         ;;
 165         ;; If matching backwards, highlight the closeparen
 166         ;; before point as well as its matching open.
 167         ;; If matching forward, and the openparen is unbalanced,
 168         ;; highlight the paren at point to indicate misbalance.
 169         ;; Otherwise, turn off any such highlighting.
 170         (if (and (= dir 1) (integerp pos))
 171             (when (and show-paren-overlay-1
 172                        (overlay-buffer show-paren-overlay-1))
 173               (delete-overlay show-paren-overlay-1))
 174           (let ((from (if (= dir 1)
 175                           (point)
 176                         (forward-point -1)))
 177                 (to (if (= dir 1)
 178                         (forward-point 1)
 179                       (point))))
 180             (if show-paren-overlay-1
 181                 (move-overlay show-paren-overlay-1 from to (current-buffer))
 182               (setq show-paren-overlay-1 (make-overlay from to)))
 183             ;; Always set the overlay face, since it varies.
 184             (overlay-put show-paren-overlay-1 'face face)))
 185         ;;
 186         ;; Turn on highlighting for the matching paren, if found.
 187         ;; If it's an unmatched paren, turn off any such highlighting.
 188         (unless (integerp pos)
 189           (delete-overlay show-paren-overlay))
 190         (let ((to (if (or (eq show-paren-style 'expression)
 191                           (and (eq show-paren-style 'mixed)
 192                                (not (pos-visible-in-window-p pos))))
 193                       (point)
 194                     pos))
 195               (from (if (or (eq show-paren-style 'expression)
 196                             (and (eq show-paren-style 'mixed)
 197                                  (not (pos-visible-in-window-p pos))))
 198                         pos
 199                       (save-excursion
 200                         (goto-char pos)
 201                         (forward-point (- dir))))))
 202           (if show-paren-overlay
 203               (move-overlay show-paren-overlay from to (current-buffer))
 204             (setq show-paren-overlay (make-overlay from to))))
 205         ;;
 206         ;; Always set the overlay face, since it varies.
 207         (overlay-put show-paren-overlay 'face face)))))
 208
 209 (provide 'paren)
 210
 211 (if show-paren-mode
 212     (show-paren-mode t))
 213
 214 ;;; paren.el ends here