lisp/autorevert.el

   1 ;;; autorevert.el --- revert buffers when files on disk change
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Anders Lindgren <andersl@andersl.com>
   6 ;; Keywords: convenience
   7 ;; Created: 1997-06-01
   8 ;; Date: 1999-11-30
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Introduction:
  30 ;;
  31 ;; Whenever a file that Emacs is editing has been changed by another
  32 ;; program the user normally has to execute the command `revert-buffer'
  33 ;; to load the new content of the file into Emacs.
  34 ;;
  35 ;; This package contains two minor modes: Global Auto-Revert Mode and
  36 ;; Auto-Revert Mode.  Both modes automatically revert buffers
  37 ;; whenever the corresponding files have been changed on disk.
  38 ;;
  39 ;; Auto-Revert Mode can be activated for individual buffers.
  40 ;; Global Auto-Revert Mode applies to all file buffers.
  41 ;;
  42 ;; Both modes operate by checking the time stamp of all files at
  43 ;; intervals of `auto-revert-interval'.  The default is every five
  44 ;; seconds.  The check is aborted whenever the user actually uses
  45 ;; Emacs.  You should never even notice that this package is active
  46 ;; (except that your buffers will be reverted, of course).
  47
  48 ;; Usage:
  49 ;;
  50 ;; Go to the appropriate buffer and press:
  51 ;;   M-x auto-revert-mode RET
  52 ;;
  53 ;; To activate Global Auto-Revert Mode, press:
  54 ;;   M-x global-auto-revert-mode RET
  55 ;;
  56 ;; To activate Global Auto-Revert Mode every time Emacs is started
  57 ;; customise the option `global-auto-revert-mode' or the following
  58 ;; line could be added to your ~/.emacs:
  59 ;;   (global-auto-revert-mode 1)
  60 ;;
  61 ;; The function `turn-on-auto-revert-mode' could be added to any major
  62 ;; mode hook to activate Auto-Revert Mode for all buffers in that
  63 ;; mode.  For example, the following line will activate Auto-Revert
  64 ;; Mode in all C mode buffers:
  65 ;;
  66 ;; (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)
  67
  68 ;;; Code:
  69
  70 ;; Dependencies:
  71
  72 (require 'timer)
  73 (autoload 'dired-get-filename "dired")
  74 (autoload 'vc-workfile-version "vc-hooks")
  75 (autoload 'vc-mode-line        "vc-hooks")
  76
  77 (eval-when-compile
  78   (defvar dired-directory)
  79   (defvar vc-mode)
  80   (require 'cl))
  81
  82
  83 ;; Custom Group:
  84 ;;
  85 ;; The two modes will be placed next to Auto Save Mode under the
  86 ;; Files group under Emacs.
  87
  88 (defgroup auto-revert nil
  89   "Revert individual buffers when files on disk change.
  90
  91 Auto-Revert Mode can be activated for individual buffer.
  92 Global Auto-Revert Mode applies to all buffers."
  93   :group 'files
  94   :group 'convenience)
  95
  96
  97 ;; Variables:
  98
  99 ;; Autoload for the benefit of `make-mode-line-mouse-sensitive'.
 100 ;;;###autoload
 101 (defvar auto-revert-mode nil
 102   "*Non-nil when Auto-Revert Mode is active.
 103 Never set this variable directly, use the command `auto-revert-mode' instead.")
 104 (put 'auto-revert-mode 'permanent-local t)
 105
 106 (defvar auto-revert-timer nil
 107   "Timer used by Auto-Revert Mode.")
 108
 109 (defcustom auto-revert-interval 5
 110   "Time, in seconds, between Auto-Revert Mode file checks.
 111 The value may be an integer or floating point number.
 112
 113 If a timer is already active, there are two ways to make sure
 114 that the new value will take effect immediately.  You can set
 115 this variable through Custom or you can call the command
 116 `auto-revert-set-timer' after setting the variable.  Otherwise,
 117 the new value will take effect the first time Auto Revert Mode
 118 calls `auto-revert-set-timer' for internal reasons or in your
 119 next editing session."
 120   :group 'auto-revert
 121   :type 'number
 122   :set (lambda (variable value)
 123          (set-default variable value)
 124          (and (boundp 'auto-revert-timer)
 125               auto-revert-timer
 126               (auto-revert-set-timer))))
 127
 128 (defcustom auto-revert-stop-on-user-input t
 129   "When non-nil Auto-Revert Mode stops checking files on user input."
 130   :group 'auto-revert
 131   :type 'boolean)
 132
 133 (defcustom auto-revert-verbose t
 134   "When nil, Auto-Revert Mode will not generate any messages.
 135
 136 Currently, messages are generated when the mode is activated or
 137 deactivated, and whenever a file is reverted."
 138   :group 'auto-revert
 139   :type 'boolean)
 140
 141 (defcustom auto-revert-mode-text " ARev"
 142   "String to display in the mode line when Auto-Revert Mode is active.
 143
 144 \(When the string is not empty, make sure that it has a leading space.)"
 145   :tag "Auto Revert Mode Text"          ; To separate it from `global-...'
 146   :group 'auto-revert
 147   :type 'string)
 148
 149 (defcustom auto-revert-mode-hook nil
 150   "Functions to run when Auto-Revert Mode is activated."
 151   :tag "Auto Revert Mode Hook"          ; To separate it from `global-...'
 152   :group 'auto-revert
 153   :type 'hook)
 154
 155 (defcustom global-auto-revert-mode-text ""
 156   "String to display when Global Auto-Revert Mode is active.
 157
 158 The default is nothing since when this mode is active this text doesn't
 159 vary over time, or between buffers.  Hence mode line text
 160 would only waste precious space."
 161   :group 'auto-revert
 162   :type 'string)
 163
 164 (defcustom global-auto-revert-mode-hook nil
 165   "Hook called when Global Auto-Revert Mode is activated."
 166   :group 'auto-revert
 167   :type 'hook)
 168
 169 (defcustom global-auto-revert-non-file-buffers nil
 170   "When nil only file buffers are reverted by Global Auto-Revert Mode.
 171
 172 When non-nil, both file buffers and buffers with a custom
 173 `revert-buffer-function' are reverted by Global Auto-Revert Mode.
 174
 175 Use this option with care since it could lead to excessive reverts."
 176   :group 'auto-revert
 177   :type 'boolean)
 178
 179 (defcustom global-auto-revert-ignore-modes '()
 180   "List of major modes Global Auto-Revert Mode should not check."
 181   :group 'auto-revert
 182   :type '(repeat sexp))
 183
 184 (defcustom auto-revert-load-hook nil
 185   "Functions to run when Auto-Revert Mode is first loaded."
 186   :tag "Load Hook"
 187   :group 'auto-revert
 188   :type 'hook)
 189
 190 (defvar global-auto-revert-ignore-buffer nil
 191   "*When non-nil, Global Auto-Revert Mode will not revert this buffer.
 192
 193 This variable becomes buffer local when set in any fashion.")
 194 (make-variable-buffer-local 'global-auto-revert-ignore-buffer)
 195
 196
 197 ;; Internal variables:
 198
 199 (defvar auto-revert-buffer-list '()
 200   "List of buffers in Auto-Revert Mode.
 201
 202 Note that only Auto-Revert Mode, never Global Auto-Revert Mode, adds
 203 buffers to this list.
 204
 205 The timer function `auto-revert-buffers' is responsible for purging
 206 the list of old buffers.")
 207
 208 (defvar auto-revert-remaining-buffers '()
 209   "Buffers not checked when user input stopped execution.")
 210
 211
 212 ;; Functions:
 213
 214 ;;;###autoload
 215 (define-minor-mode auto-revert-mode
 216   "Toggle reverting buffer when file on disk changes.
 217
 218 With arg, turn Auto Revert mode on if and only if arg is positive.
 219 This is a minor mode that affects only the current buffer.
 220 Use `global-auto-revert-mode' to automatically revert all buffers."
 221   nil auto-revert-mode-text nil
 222   (if auto-revert-mode
 223       (if (not (memq (current-buffer) auto-revert-buffer-list))
 224           (push (current-buffer) auto-revert-buffer-list))
 225     (setq auto-revert-buffer-list
 226           (delq (current-buffer) auto-revert-buffer-list)))
 227   (auto-revert-set-timer)
 228   (when auto-revert-mode
 229     (auto-revert-buffers)))
 230
 231
 232 ;;;###autoload
 233 (defun turn-on-auto-revert-mode ()
 234   "Turn on Auto-Revert Mode.
 235
 236 This function is designed to be added to hooks, for example:
 237   (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)"
 238   (auto-revert-mode 1))
 239
 240
 241 ;;;###autoload
 242 (define-minor-mode global-auto-revert-mode
 243   "Revert any buffer when file on disk change.
 244
 245 With arg, turn Auto Revert mode on globally if and only if arg is positive.
 246 This is a minor mode that affects all buffers.
 247 Use `auto-revert-mode' to revert a particular buffer."
 248   :global t :group 'auto-revert :lighter global-auto-revert-mode-text
 249   (auto-revert-set-timer)
 250   (when global-auto-revert-mode
 251     (auto-revert-buffers)))
 252
 253
 254 (defun auto-revert-set-timer ()
 255   "Restart or cancel the timer."
 256   (interactive)
 257   (if (timerp auto-revert-timer)
 258       (cancel-timer auto-revert-timer))
 259   (setq auto-revert-timer
 260         (if (or global-auto-revert-mode auto-revert-buffer-list)
 261             (run-with-timer auto-revert-interval
 262                             auto-revert-interval
 263                             'auto-revert-buffers)
 264           nil)))
 265
 266 (defun auto-revert-active-p ()
 267   "Check if auto-revert is active (in current buffer or globally)."
 268   (or auto-revert-mode
 269       (and
 270        global-auto-revert-mode
 271        (not global-auto-revert-ignore-buffer)
 272        (not (memq major-mode
 273                   global-auto-revert-ignore-modes)))))
 274
 275 (defun auto-revert-list-diff (a b)
 276   "Check if strings in list A differ from list B."
 277   (when (and a b)
 278     (setq a (sort a 'string-lessp))
 279     (setq b (sort b 'string-lessp))
 280     (let (elt1 elt2)
 281       (catch 'break
 282         (while (and (setq elt1 (and a (pop a)))
 283                     (setq elt2 (and b (pop b))))
 284           (if (not (string= elt1 elt2))
 285               (throw 'break t)))))))
 286
 287 (defun auto-revert-dired-file-list ()
 288   "Return list of dired files."
 289   (let (file list)
 290     (save-excursion
 291       (goto-char (point-min))
 292       (while (not (eobp))
 293         (if (setq file (dired-get-filename t t))
 294             (push file list))
 295         (forward-line 1)))
 296     list))
 297
 298 (defun auto-revert-dired-changed-p ()
 299   "Check if dired buffer has changed."
 300   (when (and (stringp dired-directory)
 301              ;;   Exclude remote buffers, would be too slow for user
 302              ;;   modem, timeouts, network lag ... all is possible
 303              (not (string-match "@" dired-directory))
 304              (file-directory-p dired-directory))
 305     (let ((files (directory-files dired-directory))
 306           (dired (auto-revert-dired-file-list)))
 307       (or (not (eq (length files) (length dired)))
 308           (auto-revert-list-diff files dired)))))
 309
 310 (defun auto-revert-buffer-p ()
 311   "Check if current buffer should be reverted."
 312   ;;  - Always include dired buffers to list.  It would be too expensive
 313   ;;  to test the "revert" status here each time timer launches.
 314   ;;  - Same for VC buffers.
 315   (or (and (eq major-mode 'dired-mode)
 316            (or (and global-auto-revert-mode
 317                     global-auto-revert-non-file-buffers)
 318                auto-revert-mode))
 319       (and (not (buffer-modified-p))
 320            (auto-revert-vc-buffer-p))
 321       (and (not (buffer-modified-p))
 322            (if (buffer-file-name)
 323                (and (file-readable-p (buffer-file-name))
 324                     (not (verify-visited-file-modtime (current-buffer))))
 325              (and revert-buffer-function
 326                   (or (and global-auto-revert-mode
 327                            global-auto-revert-non-file-buffers)
 328                       auto-revert-mode))))))
 329
 330 (defun auto-revert-vc-cvs-file-version (file)
 331   "Get version of FILE by reading control file on disk."
 332   (let* ((control "CVS/Entries")
 333          (name    (file-name-nondirectory file))
 334          (path    (format "%s/%s"
 335                           (file-name-directory file)
 336                           control)))
 337     (when (file-exists-p path)
 338       (with-temp-buffer
 339         (insert-file-contents-literally path)
 340         (goto-char (point-min))
 341         (when (re-search-forward
 342                ;; /file.txt/1.3/Mon Sep 15 18:43:20 2003//
 343                (format "%s/\\([.0-9]+\\)" (regexp-quote name))
 344                nil t)
 345           (match-string 1))))))
 346
 347 (defun auto-revert-vc-buffer-p ()
 348   "Check if buffer is version controlled."
 349   (and (boundp 'vc-mode)
 350        (string-match "[0-9]" (or vc-mode ""))))
 351
 352 (defun auto-revert-handler-vc ()
 353   "Check if version controlled buffer needs revert."
 354   ;; [Emacs 1]
 355   ;; 1. File is saved     (*)
 356   ;; 2. checkin is done 1.1 -> 1.2
 357   ;; 3. VC reverts, so that updated version number is shown in mode line
 358   ;;
 359   ;; Suppose the same file has been opened in another Emacs and
 360   ;; autorevert.el is on.
 361   ;;
 362   ;; [Emacs 2]
 363   ;; 1. Step (1) is detected and buffer is reverted.
 364   ;; 2. But check in does not always change the file in dis, but possibly only
 365   ;;    control files like CVS/Entries
 366   ;; 3. The buffer is not reverted to update VC version line.
 367   ;;    Incorrect version number 1.1 is shown in this Emacs
 368   ;;
 369   (when (featurep 'vc)
 370     (let* ((file           (buffer-file-name))
 371            (backend        (vc-backend (buffer-file-name)))
 372            (version-buffer (vc-workfile-version file)))
 373       (when (stringp version-buffer)
 374         (cond
 375          ((eq backend 'CVS)
 376           (let ((version-file
 377                  (auto-revert-vc-cvs-file-version (buffer-file-name))))
 378             (and (stringp version-file)
 379                  (not (string-match version-file version-buffer)))))
 380          ((eq backend 'RCS)
 381           ;; TODO:
 382           ))))))
 383
 384 (defun auto-revert-handler ()
 385   "Revert current buffer."
 386   (let (revert)
 387     (cond
 388      ((eq major-mode 'dired-mode)
 389       ;;  Dired includes revert-buffer-function
 390       (when (and revert-buffer-function
 391                  (auto-revert-dired-changed-p))
 392         (setq revert t)))
 393      ((auto-revert-vc-buffer-p)
 394       (when (auto-revert-handler-vc)
 395         (setq revert 'vc)))
 396      ((or (buffer-file-name)
 397           revert-buffer-function)
 398       (setq revert t)))
 399     (when revert
 400       (revert-buffer 'ignore-auto 'dont-ask 'preserve-modes)
 401       (if (eq revert 'vc)
 402           (vc-mode-line buffer-file-name))
 403       (if auto-revert-verbose
 404           (message "Reverting buffer `%s'." (buffer-name))))))
 405
 406 (defun auto-revert-buffers ()
 407   "Revert buffers as specified by Auto-Revert and Global Auto-Revert Mode.
 408
 409 Should `global-auto-revert-mode' be active all file buffers are checked.
 410
 411 Should `auto-revert-mode' be active in some buffers, those buffers
 412 are checked.
 413
 414 Non-file buffers that have a custom `revert-buffer-function' are
 415 reverted either when Auto-Revert Mode is active in that buffer, or
 416 when the variable `global-auto-revert-non-file-buffers' is non-nil
 417 and Global Auto-Revert Mode is active.
 418
 419 This function stops whenever there is user input.  The buffers not
 420 checked are stored in the variable `auto-revert-remaining-buffers'.
 421
 422 To avoid starvation, the buffers in `auto-revert-remaining-buffers'
 423 are checked first the next time this function is called.
 424
 425 This function is also responsible for removing buffers no longer in
 426 Auto-Revert mode from `auto-revert-buffer-list', and for canceling
 427 the timer when no buffers need to be checked."
 428   (let ((bufs (if global-auto-revert-mode
 429                   (buffer-list)
 430                 auto-revert-buffer-list))
 431         (remaining '())
 432         (new '()))
 433     ;; Partition `bufs' into two halves depending on whether or not
 434     ;; the buffers are in `auto-revert-remaining-buffers'.  The two
 435     ;; halves are then re-joined with the "remaining" buffers at the
 436     ;; head of the list.
 437     (dolist (buf auto-revert-remaining-buffers)
 438       (if (memq buf bufs)
 439           (push buf remaining)))
 440     (dolist (buf bufs)
 441       (if (not (memq buf remaining))
 442           (push buf new)))
 443     (setq bufs (nreverse (nconc new remaining)))
 444     (while (and bufs
 445                 (not (and auto-revert-stop-on-user-input
 446                           (input-pending-p))))
 447       (let ((buf (car bufs)))
 448         (if (buffer-name buf)           ; Buffer still alive?
 449             (with-current-buffer buf
 450               ;; Test if someone has turned off Auto-Revert Mode in a
 451               ;; non-standard way, for example by changing major mode.
 452               (if (and (not auto-revert-mode)
 453                        (memq buf auto-revert-buffer-list))
 454                   (setq auto-revert-buffer-list
 455                         (delq buf auto-revert-buffer-list)))
 456               (when (and (auto-revert-active-p)
 457                          (auto-revert-buffer-p))
 458                 (auto-revert-handler)
 459                 ;; `preserve-modes' avoids changing the (minor) modes.  But we
 460                 ;; do want to reset the mode for VC, so we do it explicitly.
 461                 (vc-find-file-hook)))
 462           ;; Remove dead buffer from `auto-revert-buffer-list'.
 463           (setq auto-revert-buffer-list
 464                 (delq buf auto-revert-buffer-list))))
 465       (setq bufs (cdr bufs)))
 466     (setq auto-revert-remaining-buffers bufs)
 467     ;; Check if we should cancel the timer.
 468     (when (and (not global-auto-revert-mode)
 469                (null auto-revert-buffer-list))
 470       (cancel-timer auto-revert-timer)
 471       (setq auto-revert-timer nil))))
 472
 473
 474 ;; The end:
 475 (provide 'autorevert)
 476
 477 (run-hooks 'auto-revert-load-hook)
 478
 479 ;;; arch-tag: f6bcb07b-4841-477e-9e44-b18678e58876
 480 ;;; autorevert.el ends here