lisp/vc-bzr.el

   1 ;;; vc-bzr.el --- VC backend for the bzr revision control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008, 2009  Free Software Foundation, Inc.
   4
   5 ;; Author: Dave Love <fx@gnu.org>
   6 ;;         Riccardo Murri <riccardo.murri@gmail.com>
   7 ;; Keywords: tools
   8 ;; Created: Sept 2006
   9 ;; Version: 2008-01-04 (Bzr revno 25)
  10 ;; URL: http://launchpad.net/vc-bzr
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; See <URL:http://bazaar-vcs.org/> concerning bzr.  See
  30 ;; <URL:http://launchpad.net/vc-bzr> for alternate development
  31 ;; branches of `vc-bzr'.
  32
  33 ;; Load this library to register bzr support in VC.
  34
  35 ;; Known bugs
  36 ;; ==========
  37
  38 ;; When edititing a symlink and *both* the symlink and its target
  39 ;; are bzr-versioned, `vc-bzr` presently runs `bzr status` on the
  40 ;; symlink, thereby not detecting whether the actual contents
  41 ;; (that is, the target contents) are changed.
  42 ;; See https://bugs.launchpad.net/vc-bzr/+bug/116607
  43
  44 ;; For an up-to-date list of bugs, please see:
  45 ;;   https://bugs.launchpad.net/vc-bzr/+bugs
  46
  47 ;;; Properties of the backend
  48
  49 (defun vc-bzr-revision-granularity () 'repository)
  50 (defun vc-bzr-checkout-model (files) 'implicit)
  51
  52 ;;; Code:
  53
  54 (eval-when-compile
  55   (require 'cl)
  56   (require 'vc)  ;; for vc-exec-after
  57   (require 'vc-dir))
  58
  59 ;; Clear up the cache to force vc-call to check again and discover
  60 ;; new functions when we reload this file.
  61 (put 'Bzr 'vc-functions nil)
  62
  63 (defgroup vc-bzr nil
  64   "VC bzr backend."
  65   :version "22.2"
  66   :group 'vc)
  67
  68 (defcustom vc-bzr-program "bzr"
  69   "Name of the bzr command (excluding any arguments)."
  70   :group 'vc-bzr
  71   :type 'string)
  72
  73 (defcustom vc-bzr-diff-switches nil
  74   "String or list of strings specifying switches for bzr diff under VC.
  75 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
  76   :type '(choice (const :tag "Unspecified" nil)
  77                  (const :tag "None" t)
  78                  (string :tag "Argument String")
  79                  (repeat :tag "Argument List" :value ("") string))
  80   :group 'vc-bzr)
  81
  82 (defcustom vc-bzr-log-switches nil
  83   "String or list of strings specifying switches for bzr log under VC."
  84   :type '(choice (const :tag "None" nil)
  85                  (string :tag "Argument String")
  86                  (repeat :tag "Argument List" :value ("") string))
  87   :group 'vc-bzr)
  88
  89 ;; since v0.9, bzr supports removing the progress indicators
  90 ;; by setting environment variable BZR_PROGRESS_BAR to "none".
  91 (defun vc-bzr-command (bzr-command buffer okstatus file-or-list &rest args)
  92   "Wrapper round `vc-do-command' using `vc-bzr-program' as COMMAND.
  93 Invoke the bzr command adding `BZR_PROGRESS_BAR=none' and
  94 `LC_MESSAGES=C' to the environment."
  95   (let ((process-environment
  96          (list* "BZR_PROGRESS_BAR=none" ; Suppress progress output (bzr >=0.9)
  97                 "LC_MESSAGES=C"         ; Force English output
  98                 process-environment)))
  99     (apply 'vc-do-command (or buffer "*vc*") okstatus vc-bzr-program
 100            file-or-list bzr-command args)))
 101
 102
 103 ;;;###autoload
 104 (defconst vc-bzr-admin-dirname ".bzr"
 105   "Name of the directory containing Bzr repository status files.")
 106 ;;;###autoload
 107 (defconst vc-bzr-admin-checkout-format-file
 108   (concat vc-bzr-admin-dirname "/checkout/format"))
 109 (defconst vc-bzr-admin-dirstate
 110   (concat vc-bzr-admin-dirname "/checkout/dirstate"))
 111 (defconst vc-bzr-admin-branch-format-file
 112   (concat vc-bzr-admin-dirname "/branch/format"))
 113 (defconst vc-bzr-admin-revhistory
 114   (concat vc-bzr-admin-dirname "/branch/revision-history"))
 115 (defconst vc-bzr-admin-lastrev
 116   (concat vc-bzr-admin-dirname "/branch/last-revision"))
 117
 118 ;;;###autoload (defun vc-bzr-registered (file)
 119 ;;;###autoload   (if (vc-find-root file vc-bzr-admin-checkout-format-file)
 120 ;;;###autoload       (progn
 121 ;;;###autoload         (load "vc-bzr")
 122 ;;;###autoload         (vc-bzr-registered file))))
 123
 124 (defun vc-bzr-root (file)
 125   "Return the root directory of the bzr repository containing FILE."
 126   ;; Cache technique copied from vc-arch.el.
 127   (or (vc-file-getprop file 'bzr-root)
 128       (let ((root (vc-find-root file vc-bzr-admin-checkout-format-file)))
 129         (when root (vc-file-setprop file 'bzr-root root)))))
 130
 131 (require 'sha1)                         ;For sha1-program
 132
 133 (defun vc-bzr-sha1 (file)
 134   (with-temp-buffer
 135     (set-buffer-multibyte nil)
 136     (let ((prog sha1-program)
 137           (args nil)
 138           process-file-side-effects)
 139       (when (consp prog)
 140         (setq args (cdr prog))
 141         (setq prog (car prog)))
 142       (apply 'process-file prog (file-relative-name file) t nil args)
 143       (buffer-substring (point-min) (+ (point-min) 40)))))
 144
 145 (defun vc-bzr-state-heuristic (file)
 146   "Like `vc-bzr-state' but hopefully without running Bzr."
 147   ;; `bzr status' was excrutiatingly slow with large histories and
 148   ;; pending merges, so try to avoid using it until they fix their
 149   ;; performance problems.
 150   ;; This function tries first to parse Bzr internal file
 151   ;; `checkout/dirstate', but it may fail if Bzr internal file format
 152   ;; has changed.  As a safeguard, the `checkout/dirstate' file is
 153   ;; only parsed if it contains the string `#bazaar dirstate flat
 154   ;; format 3' in the first line.
 155   ;; If the `checkout/dirstate' file cannot be parsed, fall back to
 156   ;; running `vc-bzr-state'."
 157   (lexical-let ((root (vc-bzr-root file)))
 158     (when root    ; Short cut.
 159       ;; This looks at internal files.  May break if they change
 160       ;; their format.
 161       (lexical-let ((dirstate (expand-file-name vc-bzr-admin-dirstate root)))
 162         (condition-case nil
 163             (with-temp-buffer
 164               (insert-file-contents dirstate)
 165               (goto-char (point-min))
 166               (if (not (looking-at "#bazaar dirstate flat format 3"))
 167                   (vc-bzr-state file)   ; Some other unknown format?
 168                 (let* ((relfile (file-relative-name file root))
 169                        (reldir (file-name-directory relfile)))
 170                   (if (re-search-forward
 171                        (concat "^\0"
 172                                (if reldir (regexp-quote
 173                                            (directory-file-name reldir)))
 174                                "\0"
 175                                (regexp-quote (file-name-nondirectory relfile))
 176                                "\0"
 177                                "[^\0]*\0"     ;id?
 178                                "\\([^\0]*\\)\0" ;"a/f/d", a=removed?
 179                                "\\([^\0]*\\)\0" ;sha1 (empty if conflicted)?
 180                                "\\([^\0]*\\)\0" ;size?p
 181                                "[^\0]*\0"       ;"y/n", executable?
 182                                "[^\0]*\0"       ;?
 183                                "\\([^\0]*\\)\0" ;"a/f/d" a=added?
 184                                "\\([^\0]*\\)\0" ;sha1 again?
 185                                "\\([^\0]*\\)\0" ;size again?
 186                                "[^\0]*\0" ;"y/n", executable again?
 187                                "[^\0]*\0" ;last revid?
 188                                ;; There are more fields when merges are pending.
 189                                )
 190                        nil t)
 191                       ;; Apparently the second sha1 is the one we want: when
 192                       ;; there's a conflict, the first sha1 is absent (and the
 193                       ;; first size seems to correspond to the file with
 194                       ;; conflict markers).
 195                       (cond
 196                        ((eq (char-after (match-beginning 1)) ?a) 'removed)
 197                        ((eq (char-after (match-beginning 4)) ?a) 'added)
 198                        ((or (and (eq (string-to-number (match-string 3))
 199                                  (nth 7 (file-attributes file)))
 200                              (equal (match-string 5)
 201                                     (vc-bzr-sha1 file)))
 202                             (and
 203                              ;; It looks like for lightweight
 204                              ;; checkouts \2 is empty and we need to
 205                              ;; look for size in \6.
 206                              (eq (match-beginning 2) (match-end 2))
 207                              (eq (string-to-number (match-string 6))
 208                                  (nth 7 (file-attributes file)))
 209                              (equal (match-string 5)
 210                                     (vc-bzr-sha1 file))))
 211                         'up-to-date)
 212                        (t 'edited))
 213                     'unregistered))))
 214           ;; Either the dirstate file can't be read, or the sha1
 215           ;; executable is missing, or ...
 216           ;; In either case, recent versions of Bzr aren't that slow
 217           ;; any more.
 218           (error (vc-bzr-state file)))))))
 219
 220
 221 (defun vc-bzr-registered (file)
 222   "Return non-nil if FILE is registered with bzr."
 223   (let ((state (vc-bzr-state-heuristic file)))
 224     (not (memq state '(nil unregistered ignored)))))
 225
 226 (defconst vc-bzr-state-words
 227   "added\\|ignored\\|kind changed\\|modified\\|removed\\|renamed\\|unknown"
 228   "Regexp matching file status words as reported in `bzr' output.")
 229
 230 (defun vc-bzr-file-name-relative (filename)
 231   "Return file name FILENAME stripped of the initial Bzr repository path."
 232   (lexical-let*
 233       ((filename* (expand-file-name filename))
 234        (rootdir (vc-bzr-root filename*)))
 235     (when rootdir
 236          (file-relative-name filename* rootdir))))
 237
 238 (defun vc-bzr-status (file)
 239   "Return FILE status according to Bzr.
 240 Return value is a cons (STATUS . WARNING), where WARNING is a
 241 string or nil, and STATUS is one of the symbols: `added',
 242 `ignored', `kindchanged', `modified', `removed', `renamed', `unknown',
 243 which directly correspond to `bzr status' output, or 'unchanged
 244 for files whose copy in the working tree is identical to the one
 245 in the branch repository, or nil for files that are not
 246 registered with Bzr.
 247
 248 If any error occurred in running `bzr status', then return nil."
 249   (with-temp-buffer
 250     (let ((ret (condition-case nil
 251                    (vc-bzr-command "status" t 0 file)
 252                  (file-error nil)))     ; vc-bzr-program not found.
 253           (status 'unchanged))
 254           ;; the only secure status indication in `bzr status' output
 255           ;; is a couple of lines following the pattern::
 256           ;;   | <status>:
 257           ;;   |   <file name>
 258           ;; if the file is up-to-date, we get no status report from `bzr',
 259           ;; so if the regexp search for the above pattern fails, we consider
 260           ;; the file to be up-to-date.
 261           (goto-char (point-min))
 262           (when (re-search-forward
 263                  ;; bzr prints paths relative to the repository root.
 264                  (concat "^\\(" vc-bzr-state-words "\\):[ \t\n]+"
 265                          (regexp-quote (vc-bzr-file-name-relative file))
 266                          ;; Bzr appends a '/' to directory names and
 267                          ;; '*' to executable files
 268                          (if (file-directory-p file) "/?" "\\*?")
 269                          "[ \t\n]*$")
 270                  nil t)
 271             (lexical-let ((statusword (match-string 1)))
 272               ;; Erase the status text that matched.
 273               (delete-region (match-beginning 0) (match-end 0))
 274               (setq status
 275                     (intern (replace-regexp-in-string " " "" statusword)))))
 276           (when status
 277             (goto-char (point-min))
 278             (skip-chars-forward " \n\t") ;Throw away spaces.
 279             (cons status
 280                   ;; "bzr" will output warnings and informational messages to
 281                   ;; stderr; due to Emacs' `vc-do-command' (and, it seems,
 282                   ;; `start-process' itself) limitations, we cannot catch stderr
 283                   ;; and stdout into different buffers.  So, if there's anything
 284                   ;; left in the buffer after removing the above status
 285                   ;; keywords, let us just presume that any other message from
 286                   ;; "bzr" is a user warning, and display it.
 287                   (unless (eobp) (buffer-substring (point) (point-max))))))))
 288
 289 (defun vc-bzr-state (file)
 290   (lexical-let ((result (vc-bzr-status file)))
 291     (when (consp result)
 292       (when (cdr result)
 293         (message "Warnings in `bzr' output: %s" (cdr result)))
 294       (cdr (assq (car result)
 295                  '((added . added)
 296                    (kindchanged . edited)
 297                    (renamed . edited)
 298                    (modified . edited)
 299                    (removed . removed)
 300                    (ignored . ignored)
 301                    (unknown . unregistered)
 302                    (unchanged . up-to-date)))))))
 303
 304 (defun vc-bzr-resolve-when-done ()
 305   "Call \"bzr resolve\" if the conflict markers have been removed."
 306   (save-excursion
 307     (goto-char (point-min))
 308     (unless (re-search-forward "^<<<<<<< " nil t)
 309       (vc-bzr-command "resolve" nil 0 buffer-file-name)
 310       ;; Remove the hook so that it is not called multiple times.
 311       (remove-hook 'after-save-hook 'vc-bzr-resolve-when-done t))))
 312
 313 (defun vc-bzr-find-file-hook ()
 314   (when (and buffer-file-name
 315              ;; FIXME: We should check that "bzr status" says "conflict".
 316              (file-exists-p (concat buffer-file-name ".BASE"))
 317              (file-exists-p (concat buffer-file-name ".OTHER"))
 318              (file-exists-p (concat buffer-file-name ".THIS"))
 319              ;; If "bzr status" says there's a conflict but there are no
 320              ;; conflict markers, it's not clear what we should do.
 321              (save-excursion
 322                (goto-char (point-min))
 323                (re-search-forward "^<<<<<<< " nil t)))
 324     ;; TODO: the merge algorithm used in `bzr merge' is nicely configurable,
 325     ;; but the one in `bzr pull' isn't, so it would be good to provide an
 326     ;; elisp function to remerge from the .BASE/OTHER/THIS files.
 327     (smerge-start-session)
 328     (add-hook 'after-save-hook 'vc-bzr-resolve-when-done nil t)
 329     (message "There are unresolved conflicts in this file")))
 330
 331 (defun vc-bzr-workfile-unchanged-p (file)
 332   (eq 'unchanged (car (vc-bzr-status file))))
 333
 334 (defun vc-bzr-working-revision (file)
 335   ;; Together with the code in vc-state-heuristic, this makes it possible
 336   ;; to get the initial VC state of a Bzr file even if Bzr is not installed.
 337   (lexical-let*
 338       ((rootdir (vc-bzr-root file))
 339        (branch-format-file (expand-file-name vc-bzr-admin-branch-format-file
 340                                              rootdir))
 341        (revhistory-file (expand-file-name vc-bzr-admin-revhistory rootdir))
 342        (lastrev-file (expand-file-name vc-bzr-admin-lastrev rootdir)))
 343     ;; This looks at internal files to avoid forking a bzr process.
 344     ;; May break if they change their format.
 345     (if (and (file-exists-p branch-format-file)
 346              ;; For lightweight checkouts (obtained with bzr checkout --lightweight)
 347              ;; the branch-format-file does not contain the revision
 348              ;; information, we need to look up the branch-format-file
 349              ;; in the place where the lightweight checkout comes
 350              ;; from.  We only do that if it's a local file.
 351              (let ((location-fname (expand-file-name
 352                                     (concat vc-bzr-admin-dirname
 353                                             "/branch/location") rootdir)))
 354                ;; The existence of this file is how we distinguish
 355                ;; lightweight checkouts.
 356                (if (file-exists-p location-fname)
 357                    (with-temp-buffer
 358                      (insert-file-contents location-fname)
 359                      ;; If the lightweight checkout points to a
 360                      ;; location in the local file system, then we can
 361                      ;; look there for the version information.
 362                      (when (re-search-forward "file://\\(.+\\)" nil t)
 363                        (let ((l-c-parent-dir (match-string 1)))
 364                          (setq branch-format-file
 365                                (expand-file-name vc-bzr-admin-branch-format-file
 366                                                  l-c-parent-dir))
 367                          (setq lastrev-file
 368                                (expand-file-name vc-bzr-admin-lastrev l-c-parent-dir))
 369                          ;; FIXME: maybe it's overkill to check if both these files exist.
 370                          (and (file-exists-p branch-format-file)
 371                               (file-exists-p lastrev-file)))))
 372                  t)))
 373         (with-temp-buffer
 374           (insert-file-contents branch-format-file)
 375           (goto-char (point-min))
 376           (cond
 377            ((or
 378              (looking-at "Bazaar-NG branch, format 0.0.4")
 379              (looking-at "Bazaar-NG branch format 5"))
 380             ;; count lines in .bzr/branch/revision-history
 381             (insert-file-contents revhistory-file)
 382             (number-to-string (count-lines (line-end-position) (point-max))))
 383            ((or
 384              (looking-at "Bazaar Branch Format 6 (bzr 0.15)")
 385              (looking-at "Bazaar Branch Format 7 (needs bzr 1.6)"))
 386             ;; revno is the first number in .bzr/branch/last-revision
 387             (insert-file-contents lastrev-file)
 388             (when (re-search-forward "[0-9]+" nil t)
 389               (buffer-substring (match-beginning 0) (match-end 0))))))
 390       ;; fallback to calling "bzr revno"
 391       (lexical-let*
 392           ((result (vc-bzr-command-discarding-stderr
 393                     vc-bzr-program "revno" (file-relative-name file)))
 394            (exitcode (car result))
 395            (output (cdr result)))
 396         (cond
 397          ((eq exitcode 0) (substring output 0 -1))
 398          (t nil))))))
 399
 400 (defun vc-bzr-create-repo ()
 401   "Create a new Bzr repository."
 402   (vc-bzr-command "init" nil 0 nil))
 403
 404 (defun vc-bzr-init-revision (&optional file)
 405   "Always return nil, as Bzr cannot register explicit versions."
 406   nil)
 407
 408 (defun vc-bzr-previous-revision (file rev)
 409   (if (string-match "\\`[0-9]+\\'" rev)
 410       (number-to-string (1- (string-to-number rev)))
 411     (concat "before:" rev)))
 412
 413 (defun vc-bzr-next-revision (file rev)
 414   (if (string-match "\\`[0-9]+\\'" rev)
 415       (number-to-string (1+ (string-to-number rev)))
 416     (error "Don't know how to compute the next revision of %s" rev)))
 417
 418 (defun vc-bzr-register (files &optional rev comment)
 419   "Register FILE under bzr.
 420 Signal an error unless REV is nil.
 421 COMMENT is ignored."
 422   (if rev (error "Can't register explicit revision with bzr"))
 423   (vc-bzr-command "add" nil 0 files))
 424
 425 ;; Could run `bzr status' in the directory and see if it succeeds, but
 426 ;; that's relatively expensive.
 427 (defalias 'vc-bzr-responsible-p 'vc-bzr-root
 428   "Return non-nil if FILE is (potentially) controlled by bzr.
 429 The criterion is that there is a `.bzr' directory in the same
 430 or a superior directory.")
 431
 432 (defun vc-bzr-could-register (file)
 433   "Return non-nil if FILE could be registered under bzr."
 434   (and (vc-bzr-responsible-p file)      ; shortcut
 435        (condition-case ()
 436            (with-temp-buffer
 437              (vc-bzr-command "add" t 0 file "--dry-run")
 438              ;; The command succeeds with no output if file is
 439              ;; registered (in bzr 0.8).
 440              (goto-char (point-min))
 441              (looking-at "added "))
 442          (error))))
 443
 444 (defun vc-bzr-unregister (file)
 445   "Unregister FILE from bzr."
 446   (vc-bzr-command "remove" nil 0 file "--keep"))
 447
 448 (defun vc-bzr-checkin (files rev comment)
 449   "Check FILE in to bzr with log message COMMENT.
 450 REV non-nil gets an error."
 451   (if rev (error "Can't check in a specific revision with bzr"))
 452   (vc-bzr-command "commit" nil 0 files "-m" comment))
 453
 454 (defun vc-bzr-find-revision (file rev buffer)
 455   "Fetch revision REV of file FILE and put it into BUFFER."
 456     (with-current-buffer buffer
 457       (if (and rev (stringp rev) (not (string= rev "")))
 458           (vc-bzr-command "cat" t 0 file "-r" rev)
 459         (vc-bzr-command "cat" t 0 file))))
 460
 461 (defun vc-bzr-checkout (file &optional editable rev)
 462   (if rev (error "Operation not supported")
 463     ;; Else, there's nothing to do.
 464     nil))
 465
 466 (defun vc-bzr-revert (file &optional contents-done)
 467   (unless contents-done
 468     (with-temp-buffer (vc-bzr-command "revert" t 0 file))))
 469
 470 (defvar log-view-message-re)
 471 (defvar log-view-file-re)
 472 (defvar log-view-font-lock-keywords)
 473 (defvar log-view-current-tag-function)
 474 (defvar log-view-per-file-logs)
 475 (defvar vc-short-log)
 476
 477 (define-derived-mode vc-bzr-log-view-mode log-view-mode "Bzr-Log-View"
 478   (remove-hook 'log-view-mode-hook 'vc-bzr-log-view-mode) ;Deactivate the hack.
 479   (require 'add-log)
 480   (set (make-local-variable 'log-view-per-file-logs) nil)
 481   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 482   (set (make-local-variable 'log-view-message-re)
 483        (if vc-short-log
 484            "^ *\\([0-9.]+\\) \\(.*?\\)[ \t]+\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}\\)\\( \\[merge\\]\\)?"
 485          "^ *\\(?:revno: \\([0-9.]+\\)\\|merged: .+\\)"))
 486   (set (make-local-variable 'log-view-font-lock-keywords)
 487        ;; log-view-font-lock-keywords is careful to use the buffer-local
 488        ;; value of log-view-message-re only since Emacs-23.
 489        (if vc-short-log
 490          (append `((,log-view-message-re
 491                     (1 'log-view-message-face)
 492                     (2 'change-log-name)
 493                     (3 'change-log-date)
 494                     (4 'change-log-list nil lax))))
 495          (append `((,log-view-message-re . 'log-view-message-face))
 496                  ;; log-view-font-lock-keywords
 497                  '(("^ *\\(?:committer\\|author\\): \
 498 \\([^<(]+?\\)[  ]*[(<]\\([[:alnum:]_.+-]+@[[:alnum:]_.-]+\\)[>)]"
 499                     (1 'change-log-name)
 500                     (2 'change-log-email))
 501                    ("^ *timestamp: \\(.*\\)" (1 'change-log-date-face)))))))
 502
 503 (defun vc-bzr-print-log (files buffer &optional shortlog start-revision limit)
 504   "Get bzr change log for FILES into specified BUFFER."
 505   ;; `vc-do-command' creates the buffer, but we need it before running
 506   ;; the command.
 507   (vc-setup-buffer buffer)
 508   ;; If the buffer exists from a previous invocation it might be
 509   ;; read-only.
 510   ;; FIXME: `vc-bzr-command' runs `bzr log' with `LC_MESSAGES=C', so
 511   ;; the log display may not what the user wants - but I see no other
 512   ;; way of getting the above regexps working.
 513   (with-current-buffer buffer
 514     (apply 'vc-bzr-command "log" buffer 'async files
 515            (append
 516             (when shortlog '("--short"))
 517             (when start-revision (list (format "-r..%s" start-revision)))
 518             (when limit (list "-l" (format "%s" limit)))
 519             (if (stringp vc-bzr-log-switches)
 520                 (list vc-bzr-log-switches)
 521               vc-bzr-log-switches)))))
 522
 523 (defun vc-bzr-show-log-entry (revision)
 524   "Find entry for patch name REVISION in bzr change log buffer."
 525   (goto-char (point-min))
 526   (when revision
 527     (let (case-fold-search
 528           found)
 529       (if (re-search-forward
 530            ;; "revno:" can appear either at the beginning of a line,
 531            ;; or indented.
 532            (concat "^[ ]*-+\n[ ]*revno: "
 533                    ;; The revision can contain ".", quote it so that it
 534                    ;; does not interfere with regexp matching.
 535                    (regexp-quote revision) "$") nil t)
 536           (progn
 537             (beginning-of-line 0)
 538             (setq found t))
 539         (goto-char (point-min)))
 540       found)))
 541
 542 (defun vc-bzr-diff (files &optional rev1 rev2 buffer)
 543   "VC bzr backend for diff."
 544   ;; `bzr diff' exits with code 1 if diff is non-empty.
 545   (apply #'vc-bzr-command "diff" (or buffer "*vc-diff*")
 546          (if vc-disable-async-diff 1 'async) files
 547          "--diff-options" (mapconcat 'identity
 548                                      (vc-switches 'bzr 'diff)
 549                                      " ")
 550          ;; This `when' is just an optimization because bzr-1.2 is *much*
 551          ;; faster when the revision argument is not given.
 552          (when (or rev1 rev2)
 553            (list "-r" (format "%s..%s"
 554                               (or rev1 "revno:-1")
 555                               (or rev2 ""))))))
 556
 557
 558 ;; FIXME: vc-{next,previous}-revision need fixing in vc.el to deal with
 559 ;; straight integer revisions.
 560
 561 (defun vc-bzr-delete-file (file)
 562   "Delete FILE and delete it in the bzr repository."
 563   (condition-case ()
 564       (delete-file file)
 565     (file-error nil))
 566   (vc-bzr-command "remove" nil 0 file))
 567
 568 (defun vc-bzr-rename-file (old new)
 569   "Rename file from OLD to NEW using `bzr mv'."
 570   (vc-bzr-command "mv" nil 0 new old))
 571
 572 (defvar vc-bzr-annotation-table nil
 573   "Internal use.")
 574 (make-variable-buffer-local 'vc-bzr-annotation-table)
 575
 576 (defun vc-bzr-annotate-command (file buffer &optional revision)
 577   "Prepare BUFFER for `vc-annotate' on FILE.
 578 Each line is tagged with the revision number, which has a `help-echo'
 579 property containing author and date information."
 580   (apply #'vc-bzr-command "annotate" buffer 'async file "--long" "--all"
 581          (if revision (list "-r" revision)))
 582   (lexical-let ((table (make-hash-table :test 'equal)))
 583     (set-process-filter
 584      (get-buffer-process buffer)
 585      (lambda (proc string)
 586        (when (process-buffer proc)
 587          (with-current-buffer (process-buffer proc)
 588            (setq string (concat (process-get proc :vc-left-over) string))
 589            (while (string-match "^\\( *[0-9.]+ *\\) \\([^\n ]+\\) +\\([0-9]\\{8\\}\\)\\( |.*\n\\)" string)
 590              (let* ((rev (match-string 1 string))
 591                     (author (match-string 2 string))
 592                     (date (match-string 3 string))
 593                     (key (substring string (match-beginning 0)
 594                                     (match-beginning 4)))
 595                     (line (match-string 4 string))
 596                     (tag (gethash key table))
 597                     (inhibit-read-only t))
 598                (setq string (substring string (match-end 0)))
 599                (unless tag
 600                  (setq tag
 601                        (propertize
 602                         (format "%s %-7.7s" rev author)
 603                         'help-echo (format "Revision: %d, author: %s, date: %s"
 604                                            (string-to-number rev)
 605                                            author date)
 606                         'mouse-face 'highlight))
 607                  (puthash key tag table))
 608                (goto-char (process-mark proc))
 609                (insert tag line)
 610                (move-marker (process-mark proc) (point))))
 611            (process-put proc :vc-left-over string)))))))
 612
 613 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 614
 615 (defun vc-bzr-annotate-time ()
 616   (when (re-search-forward "^ *[0-9.]+ +[^\n ]* +|" nil t)
 617     (let ((prop (get-text-property (line-beginning-position) 'help-echo)))
 618       (string-match "[0-9]+\\'" prop)
 619       (let ((str (match-string-no-properties 0 prop)))
 620       (vc-annotate-convert-time
 621        (encode-time 0 0 0
 622                       (string-to-number (substring str 6 8))
 623                       (string-to-number (substring str 4 6))
 624                       (string-to-number (substring str 0 4))))))))
 625
 626 (defun vc-bzr-annotate-extract-revision-at-line ()
 627   "Return revision for current line of annoation buffer, or nil.
 628 Return nil if current line isn't annotated."
 629   (save-excursion
 630     (beginning-of-line)
 631     (if (looking-at "^ *\\([0-9.]+\\) +[^\n ]* +|")
 632         (match-string-no-properties 1))))
 633
 634 (defun vc-bzr-command-discarding-stderr (command &rest args)
 635   "Execute shell command COMMAND (with ARGS); return its output and exitcode.
 636 Return value is a cons (EXITCODE . OUTPUT), where EXITCODE is
 637 the (numerical) exit code of the process, and OUTPUT is a string
 638 containing whatever the process sent to its standard output
 639 stream.  Standard error output is discarded."
 640   (with-temp-buffer
 641     (cons
 642      (apply #'process-file command nil (list (current-buffer) nil) nil args)
 643      (buffer-substring (point-min) (point-max)))))
 644
 645 (defstruct (vc-bzr-extra-fileinfo
 646             (:copier nil)
 647             (:constructor vc-bzr-create-extra-fileinfo (extra-name))
 648             (:conc-name vc-bzr-extra-fileinfo->))
 649   extra-name)         ;; original name for rename targets, new name for
 650
 651 (defun vc-bzr-dir-printer (info)
 652   "Pretty-printer for the vc-dir-fileinfo structure."
 653   (let ((extra (vc-dir-fileinfo->extra info)))
 654     (vc-default-dir-printer 'Bzr info)
 655     (when extra
 656       (insert (propertize
 657                (format "   (renamed from %s)"
 658                        (vc-bzr-extra-fileinfo->extra-name extra))
 659                'face 'font-lock-comment-face)))))
 660
 661 ;; FIXME: this needs testing, it's probably incomplete.
 662 (defun vc-bzr-after-dir-status (update-function relative-dir)
 663   (let ((status-str nil)
 664         (translation '(("+N " . added)
 665                        ("-D " . removed)
 666                        (" M " . edited) ;; file text modified
 667                        ("  *" . edited) ;; execute bit changed
 668                        (" M*" . edited) ;; text modified + execute bit changed
 669                        ;; FIXME: what about ignored files?
 670                        (" D " . missing)
 671                        ;; For conflicts, should we list the .THIS/.BASE/.OTHER?
 672                        ("C  " . conflict)
 673                        ("?  " . unregistered)
 674                        ;; No such state, but we need to distinguish this case.
 675                        ("R  " . renamed)
 676                        ;; For a non existent file FOO, the output is:
 677                        ;; bzr: ERROR: Path(s) do not exist: FOO
 678                        ("bzr" . not-found)
 679                        ;; If the tree is not up to date, bzr will print this warning:
 680                        ;; working tree is out of date, run 'bzr update'
 681                        ;; ignore it.
 682                        ;; FIXME: maybe this warning can be put in the vc-dir header...
 683                        ("wor" . not-found)
 684                        ;; Ignore "P " and "P." for pending patches.
 685                        ("P  " . not-found)
 686                        ("P. " . not-found)
 687                        ))
 688         (translated nil)
 689         (result nil))
 690       (goto-char (point-min))
 691       (while (not (eobp))
 692         (setq status-str
 693               (buffer-substring-no-properties (point) (+ (point) 3)))
 694         (setq translated (cdr (assoc status-str translation)))
 695         (cond
 696          ((eq translated 'conflict)
 697           ;; For conflicts the file appears twice in the listing: once
 698           ;; with the M flag and once with the C flag, so take care
 699           ;; not to add it twice to `result'.  Ugly.
 700           (let* ((file
 701                   (buffer-substring-no-properties
 702                    ;;For files with conflicts the format is:
 703                    ;;C   Text conflict in FILENAME
 704                    ;; Bah.
 705                    (+ (point) 21) (line-end-position)))
 706                  (entry (assoc file result)))
 707             (when entry
 708               (setf (nth 1 entry) 'conflict))))
 709          ((eq translated 'renamed)
 710           (re-search-forward "R   \\(.*\\) => \\(.*\\)$" (line-end-position) t)
 711           (let ((new-name (file-relative-name (match-string 2) relative-dir))
 712                 (old-name (file-relative-name (match-string 1) relative-dir)))
 713             (push (list new-name 'edited
 714                       (vc-bzr-create-extra-fileinfo old-name)) result)))
 715          ;; do nothing for non existent files
 716          ((eq translated 'not-found))
 717          (t
 718           (push (list (file-relative-name
 719                        (buffer-substring-no-properties
 720                         (+ (point) 4)
 721                         (line-end-position)) relative-dir)
 722                       translated) result)))
 723         (forward-line))
 724       (funcall update-function result)))
 725
 726 (defun vc-bzr-dir-status (dir update-function)
 727   "Return a list of conses (file . state) for DIR."
 728   (vc-bzr-command "status" (current-buffer) 'async dir "-v" "-S")
 729   (vc-exec-after
 730    `(vc-bzr-after-dir-status (quote ,update-function)
 731                              ;; "bzr status" results are relative to
 732                              ;; the bzr root directory, NOT to the
 733                              ;; directory "bzr status" was invoked in.
 734                              ;; Ugh.
 735                              ;; We pass the relative directory here so
 736                              ;; that `vc-bzr-after-dir-status' can
 737                              ;; frob the results accordingly.
 738                              (file-relative-name ,dir (vc-bzr-root ,dir)))))
 739
 740 (defun vc-bzr-dir-status-files (dir files default-state update-function)
 741   "Return a list of conses (file . state) for DIR."
 742   (apply 'vc-bzr-command "status" (current-buffer) 'async dir "-v" "-S" files)
 743   (vc-exec-after
 744    `(vc-bzr-after-dir-status (quote ,update-function)
 745                              (file-relative-name ,dir (vc-bzr-root ,dir)))))
 746
 747 (defvar vc-bzr-shelve-map
 748   (let ((map (make-sparse-keymap)))
 749     ;; Turn off vc-dir marking
 750     (define-key map [mouse-2] 'ignore)
 751
 752     (define-key map [down-mouse-3] 'vc-bzr-shelve-menu)
 753     (define-key map "\C-k" 'vc-bzr-shelve-delete-at-point)
 754     ;; (define-key map "=" 'vc-bzr-shelve-show-at-point)
 755     ;; (define-key map "\C-m" 'vc-bzr-shelve-show-at-point)
 756     (define-key map "P" 'vc-bzr-shelve-apply-at-point)
 757     map))
 758
 759 (defvar vc-bzr-shelve-menu-map
 760   (let ((map (make-sparse-keymap "Bzr Shelve")))
 761     (define-key map [de]
 762       '(menu-item "Delete shelf" vc-bzr-shelve-delete-at-point
 763                   :help "Delete the current shelf"))
 764     (define-key map [po]
 765       '(menu-item "Apply and remove shelf (pop)" vc-bzr-shelve-apply-at-point
 766                   :help "Apply the current shelf and remove it"))
 767     ;; (define-key map [sh]
 768     ;;   '(menu-item "Show shelve" vc-bzr-shelve-show-at-point
 769     ;;            :help "Show the contents of the current shelve"))
 770     map))
 771
 772 (defvar vc-bzr-extra-menu-map
 773   (let ((map (make-sparse-keymap)))
 774     (define-key map [bzr-sh]
 775       '(menu-item "Shelve..." vc-bzr-shelve
 776                   :help "Shelve changes"))
 777     map))
 778
 779 (defun vc-bzr-extra-menu () vc-bzr-extra-menu-map)
 780
 781 (defun vc-bzr-extra-status-menu () vc-bzr-extra-menu-map)
 782
 783 (defun vc-bzr-dir-extra-headers (dir)
 784   (let*
 785       ((str (with-temp-buffer
 786               (vc-bzr-command "info" t 0 dir)
 787               (buffer-string)))
 788        (shelve (vc-bzr-shelve-list))
 789        (shelve-help-echo "Use M-x vc-bzr-shelve to create shelves")
 790        (light-checkout
 791         (when (string-match ".+light checkout root: \\(.+\\)$" str)
 792           (match-string 1 str)))
 793        (light-checkout-branch
 794         (when light-checkout
 795           (when (string-match ".+checkout of branch: \\(.+\\)$" str)
 796             (match-string 1 str)))))
 797     (concat
 798      (propertize "Parent branch      : " 'face 'font-lock-type-face)
 799      (propertize
 800       (if (string-match "parent branch: \\(.+\\)$" str)
 801           (match-string 1 str)
 802         "None")
 803        'face 'font-lock-variable-name-face)
 804      "\n"
 805       (when light-checkout
 806         (concat
 807          (propertize "Light checkout root: " 'face 'font-lock-type-face)
 808          (propertize light-checkout 'face 'font-lock-variable-name-face)
 809          "\n"))
 810       (when light-checkout-branch
 811         (concat
 812          (propertize "Checkout of branch : " 'face 'font-lock-type-face)
 813          (propertize light-checkout-branch 'face 'font-lock-variable-name-face)
 814          "\n"))
 815      (if shelve
 816          (concat
 817           (propertize "Shelves            :\n" 'face 'font-lock-type-face
 818                       'help-echo shelve-help-echo)
 819           (mapconcat
 820            (lambda (x)
 821              (propertize x
 822                          'face 'font-lock-variable-name-face
 823                          'mouse-face 'highlight
 824                          'help-echo "mouse-3: Show shelve menu\nP: Apply and remove shelf (pop)\nC-k: Delete shelf"
 825                          'keymap vc-bzr-shelve-map))
 826            shelve "\n"))
 827        (concat
 828         (propertize "Shelves            : " 'face 'font-lock-type-face
 829                     'help-echo shelve-help-echo)
 830         (propertize "No shelved changes"
 831                     'help-echo shelve-help-echo
 832                     'face 'font-lock-variable-name-face))))))
 833
 834 (defun vc-bzr-shelve (name)
 835   "Create a shelve."
 836   (interactive "sShelf name: ")
 837   (let ((root (vc-bzr-root default-directory)))
 838     (when root
 839       (vc-bzr-command "shelve" nil 0 nil "--all" "-m" name)
 840       (vc-resynch-buffer root t t))))
 841
 842 ;; (defun vc-bzr-shelve-show (name)
 843 ;;   "Show the contents of shelve NAME."
 844 ;;   (interactive "sShelve name: ")
 845 ;;   (vc-setup-buffer "*vc-bzr-shelve*")
 846 ;;   ;; FIXME: how can you show the contents of a shelf?
 847 ;;   (vc-bzr-command "shelve" "*vc-bzr-shelve*" 'async nil name)
 848 ;;   (set-buffer "*vc-bzr-shelve*")
 849 ;;   (diff-mode)
 850 ;;   (setq buffer-read-only t)
 851 ;;   (pop-to-buffer (current-buffer)))
 852
 853 (defun vc-bzr-shelve-apply (name)
 854   "Apply shelve NAME and remove it afterwards."
 855   (interactive "sApply (and remove) shelf: ")
 856   (vc-bzr-command "unshelve" "*vc-bzr-shelve*" 0 nil "--apply" name)
 857   (vc-resynch-buffer (vc-bzr-root default-directory) t t))
 858
 859 (defun vc-bzr-shelve-list ()
 860   (with-temp-buffer
 861     (vc-bzr-command "shelve" (current-buffer) 1 nil "--list" "-q")
 862     (delete
 863      ""
 864      (split-string
 865       (buffer-substring (point-min) (point-max))
 866       "\n"))))
 867
 868 (defun vc-bzr-shelve-get-at-point (point)
 869   (save-excursion
 870     (goto-char point)
 871     (beginning-of-line)
 872     (if (looking-at "^ +\\([0-9]+\\):")
 873         (match-string 1)
 874       (error "Cannot find shelf at point"))))
 875
 876 (defun vc-bzr-shelve-delete-at-point ()
 877   (interactive)
 878   (let ((shelve (vc-bzr-shelve-get-at-point (point))))
 879     (when (y-or-n-p (format "Remove shelf %s ?" shelve))
 880       (vc-bzr-command "unshelve" nil 0 nil "--delete-only" shelve)
 881       (vc-dir-refresh))))
 882
 883 ;; (defun vc-bzr-shelve-show-at-point ()
 884 ;;   (interactive)
 885 ;;   (vc-bzr-shelve-show (vc-bzr-shelve-get-at-point (point))))
 886
 887 (defun vc-bzr-shelve-apply-at-point ()
 888   (interactive)
 889   (vc-bzr-shelve-apply (vc-bzr-shelve-get-at-point (point))))
 890
 891 (defun vc-bzr-shelve-menu (e)
 892   (interactive "e")
 893   (vc-dir-at-event e (popup-menu vc-bzr-shelve-menu-map e)))
 894
 895 ;;; Revision completion
 896
 897 (eval-and-compile
 898   (defconst vc-bzr-revision-keywords
 899     '("revno" "revid" "last" "before"
 900       "tag" "date" "ancestor" "branch" "submit")))
 901
 902 (defun vc-bzr-revision-completion-table (files)
 903   (lexical-let ((files files))
 904     ;; What about using `files'?!?  --Stef
 905     (lambda (string pred action)
 906       (cond
 907        ((string-match "\\`\\(ancestor\\|branch\\|\\(revno:\\)?[-0-9]+:\\):"
 908                       string)
 909         (completion-table-with-context (substring string 0 (match-end 0))
 910                                        'completion-file-name-table
 911                                        (substring string (match-end 0))
 912                                        ;; Dropping `pred' for no good reason.
 913                                        'file-directory-p
 914                                        action))
 915        ((string-match "\\`\\(before\\):" string)
 916         (completion-table-with-context (substring string 0 (match-end 0))
 917                                        (vc-bzr-revision-completion-table files)
 918                                        (substring string (match-end 0))
 919                                        pred
 920                                        action))
 921        ((string-match "\\`\\(tag\\):" string)
 922         (let ((prefix (substring string 0 (match-end 0)))
 923               (tag (substring string (match-end 0)))
 924               (table nil)
 925               process-file-side-effects)
 926           (with-temp-buffer
 927             ;; "bzr-1.2 tags" is much faster with --show-ids.
 928             (process-file vc-bzr-program nil '(t) nil "tags" "--show-ids")
 929             ;; The output is ambiguous, unless we assume that revids do not
 930             ;; contain spaces.
 931             (goto-char (point-min))
 932             (while (re-search-forward "^\\(.*[^ \n]\\) +[^ \n]*$" nil t)
 933               (push (match-string-no-properties 1) table)))
 934           (completion-table-with-context prefix table tag pred action)))
 935
 936        ((string-match "\\`\\([a-z]+\\):" string)
 937         ;; no actual completion for the remaining keywords.
 938         (completion-table-with-context (substring string 0 (match-end 0))
 939                                        (if (member (match-string 1 string)
 940                                                    vc-bzr-revision-keywords)
 941                                            ;; If it's a valid keyword,
 942                                            ;; use a non-empty table to
 943                                            ;; indicate it.
 944                                            '("") nil)
 945                                        (substring string (match-end 0))
 946                                        pred
 947                                        action))
 948        (t
 949         ;; Could use completion-table-with-terminator, except that it
 950         ;; currently doesn't work right w.r.t pcm and doesn't give
 951         ;; the *Completions* output we want.
 952         (complete-with-action action (eval-when-compile
 953                                        (mapcar (lambda (s) (concat s ":"))
 954                                                vc-bzr-revision-keywords))
 955                               string pred))))))
 956
 957 (eval-after-load "vc"
 958   '(add-to-list 'vc-directory-exclusion-list vc-bzr-admin-dirname t))
 959
 960 (provide 'vc-bzr)
 961 ;; arch-tag: 8101bad8-4e92-4e7d-85ae-d8e08b4e7c06
 962 ;;; vc-bzr.el ends here