lisp/startup.el

   1 ;;; startup.el --- process Emacs shell arguments
   2
   3 ;; Copyright (C) 1985, 1986, 1992, 1994 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ; These are processed only at the beginning of the argument list.
  27 ; -batch                execute noninteractively (messages go to stdout,
  28 ;                        variable noninteractive set to t)
  29 ;                        This option must be the first in the arglist.
  30 ;                        Processed by `main' in emacs.c -- never seen by lisp
  31 ; -t file               Specify to use file rather than stdin/stdout
  32 ;                        as the terminal.
  33 ;                        This option must be the first in the arglist.
  34 ;                        Processed by `main' in emacs.c -- never seen by lisp
  35 ; -nw                   Inhibit the use of any window-system-specific display
  36 ;                        code; use the current virtual terminal.
  37 ;                        This option must be the first in the arglist.
  38 ;                        Processed by `main' in emacs.c -- never seen by lisp
  39 ; -q                    load no init file
  40 ; -no-init-file         same
  41 ; -u user               load user's init file
  42 ; -user user            same
  43 ; -debug-init           Don't catch errors in init file; let debugger run.
  44
  45 ; These are processed in the order encountered.
  46 ; -f function           execute function
  47 ; -funcall function     same
  48 ; -l file               load file
  49 ; -load file            same
  50 ; -insert file          same
  51 ; file                  visit file
  52 ; -kill                 kill (exit) emacs
  53
  54 ;;; Code:
  55
  56 (setq top-level '(normal-top-level))
  57
  58 (defvar command-line-processed nil "t once command line has been processed")
  59
  60 (defconst inhibit-startup-message nil
  61   "*Non-nil inhibits the initial startup message.
  62 This is for use in your personal init file, once you are familiar
  63 with the contents of the startup message.")
  64
  65 (defconst inhibit-startup-echo-area-message nil
  66   "*Non-nil inhibits the initial startup echo area message.
  67 Inhibition takes effect only if your `.emacs' file contains
  68 a line of the form
  69  (setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\")
  70 Thus, someone else using a copy of your `.emacs' file will see
  71 the startup message unless he personally acts to inhibit it.")
  72
  73 (defconst inhibit-default-init nil
  74   "*Non-nil inhibits loading the `default' library.")
  75
  76 (defconst command-switch-alist nil
  77   "Alist of command-line switches.
  78 Elements look like (SWITCH-STRING . HANDLER-FUNCTION).
  79 HANDLER-FUNCTION receives switch name as sole arg;
  80 remaining command-line args are in the variable `command-line-args-left'.")
  81
  82 (defvar command-line-functions nil    ;; lrs 7/31/89
  83   "List of functions to process unrecognized command-line arguments.
  84 Each function should access the dynamically bound variables
  85 `argi' (the current argument) and `command-line-args-left' (the remaining
  86 arguments).  The function should return non-nil only if it recognizes and
  87 processes `argi'.  If it does so, it may consume successive arguments by
  88 altering `command-line-args-left' to remove them.")
  89
  90 (defvar command-line-default-directory nil
  91   "Default directory to use for command line arguments.
  92 This is normally copied from `default-directory' when Emacs starts.")
  93
  94 (defvar before-init-hook nil
  95   "Functions to call after handling urgent options but before init files.
  96 The frame system uses this to open frames to display messages while
  97 Emacs loads the user's initialization file.")
  98
  99 (defvar after-init-hook nil
 100   "Functions to call after loading the init file (`~/.emacs').
 101 The call is not protected by a condition-case, so you can set `debug-on-error'
 102 in `.emacs', and put all the actual code on `after-init-hook'.")
 103
 104 (defvar term-setup-hook nil
 105   "Functions to be called after loading terminal-specific Lisp code.
 106 See `run-hooks'.  This variable exists for users to set,
 107 so as to override the definitions made by the terminal-specific file.
 108 Emacs never sets this variable itself.")
 109
 110 (defvar keyboard-type nil
 111   "The brand of keyboard you are using.
 112 This variable is used to define
 113 the proper function and keypad keys for use under X.  It is used in a
 114 fashion analogous to the environment value TERM.")
 115
 116 (defvar window-setup-hook nil
 117   "Normal hook run to initialize window system display.
 118 Emacs runs this hook after processing the command line arguments and loading
 119 the user's init file.")
 120
 121 (defconst initial-major-mode 'lisp-interaction-mode
 122   "Major mode command symbol to use for the initial *scratch* buffer.")
 123
 124 (defvar init-file-user nil
 125   "Identity of user whose `.emacs' file is or was read.
 126 The value is nil if no init file is being used; otherwise, it may be either
 127 the null string, meaning that the init file was taken from the user that
 128 originally logged in, or it may be a string containing a user's name.
 129
 130 In either of the latter cases, `(concat \"~\" init-file-user \"/\")'
 131 evaluates to the name of the directory where the `.emacs' file was
 132 looked for.")
 133
 134 (defvar site-run-file "site-start"
 135   "File containing site-wide run-time initializations.
 136 This file is loaded at run-time before `~/.emacs'.  It contains inits
 137 that need to be in place for the entire site, but which, due to their
 138 higher incidence of change, don't make sense to load into emacs'
 139 dumped image.  Thus, the run-time load order is: 1. file described in
 140 this variable, if non-nil; 2. `~/.emacs'; 3. `default.el'.")
 141
 142 (defvar init-file-debug nil)
 143
 144 (defvar init-file-had-error nil)
 145
 146 (defun normal-top-level ()
 147   (if command-line-processed
 148       (message "Back to top level.")
 149     (setq command-line-processed t)
 150     (if (not (eq system-type 'vax-vms))
 151         (progn
 152           ;; If the PWD environment variable isn't accurate, delete it.
 153           (let ((pwd (getenv "PWD")))
 154             (and (stringp pwd)
 155                  ;; Use FOO/., so that if FOO is a symlink, file-attributes
 156                  ;; describes the directory linked to, not FOO itself.
 157                  (or (equal (file-attributes
 158                              (concat (file-name-as-directory pwd) "."))
 159                             (file-attributes
 160                              (concat (file-name-as-directory default-directory)
 161                                      ".")))
 162                      (setq process-environment
 163                            (delete (concat "PWD=" pwd)
 164                                    process-environment)))))))
 165     (setq default-directory (abbreviate-file-name default-directory))
 166     (unwind-protect
 167         (command-line)
 168       ;; Do this again, in case .emacs defined more abbreviations.
 169       (setq default-directory (abbreviate-file-name default-directory))
 170       (run-hooks 'emacs-startup-hook)
 171       (and term-setup-hook
 172            (run-hooks 'term-setup-hook))
 173       ;; Modify the initial frame based on what .emacs puts into
 174       ;; ...-frame-alist.
 175       (if (fboundp 'frame-notice-user-settings)
 176           (frame-notice-user-settings))
 177       ;; Now we know the user's default font, so add it to the menu.
 178       (if (fboundp 'font-menu-add-default)
 179           (font-menu-add-default))
 180       (and window-setup-hook
 181            (run-hooks 'window-setup-hook)))))
 182
 183 (defun command-line ()
 184   (setq command-line-default-directory default-directory)
 185
 186   ;; See if we should import version-control from the environment variable.
 187   (let ((vc (getenv "VERSION_CONTROL")))
 188     (cond ((eq vc nil))                 ;don't do anything if not set
 189           ((or (string= vc "t")
 190                (string= vc "numbered"))
 191            (setq version-control t))
 192           ((or (string= vc "nil")
 193                (string= vc "existing"))
 194            (setq version-control nil))
 195           ((or (string= vc "never")
 196                (string= vc "simple"))
 197            (setq version-control 'never))))
 198
 199   ;;! This has been commented out; I currently find the behavior when
 200   ;;! split-window-keep-point is nil disturbing, but if I can get used
 201   ;;! to it, then it would be better to eliminate the option.
 202   ;;! ;; Choose a good default value for split-window-keep-point.
 203   ;;! (setq split-window-keep-point (> baud-rate 2400))
 204
 205   ;; Read window system's init file if using a window system.
 206   (if (and window-system (not noninteractive))
 207       (load (concat term-file-prefix
 208                     (symbol-name window-system)
 209                     "-win")
 210             ;; Every window system should have a startup file;
 211             ;; barf if we can't find it.
 212             nil t))
 213
 214   (let ((done nil)
 215         (args (cdr command-line-args)))
 216
 217     ;; Figure out which user's init file to load,
 218     ;; either from the environment or from the options.
 219     (setq init-file-user (if noninteractive nil (user-login-name)))
 220     ;; If user has not done su, use current $HOME to find .emacs.
 221     (and init-file-user (string= init-file-user (user-real-login-name))
 222          (setq init-file-user ""))
 223
 224     ;; Process the command-line args, and delete the arguments
 225     ;; processed.  This is consistent with the way main in emacs.c
 226     ;; does things.
 227     (while (and (not done) args)
 228       (let ((argi (car args)))
 229         (cond
 230          ((or (string-equal argi "-q")
 231               (string-equal argi "-no-init-file"))
 232           (setq init-file-user nil
 233                 args (cdr args)))
 234          ((or (string-equal argi "-u")
 235               (string-equal argi "-user"))
 236           (setq args (cdr args)
 237                 init-file-user (car args)
 238                 args (cdr args)))
 239          ((string-equal argi "-no-site-file")
 240           (setq site-run-file nil
 241                 args (cdr args)))
 242          ((string-equal argi "-debug-init")
 243           (setq init-file-debug t
 244                 args (cdr args)))
 245          (t (setq done t)))))
 246
 247     ;; Re-attach the program name to the front of the arg list.
 248     (setcdr command-line-args args))
 249
 250   ;; Under X Windows, this creates the X frame and deletes the terminal frame.
 251   (if (fboundp 'face-initialize)
 252       (face-initialize))
 253   (if (fboundp 'frame-initialize)
 254       (frame-initialize))
 255
 256   (run-hooks 'before-init-hook)
 257
 258   ;; Run the site-start library if it exists.  The point of this file is
 259   ;; that it is run before .emacs.  There is no point in doing this after
 260   ;; .emacs; that is useless.
 261   (if site-run-file
 262       (load site-run-file t t))
 263
 264   ;; Sites should not disable this.  Only individuals should disable
 265   ;; the startup message.
 266   (setq inhibit-startup-message nil)
 267
 268   ;; Load that user's init file, or the default one, or none.
 269   (let (debug-on-error-from-init-file
 270         debug-on-error-should-be-set
 271         (debug-on-error-initial
 272          (if (eq init-file-debug t) 'startup init-file-debug)))
 273     (let ((debug-on-error debug-on-error-initial)
 274           ;; This function actually reads the init files.
 275           (inner
 276            (function
 277             (lambda ()
 278               (if init-file-user
 279                   (progn
 280                     (setq user-init-file
 281                           (cond
 282                            ((eq system-type 'ms-dos)
 283                             (concat "~" init-file-user "/_emacs"))
 284                            ((eq system-type 'vax-vms)
 285                             "sys$login:.emacs")
 286                            (t
 287                             (concat "~" init-file-user "/.emacs"))))
 288                     (load user-init-file t t t)
 289                     (or inhibit-default-init
 290                         (let ((inhibit-startup-message nil))
 291                           ;; Users are supposed to be told their rights.
 292                           ;; (Plus how to get help and how to undo.)
 293                           ;; Don't you dare turn this off for anyone
 294                           ;; except yourself.
 295                           (load "default" t t)))))))))
 296       (if init-file-debug
 297           ;; Do this without a condition-case if the user wants to debug.
 298           (funcall inner)
 299         (condition-case error
 300             (progn
 301               (funcall inner)
 302               (setq init-file-had-error nil))
 303           (error (message "Error in init file: %s%s%s"
 304                           (get (car error) 'error-message)
 305                           (if (cdr error) ": " "")
 306                           (mapconcat 'prin1-to-string (cdr error) ", "))
 307                  (setq init-file-had-error t))))
 308       ;; If we can tell that the init file altered debug-on-error,
 309       ;; arrange to preserve the value that it set up.
 310       (or (eq debug-on-error debug-on-error-initial)
 311           (setq debug-on-error-should-be-set t
 312                 debug-on-error-from-init-file debug-on-error)))
 313     (if debug-on-error-should-be-set
 314         (setq debug-on-error debug-on-error-from-init-file)))
 315
 316   (run-hooks 'after-init-hook)
 317
 318   ;; If *scratch* exists and init file didn't change its mode, initialize it.
 319   (if (get-buffer "*scratch*")
 320       (save-excursion
 321         (set-buffer "*scratch*")
 322         (if (eq major-mode 'fundamental-mode)
 323             (funcall initial-major-mode))))
 324   ;; Load library for our terminal type.
 325   ;; User init file can set term-file-prefix to nil to prevent this.
 326   (and term-file-prefix (not noninteractive) (not window-system)
 327        (let ((term (getenv "TERM"))
 328              hyphend)
 329          (while (and term
 330                      (not (load (concat term-file-prefix term) t t)))
 331            ;; Strip off last hyphen and what follows, then try again
 332            (if (setq hyphend (string-match "[-_][^-_]+$" term))
 333                (setq term (substring term 0 hyphend))
 334              (setq term nil)))))
 335
 336   ;; Process the remaining args.
 337   (command-line-1 (cdr command-line-args))
 338
 339   ;; If -batch, terminate after processing the command options.
 340   (if noninteractive (kill-emacs t)))
 341
 342 (defun command-line-1 (command-line-args-left)
 343   (or noninteractive (input-pending-p) init-file-had-error
 344       (and inhibit-startup-echo-area-message
 345            (let ((buffer (get-buffer-create " *temp*")))
 346              (prog1
 347                  (condition-case nil
 348                      (save-excursion
 349                        (set-buffer buffer)
 350                        (insert-file-contents user-init-file)
 351                        (re-search-forward
 352                         (concat
 353                          "([ \t\n]*setq[ \t\n]+"
 354                          "inhibit-startup-echo-area-message[ \t\n]+"
 355                          (regexp-quote
 356                           (prin1-to-string
 357                            (if (string= init-file-user "")
 358                                (user-login-name)
 359                              init-file-user)))
 360                          "[ \t\n]*)")
 361                         nil t))
 362                    (error nil))
 363                (kill-buffer buffer))))
 364       (message (if (eq (key-binding "\C-h\C-p") 'describe-project)
 365                    "For information about the GNU Project and its goals, type C-h C-p."
 366                  (substitute-command-keys
 367                   "For information about the GNU Project and its goals, type \\[describe-project]."))))
 368   (if (null command-line-args-left)
 369       (cond ((and (not inhibit-startup-message) (not noninteractive)
 370                   ;; Don't clobber a non-scratch buffer if init file
 371                   ;; has selected it.
 372                   (string= (buffer-name) "*scratch*")
 373                   (not (input-pending-p)))
 374              ;; If there are no switches to process, we might as well
 375              ;; run this hook now, and there may be some need to do it
 376              ;; before doing any output.
 377              (and term-setup-hook
 378                   (run-hooks 'term-setup-hook))
 379              ;; Don't let the hook be run twice.
 380              (setq term-setup-hook nil)
 381
 382              ;; It's important to notice the user settings before we
 383              ;; display the startup message; otherwise, the settings
 384              ;; won't take effect until the user gives the first
 385              ;; keystroke, and that's distracting.
 386              (if (fboundp 'frame-notice-user-settings)
 387                  (frame-notice-user-settings))
 388
 389              (and window-setup-hook
 390                   (run-hooks 'window-setup-hook))
 391              (setq window-setup-hook nil)
 392              (unwind-protect
 393                  (progn
 394                    (insert (emacs-version)
 395                            "
 396 Copyright (C) 1994 Free Software Foundation, Inc.\n\n")
 397                    ;; If keys have their default meanings,
 398                    ;; use precomputed string to save lots of time.
 399                    (if (and (eq (key-binding "\C-h") 'help-command)
 400                             (eq (key-binding "\C-xu") 'advertised-undo)
 401                             (eq (key-binding "\C-x\C-c") 'save-buffers-kill-emacs)
 402                             (eq (key-binding "\C-h\C-c") 'describe-copying)
 403                             (eq (key-binding "\C-h\C-d") 'describe-distribution)
 404                             (eq (key-binding "\C-h\C-w") 'describe-no-warranty)
 405                             (eq (key-binding "\C-ht") 'help-with-tutorial))
 406                        (insert
 407        "Type C-h for help; C-x u to undo changes.  (`C-' means use CTRL key.)
 408 To kill the Emacs job, type C-x C-c.
 409 Type C-h t for a tutorial on using Emacs.
 410 Type C-h i to enter Info, which you can use to read GNU documentation.
 411
 412 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type C-h C-w for full details.
 413 You may give out copies of Emacs; type C-h C-c to see the conditions.
 414 Type C-h C-d for information on getting the latest version.")
 415                      (insert (substitute-command-keys
 416        "Type \\[help-command] for help; \\[advertised-undo] to undo changes.  (`C-' means use CTRL key.)
 417 To kill the Emacs job, type \\[save-buffers-kill-emacs].
 418 Type \\[help-with-tutorial] for a tutorial on using Emacs.
 419 Type \\[info] to enter Info, which you can use to read GNU documentation.
 420
 421 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type \\[describe-no-warranty] for full details.
 422 You may give out copies of Emacs; type \\[describe-copying] to see the conditions.
 423 Type \\[describe-distribution] for information on getting the latest version.")))
 424                    (set-buffer-modified-p nil)
 425                    (sit-for 120))
 426                (save-excursion
 427                  ;; In case the Emacs server has already selected
 428                  ;; another buffer, erase the one our message is in.
 429                  (set-buffer (get-buffer "*scratch*"))
 430                  (erase-buffer)
 431                  (set-buffer-modified-p nil)))))
 432     (let ((dir command-line-default-directory)
 433           (file-count 0)
 434           first-file-buffer
 435           (line 0))
 436       (while command-line-args-left
 437         (let ((argi (car command-line-args-left))
 438               tem)
 439           (setq command-line-args-left (cdr command-line-args-left))
 440           (cond ((setq tem (assoc argi command-switch-alist))
 441                  (funcall (cdr tem) argi))
 442                 ((or (string-equal argi "-f")  ;what the manual claims
 443                      (string-equal argi "-funcall")
 444                      (string-equal argi "-e")) ; what the source used to say
 445                  (setq tem (intern (car command-line-args-left)))
 446                  (setq command-line-args-left (cdr command-line-args-left))
 447                  (funcall tem))
 448                 ((or (string-equal argi "-l")
 449                      (string-equal argi "-load"))
 450                  (let ((file (car command-line-args-left)))
 451                    ;; Take file from default dir if it exists there;
 452                    ;; otherwise let `load' search for it.
 453                    (if (file-exists-p (expand-file-name file))
 454                        (setq file (expand-file-name file)))
 455                    (load file nil t))
 456                  (setq command-line-args-left (cdr command-line-args-left)))
 457                 ((string-equal argi "-insert")
 458                  (or (stringp (car command-line-args-left))
 459                      (error "filename omitted from `-insert' option"))
 460                  (insert-file-contents (car command-line-args-left))
 461                  (setq command-line-args-left (cdr command-line-args-left)))
 462                 ((string-equal argi "-kill")
 463                  (kill-emacs t))
 464                 ((string-match "^\\+[0-9]+\\'" argi)
 465                  (setq line (string-to-int argi)))
 466                 (t
 467                  ;; We have almost exhausted our options. See if the
 468                  ;; user has made any other command-line options available
 469                  (let ((hooks command-line-functions);; lrs 7/31/89
 470                        (did-hook nil))
 471                    (while (and hooks
 472                                (not (setq did-hook (funcall (car hooks)))))
 473                      (setq hooks (cdr hooks)))
 474                    (if (not did-hook)
 475                        ;; Ok, presume that the argument is a file name
 476                        (progn
 477                          (setq file-count (1+ file-count))
 478                          (cond ((= file-count 1)
 479                                 (setq first-file-buffer
 480                                       (find-file (expand-file-name argi dir))))
 481                                (t
 482                                 (find-file-other-window (expand-file-name argi dir))))
 483                          (or (zerop line)
 484                              (goto-line line))
 485                          (setq line 0))))))))
 486       ;; If 3 or more files visited, and not all visible,
 487       ;; show user what they all are.
 488       (if (> file-count 2)
 489           (or (get-buffer-window first-file-buffer)
 490               (progn (other-window 1)
 491                      (buffer-menu)))))))
 492
 493 ;;; startup.el ends here