lisp/emacs-lisp/byte-run.el

   1 ;;; byte-run.el --- byte-compiler support for inlining
   2
   3 ;; Copyright (C) 1992, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
   4 ;;   2009  Free Software Foundation, Inc.
   5
   6 ;; Author: Jamie Zawinski <jwz@lucid.com>
   7 ;;      Hallvard Furuseth <hbf@ulrik.uio.no>
   8 ;; Maintainer: FSF
   9 ;; Keywords: internal
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; interface to selectively inlining functions.
  29 ;; This only happens when source-code optimization is turned on.
  30
  31 ;;; Code:
  32
  33 ;; We define macro-declaration-function here because it is needed to
  34 ;; handle declarations in macro definitions and this is the first file
  35 ;; loaded by loadup.el that uses declarations in macros.
  36
  37 (defun macro-declaration-function (macro decl)
  38   "Process a declaration found in a macro definition.
  39 This is set as the value of the variable `macro-declaration-function'.
  40 MACRO is the name of the macro being defined.
  41 DECL is a list `(declare ...)' containing the declarations.
  42 The return value of this function is not used."
  43   ;; We can't use `dolist' or `cadr' yet for bootstrapping reasons.
  44   (let (d)
  45     ;; Ignore the first element of `decl' (it's always `declare').
  46     (while (setq decl (cdr decl))
  47       (setq d (car decl))
  48       (if (and (consp d)
  49                (listp (cdr d))
  50                (null (cdr (cdr d))))
  51           (cond ((eq (car d) 'indent)
  52                  (put macro 'lisp-indent-function (car (cdr d))))
  53                 ((eq (car d) 'debug)
  54                  (put macro 'edebug-form-spec (car (cdr d))))
  55                 ((eq (car d) 'doc-string)
  56                  (put macro 'doc-string-elt (car (cdr d))))
  57                 (t
  58                  (message "Unknown declaration %s" d)))
  59         (message "Invalid declaration %s" d)))))
  60
  61
  62 (setq macro-declaration-function 'macro-declaration-function)
  63
  64 \f
  65 ;; Redefined in byte-optimize.el.
  66 ;; This is not documented--it's not clear that we should promote it.
  67 (fset 'inline 'progn)
  68 (put 'inline 'lisp-indent-function 0)
  69
  70 ;;; Interface to inline functions.
  71
  72 ;; (defmacro proclaim-inline (&rest fns)
  73 ;;   "Cause the named functions to be open-coded when called from compiled code.
  74 ;; They will only be compiled open-coded when byte-compile-optimize is true."
  75 ;;   (cons 'eval-and-compile
  76 ;;      (mapcar '(lambda (x)
  77 ;;                 (or (memq (get x 'byte-optimizer)
  78 ;;                           '(nil byte-compile-inline-expand))
  79 ;;                     (error
  80 ;;                      "%s already has a byte-optimizer, can't make it inline"
  81 ;;                      x))
  82 ;;                 (list 'put (list 'quote x)
  83 ;;                       ''byte-optimizer ''byte-compile-inline-expand))
  84 ;;              fns)))
  85
  86 ;; (defmacro proclaim-notinline (&rest fns)
  87 ;;   "Cause the named functions to no longer be open-coded."
  88 ;;   (cons 'eval-and-compile
  89 ;;      (mapcar '(lambda (x)
  90 ;;                 (if (eq (get x 'byte-optimizer) 'byte-compile-inline-expand)
  91 ;;                     (put x 'byte-optimizer nil))
  92 ;;                 (list 'if (list 'eq (list 'get (list 'quote x) ''byte-optimizer)
  93 ;;                                 ''byte-compile-inline-expand)
  94 ;;                       (list 'put x ''byte-optimizer nil)))
  95 ;;              fns)))
  96
  97 ;; This has a special byte-hunk-handler in bytecomp.el.
  98 (defmacro defsubst (name arglist &rest body)
  99   "Define an inline function.  The syntax is just like that of `defun'."
 100   (declare (debug defun))
 101   (or (memq (get name 'byte-optimizer)
 102             '(nil byte-compile-inline-expand))
 103       (error "`%s' is a primitive" name))
 104   `(prog1
 105        (defun ,name ,arglist ,@body)
 106      (eval-and-compile
 107        (put ',name 'byte-optimizer 'byte-compile-inline-expand))))
 108
 109 (defvar advertised-signature-table (make-hash-table :test 'eq :weakness 'key))
 110
 111 (defun set-advertised-calling-convention (function signature)
 112   "Set the advertised SIGNATURE of FUNCTION.
 113 This will allow the byte-compiler to warn the programmer when she uses
 114 an obsolete calling convention."
 115   (puthash (indirect-function function) signature
 116            advertised-signature-table))
 117
 118 (defun make-obsolete (obsolete-name current-name &optional when)
 119   "Make the byte-compiler warn that OBSOLETE-NAME is obsolete.
 120 The warning will say that CURRENT-NAME should be used instead.
 121 If CURRENT-NAME is a string, that is the `use instead' message
 122 \(it should end with a period, and not start with a capital).
 123 If provided, WHEN should be a string indicating when the function
 124 was first made obsolete, for example a date or a release number."
 125   (interactive "aMake function obsolete: \nxObsoletion replacement: ")
 126   (let ((handler (get obsolete-name 'byte-compile)))
 127     (if (eq 'byte-compile-obsolete handler)
 128         (setq handler (nth 1 (get obsolete-name 'byte-obsolete-info)))
 129       (put obsolete-name 'byte-compile 'byte-compile-obsolete))
 130     (put obsolete-name 'byte-obsolete-info
 131          (list (purecopy current-name) handler (purecopy when))))
 132   obsolete-name)
 133 (set-advertised-calling-convention
 134  ;; New code should always provide the `when' argument.
 135  'make-obsolete '(obsolete-name current-name when))
 136
 137 (defmacro define-obsolete-function-alias (obsolete-name current-name
 138                                                    &optional when docstring)
 139   "Set OBSOLETE-NAME's function definition to CURRENT-NAME and mark it obsolete.
 140
 141 \(define-obsolete-function-alias 'old-fun 'new-fun \"22.1\" \"old-fun's doc.\")
 142
 143 is equivalent to the following two lines of code:
 144
 145 \(defalias 'old-fun 'new-fun \"old-fun's doc.\")
 146 \(make-obsolete 'old-fun 'new-fun \"22.1\")
 147
 148 See the docstrings of `defalias' and `make-obsolete' for more details."
 149   (declare (doc-string 4))
 150   `(progn
 151      (defalias ,obsolete-name ,current-name ,docstring)
 152      (make-obsolete ,obsolete-name ,current-name ,when)))
 153 (set-advertised-calling-convention
 154  ;; New code should always provide the `when' argument.
 155  'define-obsolete-function-alias
 156  '(obsolete-name current-name when &optional docstring))
 157
 158 (defun make-obsolete-variable (obsolete-name current-name &optional when)
 159   "Make the byte-compiler warn that OBSOLETE-NAME is obsolete.
 160 The warning will say that CURRENT-NAME should be used instead.
 161 If CURRENT-NAME is a string, that is the `use instead' message.
 162 If provided, WHEN should be a string indicating when the variable
 163 was first made obsolete, for example a date or a release number."
 164   (interactive
 165    (list
 166     (let ((str (completing-read "Make variable obsolete: " obarray 'boundp t)))
 167       (if (equal str "") (error ""))
 168       (intern str))
 169     (car (read-from-string (read-string "Obsoletion replacement: ")))))
 170   (put obsolete-name 'byte-obsolete-variable
 171        (cons
 172         (if (stringp current-name)
 173             (purecopy current-name)
 174           current-name) (purecopy when)))
 175   obsolete-name)
 176 (set-advertised-calling-convention
 177  ;; New code should always provide the `when' argument.
 178  'make-obsolete-variable '(obsolete-name current-name when))
 179
 180 (defmacro define-obsolete-variable-alias (obsolete-name current-name
 181                                                  &optional when docstring)
 182   "Make OBSOLETE-NAME a variable alias for CURRENT-NAME and mark it obsolete.
 183 This uses `defvaralias' and `make-obsolete-variable' (which see).
 184 See the Info node `(elisp)Variable Aliases' for more details.
 185
 186 If CURRENT-NAME is a defcustom (more generally, any variable
 187 where OBSOLETE-NAME may be set, e.g. in a .emacs file, before the
 188 alias is defined), then the define-obsolete-variable-alias
 189 statement should be evaluated before the defcustom, if user
 190 customizations are to be respected.  The simplest way to achieve
 191 this is to place the alias statement before the defcustom (this
 192 is not necessary for aliases that are autoloaded, or in files
 193 dumped with Emacs).  This is so that any user customizations are
 194 applied before the defcustom tries to initialize the
 195 variable (this is due to the way `defvaralias' works).
 196
 197 For the benefit of `custom-set-variables', if OBSOLETE-NAME has
 198 any of the following properties, they are copied to
 199 CURRENT-NAME, if it does not already have them:
 200 'saved-value, 'saved-variable-comment."
 201   (declare (doc-string 4))
 202   `(progn
 203      (defvaralias ,obsolete-name ,current-name ,docstring)
 204      ;; See Bug#4706.
 205      (dolist (prop '(saved-value saved-variable-comment))
 206        (and (get ,obsolete-name prop)
 207             (null (get ,current-name prop))
 208             (put ,current-name prop (get ,obsolete-name prop))))
 209      (make-obsolete-variable ,obsolete-name ,current-name ,when)))
 210 (set-advertised-calling-convention
 211  ;; New code should always provide the `when' argument.
 212  'define-obsolete-variable-alias
 213  '(obsolete-name current-name when &optional docstring))
 214
 215 ;; FIXME This is only defined in this file because the variable- and
 216 ;; function- versions are too.  Unlike those two, this one is not used
 217 ;; by the byte-compiler (would be nice if it could warn about obsolete
 218 ;; faces, but it doesn't really do anything special with faces).
 219 ;; It only really affects M-x describe-face output.
 220 (defmacro define-obsolete-face-alias (obsolete-face current-face when)
 221   "Make OBSOLETE-FACE a face alias for CURRENT-FACE and mark it obsolete.
 222 The string WHEN gives the Emacs version where OBSOLETE-FACE became
 223 obsolete."
 224   `(progn
 225      (put ,obsolete-face 'face-alias ,current-face)
 226      ;; Used by M-x describe-face.
 227      (put ,obsolete-face 'obsolete-face (or (purecopy ,when) t))))
 228
 229 (defmacro dont-compile (&rest body)
 230   "Like `progn', but the body always runs interpreted (not compiled).
 231 If you think you need this, you're probably making a mistake somewhere."
 232   (declare (debug t) (indent 0))
 233   (list 'eval (list 'quote (if (cdr body) (cons 'progn body) (car body)))))
 234
 235 \f
 236 ;; interface to evaluating things at compile time and/or load time
 237 ;; these macro must come after any uses of them in this file, as their
 238 ;; definition in the file overrides the magic definitions on the
 239 ;; byte-compile-macro-environment.
 240
 241 (defmacro eval-when-compile (&rest body)
 242   "Like `progn', but evaluates the body at compile time if you're compiling.
 243 Thus, the result of the body appears to the compiler as a quoted constant.
 244 In interpreted code, this is entirely equivalent to `progn'."
 245   (declare (debug t) (indent 0))
 246   ;; Not necessary because we have it in b-c-initial-macro-environment
 247   ;; (list 'quote (eval (cons 'progn body)))
 248   (cons 'progn body))
 249
 250 (defmacro eval-and-compile (&rest body)
 251   "Like `progn', but evaluates the body at compile time and at load time."
 252   (declare (debug t) (indent 0))
 253   ;; Remember, it's magic.
 254   (cons 'progn body))
 255
 256 (put 'with-no-warnings 'lisp-indent-function 0)
 257 (defun with-no-warnings (&rest body)
 258   "Like `progn', but prevents compiler warnings in the body."
 259   ;; The implementation for the interpreter is basically trivial.
 260   (car (last body)))
 261
 262 \f
 263 ;; I nuked this because it's not a good idea for users to think of using it.
 264 ;; These options are a matter of installation preference, and have nothing to
 265 ;; with particular source files; it's a mistake to suggest to users
 266 ;; they should associate these with particular source files.
 267 ;; There is hardly any reason to change these parameters, anyway.
 268 ;; --rms.
 269
 270 ;; (put 'byte-compiler-options 'lisp-indent-function 0)
 271 ;; (defmacro byte-compiler-options (&rest args)
 272 ;;   "Set some compilation-parameters for this file.  This will affect only the
 273 ;; file in which it appears; this does nothing when evaluated, and when loaded
 274 ;; from a .el file.
 275 ;;
 276 ;; Each argument to this macro must be a list of a key and a value.
 277 ;;
 278 ;;   Keys:                Values:               Corresponding variable:
 279 ;;
 280 ;;   verbose      t, nil                byte-compile-verbose
 281 ;;   optimize     t, nil, source, byte  byte-compile-optimize
 282 ;;   warnings     list of warnings      byte-compile-warnings
 283 ;;                    Valid elements: (callargs redefine free-vars unresolved)
 284 ;;   file-format          emacs18, emacs19      byte-compile-compatibility
 285 ;;
 286 ;; For example, this might appear at the top of a source file:
 287 ;;
 288 ;;     (byte-compiler-options
 289 ;;       (optimize t)
 290 ;;       (warnings (- free-vars))               ; Don't warn about free variables
 291 ;;       (file-format emacs19))"
 292 ;;   nil)
 293
 294 ;; arch-tag: 76f8328a-1f66-4df2-9b6d-5c3666dc05e9
 295 ;;; byte-run.el ends here