lisp/vc-cvs.el

   1 ;;; vc-cvs.el --- non-resident support for CVS version-control
   2
   3 ;; Copyright (C) 1995, 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author:      FSF (see vc.el for full credits)
   7 ;; Maintainer:  Andre Spiegel <spiegel@gnu.org>
   8
   9 ;; $Id$
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;;; Code:
  31
  32 (eval-when-compile (require 'cl) (require 'vc))
  33
  34 ;; Clear up the cache to force vc-call to check again and discover
  35 ;; new functions when we reload this file.
  36 (put 'CVS 'vc-functions nil)
  37
  38 ;;;
  39 ;;; Customization options
  40 ;;;
  41
  42 (defcustom vc-cvs-global-switches nil
  43   "*Global switches to pass to any CVS command."
  44   :type '(choice (const :tag "None" nil)
  45                  (string :tag "Argument String")
  46                  (repeat :tag "Argument List"
  47                          :value ("")
  48                          string))
  49   :version "22.1"
  50   :group 'vc)
  51
  52 (defcustom vc-cvs-register-switches nil
  53   "*Extra switches for registering a file into CVS.
  54 A string or list of strings passed to the checkin program by
  55 \\[vc-register]."
  56   :type '(choice (const :tag "None" nil)
  57                  (string :tag "Argument String")
  58                  (repeat :tag "Argument List"
  59                          :value ("")
  60                          string))
  61   :version "21.1"
  62   :group 'vc)
  63
  64 (defcustom vc-cvs-diff-switches nil
  65   "*A string or list of strings specifying extra switches for cvs diff under VC."
  66     :type '(choice (const :tag "None" nil)
  67                  (string :tag "Argument String")
  68                  (repeat :tag "Argument List"
  69                          :value ("")
  70                          string))
  71   :version "21.1"
  72   :group 'vc)
  73
  74 (defcustom vc-cvs-header (or (cdr (assoc 'CVS vc-header-alist)) '("\$Id\$"))
  75   "*Header keywords to be inserted by `vc-insert-headers'."
  76   :version "21.1"
  77   :type '(repeat string)
  78   :group 'vc)
  79
  80 (defcustom vc-cvs-use-edit t
  81   "*Non-nil means to use `cvs edit' to \"check out\" a file.
  82 This is only meaningful if you don't use the implicit checkout model
  83 \(i.e. if you have $CVSREAD set)."
  84   :type 'boolean
  85   :version "21.1"
  86   :group 'vc)
  87
  88 (defcustom vc-cvs-stay-local t
  89   "*Non-nil means use local operations when possible for remote repositories.
  90 This avoids slow queries over the network and instead uses heuristics
  91 and past information to determine the current status of a file.
  92
  93 The value can also be a regular expression or list of regular
  94 expressions to match against the host name of a repository; then VC
  95 only stays local for hosts that match it.  Alternatively, the value
  96 can be a list of regular expressions where the first element is the
  97 symbol `except'; then VC always stays local except for hosts matched
  98 by these regular expressions."
  99   :type '(choice (const :tag "Always stay local" t)
 100                 (const :tag "Don't stay local" nil)
 101                  (list :format "\nExamine hostname and %v" :tag "Examine hostname ..."
 102                        (set :format "%v" :inline t (const :format "%t" :tag "don't" except))
 103                        (regexp :format " stay local,\n%t: %v" :tag "if it matches")
 104                        (repeat :format "%v%i\n" :inline t (regexp :tag "or"))))
 105   :version "21.1"
 106   :group 'vc)
 107
 108 (defcustom vc-cvs-sticky-date-format-string "%c"
 109   "*Format string for mode-line display of sticky date.
 110 Format is according to `format-time-string'.  Only used if
 111 `vc-cvs-sticky-tag-display' is t."
 112   :type '(string)
 113   :version "22.1"
 114   :group 'vc)
 115
 116 (defcustom vc-cvs-sticky-tag-display t
 117   "*Specify the mode-line display of sticky tags.
 118 Value t means default display, nil means no display at all.  If the
 119 value is a function or macro, it is called with the sticky tag and
 120 its' type as parameters, in that order.  TYPE can have three different
 121 values: `symbolic-name' (TAG is a string), `revision-number' (TAG is a
 122 string) and `date' (TAG is a date as returned by `encode-time').  The
 123 return value of the function or macro will be displayed as a string.
 124
 125 Here's an example that will display the formatted date for sticky
 126 dates and the word \"Sticky\" for sticky tag names and revisions.
 127
 128   (lambda (tag type)
 129     (cond ((eq type 'date) (format-time-string
 130                               vc-cvs-sticky-date-format-string tag))
 131           ((eq type 'revision-number) \"Sticky\")
 132           ((eq type 'symbolic-name) \"Sticky\")))
 133
 134 Here's an example that will abbreviate to the first character only,
 135 any text before the first occurrence of `-' for sticky symbolic tags.
 136 If the sticky tag is a revision number, the word \"Sticky\" is
 137 displayed.  Date and time is displayed for sticky dates.
 138
 139    (lambda (tag type)
 140      (cond ((eq type 'date) (format-time-string \"%Y%m%d %H:%M\" tag))
 141            ((eq type 'revision-number) \"Sticky\")
 142            ((eq type 'symbolic-name)
 143             (condition-case nil
 144                 (progn
 145                   (string-match \"\\\\([^-]*\\\\)\\\\(.*\\\\)\" tag)
 146                   (concat (substring (match-string 1 tag) 0 1) \":\"
 147                           (substring (match-string 2 tag) 1 nil)))
 148               (error tag)))))       ; Fall-back to given tag name.
 149
 150 See also variable `vc-cvs-sticky-date-format-string'."
 151   :type '(choice boolean function)
 152   :version "22.1"
 153   :group 'vc)
 154
 155 ;;;
 156 ;;; Internal variables
 157 ;;;
 158
 159
 160 ;;;
 161 ;;; State-querying functions
 162 ;;;
 163
 164 ;;;###autoload (defun vc-cvs-registered (f)
 165 ;;;###autoload   (when (file-readable-p (expand-file-name
 166 ;;;###autoload                    "CVS/Entries" (file-name-directory f)))
 167 ;;;###autoload       (load "vc-cvs")
 168 ;;;###autoload       (vc-cvs-registered f)))
 169
 170 (defun vc-cvs-registered (file)
 171   "Check if FILE is CVS registered."
 172   (let ((dirname (or (file-name-directory file) ""))
 173         (basename (file-name-nondirectory file))
 174         ;; make sure that the file name is searched case-sensitively
 175         (case-fold-search nil))
 176     (if (file-readable-p (expand-file-name "CVS/Entries" dirname))
 177         (with-temp-buffer
 178           (vc-cvs-get-entries dirname)
 179           (goto-char (point-min))
 180           (cond
 181            ((re-search-forward
 182              ;; CVS-removed files are not taken under VC control.
 183              (concat "^/" (regexp-quote basename) "/[^/-]") nil t)
 184             (beginning-of-line)
 185             (vc-cvs-parse-entry file)
 186             t)
 187            (t nil)))
 188       nil)))
 189
 190 (defun vc-cvs-state (file)
 191   "CVS-specific version of `vc-state'."
 192   (if (vc-stay-local-p file)
 193       (let ((state (vc-file-getprop file 'vc-state)))
 194         ;; If we should stay local, use the heuristic but only if
 195         ;; we don't have a more precise state already available.
 196         (if (memq state '(up-to-date edited nil))
 197             (vc-cvs-state-heuristic file)
 198           state))
 199     (with-temp-buffer
 200       (cd (file-name-directory file))
 201       (vc-cvs-command t 0 file "status")
 202       (vc-cvs-parse-status t))))
 203
 204 (defun vc-cvs-state-heuristic (file)
 205   "CVS-specific state heuristic."
 206   ;; If the file has not changed since checkout, consider it `up-to-date'.
 207   ;; Otherwise consider it `edited'.
 208   (let ((checkout-time (vc-file-getprop file 'vc-checkout-time))
 209         (lastmod (nth 5 (file-attributes file))))
 210     (if (equal checkout-time lastmod)
 211         'up-to-date
 212       'edited)))
 213
 214 (defun vc-cvs-dir-state (dir)
 215   "Find the CVS state of all files in DIR."
 216   ;; if DIR is not under CVS control, don't do anything.
 217   (when (file-readable-p (expand-file-name "CVS/Entries" dir))
 218     (if (vc-stay-local-p dir)
 219         (vc-cvs-dir-state-heuristic dir)
 220       (let ((default-directory dir))
 221         ;; Don't specify DIR in this command, the default-directory is
 222         ;; enough.  Otherwise it might fail with remote repositories.
 223         (with-temp-buffer
 224           (vc-cvs-command t 0 nil "status" "-l")
 225           (goto-char (point-min))
 226           (while (re-search-forward "^=+\n\\([^=\n].*\n\\|\n\\)+" nil t)
 227             (narrow-to-region (match-beginning 0) (match-end 0))
 228             (vc-cvs-parse-status)
 229             (goto-char (point-max))
 230             (widen)))))))
 231
 232 (defun vc-cvs-workfile-version (file)
 233   "CVS-specific version of `vc-workfile-version'."
 234   ;; There is no need to consult RCS headers under CVS, because we
 235   ;; get the workfile version for free when we recognize that a file
 236   ;; is registered in CVS.
 237   (vc-cvs-registered file)
 238   (vc-file-getprop file 'vc-workfile-version))
 239
 240 (defun vc-cvs-checkout-model (file)
 241   "CVS-specific version of `vc-checkout-model'."
 242   (if (getenv "CVSREAD")
 243       'announce
 244     (let ((attrib (file-attributes file)))
 245       (if (and attrib ;; don't check further if FILE doesn't exist
 246                ;; If the file is not writable (despite CVSREAD being
 247                ;; undefined), this is probably because the file is being
 248                ;; "watched" by other developers.
 249                ;; (If vc-mistrust-permissions was t, we actually shouldn't
 250                ;; trust this, but there is no other way to learn this from CVS
 251                ;; at the moment (version 1.9).)
 252                (string-match "r-..-..-." (nth 8 attrib)))
 253           'announce
 254         'implicit))))
 255
 256 (defun vc-cvs-mode-line-string (file)
 257   "Return string for placement into the modeline for FILE.
 258 Compared to the default implementation, this function does two things:
 259 Handle the special case of a CVS file that is added but not yet
 260 committed and support display of sticky tags."
 261   (let* ((sticky-tag (vc-file-getprop file 'vc-cvs-sticky-tag))
 262          help-echo
 263          (string
 264           (if (string= (vc-workfile-version file) "0")
 265               ;; A file that is added but not yet committed.
 266               (progn
 267                 (setq help-echo "Added file (needs commit) under CVS")
 268                 "CVS @@")
 269             (let ((def-ml (vc-default-mode-line-string 'CVS file)))
 270               (setq help-echo
 271                     (get-text-property 0 'help-echo def-ml))
 272               def-ml))))
 273     (propertize
 274      (if (zerop (length sticky-tag))
 275          string
 276        (setq help-echo (format "%s on the '%s' branch"
 277                                help-echo sticky-tag))
 278        (concat string "[" sticky-tag "]"))
 279      'help-echo help-echo)))
 280
 281 (defun vc-cvs-dired-state-info (file)
 282   "CVS-specific version of `vc-dired-state-info'."
 283   (let ((cvs-state (vc-state file)))
 284     (cond ((eq cvs-state 'edited)
 285            (if (equal (vc-workfile-version file) "0")
 286                "(added)" "(modified)"))
 287           ((eq cvs-state 'needs-patch) "(patch)")
 288           ((eq cvs-state 'needs-merge) "(merge)"))))
 289
 290
 291 ;;;
 292 ;;; State-changing functions
 293 ;;;
 294
 295 (defun vc-cvs-register (files &optional rev comment)
 296   "Register FILES into the CVS version-control system.
 297 COMMENT can be used to provide an initial description of FILES.
 298
 299 `vc-register-switches' and `vc-cvs-register-switches' are passed to
 300 the CVS command (in that order)."
 301   (when (and (not (vc-cvs-responsible-p file))
 302                (vc-cvs-could-register file))
 303       ;; Register the directory if needed.
 304       (vc-cvs-register (directory-file-name (file-name-directory file))))
 305     (apply 'vc-cvs-command nil 0 files
 306            "add"
 307            (and comment (string-match "[^\t\n ]" comment)
 308                 (concat "-m" comment))
 309            (vc-switches 'CVS 'register)))
 310
 311 (defun vc-cvs-responsible-p (file)
 312   "Return non-nil if CVS thinks it is responsible for FILE."
 313   (file-directory-p (expand-file-name "CVS"
 314                                       (if (file-directory-p file)
 315                                           file
 316                                         (file-name-directory file)))))
 317
 318 (defun vc-cvs-could-register (file)
 319   "Return non-nil if FILE could be registered in CVS.
 320 This is only possible if CVS is managing FILE's directory or one of
 321 its parents."
 322   (let ((dir file))
 323     (while (and (stringp dir)
 324                 (not (equal dir (setq dir (file-name-directory dir))))
 325                 dir)
 326       (setq dir (if (file-directory-p
 327                      (expand-file-name "CVS/Entries" dir))
 328                     t (directory-file-name dir))))
 329     (eq dir t)))
 330
 331 (defun vc-cvs-checkin (files rev comment)
 332   "CVS-specific version of `vc-backend-checkin'."
 333   (unless (or (not rev) (vc-cvs-valid-version-number-p rev))
 334     (if (not (vc-cvs-valid-symbolic-tag-name-p rev))
 335         (error "%s is not a valid symbolic tag name" rev)
 336       ;; If the input revison is a valid symbolic tag name, we create it
 337       ;; as a branch, commit and switch to it.
 338       (apply 'vc-cvs-command nil 0 files "tag" "-b" (list rev))
 339       (apply 'vc-cvs-command nil 0 files "update" "-r" (list rev))
 340       (mapc (lambda (file) (vc-file-setprop file 'vc-cvs-sticky-tag rev))
 341             files)))
 342   (let ((status (apply 'vc-cvs-command nil 1 files
 343                        "ci" (if rev (concat "-r" rev))
 344                        (concat "-m" comment)
 345                        (vc-switches 'CVS 'checkin))))
 346     (set-buffer "*vc*")
 347     (goto-char (point-min))
 348     (when (not (zerop status))
 349       ;; Check checkin problem.
 350       (cond
 351        ((re-search-forward "Up-to-date check failed" nil t)
 352         (mapc (lambda (file) (vc-file-setprop file 'vc-state 'needs-merge))
 353               files)
 354         (error (substitute-command-keys
 355                 (concat "Up-to-date check failed: "
 356                         "type \\[vc-next-action] to merge in changes"))))
 357        (t
 358         (pop-to-buffer (current-buffer))
 359         (goto-char (point-min))
 360         (shrink-window-if-larger-than-buffer)
 361         (error "Check-in failed"))))
 362     ;; Single-file commit?  Then update the version by parsing the buffer.
 363     ;; Otherwise we can't necessarily tell what goes with what; clear
 364     ;; its properties so they have to be refetched.
 365     (if (= (length files) 1)
 366         (vc-file-setprop
 367          (car files) 'vc-workfile-version
 368          (vc-parse-buffer "^\\(new\\|initial\\) revision: \\([0-9.]+\\)" 2))
 369       (mapc (lambda (file) (vc-file-clearprops file)) files))
 370     ;; Anyway, forget the checkout model of the file, because we might have
 371     ;; guessed wrong when we found the file.  After commit, we can
 372     ;; tell it from the permissions of the file (see
 373     ;; vc-cvs-checkout-model).
 374     (mapc (lambda (file) (vc-file-setprop file 'vc-checkout-model nil))
 375           files)
 376
 377     ;; if this was an explicit check-in (does not include creation of
 378     ;; a branch), remove the sticky tag.
 379     (if (and rev (not (vc-cvs-valid-symbolic-tag-name-p rev)))
 380         (vc-cvs-command nil 0 files "update" "-A"))))
 381
 382 (defun vc-cvs-find-version (file rev buffer)
 383   (apply 'vc-cvs-command
 384          buffer 0 file
 385          "-Q"                           ; suppress diagnostic output
 386          "update"
 387          (and rev (not (string= rev ""))
 388               (concat "-r" rev))
 389          "-p"
 390          (vc-switches 'CVS 'checkout)))
 391
 392 (defun vc-cvs-checkout (file &optional editable rev)
 393   "Checkout a revision of FILE into the working area.
 394 EDITABLE non-nil means that the file should be writable.
 395 REV is the revision to check out."
 396   (message "Checking out %s..." file)
 397   ;; Change buffers to get local value of vc-checkout-switches.
 398   (with-current-buffer (or (get-file-buffer file) (current-buffer))
 399     (if (and (file-exists-p file) (not rev))
 400         ;; If no revision was specified, just make the file writable
 401         ;; if necessary (using `cvs-edit' if requested).
 402         (and editable (not (eq (vc-cvs-checkout-model file) 'implicit))
 403              (if vc-cvs-use-edit
 404                  (vc-cvs-command nil 0 file "edit")
 405                (set-file-modes file (logior (file-modes file) 128))
 406                (if (equal file buffer-file-name) (toggle-read-only -1))))
 407       ;; Check out a particular version (or recreate the file).
 408       (vc-file-setprop file 'vc-workfile-version nil)
 409       (apply 'vc-cvs-command nil 0 file
 410              (and editable "-w")
 411              "update"
 412              (when rev
 413                (unless (eq rev t)
 414                  ;; default for verbose checkout: clear the
 415                  ;; sticky tag so that the actual update will
 416                  ;; get the head of the trunk
 417                  (if (string= rev "")
 418                      "-A"
 419                    (concat "-r" rev))))
 420              (vc-switches 'CVS 'checkout)))
 421     (vc-mode-line file))
 422   (message "Checking out %s...done" file))
 423
 424 (defun vc-cvs-delete-file (file)
 425   (vc-cvs-command nil 0 file "remove" "-f")
 426   (vc-cvs-command nil 0 file "commit" "-mRemoved."))
 427
 428 (defun vc-cvs-revert (file &optional contents-done)
 429   "Revert FILE to the version on which it was based."
 430   (vc-default-revert 'CVS file contents-done)
 431   (unless (eq (vc-checkout-model file) 'implicit)
 432     (if vc-cvs-use-edit
 433         (vc-cvs-command nil 0 file "unedit")
 434       ;; Make the file read-only by switching off all w-bits
 435       (set-file-modes file (logand (file-modes file) 3950)))))
 436
 437 (defun vc-cvs-merge (file first-version &optional second-version)
 438   "Merge changes into current working copy of FILE.
 439 The changes are between FIRST-VERSION and SECOND-VERSION."
 440   (vc-cvs-command nil 0 file
 441                  "update" "-kk"
 442                  (concat "-j" first-version)
 443                  (concat "-j" second-version))
 444   (vc-file-setprop file 'vc-state 'edited)
 445   (with-current-buffer (get-buffer "*vc*")
 446     (goto-char (point-min))
 447     (if (re-search-forward "conflicts during merge" nil t)
 448         1                               ; signal error
 449       0)))                              ; signal success
 450
 451 (defun vc-cvs-merge-news (file)
 452   "Merge in any new changes made to FILE."
 453   (message "Merging changes into %s..." file)
 454   ;; (vc-file-setprop file 'vc-workfile-version nil)
 455   (vc-file-setprop file 'vc-checkout-time 0)
 456   (vc-cvs-command nil 0 file "update")
 457   ;; Analyze the merge result reported by CVS, and set
 458   ;; file properties accordingly.
 459   (with-current-buffer (get-buffer "*vc*")
 460     (goto-char (point-min))
 461     ;; get new workfile version
 462     (if (re-search-forward
 463          "^Merging differences between [0-9.]* and \\([0-9.]*\\) into" nil t)
 464         (vc-file-setprop file 'vc-workfile-version (match-string 1))
 465       (vc-file-setprop file 'vc-workfile-version nil))
 466     ;; get file status
 467     (prog1
 468         (if (eq (buffer-size) 0)
 469             0 ;; there were no news; indicate success
 470           (if (re-search-forward
 471                (concat "^\\([CMUP] \\)?"
 472                        (regexp-quote (file-name-nondirectory file))
 473                        "\\( already contains the differences between \\)?")
 474                nil t)
 475               (cond
 476                ;; Merge successful, we are in sync with repository now
 477                ((or (match-string 2)
 478                     (string= (match-string 1) "U ")
 479                     (string= (match-string 1) "P "))
 480                 (vc-file-setprop file 'vc-state 'up-to-date)
 481                 (vc-file-setprop file 'vc-checkout-time
 482                                  (nth 5 (file-attributes file)))
 483                 0);; indicate success to the caller
 484                ;; Merge successful, but our own changes are still in the file
 485                ((string= (match-string 1) "M ")
 486                 (vc-file-setprop file 'vc-state 'edited)
 487                 0);; indicate success to the caller
 488                ;; Conflicts detected!
 489                (t
 490                 (vc-file-setprop file 'vc-state 'edited)
 491                 1);; signal the error to the caller
 492                )
 493             (pop-to-buffer "*vc*")
 494             (error "Couldn't analyze cvs update result")))
 495       (message "Merging changes into %s...done" file))))
 496
 497
 498 ;;;
 499 ;;; History functions
 500 ;;;
 501
 502 (defun vc-cvs-print-log (files &optional buffer)
 503   "Get change log associated with FILE."
 504   (vc-cvs-command
 505    buffer
 506    (if (and (vc-stay-local-p files) (fboundp 'start-process)) 'async 0)
 507    files "log"))
 508
 509 (defun vc-cvs-wash-log ()
 510   "Remove all non-comment information from log output."
 511   (vc-call-backend 'RCS 'wash-log)
 512   nil)
 513
 514 (defun vc-cvs-diff (files &optional oldvers newvers buffer)
 515   "Get a difference report using CVS between two versions of FILE."
 516     (let* ((async (and (not vc-disable-async-diff)
 517                        (vc-stay-local-p files)
 518                        (fboundp 'start-process)))
 519            (status (apply 'vc-cvs-command (or buffer "*vc-diff*")
 520                           (if async 'async 1)
 521                           files "diff"
 522                           (and oldvers (concat "-r" oldvers))
 523                           (and newvers (concat "-r" newvers))
 524                           (vc-switches 'CVS 'diff))))
 525       (if async 1 status)))             ; async diff, pessimistic assumption
 526
 527 (defun vc-cvs-diff-tree (dir &optional rev1 rev2)
 528   "Diff all files at and below DIR."
 529   (with-current-buffer "*vc-diff*"
 530     (setq default-directory dir)
 531     (if (vc-stay-local-p dir)
 532         ;; local diff: do it filewise, and only for files that are modified
 533         (vc-file-tree-walk
 534          dir
 535          (lambda (f)
 536            (vc-exec-after
 537             `(let ((coding-system-for-read (vc-coding-system-for-diff ',f)))
 538                ;; possible optimization: fetch the state of all files
 539                ;; in the tree via vc-cvs-dir-state-heuristic
 540                (unless (vc-up-to-date-p ',f)
 541                  (message "Looking at %s" ',f)
 542                  (vc-diff-internal ',f ',rev1 ',rev2))))))
 543       ;; cvs diff: use a single call for the entire tree
 544       (let ((coding-system-for-read
 545              (or coding-system-for-read 'undecided)))
 546         (apply 'vc-cvs-command "*vc-diff*" 1 nil "diff"
 547                (and rev1 (concat "-r" rev1))
 548                (and rev2 (concat "-r" rev2))
 549                (vc-switches 'CVS 'diff))))))
 550
 551 (defconst vc-cvs-annotate-first-line-re "^[0-9]")
 552
 553 (defun vc-cvs-annotate-process-filter (process string)
 554   (setq string (concat (process-get process 'output) string))
 555   (if (not (string-match vc-cvs-annotate-first-line-re string))
 556       ;; Still waiting for the first real line.
 557       (process-put process 'output string)
 558     (let ((vc-filter (process-get process 'vc-filter)))
 559       (set-process-filter process vc-filter)
 560       (funcall vc-filter process (substring string (match-beginning 0))))))
 561
 562 (defun vc-cvs-annotate-command (file buffer &optional version)
 563   "Execute \"cvs annotate\" on FILE, inserting the contents in BUFFER.
 564 Optional arg VERSION is a version to annotate from."
 565   (vc-cvs-command buffer
 566                   (if (and (vc-stay-local-p file) (fboundp 'start-process))
 567                       'async 0)
 568                   file "annotate"
 569                   (if version (concat "-r" version)))
 570   ;; Strip the leading few lines.
 571   (let ((proc (get-buffer-process buffer)))
 572     (if proc
 573         ;; If running asynchronously, use a process filter.
 574         (progn
 575           (process-put proc 'vc-filter (process-filter proc))
 576           (set-process-filter proc 'vc-cvs-annotate-process-filter))
 577       (with-current-buffer buffer
 578         (goto-char (point-min))
 579         (re-search-forward vc-cvs-annotate-first-line-re)
 580         (delete-region (point-min) (1- (point)))))))
 581
 582 (defun vc-cvs-annotate-current-time ()
 583   "Return the current time, based at midnight of the current day, and
 584 encoded as fractional days."
 585   (vc-annotate-convert-time
 586    (apply 'encode-time 0 0 0 (nthcdr 3 (decode-time (current-time))))))
 587
 588 (defun vc-cvs-annotate-time ()
 589   "Return the time of the next annotation (as fraction of days)
 590 systime, or nil if there is none."
 591   (let* ((bol (point))
 592          (cache (get-text-property bol 'vc-cvs-annotate-time))
 593          buffer-read-only)
 594     (cond
 595      (cache)
 596      ((looking-at
 597        "^\\S-+\\s-+\\S-+\\s-+\\([0-9]+\\)-\\(\\sw+\\)-\\([0-9]+\\)): ")
 598       (let ((day (string-to-number (match-string 1)))
 599             (month (cdr (assq (intern (match-string 2))
 600                               '((Jan .  1) (Feb .  2) (Mar .  3)
 601                                 (Apr .  4) (May .  5) (Jun .  6)
 602                                 (Jul .  7) (Aug .  8) (Sep .  9)
 603                                 (Oct . 10) (Nov . 11) (Dec . 12)))))
 604             (year (let ((tmp (string-to-number (match-string 3))))
 605                     ;; Years 0..68 are 2000..2068.
 606                     ;; Years 69..99 are 1969..1999.
 607                     (+ (cond ((> 69 tmp) 2000)
 608                              ((> 100 tmp) 1900)
 609                              (t 0))
 610                        tmp))))
 611         (put-text-property
 612          bol (1+ bol) 'vc-cvs-annotate-time
 613          (setq cache (cons
 614                       ;; Position at end makes for nicer overlay result.
 615                       (match-end 0)
 616                       (vc-annotate-convert-time
 617                        (encode-time 0 0 0 day month year))))))))
 618     (when cache
 619       (goto-char (car cache))           ; fontify from here to eol
 620       (cdr cache))))                    ; days (float)
 621
 622 (defun vc-cvs-annotate-extract-revision-at-line ()
 623   (save-excursion
 624     (beginning-of-line)
 625     (if (re-search-forward "^\\([0-9]+\\.[0-9]+\\(\\.[0-9]+\\)*\\) +("
 626                            (line-end-position) t)
 627         (match-string-no-properties 1)
 628       nil)))
 629
 630 ;;;
 631 ;;; Snapshot system
 632 ;;;
 633
 634 (defun vc-cvs-create-snapshot (dir name branchp)
 635   "Assign to DIR's current version a given NAME.
 636 If BRANCHP is non-nil, the name is created as a branch (and the current
 637 workspace is immediately moved to that new branch)."
 638   (vc-cvs-command nil 0 dir "tag" "-c" (if branchp "-b") name)
 639   (when branchp (vc-cvs-command nil 0 dir "update" "-r" name)))
 640
 641 (defun vc-cvs-retrieve-snapshot (dir name update)
 642   "Retrieve a snapshot at and below DIR.
 643 NAME is the name of the snapshot; if it is empty, do a `cvs update'.
 644 If UPDATE is non-nil, then update (resynch) any affected buffers."
 645   (with-current-buffer (get-buffer-create "*vc*")
 646     (let ((default-directory dir)
 647           (sticky-tag))
 648       (erase-buffer)
 649       (if (or (not name) (string= name ""))
 650           (vc-cvs-command t 0 nil "update")
 651         (vc-cvs-command t 0 nil "update" "-r" name)
 652         (setq sticky-tag name))
 653       (when update
 654         (goto-char (point-min))
 655         (while (not (eobp))
 656           (if (looking-at "\\([CMUP]\\) \\(.*\\)")
 657               (let* ((file (expand-file-name (match-string 2) dir))
 658                      (state (match-string 1))
 659                      (buffer (find-buffer-visiting file)))
 660                 (when buffer
 661                   (cond
 662                    ((or (string= state "U")
 663                         (string= state "P"))
 664                     (vc-file-setprop file 'vc-state 'up-to-date)
 665                     (vc-file-setprop file 'vc-workfile-version nil)
 666                     (vc-file-setprop file 'vc-checkout-time
 667                                      (nth 5 (file-attributes file))))
 668                    ((or (string= state "M")
 669                         (string= state "C"))
 670                     (vc-file-setprop file 'vc-state 'edited)
 671                     (vc-file-setprop file 'vc-workfile-version nil)
 672                     (vc-file-setprop file 'vc-checkout-time 0)))
 673                   (vc-file-setprop file 'vc-cvs-sticky-tag sticky-tag)
 674                   (vc-resynch-buffer file t t))))
 675           (forward-line 1))))))
 676
 677
 678 ;;;
 679 ;;; Miscellaneous
 680 ;;;
 681
 682 (defalias 'vc-cvs-make-version-backups-p 'vc-stay-local-p
 683   "Return non-nil if version backups should be made for FILE.")
 684
 685 (defun vc-cvs-check-headers ()
 686   "Check if the current file has any headers in it."
 687   (save-excursion
 688     (goto-char (point-min))
 689     (re-search-forward "\\$[A-Za-z\300-\326\330-\366\370-\377]+\
 690 \\(: [\t -#%-\176\240-\377]*\\)?\\$" nil t)))
 691
 692
 693 ;;;
 694 ;;; Internal functions
 695 ;;;
 696
 697 (defun vc-cvs-command (buffer okstatus files &rest flags)
 698   "A wrapper around `vc-do-command' for use in vc-cvs.el.
 699 The difference to vc-do-command is that this function always invokes `cvs',
 700 and that it passes `vc-cvs-global-switches' to it before FLAGS."
 701   (apply 'vc-do-command buffer okstatus "cvs" files
 702          (if (stringp vc-cvs-global-switches)
 703              (cons vc-cvs-global-switches flags)
 704            (append vc-cvs-global-switches
 705                    flags))))
 706
 707 (defalias 'vc-cvs-stay-local-p 'vc-stay-local-p)  ;Back-compatibility.
 708
 709 (defun vc-cvs-repository-hostname (dirname)
 710   "Hostname of the CVS server associated to workarea DIRNAME."
 711   (let ((rootname (expand-file-name "CVS/Root" dirname)))
 712     (when (file-readable-p rootname)
 713       (with-temp-buffer
 714         (let ((coding-system-for-read
 715                (or file-name-coding-system
 716                    default-file-name-coding-system)))
 717           (vc-insert-file rootname))
 718         (goto-char (point-min))
 719         (nth 2 (vc-cvs-parse-root
 720                 (buffer-substring (point)
 721                                   (line-end-position))))))))
 722
 723 (defun vc-cvs-parse-root (root)
 724   "Split CVS ROOT specification string into a list of fields.
 725 A CVS root specification of the form
 726   [:METHOD:][[USER@]HOSTNAME:]/path/to/repository
 727 is converted to a normalized record with the following structure:
 728   \(METHOD USER HOSTNAME CVS-ROOT).
 729 The default METHOD for a CVS root of the form
 730   /path/to/repository
 731 is `local'.
 732 The default METHOD for a CVS root of the form
 733   [USER@]HOSTNAME:/path/to/repository
 734 is `ext'.
 735 For an empty string, nil is returned (invalid CVS root)."
 736   ;; Split CVS root into colon separated fields (0-4).
 737   ;; The `x:' makes sure, that leading colons are not lost;
 738   ;; `HOST:/PATH' is then different from `:METHOD:/PATH'.
 739   (let* ((root-list (cdr (split-string (concat "x:" root) ":")))
 740          (len (length root-list))
 741          ;; All syntactic varieties will get a proper METHOD.
 742          (root-list
 743           (cond
 744            ((= len 0)
 745             ;; Invalid CVS root
 746             nil)
 747            ((= len 1)
 748             ;; Simple PATH => method `local'
 749             (cons "local"
 750                   (cons nil root-list)))
 751            ((= len 2)
 752             ;; [USER@]HOST:PATH => method `ext'
 753             (and (not (equal (car root-list) ""))
 754                  (cons "ext" root-list)))
 755            ((= len 3)
 756             ;; :METHOD:PATH
 757             (cons (cadr root-list)
 758                   (cons nil (cddr root-list))))
 759            (t
 760             ;; :METHOD:[USER@]HOST:PATH
 761             (cdr root-list)))))
 762     (if root-list
 763         (let ((method (car root-list))
 764               (uhost (or (cadr root-list) ""))
 765               (root (nth 2 root-list))
 766               user host)
 767           ;; Split USER@HOST
 768           (if (string-match "\\(.*\\)@\\(.*\\)" uhost)
 769               (setq user (match-string 1 uhost)
 770                     host (match-string 2 uhost))
 771             (setq host uhost))
 772           ;; Remove empty HOST
 773           (and (equal host "")
 774                (setq host))
 775           ;; Fix windows style CVS root `:local:C:\\project\\cvs\\some\\dir'
 776           (and host
 777                (equal method "local")
 778                (setq root (concat host ":" root) host))
 779           ;; Normalize CVS root record
 780           (list method user host root)))))
 781
 782 (defun vc-cvs-parse-status (&optional full)
 783   "Parse output of \"cvs status\" command in the current buffer.
 784 Set file properties accordingly.  Unless FULL is t, parse only
 785 essential information."
 786   (let (file status)
 787     (goto-char (point-min))
 788     (if (re-search-forward "^File: " nil t)
 789         (cond
 790          ((looking-at "no file") nil)
 791          ((re-search-forward "\\=\\([^ \t]+\\)" nil t)
 792           (setq file (expand-file-name (match-string 1)))
 793           (vc-file-setprop file 'vc-backend 'CVS)
 794           (if (not (re-search-forward "\\=[ \t]+Status: \\(.*\\)" nil t))
 795               (setq status "Unknown")
 796             (setq status (match-string 1)))
 797           (if (and full
 798                    (re-search-forward
 799                     "\\(RCS Version\\|RCS Revision\\|Repository revision\\):\
 800 \[\t ]+\\([0-9.]+\\)"
 801                     nil t))
 802               (vc-file-setprop file 'vc-latest-version (match-string 2)))
 803           (vc-file-setprop
 804            file 'vc-state
 805            (cond
 806             ((string-match "Up-to-date" status)
 807              (vc-file-setprop file 'vc-checkout-time
 808                               (nth 5 (file-attributes file)))
 809              'up-to-date)
 810             ((string-match "Locally Modified" status)             'edited)
 811             ((string-match "Needs Merge" status)                  'needs-merge)
 812             ((string-match "Needs \\(Checkout\\|Patch\\)" status) 'needs-patch)
 813             (t 'edited))))))))
 814
 815 (defun vc-cvs-dir-state-heuristic (dir)
 816   "Find the CVS state of all files in DIR, using only local information."
 817   (with-temp-buffer
 818     (vc-cvs-get-entries dir)
 819     (goto-char (point-min))
 820     (while (not (eobp))
 821       ;; CVS-removed files are not taken under VC control.
 822       (when (looking-at "/\\([^/]*\\)/[^/-]")
 823         (let ((file (expand-file-name (match-string 1) dir)))
 824           (unless (vc-file-getprop file 'vc-state)
 825             (vc-cvs-parse-entry file t))))
 826       (forward-line 1))))
 827
 828 (defun vc-cvs-get-entries (dir)
 829   "Insert the CVS/Entries file from below DIR into the current buffer.
 830 This function ensures that the correct coding system is used for that,
 831 which may not be the one that is used for the files' contents.
 832 CVS/Entries should only be accessed through this function."
 833   (let ((coding-system-for-read (or file-name-coding-system
 834                                     default-file-name-coding-system)))
 835     (vc-insert-file (expand-file-name "CVS/Entries" dir))))
 836
 837 (defun vc-cvs-valid-symbolic-tag-name-p (tag)
 838   "Return non-nil if TAG is a valid symbolic tag name."
 839   ;; According to the CVS manual, a valid symbolic tag must start with
 840   ;; an uppercase or lowercase letter and can contain uppercase and
 841   ;; lowercase letters, digits, `-', and `_'.
 842   (and (string-match "^[a-zA-Z]" tag)
 843        (not (string-match "[^a-z0-9A-Z-_]" tag))))
 844
 845 (defun vc-cvs-valid-version-number-p (tag)
 846   "Return non-nil if TAG is a valid version number."
 847   (and (string-match "^[0-9]" tag)
 848        (not (string-match "[^0-9.]" tag))))
 849
 850 (defun vc-cvs-parse-sticky-tag (match-type match-tag)
 851   "Parse and return the sticky tag as a string.
 852 `match-data' is protected."
 853   (let ((data (match-data))
 854         (tag)
 855         (type (cond ((string= match-type "D") 'date)
 856                     ((string= match-type "T")
 857                      (if (vc-cvs-valid-symbolic-tag-name-p match-tag)
 858                          'symbolic-name
 859                        'revision-number))
 860                     (t nil))))
 861     (unwind-protect
 862         (progn
 863           (cond
 864            ;; Sticky Date tag.  Convert to a proper date value (`encode-time')
 865            ((eq type 'date)
 866             (string-match
 867              "\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)\\.\\([0-9]+\\)"
 868              match-tag)
 869             (let* ((year-tmp (string-to-number (match-string 1 match-tag)))
 870                    (month    (string-to-number (match-string 2 match-tag)))
 871                    (day      (string-to-number (match-string 3 match-tag)))
 872                    (hour     (string-to-number (match-string 4 match-tag)))
 873                    (min      (string-to-number (match-string 5 match-tag)))
 874                    (sec      (string-to-number (match-string 6 match-tag)))
 875                    ;; Years 0..68 are 2000..2068.
 876                    ;; Years 69..99 are 1969..1999.
 877                    (year (+ (cond ((> 69 year-tmp) 2000)
 878                                   ((> 100 year-tmp) 1900)
 879                                   (t 0))
 880                             year-tmp)))
 881               (setq tag (encode-time sec min hour day month year))))
 882            ;; Sticky Tag name or revision number
 883            ((eq type 'symbolic-name) (setq tag match-tag))
 884            ((eq type 'revision-number) (setq tag match-tag))
 885            ;; Default is no sticky tag at all
 886            (t nil))
 887           (cond ((eq vc-cvs-sticky-tag-display nil) nil)
 888                 ((eq vc-cvs-sticky-tag-display t)
 889                  (cond ((eq type 'date) (format-time-string
 890                                          vc-cvs-sticky-date-format-string
 891                                          tag))
 892                        ((eq type 'symbolic-name) tag)
 893                        ((eq type 'revision-number) tag)
 894                        (t nil)))
 895                 ((functionp vc-cvs-sticky-tag-display)
 896                  (funcall vc-cvs-sticky-tag-display tag type))
 897                 (t nil)))
 898
 899       (set-match-data data))))
 900
 901 (defun vc-cvs-parse-entry (file &optional set-state)
 902   "Parse a line from CVS/Entries.
 903 Compare modification time to that of the FILE, set file properties
 904 accordingly.  However, `vc-state' is set only if optional arg SET-STATE
 905 is non-nil."
 906   (cond
 907    ;; entry for a "locally added" file (not yet committed)
 908    ((looking-at "/[^/]+/0/")
 909     (vc-file-setprop file 'vc-checkout-time 0)
 910     (vc-file-setprop file 'vc-workfile-version "0")
 911     (if set-state (vc-file-setprop file 'vc-state 'edited)))
 912    ;; normal entry
 913    ((looking-at
 914      (concat "/[^/]+"
 915              ;; revision
 916              "/\\([^/]*\\)"
 917              ;; timestamp and optional conflict field
 918              "/\\([^/]*\\)/"
 919              ;; options
 920              "\\([^/]*\\)/"
 921              ;; sticky tag
 922              "\\(.\\|\\)" ;Sticky tag type (date or tag name, could be empty)
 923              "\\(.*\\)"))               ;Sticky tag
 924     (vc-file-setprop file 'vc-workfile-version (match-string 1))
 925     (vc-file-setprop file 'vc-cvs-sticky-tag
 926                      (vc-cvs-parse-sticky-tag (match-string 4)
 927                                               (match-string 5)))
 928     ;; Compare checkout time and modification time.
 929     ;; This is intentionally different from the algorithm that CVS uses
 930     ;; (which is based on textual comparison), because there can be problems
 931     ;; generating a time string that looks exactly like the one from CVS.
 932     (let ((mtime (nth 5 (file-attributes file))))
 933       (require 'parse-time)
 934       (let ((parsed-time
 935              (parse-time-string (concat (match-string 2) " +0000"))))
 936         (cond ((and (not (string-match "\\+" (match-string 2)))
 937                     (car parsed-time)
 938                     (equal mtime (apply 'encode-time parsed-time)))
 939                (vc-file-setprop file 'vc-checkout-time mtime)
 940                (if set-state (vc-file-setprop file 'vc-state 'up-to-date)))
 941               (t
 942                (vc-file-setprop file 'vc-checkout-time 0)
 943                (if set-state (vc-file-setprop file 'vc-state 'edited)))))))))
 944
 945 ;; Completion of revision names.
 946 ;; Just so I don't feel like I'm duplicating code from pcl-cvs, I'll use
 947 ;; `cvs log' so I can list all the revision numbers rather than only
 948 ;; tag names.
 949
 950 (defun vc-cvs-revision-table (file)
 951   (let ((default-directory (file-name-directory file))
 952         (res nil))
 953     (with-temp-buffer
 954       (vc-cvs-command t nil file "log")
 955       (goto-char (point-min))
 956       (when (re-search-forward "^symbolic names:\n" nil t)
 957         (while (looking-at "^   \\(.*\\): \\(.*\\)")
 958           (push (cons (match-string 1) (match-string 2)) res)
 959           (forward-line 1)))
 960       (while (re-search-forward "^revision \\([0-9.]+\\)" nil t)
 961         (push (match-string 1) res))
 962       res)))
 963
 964 (defun vc-cvs-revision-completion-table (file)
 965   (lexical-let ((file file)
 966                 table)
 967     (setq table (lazy-completion-table
 968                  table (lambda () (vc-cvs-revision-table file))))
 969     table))
 970
 971
 972 (provide 'vc-cvs)
 973
 974 ;; arch-tag: 60e1402a-aa53-4607-927a-cf74f144b432
 975 ;;; vc-cvs.el ends here