lisp/compare-w.el

   1 ;;; compare-w.el --- compare text between windows for Emacs.
   2
   3 ;; Copyright (C) 1986, 1989, 1993, 1997 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This package provides one entry point, compare-windows.  It compares
  27 ;; text starting from point in two adjacent windows, advancing point
  28 ;; until it finds a difference.  Option variables permit you to ignore
  29 ;; whitespace differences, or case differences, or both.
  30
  31 ;;; Code:
  32
  33 (defvar compare-windows-whitespace "[ \t\n]+"
  34   "*Regexp that defines whitespace sequences for \\[compare-windows].
  35 Changes in whitespace are optionally ignored.
  36
  37 The value of `compare-windows-whitespace' may instead be a function; this
  38 function is called in each buffer, with point at the current scanning point.
  39 The function's job is to categorize any whitespace around (including before)
  40 point; it should also advance past any whitespace.
  41
  42 The function is passed one argument, the point where `compare-windows'
  43 was originally called; it should not consider any text before that point.
  44 If the function returns the same value for both buffers, then the
  45 whitespace is considered to match, and is skipped.")
  46
  47 (defvar compare-ignore-case nil
  48   "*Non-nil means \\[compare-windows] ignores case differences.")
  49
  50 ;;;###autoload
  51 (defun compare-windows (ignore-whitespace)
  52   "Compare text in current window with text in next window.
  53 Compares the text starting at point in each window,
  54 moving over text in each one as far as they match.
  55
  56 This command pushes the mark in each window
  57 at the prior location of point in that window.
  58 If both windows display the same buffer,
  59 the mark is pushed twice in that buffer:
  60 first in the other window, then in the selected window.
  61
  62 A prefix arg means ignore changes in whitespace.
  63 The variable `compare-windows-whitespace' controls how whitespace is skipped.
  64 If `compare-ignore-case' is non-nil, changes in case are also ignored."
  65   (interactive "P")
  66   (let* (p1 p2 maxp1 maxp2 b1 b2 w2
  67             (progress 1)
  68             (opoint1 (point))
  69             opoint2
  70             (skip-func (if ignore-whitespace
  71                          (if (stringp compare-windows-whitespace)
  72                              'compare-windows-skip-whitespace
  73                            compare-windows-whitespace))))
  74     (setq p1 (point) b1 (current-buffer))
  75     (setq w2 (next-window (selected-window) nil 'visible))
  76     (if (eq w2 (selected-window))
  77         (error "No other window"))
  78     (setq p2 (window-point w2)
  79           b2 (window-buffer w2))
  80     (setq opoint2 p2)
  81     (setq maxp1 (point-max))
  82     (save-excursion
  83       (set-buffer b2)
  84       (push-mark p2 t)
  85       (setq maxp2 (point-max)))
  86     (push-mark)
  87
  88     (while (> progress 0)
  89       ;; If both buffers have whitespace next to point,
  90       ;; optionally skip over it.
  91
  92       (and skip-func
  93            (save-excursion
  94              (let (p1a p2a w1 w2 result1 result2)
  95                (setq result1 (funcall skip-func opoint1))
  96                (setq p1a (point))
  97                (set-buffer b2)
  98                (goto-char p2)
  99                (setq result2 (funcall skip-func opoint2))
 100                (setq p2a (point))
 101                (if (or (stringp compare-windows-whitespace)
 102                        (and result1 result2 (eq result1 result2)))
 103                    (setq p1 p1a
 104                          p2 p2a)))))
 105
 106       (let ((size (min (- maxp1 p1) (- maxp2 p2)))
 107             (case-fold-search compare-ignore-case))
 108         (setq progress (compare-buffer-substrings b2 p2 (+ size p2)
 109                                                   b1 p1 (+ size p1)))
 110         (setq progress (if (zerop progress) size (1- (abs progress))))
 111         (setq p1 (+ p1 progress) p2 (+ p2 progress)))
 112       ;; Advance point now rather than later, in case we're interrupted.
 113       (goto-char p1)
 114       (set-window-point w2 p2))
 115
 116     (if (= (point) opoint1)
 117         (ding))))
 118
 119 ;; Move forward over whatever might be called whitespace.
 120 ;; compare-windows-whitespace is a regexp that matches whitespace.
 121 ;; Match it at various starting points before the original point
 122 ;; and find the latest point at which a match ends.
 123 ;; Don't try starting points before START, though.
 124 ;; Value is non-nil if whitespace is found.
 125
 126 ;; If there is whitespace before point, but none after,
 127 ;; then return t, but don't advance point.
 128 (defun compare-windows-skip-whitespace (start)
 129   (let ((end (point))
 130         (beg (point))
 131         (opoint (point)))
 132     (while (or (and (looking-at compare-windows-whitespace)
 133                     (<= end (match-end 0))
 134                     ;; This match goes past END, so advance END.
 135                     (progn (setq end (match-end 0))
 136                            (> (point) start)))
 137                (and (/= (point) start)
 138                     ;; Consider at least the char before point,
 139                     ;; unless it is also before START.
 140                     (= (point) opoint)))
 141       ;; keep going back until whitespace
 142       ;; doesn't extend to or past end
 143       (forward-char -1))
 144     (setq beg (point))
 145     (goto-char end)
 146     (or (/= beg opoint)
 147         (/= end opoint))))
 148
 149 (provide 'compare-w)
 150
 151 ;;; compare-w.el ends here