lisp/help.el

   1 ;;; help.el --- help commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This code implements GNU Emacs' on-line help system, the one invoked by
  29 ;; `M-x help-for-help'.
  30
  31 ;;; Code:
  32
  33 ;; Get the macro make-help-screen when this is compiled,
  34 ;; or run interpreted, but not when the compiled code is loaded.
  35 (eval-when-compile (require 'help-macro))
  36
  37 ;; This makes `with-output-to-temp-buffer' buffers use `help-mode'.
  38 (add-hook 'temp-buffer-setup-hook 'help-mode-setup)
  39 (add-hook 'temp-buffer-show-hook 'help-mode-finish)
  40
  41 (defvar help-map
  42   (let ((map (make-sparse-keymap)))
  43     (define-key map (char-to-string help-char) 'help-for-help)
  44     (define-key map [help] 'help-for-help)
  45     (define-key map [f1] 'help-for-help)
  46     (define-key map "." 'display-local-help)
  47     (define-key map "?" 'help-for-help)
  48
  49     (define-key map "\C-c" 'describe-copying)
  50     (define-key map "\C-d" 'describe-distribution)
  51     (define-key map "\C-e" 'view-emacs-problems)
  52     (define-key map "\C-f" 'view-emacs-FAQ)
  53     (define-key map "\C-m" 'view-order-manuals)
  54     (define-key map "\C-n" 'view-emacs-news)
  55     (define-key map "\C-p" 'describe-project)
  56     (define-key map "\C-t" 'view-todo)
  57     (define-key map "\C-w" 'describe-no-warranty)
  58
  59     ;; This does not fit the pattern, but it is natural given the C-\ command.
  60     (define-key map "\C-\\" 'describe-input-method)
  61
  62     (define-key map "C" 'describe-coding-system)
  63     (define-key map "F" 'Info-goto-emacs-command-node)
  64     (define-key map "I" 'describe-input-method)
  65     (define-key map "K" 'Info-goto-emacs-key-command-node)
  66     (define-key map "L" 'describe-language-environment)
  67     (define-key map "S" 'info-lookup-symbol)
  68
  69     (define-key map "a" 'apropos-command)
  70     (define-key map "b" 'describe-bindings)
  71     (define-key map "c" 'describe-key-briefly)
  72     (define-key map "d" 'apropos-documentation)
  73     (define-key map "e" 'view-echo-area-messages)
  74     (define-key map "f" 'describe-function)
  75     (define-key map "h" 'view-hello-file)
  76
  77     (define-key map "i" 'info)
  78     (define-key map "4i" 'info-other-window)
  79
  80     (define-key map "k" 'describe-key)
  81     (define-key map "l" 'view-lossage)
  82     (define-key map "m" 'describe-mode)
  83     (define-key map "n" 'view-emacs-news)
  84     (define-key map "p" 'finder-by-keyword)
  85     (define-key map "r" 'info-emacs-manual)
  86     (define-key map "s" 'describe-syntax)
  87     (define-key map "t" 'help-with-tutorial)
  88     (define-key map "w" 'where-is)
  89     (define-key map "v" 'describe-variable)
  90     (define-key map "q" 'help-quit)
  91     map)
  92   "Keymap for characters following the Help key.")
  93
  94 (define-key global-map (char-to-string help-char) 'help-command)
  95 (define-key global-map [help] 'help-command)
  96 (define-key global-map [f1] 'help-command)
  97 (fset 'help-command help-map)
  98
  99 (autoload 'finder-by-keyword "finder"
 100   "Find packages matching a given keyword." t)
 101
 102 ;; insert-button makes the action nil if it is not store somewhere
 103 (defvar help-button-cache nil)
 104
 105 \f
 106 (defun help-quit ()
 107   "Just exit from the Help command's command loop."
 108   (interactive)
 109   nil)
 110
 111 (defvar help-return-method nil
 112   "What to do to \"exit\" the help buffer.
 113 This is a list
 114  (WINDOW . t)              delete the selected window (and possibly its frame,
 115                            see `quit-window' and `View-quit'), go to WINDOW.
 116  (WINDOW . quit-window)    do quit-window, then select WINDOW.
 117  (WINDOW BUF START POINT)  display BUF at START, POINT, then select WINDOW.")
 118
 119 (defun print-help-return-message (&optional function)
 120   "Display or return message saying how to restore windows after help command.
 121 This function assumes that `standard-output' is the help buffer.
 122 It computes a message, and applies the optional argument FUNCTION to it.
 123 If FUNCTION is nil, it applies `message', thus displaying the message.
 124 In addition, this function sets up `help-return-method', which see, that
 125 specifies what to do when the user exits the help buffer."
 126   (and (not (get-buffer-window standard-output))
 127        (let ((first-message
 128               (cond ((or
 129                       pop-up-frames
 130                       (special-display-p (buffer-name standard-output)))
 131                      (setq help-return-method (cons (selected-window) t))
 132                      ;; If the help output buffer is a special display buffer,
 133                      ;; don't say anything about how to get rid of it.
 134                      ;; First of all, the user will do that with the window
 135                      ;; manager, not with Emacs.
 136                      ;; Secondly, the buffer has not been displayed yet,
 137                      ;; so we don't know whether its frame will be selected.
 138                      nil)
 139                     (display-buffer-reuse-frames
 140                      (setq help-return-method (cons (selected-window)
 141                                                     'quit-window))
 142                      nil)
 143                     ((not (one-window-p t))
 144                      (setq help-return-method
 145                            (cons (selected-window) 'quit-window))
 146                      "Type \\[display-buffer] RET to restore the other window.")
 147                     (pop-up-windows
 148                      (setq help-return-method (cons (selected-window) t))
 149                      "Type \\[delete-other-windows] to remove help window.")
 150                     (t
 151                      (setq help-return-method
 152                            (list (selected-window) (window-buffer)
 153                                  (window-start) (window-point)))
 154                      "Type \\[switch-to-buffer] RET to remove help window."))))
 155          (funcall (or function 'message)
 156                   (concat
 157                    (if first-message
 158                        (substitute-command-keys first-message))
 159                    (if first-message "  ")
 160                    ;; If the help buffer will go in a separate frame,
 161                    ;; it's no use mentioning a command to scroll, so don't.
 162                    (if (or pop-up-windows
 163                            (special-display-p (buffer-name standard-output)))
 164                        nil
 165                      (if (same-window-p (buffer-name standard-output))
 166                          ;; Say how to scroll this window.
 167                          (substitute-command-keys
 168                           "\\[scroll-up] to scroll the help.")
 169                        ;; Say how to scroll some other window.
 170                        (substitute-command-keys
 171                         "\\[scroll-other-window] to scroll the help."))))))))
 172
 173 ;; So keyboard macro definitions are documented correctly
 174 (fset 'defining-kbd-macro (symbol-function 'start-kbd-macro))
 175
 176 (defalias 'help 'help-for-help-internal)
 177 ;; find-function can find this.
 178 (defalias 'help-for-help 'help-for-help-internal)
 179 ;; It can't find this, but nobody will look.
 180 (make-help-screen help-for-help-internal
 181   "a b c C e f F i I k C-k l L m p r s t v w C-c C-d C-f C-n C-p C-t C-w . or ? :"
 182   "You have typed %THIS-KEY%, the help character.  Type a Help option:
 183 \(Use SPC or DEL to scroll through this text.  Type \\<help-map>\\[help-quit] to exit the Help command.)
 184
 185 a  command-apropos.  Type a list of words or a regexp; it shows a list of
 186         commands whose names match.  See also the  apropos  command.
 187 b  describe-bindings.  Display a table of all key bindings.
 188 c  describe-key-briefly.  Type a key sequence;
 189         it displays the command name run by that key sequence.
 190 C  describe-coding-system.  Type the name of the coding system to describe,
 191         or just RET to describe the ones currently in use.
 192 d  apropos-documentation.  Type a pattern (a list of words or a regexp), and
 193         it shows a list of functions, variables, and other items whose
 194         documentation matches that pattern.  See also the apropos command.
 195 e  view-echo-area-messages.  Go to the buffer that logs echo-area messages.
 196 f  describe-function.  Type a function name and you see its documentation.
 197 F  Info-goto-emacs-command-node.  Type a command name;
 198         it goes to the on-line manual's section that describes the command.
 199 h  Display the HELLO file which illustrates various scripts.
 200 i  info.  The Info documentation reader: read on-line manuals.
 201 I  describe-input-method.  Describe a specific input method (if you type
 202         its name) or the current input method (if you type just RET).
 203 k  describe-key.  Type a key sequence;
 204         it displays the full documentation for that key sequence.
 205 K  Info-goto-emacs-key-command-node.  Type a key sequence;
 206         it goes to the on-line manual's section that describes
 207         the command bound to that key.
 208 l  view-lossage.  Show last 100 characters you typed.
 209 L  describe-language-environment.  This describes either a
 210         specific language environment (if you type its name)
 211         or the current language environment (if you type just RET).
 212 m  describe-mode.  Display documentation of current minor modes,
 213         and the current major mode, including their special commands.
 214 n  view-emacs-news.  Display news of recent Emacs changes.
 215 p  finder-by-keyword. Find packages matching a given topic keyword.
 216 r  info-emacs-manual.  Display the Emacs manual in Info mode.
 217 s  describe-syntax.  Display contents of syntax table, plus explanations.
 218 S  info-lookup-symbol.  Type a symbol; it goes to that symbol in the
 219         on-line manual for the programming language used in this buffer.
 220 t  help-with-tutorial.  Select the Emacs learn-by-doing tutorial.
 221 v  describe-variable.  Type name of a variable;
 222         it displays the variable's documentation and value.
 223 w  where-is.  Type a command name; it displays which keystrokes
 224         invoke that command.
 225 .  display-local-help.  Display any available local help at point
 226         in the echo area.
 227
 228 C-c Display Emacs copying permission (GNU General Public License).
 229 C-d Display Emacs ordering information.
 230 C-e Display info about Emacs problems.
 231 C-f Display the Emacs FAQ.
 232 C-m Display how to order printed Emacs manuals.
 233 C-n Display news of recent Emacs changes.
 234 C-p Display information about the GNU project.
 235 C-t Display the Emacs TODO list.
 236 C-w Display information on absence of warranty for GNU Emacs."
 237   help-map)
 238
 239 \f
 240
 241 (defun function-called-at-point ()
 242   "Return a function around point or else called by the list containing point.
 243 If that doesn't give a function, return nil."
 244   (or (with-syntax-table emacs-lisp-mode-syntax-table
 245         (or (condition-case ()
 246                 (save-excursion
 247                   (or (not (zerop (skip-syntax-backward "_w")))
 248                       (eq (char-syntax (following-char)) ?w)
 249                       (eq (char-syntax (following-char)) ?_)
 250                       (forward-sexp -1))
 251                   (skip-chars-forward "'")
 252                   (let ((obj (read (current-buffer))))
 253                     (and (symbolp obj) (fboundp obj) obj)))
 254               (error nil))
 255             (condition-case ()
 256                 (save-excursion
 257                   (save-restriction
 258                     (narrow-to-region (max (point-min)
 259                                            (- (point) 1000)) (point-max))
 260                     ;; Move up to surrounding paren, then after the open.
 261                     (backward-up-list 1)
 262                     (forward-char 1)
 263                     ;; If there is space here, this is probably something
 264                     ;; other than a real Lisp function call, so ignore it.
 265                     (if (looking-at "[ \t]")
 266                         (error "Probably not a Lisp function call"))
 267                     (let ((obj (read (current-buffer))))
 268                       (and (symbolp obj) (fboundp obj) obj))))
 269               (error nil))))
 270       (let* ((str (find-tag-default))
 271              (sym (if str (intern-soft str))))
 272         (if (and sym (fboundp sym))
 273             sym
 274           (save-match-data
 275             (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 276               (setq sym (intern-soft (match-string 1 str)))
 277               (and (fboundp sym) sym)))))))
 278
 279 \f
 280 ;;; `User' help functions
 281
 282 (defun describe-distribution ()
 283   "Display info on how to obtain the latest version of GNU Emacs."
 284   (interactive)
 285   (view-file (expand-file-name "DISTRIB" data-directory)))
 286
 287 (defun describe-copying ()
 288   "Display info on how you may redistribute copies of GNU Emacs."
 289   (interactive)
 290   (view-file (expand-file-name "COPYING" data-directory))
 291   (goto-char (point-min)))
 292
 293 (defun describe-project ()
 294   "Display info on the GNU project."
 295   (interactive)
 296   (view-file (expand-file-name "THE-GNU-PROJECT" data-directory))
 297   (goto-char (point-min)))
 298
 299 (defun describe-no-warranty ()
 300   "Display info on all the kinds of warranty Emacs does NOT have."
 301   (interactive)
 302   (describe-copying)
 303   (let (case-fold-search)
 304     (search-forward "NO WARRANTY")
 305     (recenter 0)))
 306
 307 (defun describe-prefix-bindings ()
 308   "Describe the bindings of the prefix used to reach this command.
 309 The prefix described consists of all but the last event
 310 of the key sequence that ran this command."
 311   (interactive)
 312   (let ((key (this-command-keys)))
 313     (describe-bindings
 314      (if (stringp key)
 315          (substring key 0 (1- (length key)))
 316        (let ((prefix (make-vector (1- (length key)) nil))
 317              (i 0))
 318          (while (< i (length prefix))
 319            (aset prefix i (aref key i))
 320            (setq i (1+ i)))
 321          prefix)))))
 322 ;; Make C-h after a prefix, when not specifically bound,
 323 ;; run describe-prefix-bindings.
 324 (setq prefix-help-command 'describe-prefix-bindings)
 325
 326 (defun view-emacs-news (&optional version)
 327   "Display info on recent changes to Emacs.
 328 With argument, display info only for the selected version."
 329   (interactive "P")
 330   (unless version
 331     (setq version emacs-major-version))
 332   (when (consp version)
 333     (let* ((all-versions
 334             (let (res)
 335               (mapcar
 336                (lambda (file)
 337                  (with-temp-buffer
 338                    (insert-file-contents
 339                     (expand-file-name file data-directory))
 340                    (while (re-search-forward
 341                            (if (member file '("NEWS.18" "NEWS.1-17"))
 342                                "Changes in \\(?:Emacs\\|version\\)?[ \t]*\\([0-9]+\\(?:\\.[0-9]+\\)?\\)"
 343                              "^\* [^0-9\n]*\\([0-9]+\\.[0-9]+\\)") nil t)
 344                      (setq res (cons (match-string-no-properties 1) res)))))
 345                (cons "NEWS"
 346                      (directory-files data-directory nil
 347                                       "^NEWS\\.[0-9][-0-9]*$" nil)))
 348               (sort (delete-dups res) (lambda (a b) (string< b a)))))
 349            (current (car all-versions)))
 350       (setq version (completing-read
 351                      (format "Read NEWS for the version (default %s): " current)
 352                      all-versions nil nil nil nil current))
 353       (if (integerp (string-to-number version))
 354           (setq version (string-to-number version))
 355         (unless (or (member version all-versions)
 356                     (<= (string-to-number version) (string-to-number current)))
 357           (error "No news about version %s" version)))))
 358   (when (integerp version)
 359     (cond ((<= version 12)
 360            (setq version (format "1.%d" version)))
 361           ((<= version 18)
 362            (setq version (format "%d" version)))
 363           ((> version emacs-major-version)
 364            (error "No news about Emacs %d (yet)" version))))
 365   (let* ((vn (if (stringp version)
 366                  (string-to-number version)
 367                version))
 368          (file (cond
 369                 ((>= vn emacs-major-version) "NEWS")
 370                 ((< vn 18) "NEWS.1-17")
 371                 (t (format "NEWS.%d" vn))))
 372          res)
 373     (view-file (expand-file-name file data-directory))
 374     (widen)
 375     (goto-char (point-min))
 376     (when (stringp version)
 377       (when (re-search-forward
 378              (concat (if (< vn 19)
 379                          "Changes in Emacs[ \t]*"
 380                        "^\* [^0-9\n]*") version "$")
 381              nil t)
 382         (beginning-of-line)
 383         (narrow-to-region
 384          (point)
 385          (save-excursion
 386            (while (and (setq res
 387                              (re-search-forward
 388                               (if (< vn 19)
 389                                   "Changes in \\(?:Emacs\\|version\\)?[ \t]*\\([0-9]+\\(?:\\.[0-9]+\\)?\\)"
 390                                 "^\* [^0-9\n]*\\([0-9]+\\.[0-9]+\\)") nil t))
 391                        (equal (match-string-no-properties 1) version)))
 392            (or res (goto-char (point-max)))
 393            (beginning-of-line)
 394            (point)))))))
 395
 396
 397 (defun view-todo (&optional arg)
 398   "Display the Emacs TODO list."
 399   (interactive "P")
 400   (view-file (expand-file-name "TODO" data-directory)))
 401
 402 (defun view-echo-area-messages ()
 403   "View the log of recent echo-area messages: the `*Messages*' buffer.
 404 The number of messages retained in that buffer
 405 is specified by the variable `message-log-max'."
 406   (interactive)
 407   (switch-to-buffer (get-buffer-create "*Messages*")))
 408
 409 (defun view-order-manuals ()
 410   "Display the Emacs ORDERS file."
 411   (interactive)
 412   (view-file (expand-file-name "ORDERS" data-directory))
 413   (goto-address))
 414
 415 (defun view-emacs-FAQ ()
 416   "Display the Emacs Frequently Asked Questions (FAQ) file."
 417   (interactive)
 418   ;; (find-file-read-only (expand-file-name "FAQ" data-directory))
 419   (info "(efaq)"))
 420
 421 (defun view-emacs-problems ()
 422   "Display info on known problems with Emacs and possible workarounds."
 423   (interactive)
 424   (view-file (expand-file-name "PROBLEMS" data-directory)))
 425
 426 (defun view-lossage ()
 427   "Display last 100 input keystrokes.
 428
 429 To record all your input on a file, use `open-dribble-file'."
 430   (interactive)
 431   (help-setup-xref (list #'view-lossage) (interactive-p))
 432   (with-output-to-temp-buffer (help-buffer)
 433     (princ (mapconcat (lambda (key)
 434                         (if (or (integerp key) (symbolp key) (listp key))
 435                             (single-key-description key)
 436                           (prin1-to-string key nil)))
 437                       (recent-keys)
 438                       " "))
 439     (with-current-buffer standard-output
 440       (goto-char (point-min))
 441       (while (progn (move-to-column 50) (not (eobp)))
 442         (when (search-forward " " nil t)
 443           (delete-char -1))
 444         (insert "\n")))
 445     (print-help-return-message)))
 446
 447 \f
 448 ;; Key bindings
 449
 450 (defun describe-bindings (&optional prefix buffer)
 451   "Show a list of all defined keys, and their definitions.
 452 We put that list in a buffer, and display the buffer.
 453
 454 The optional argument PREFIX, if non-nil, should be a key sequence;
 455 then we display only bindings that start with that prefix.
 456 The optional argument BUFFER specifies which buffer's bindings
 457 to display (default, the current buffer).  BUFFER can be a buffer
 458 or a buffer name."
 459   (interactive)
 460   (or buffer (setq buffer (current-buffer)))
 461   (help-setup-xref (list #'describe-bindings prefix buffer) (interactive-p))
 462   (with-current-buffer buffer
 463     (describe-bindings-internal nil prefix)))
 464
 465 ;; This function used to be in keymap.c.
 466 (defun describe-bindings-internal (&optional menus prefix)
 467   "Show a list of all defined keys, and their definitions.
 468 We put that list in a buffer, and display the buffer.
 469
 470 The optional argument MENUS, if non-nil, says to mention menu bindings.
 471 \(Ordinarily these are omitted from the output.)
 472 The optional argument PREFIX, if non-nil, should be a key sequence;
 473 then we display only bindings that start with that prefix."
 474   (interactive)
 475   (let ((buf (current-buffer)))
 476     (with-output-to-temp-buffer "*Help*"
 477       (with-current-buffer standard-output
 478         (describe-buffer-bindings buf prefix menus)))))
 479
 480 (defun where-is (definition &optional insert)
 481   "Print message listing key sequences that invoke the command DEFINITION.
 482 Argument is a command definition, usually a symbol with a function definition.
 483 If INSERT (the prefix arg) is non-nil, insert the message in the buffer."
 484   (interactive
 485    (let ((fn (function-called-at-point))
 486          (enable-recursive-minibuffers t)
 487          val)
 488      (setq val (completing-read
 489                 (if fn
 490                     (format "Where is command (default %s): " fn)
 491                   "Where is command: ")
 492                 obarray 'commandp t))
 493      (list (if (equal val "") fn (intern val)) current-prefix-arg)))
 494   (unless definition (error "No command"))
 495   (let ((func (indirect-function definition))
 496         (defs nil)
 497         (standard-output (if insert (current-buffer) t)))
 498     ;; In DEFS, find all symbols that are aliases for DEFINITION.
 499     (mapatoms (lambda (symbol)
 500                 (and (fboundp symbol)
 501                      (not (eq symbol definition))
 502                      (eq func (condition-case ()
 503                                   (indirect-function symbol)
 504                                 (error symbol)))
 505                      (push symbol defs))))
 506     ;; Look at all the symbols--first DEFINITION,
 507     ;; then its aliases.
 508     (dolist (symbol (cons definition defs))
 509       (let* ((remapped (command-remapping symbol))
 510              (keys (where-is-internal
 511                     symbol overriding-local-map nil nil remapped))
 512              (keys (mapconcat 'key-description keys ", "))
 513              string)
 514         (setq string
 515               (if insert
 516                   (if (> (length keys) 0)
 517                       (if remapped
 518                           (format "%s (%s) (remapped from %s)"
 519                                   keys remapped symbol)
 520                         (format "%s (%s)" keys symbol))
 521                     (format "M-x %s RET" symbol))
 522                 (if (> (length keys) 0)
 523                     (if remapped
 524                         (format "%s is remapped to %s which is on %s"
 525                                 symbol remapped keys)
 526                       (format "%s is on %s" symbol keys))
 527                   ;; If this is the command the user asked about,
 528                   ;; and it is not on any key, say so.
 529                   ;; For other symbols, its aliases, say nothing
 530                   ;; about them unless they are on keys.
 531                   (if (eq symbol definition)
 532                       (format "%s is not on any key" symbol)))))
 533         (when string
 534           (unless (eq symbol definition)
 535             (princ ";\n its alias "))
 536           (princ string)))))
 537   nil)
 538
 539 (defun help-key-description (key untranslated)
 540   (let ((string (key-description key)))
 541     (if (or (not untranslated)
 542             (and (eq (aref untranslated 0) ?\e) (not (eq (aref key 0) ?\e))))
 543         string
 544       (let ((otherstring (key-description untranslated)))
 545         (if (equal string otherstring)
 546             string
 547           (format "%s (translated from %s)" string otherstring))))))
 548
 549 (defun describe-key-briefly (&optional key insert untranslated)
 550   "Print the name of the function KEY invokes.  KEY is a string.
 551 If INSERT (the prefix arg) is non-nil, insert the message in the buffer.
 552 If non-nil, UNTRANSLATED is a vector of the untranslated events.
 553 It can also be a number in which case the untranslated events from
 554 the last key hit are used.
 555
 556 If KEY is a menu item or a tool-bar button that is disabled, this command
 557 temporarily enables it to allow getting help on disabled items and buttons."
 558   (interactive
 559    (let ((enable-disabled-menus-and-buttons t)
 560          (cursor-in-echo-area t)
 561          saved-yank-menu)
 562      (unwind-protect
 563          (let (key)
 564            ;; If yank-menu is empty, populate it temporarily, so that
 565            ;; "Select and Paste" menu can generate a complete event.
 566            (when (null (cdr yank-menu))
 567              (setq saved-yank-menu (copy-sequence yank-menu))
 568              (menu-bar-update-yank-menu "(any string)" nil))
 569            (setq key (read-key-sequence "Describe key (or click or menu item): "))
 570            ;; If KEY is a down-event, read and discard the
 571            ;; corresponding up-event.  Note that there are also
 572            ;; down-events on scroll bars and mode lines: the actual
 573            ;; event then is in the second element of the vector.
 574            (and (vectorp key)
 575                 (let ((last-idx (1- (length key))))
 576                   (and (eventp (aref key last-idx))
 577                        (memq 'down (event-modifiers (aref key last-idx)))))
 578                 (read-event))
 579            (list
 580             key
 581             (if current-prefix-arg (prefix-numeric-value current-prefix-arg))
 582             1))
 583        ;; Put yank-menu back as it was, if we changed it.
 584        (when saved-yank-menu
 585          (setq yank-menu (copy-sequence saved-yank-menu))
 586          (fset 'yank-menu (cons 'keymap yank-menu))))))
 587   (if (numberp untranslated)
 588       (setq untranslated (this-single-command-raw-keys)))
 589   (let* ((event (if (and (symbolp (aref key 0))
 590                          (> (length key) 1)
 591                          (consp (aref key 1)))
 592                     (aref key 1)
 593                   (aref key 0)))
 594          (modifiers (event-modifiers event))
 595          (standard-output (if insert (current-buffer) t))
 596          (mouse-msg (if (or (memq 'click modifiers) (memq 'down modifiers)
 597                             (memq 'drag modifiers)) " at that spot" ""))
 598          (defn (key-binding key t))
 599          key-desc)
 600     ;; Handle the case where we faked an entry in "Select and Paste" menu.
 601     (if (and (eq defn nil)
 602              (stringp (aref key (1- (length key))))
 603              (eq (key-binding (substring key 0 -1)) 'yank-menu))
 604         (setq defn 'menu-bar-select-yank))
 605     ;; Don't bother user with strings from (e.g.) the select-paste menu.
 606     (if (stringp (aref key (1- (length key))))
 607         (aset key (1- (length key)) "(any string)"))
 608     (if (and (> (length untranslated) 0)
 609              (stringp (aref untranslated (1- (length untranslated)))))
 610         (aset untranslated (1- (length untranslated)) "(any string)"))
 611     ;; Now describe the key, perhaps as changed.
 612     (setq key-desc (help-key-description key untranslated))
 613     (if (or (null defn) (integerp defn) (equal defn 'undefined))
 614         (princ (format "%s%s is undefined" key-desc mouse-msg))
 615       (princ (format "%s%s runs the command %S" key-desc mouse-msg defn)))))
 616
 617 (defun describe-key (&optional key untranslated up-event)
 618   "Display documentation of the function invoked by KEY.
 619 KEY can be any kind of a key sequence; it can include keyboard events,
 620 mouse events, and/or menu events.  When calling from a program,
 621 pass KEY as a string or a vector.
 622
 623 If non-nil, UNTRANSLATED is a vector of the corresponding untranslated events.
 624 It can also be a number, in which case the untranslated events from
 625 the last key sequence entered are used.
 626 UP-EVENT is the up-event that was discarded by reading KEY, or nil.
 627
 628 If KEY is a menu item or a tool-bar button that is disabled, this command
 629 temporarily enables it to allow getting help on disabled items and buttons."
 630   (interactive
 631    (let ((enable-disabled-menus-and-buttons t)
 632          (cursor-in-echo-area t)
 633          saved-yank-menu)
 634      (unwind-protect
 635          (let (key)
 636            ;; If yank-menu is empty, populate it temporarily, so that
 637            ;; "Select and Paste" menu can generate a complete event.
 638            (when (null (cdr yank-menu))
 639              (setq saved-yank-menu (copy-sequence yank-menu))
 640              (menu-bar-update-yank-menu "(any string)" nil))
 641            (setq key (read-key-sequence "Describe key (or click or menu item): "))
 642            (list
 643             key
 644             (prefix-numeric-value current-prefix-arg)
 645             ;; If KEY is a down-event, read and include the
 646             ;; corresponding up-event.  Note that there are also
 647             ;; down-events on scroll bars and mode lines: the actual
 648             ;; event then is in the second element of the vector.
 649             (and (vectorp key)
 650                  (let ((last-idx (1- (length key))))
 651                    (and (eventp (aref key last-idx))
 652                         (memq 'down (event-modifiers (aref key last-idx)))))
 653                  (or (and (eventp (aref key 0))
 654                           (memq 'down (event-modifiers (aref key 0)))
 655                           ;; However, for the C-down-mouse-2 popup
 656                           ;; menu, there is no subsequent up-event.  In
 657                           ;; this case, the up-event is the next
 658                           ;; element in the supplied vector.
 659                           (= (length key) 1))
 660                      (and (> (length key) 1)
 661                           (eventp (aref key 1))
 662                           (memq 'down (event-modifiers (aref key 1)))))
 663                  (read-event))))
 664        ;; Put yank-menu back as it was, if we changed it.
 665        (when saved-yank-menu
 666          (setq yank-menu (copy-sequence saved-yank-menu))
 667          (fset 'yank-menu (cons 'keymap yank-menu))))))
 668   (if (numberp untranslated)
 669       (setq untranslated (this-single-command-raw-keys)))
 670   (let* ((event (aref key (if (and (symbolp (aref key 0))
 671                                    (> (length key) 1)
 672                                    (consp (aref key 1)))
 673                               1
 674                             0)))
 675          (modifiers (event-modifiers event))
 676          (mouse-msg (if (or (memq 'click modifiers) (memq 'down modifiers)
 677                             (memq 'drag modifiers)) " at that spot" ""))
 678          (defn (key-binding key t))
 679          defn-up defn-up-tricky ev-type
 680          mouse-1-remapped mouse-1-tricky)
 681
 682     ;; Handle the case where we faked an entry in "Select and Paste" menu.
 683     (when (and (eq defn nil)
 684                (stringp (aref key (1- (length key))))
 685                (eq (key-binding (substring key 0 -1)) 'yank-menu))
 686       (setq defn 'menu-bar-select-yank))
 687     (if (or (null defn) (integerp defn) (equal defn 'undefined))
 688         (message "%s%s is undefined"
 689                  (help-key-description key untranslated) mouse-msg)
 690       (help-setup-xref (list #'describe-function defn) (interactive-p))
 691       ;; Don't bother user with strings from (e.g.) the select-paste menu.
 692       (when (stringp (aref key (1- (length key))))
 693         (aset key (1- (length key)) "(any string)"))
 694       (when (and untranslated
 695                  (stringp (aref untranslated (1- (length untranslated)))))
 696         (aset untranslated (1- (length untranslated))
 697               "(any string)"))
 698       ;; Need to do this before erasing *Help* buffer in case event
 699       ;; is a mouse click in an existing *Help* buffer.
 700       (when up-event
 701         (setq ev-type (event-basic-type up-event))
 702         (let ((sequence (vector up-event)))
 703           (when (and (eq ev-type 'mouse-1)
 704                      mouse-1-click-follows-link
 705                      (not (eq mouse-1-click-follows-link 'double))
 706                      (setq mouse-1-remapped
 707                            (mouse-on-link-p (event-start up-event))))
 708             (setq mouse-1-tricky (and (integerp mouse-1-click-follows-link)
 709                                       (> mouse-1-click-follows-link 0)))
 710             (cond ((stringp mouse-1-remapped)
 711                    (setq sequence mouse-1-remapped))
 712                   ((vectorp mouse-1-remapped)
 713                    (setcar up-event (elt mouse-1-remapped 0)))
 714                   (t (setcar up-event 'mouse-2))))
 715           (setq defn-up (key-binding sequence nil nil (event-start up-event)))
 716           (when mouse-1-tricky
 717             (setq sequence (vector up-event))
 718             (aset sequence 0 'mouse-1)
 719             (setq defn-up-tricky (key-binding sequence nil nil (event-start up-event))))))
 720       (with-output-to-temp-buffer (help-buffer)
 721         (princ (help-key-description key untranslated))
 722         (princ (format "\
 723 %s runs the command %S
 724   which is "
 725                        mouse-msg defn))
 726         (describe-function-1 defn)
 727         (when up-event
 728           (unless (or (null defn-up)
 729                       (integerp defn-up)
 730                       (equal defn-up 'undefined))
 731             (princ (format "
 732
 733 ----------------- up-event %s----------------
 734
 735 <%S>%s%s runs the command %S
 736   which is "
 737                            (if mouse-1-tricky "(short click) " "")
 738                            ev-type mouse-msg
 739                            (if mouse-1-remapped
 740                                " is remapped to <mouse-2>\nwhich" "")
 741                            defn-up))
 742             (describe-function-1 defn-up))
 743           (unless (or (null defn-up-tricky)
 744                       (integerp defn-up-tricky)
 745                       (eq defn-up-tricky 'undefined))
 746             (princ (format "
 747
 748 ----------------- up-event (long click) ----------------
 749
 750 Pressing <%S>%s for longer than %d milli-seconds
 751 runs the command %S
 752   which is "
 753                            ev-type mouse-msg
 754                            mouse-1-click-follows-link
 755                            defn-up-tricky))
 756             (describe-function-1 defn-up-tricky)))
 757         (print-help-return-message)))))
 758 \f
 759 (defun describe-mode (&optional buffer)
 760   "Display documentation of current major mode and minor modes.
 761 A brief summary of the minor modes comes first, followed by the
 762 major mode description.  This is followed by detailed
 763 descriptions of the minor modes, each on a separate page.
 764
 765 For this to work correctly for a minor mode, the mode's indicator
 766 variable \(listed in `minor-mode-alist') must also be a function
 767 whose documentation describes the minor mode."
 768   (interactive "@")
 769   (unless buffer (setq buffer (current-buffer)))
 770   (help-setup-xref (list #'describe-mode buffer)
 771                    (interactive-p))
 772   ;; For the sake of help-do-xref and help-xref-go-back,
 773   ;; don't switch buffers before calling `help-buffer'.
 774   (with-output-to-temp-buffer (help-buffer)
 775     (with-current-buffer buffer
 776       (let (minor-modes)
 777         ;; Older packages do not register in minor-mode-list but only in
 778         ;; minor-mode-alist.
 779         (dolist (x minor-mode-alist)
 780           (setq x (car x))
 781           (unless (memq x minor-mode-list)
 782             (push x minor-mode-list)))
 783         ;; Find enabled minor mode we will want to mention.
 784         (dolist (mode minor-mode-list)
 785           ;; Document a minor mode if it is listed in minor-mode-alist,
 786           ;; non-nil, and has a function definition.
 787           (let ((fmode (or (get mode :minor-mode-function) mode)))
 788             (and (boundp mode) (symbol-value mode)
 789                  (fboundp fmode)
 790                  (let ((pretty-minor-mode
 791                         (if (string-match "\\(\\(-minor\\)?-mode\\)?\\'"
 792                                           (symbol-name fmode))
 793                             (capitalize
 794                              (substring (symbol-name fmode)
 795                                         0 (match-beginning 0)))
 796                           fmode)))
 797                    (push (list fmode pretty-minor-mode
 798                                (format-mode-line (assq mode minor-mode-alist)))
 799                          minor-modes)))))
 800         (setq minor-modes
 801               (sort minor-modes
 802                     (lambda (a b) (string-lessp (cadr a) (cadr b)))))
 803         (when minor-modes
 804           (princ "Enabled minor modes:\n")
 805           (make-local-variable 'help-button-cache)
 806           (with-current-buffer standard-output
 807             (dolist (mode minor-modes)
 808               (let ((mode-function (nth 0 mode))
 809                     (pretty-minor-mode (nth 1 mode))
 810                     (indicator (nth 2 mode)))
 811                 (add-text-properties 0 (length pretty-minor-mode)
 812                                      '(face bold) pretty-minor-mode)
 813                 (save-excursion
 814                   (goto-char (point-max))
 815                   (princ "\n\f\n")
 816                   (push (point-marker) help-button-cache)
 817                   ;; Document the minor modes fully.
 818                   (insert pretty-minor-mode)
 819                   (princ (format " minor mode (%s):\n"
 820                                  (if (zerop (length indicator))
 821                                      "no indicator"
 822                                    (format "indicator%s"
 823                                            indicator))))
 824                   (princ (documentation mode-function)))
 825                 (insert-button pretty-minor-mode
 826                                'action (car help-button-cache)
 827                                'follow-link t
 828                                'help-echo "mouse-2, RET: show full information")
 829                 (newline)))
 830             (forward-line -1)
 831             (fill-paragraph nil)
 832             (forward-line 1))
 833
 834           (princ "\n(Information about these minor modes follows the major mode info.)\n\n"))
 835         ;; Document the major mode.
 836         (let ((mode mode-name))
 837           (with-current-buffer standard-output
 838             (let ((start (point)))
 839               (insert (format-mode-line mode))
 840               (add-text-properties start (point) '(face bold)))))
 841         (princ " mode:\n")
 842         (princ (documentation major-mode)))
 843       (print-help-return-message))))
 844
 845
 846 (defun describe-minor-mode (minor-mode)
 847   "Display documentation of a minor mode given as MINOR-MODE.
 848 MINOR-MODE can be a minor mode symbol or a minor mode indicator string
 849 appeared on the mode-line."
 850   (interactive (list (completing-read
 851                       "Minor mode: "
 852                               (nconc
 853                                (describe-minor-mode-completion-table-for-symbol)
 854                                (describe-minor-mode-completion-table-for-indicator)
 855                                ))))
 856   (if (symbolp minor-mode)
 857       (setq minor-mode (symbol-name minor-mode)))
 858   (let ((symbols (describe-minor-mode-completion-table-for-symbol))
 859         (indicators (describe-minor-mode-completion-table-for-indicator)))
 860     (cond
 861      ((member minor-mode symbols)
 862       (describe-minor-mode-from-symbol (intern minor-mode)))
 863      ((member minor-mode indicators)
 864       (describe-minor-mode-from-indicator minor-mode))
 865      (t
 866       (error "No such minor mode: %s" minor-mode)))))
 867
 868 ;; symbol
 869 (defun describe-minor-mode-completion-table-for-symbol ()
 870   ;; In order to list up all minor modes, minor-mode-list
 871   ;; is used here instead of minor-mode-alist.
 872   (delq nil (mapcar 'symbol-name minor-mode-list)))
 873 (defun describe-minor-mode-from-symbol (symbol)
 874   "Display documentation of a minor mode given as a symbol, SYMBOL"
 875   (interactive (list (intern (completing-read
 876                               "Minor mode symbol: "
 877                               (describe-minor-mode-completion-table-for-symbol)))))
 878   (if (fboundp symbol)
 879       (describe-function symbol)
 880     (describe-variable symbol)))
 881
 882 ;; indicator
 883 (defun describe-minor-mode-completion-table-for-indicator ()
 884   (delq nil
 885         (mapcar (lambda (x)
 886                   (let ((i (format-mode-line x)))
 887                     ;; remove first space if existed
 888                     (cond
 889                      ((= 0 (length i))
 890                       nil)
 891                      ((eq (aref i 0) ?\s)
 892                       (substring i 1))
 893                      (t
 894                       i))))
 895                 minor-mode-alist)))
 896 (defun describe-minor-mode-from-indicator (indicator)
 897   "Display documentation of a minor mode specified by INDICATOR.
 898 If you call this function interactively, you can give indicator which
 899 is currently activated with completion."
 900   (interactive (list
 901                 (completing-read
 902                  "Minor mode indicator: "
 903                  (describe-minor-mode-completion-table-for-indicator))))
 904   (let ((minor-mode (lookup-minor-mode-from-indicator indicator)))
 905     (if minor-mode
 906         (describe-minor-mode-from-symbol minor-mode)
 907       (error "Cannot find minor mode for `%s'" indicator))))
 908
 909 (defun lookup-minor-mode-from-indicator (indicator)
 910   "Return a minor mode symbol from its indicator on the modeline."
 911   ;; remove first space if existed
 912   (if (and (< 0 (length indicator))
 913            (eq (aref indicator 0) ?\s))
 914       (setq indicator (substring indicator 1)))
 915   (let ((minor-modes minor-mode-alist)
 916         result)
 917     (while minor-modes
 918       (let* ((minor-mode (car (car minor-modes)))
 919              (anindicator (format-mode-line
 920                            (car (cdr (car minor-modes))))))
 921         ;; remove first space if existed
 922         (if (and (stringp anindicator)
 923                  (> (length anindicator) 0)
 924                  (eq (aref anindicator 0) ?\s))
 925             (setq anindicator (substring anindicator 1)))
 926         (if (equal indicator anindicator)
 927             (setq result minor-mode
 928                   minor-modes nil)
 929           (setq minor-modes (cdr minor-modes)))))
 930     result))
 931
 932 \f
 933 ;;; Automatic resizing of temporary buffers.
 934
 935 (defcustom temp-buffer-max-height (lambda (buffer) (/ (- (frame-height) 2) 2))
 936   "Maximum height of a window displaying a temporary buffer.
 937 This is effective only when Temp Buffer Resize mode is enabled.
 938 The value is the maximum height (in lines) which `resize-temp-buffer-window'
 939 will give to a window displaying a temporary buffer.
 940 It can also be a function to be called to choose the height for such a buffer.
 941 It gets one argumemt, the buffer, and should return a positive integer."
 942   :type '(choice integer function)
 943   :group 'help
 944   :version "20.4")
 945
 946 (define-minor-mode temp-buffer-resize-mode
 947   "Toggle the mode which makes windows smaller for temporary buffers.
 948 With prefix argument ARG, turn the resizing of windows displaying temporary
 949 buffers on if ARG is positive or off otherwise.
 950 This makes the window the right height for its contents, but never
 951 more than `temp-buffer-max-height' nor less than `window-min-height'.
 952 This applies to `help', `apropos' and `completion' buffers, and some others."
 953   :global t :group 'help
 954   (if temp-buffer-resize-mode
 955       ;; `help-make-xrefs' may add a `back' button and thus increase the
 956       ;; text size, so `resize-temp-buffer-window' must be run *after* it.
 957       (add-hook 'temp-buffer-show-hook 'resize-temp-buffer-window 'append)
 958     (remove-hook 'temp-buffer-show-hook 'resize-temp-buffer-window)))
 959
 960 (defun resize-temp-buffer-window ()
 961   "Resize the selected window to fit its contents.
 962 Will not make it higher than `temp-buffer-max-height' nor smaller than
 963 `window-min-height'.  Do nothing if it is the only window on its frame, if it
 964 is not as wide as the frame or if some of the window's contents are scrolled
 965 out of view."
 966   (unless (or (one-window-p 'nomini)
 967               (not (pos-visible-in-window-p (point-min)))
 968               (not (window-full-width-p)))
 969     (fit-window-to-buffer
 970      (selected-window)
 971      (if (functionp temp-buffer-max-height)
 972          (funcall temp-buffer-max-height (current-buffer))
 973        temp-buffer-max-height))))
 974
 975 \f
 976 (provide 'help)
 977
 978 ;; arch-tag: cf427352-27e9-49b7-9a6f-741ebab02423
 979 ;;; help.el ends here