lisp/emacs-lisp/byte-run.el

   1 ;;; byte-run.el --- byte-compiler support for inlining
   2
   3 ;; Copyright (C) 1992, 2001-2011  Free Software Foundation, Inc.
   4
   5 ;; Author: Jamie Zawinski <jwz@lucid.com>
   6 ;;      Hallvard Furuseth <hbf@ulrik.uio.no>
   7 ;; Maintainer: FSF
   8 ;; Keywords: internal
   9 ;; Package: emacs
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; interface to selectively inlining functions.
  29 ;; This only happens when source-code optimization is turned on.
  30
  31 ;;; Code:
  32
  33 ;; We define macro-declaration-function here because it is needed to
  34 ;; handle declarations in macro definitions and this is the first file
  35 ;; loaded by loadup.el that uses declarations in macros.
  36
  37 (defun macro-declaration-function (macro decl)
  38   "Process a declaration found in a macro definition.
  39 This is set as the value of the variable `macro-declaration-function'.
  40 MACRO is the name of the macro being defined.
  41 DECL is a list `(declare ...)' containing the declarations.
  42 The return value of this function is not used."
  43   ;; We can't use `dolist' or `cadr' yet for bootstrapping reasons.
  44   (let (d)
  45     ;; Ignore the first element of `decl' (it's always `declare').
  46     (while (setq decl (cdr decl))
  47       (setq d (car decl))
  48       (if (and (consp d)
  49                (listp (cdr d))
  50                (null (cdr (cdr d))))
  51           (cond ((eq (car d) 'indent)
  52                  (put macro 'lisp-indent-function (car (cdr d))))
  53                 ((eq (car d) 'debug)
  54                  (put macro 'edebug-form-spec (car (cdr d))))
  55                 ((eq (car d) 'doc-string)
  56                  (put macro 'doc-string-elt (car (cdr d))))
  57                 (t
  58                  (message "Unknown declaration %s" d)))
  59         (message "Invalid declaration %s" d)))))
  60
  61
  62 (setq macro-declaration-function 'macro-declaration-function)
  63
  64 \f
  65 ;; Redefined in byte-optimize.el.
  66 ;; This is not documented--it's not clear that we should promote it.
  67 (fset 'inline 'progn)
  68
  69 ;;; Interface to inline functions.
  70
  71 ;; (defmacro proclaim-inline (&rest fns)
  72 ;;   "Cause the named functions to be open-coded when called from compiled code.
  73 ;; They will only be compiled open-coded when byte-compile-optimize is true."
  74 ;;   (cons 'eval-and-compile
  75 ;;      (mapcar (lambda (x)
  76 ;;                 (or (memq (get x 'byte-optimizer)
  77 ;;                           '(nil byte-compile-inline-expand))
  78 ;;                     (error
  79 ;;                      "%s already has a byte-optimizer, can't make it inline"
  80 ;;                      x))
  81 ;;                 (list 'put (list 'quote x)
  82 ;;                       ''byte-optimizer ''byte-compile-inline-expand))
  83 ;;              fns)))
  84
  85 ;; (defmacro proclaim-notinline (&rest fns)
  86 ;;   "Cause the named functions to no longer be open-coded."
  87 ;;   (cons 'eval-and-compile
  88 ;;      (mapcar (lambda (x)
  89 ;;                 (if (eq (get x 'byte-optimizer) 'byte-compile-inline-expand)
  90 ;;                     (put x 'byte-optimizer nil))
  91 ;;                 (list 'if (list 'eq (list 'get (list 'quote x) ''byte-optimizer)
  92 ;;                                 ''byte-compile-inline-expand)
  93 ;;                       (list 'put x ''byte-optimizer nil)))
  94 ;;              fns)))
  95
  96 ;; This has a special byte-hunk-handler in bytecomp.el.
  97 (defmacro defsubst (name arglist &rest body)
  98   "Define an inline function.  The syntax is just like that of `defun'."
  99   (declare (debug defun))
 100   (or (memq (get name 'byte-optimizer)
 101             '(nil byte-compile-inline-expand))
 102       (error "`%s' is a primitive" name))
 103   `(prog1
 104        (defun ,name ,arglist ,@body)
 105      (eval-and-compile
 106        (put ',name 'byte-optimizer 'byte-compile-inline-expand))))
 107
 108 (defvar advertised-signature-table (make-hash-table :test 'eq :weakness 'key))
 109
 110 (defun set-advertised-calling-convention (function signature when)
 111   "Set the advertised SIGNATURE of FUNCTION.
 112 This will allow the byte-compiler to warn the programmer when she uses
 113 an obsolete calling convention.  WHEN specifies since when the calling
 114 convention was modified."
 115   (puthash (indirect-function function) signature
 116            advertised-signature-table))
 117
 118 (defun make-obsolete (obsolete-name current-name &optional when)
 119   "Make the byte-compiler warn that OBSOLETE-NAME is obsolete.
 120 The warning will say that CURRENT-NAME should be used instead.
 121 If CURRENT-NAME is a string, that is the `use instead' message
 122 \(it should end with a period, and not start with a capital).
 123 WHEN should be a string indicating when the function
 124 was first made obsolete, for example a date or a release number."
 125   (interactive "aMake function obsolete: \nxObsoletion replacement: ")
 126   (put obsolete-name 'byte-obsolete-info
 127        ;; The second entry used to hold the `byte-compile' handler, but
 128        ;; is not used any more nowadays.
 129        (purecopy (list current-name nil when)))
 130   obsolete-name)
 131 (set-advertised-calling-convention
 132  ;; New code should always provide the `when' argument.
 133  'make-obsolete '(obsolete-name current-name when) "23.1")
 134
 135 (defmacro define-obsolete-function-alias (obsolete-name current-name
 136                                                    &optional when docstring)
 137   "Set OBSOLETE-NAME's function definition to CURRENT-NAME and mark it obsolete.
 138
 139 \(define-obsolete-function-alias 'old-fun 'new-fun \"22.1\" \"old-fun's doc.\")
 140
 141 is equivalent to the following two lines of code:
 142
 143 \(defalias 'old-fun 'new-fun \"old-fun's doc.\")
 144 \(make-obsolete 'old-fun 'new-fun \"22.1\")
 145
 146 See the docstrings of `defalias' and `make-obsolete' for more details."
 147   (declare (doc-string 4))
 148   `(progn
 149      (defalias ,obsolete-name ,current-name ,docstring)
 150      (make-obsolete ,obsolete-name ,current-name ,when)))
 151 (set-advertised-calling-convention
 152  ;; New code should always provide the `when' argument.
 153  'define-obsolete-function-alias
 154  '(obsolete-name current-name when &optional docstring) "23.1")
 155
 156 (defun make-obsolete-variable (obsolete-name current-name &optional when access-type)
 157   "Make the byte-compiler warn that OBSOLETE-NAME is obsolete.
 158 The warning will say that CURRENT-NAME should be used instead.
 159 If CURRENT-NAME is a string, that is the `use instead' message.
 160 WHEN should be a string indicating when the variable
 161 was first made obsolete, for example a date or a release number.
 162 ACCESS-TYPE if non-nil should specify the kind of access that will trigger
 163   obsolescence warnings; it can be either `get' or `set'."
 164   (put obsolete-name 'byte-obsolete-variable
 165        (purecopy (list current-name access-type when)))
 166   obsolete-name)
 167 (set-advertised-calling-convention
 168  ;; New code should always provide the `when' argument.
 169  'make-obsolete-variable
 170  '(obsolete-name current-name when &optional access-type) "23.1")
 171
 172 (defmacro define-obsolete-variable-alias (obsolete-name current-name
 173                                                  &optional when docstring)
 174   "Make OBSOLETE-NAME a variable alias for CURRENT-NAME and mark it obsolete.
 175 This uses `defvaralias' and `make-obsolete-variable' (which see).
 176 See the Info node `(elisp)Variable Aliases' for more details.
 177
 178 If CURRENT-NAME is a defcustom (more generally, any variable
 179 where OBSOLETE-NAME may be set, e.g. in a .emacs file, before the
 180 alias is defined), then the define-obsolete-variable-alias
 181 statement should be evaluated before the defcustom, if user
 182 customizations are to be respected.  The simplest way to achieve
 183 this is to place the alias statement before the defcustom (this
 184 is not necessary for aliases that are autoloaded, or in files
 185 dumped with Emacs).  This is so that any user customizations are
 186 applied before the defcustom tries to initialize the
 187 variable (this is due to the way `defvaralias' works).
 188
 189 For the benefit of `custom-set-variables', if OBSOLETE-NAME has
 190 any of the following properties, they are copied to
 191 CURRENT-NAME, if it does not already have them:
 192 'saved-value, 'saved-variable-comment."
 193   (declare (doc-string 4))
 194   `(progn
 195      (defvaralias ,obsolete-name ,current-name ,docstring)
 196      ;; See Bug#4706.
 197      (dolist (prop '(saved-value saved-variable-comment))
 198        (and (get ,obsolete-name prop)
 199             (null (get ,current-name prop))
 200             (put ,current-name prop (get ,obsolete-name prop))))
 201      (make-obsolete-variable ,obsolete-name ,current-name ,when)))
 202 (set-advertised-calling-convention
 203  ;; New code should always provide the `when' argument.
 204  'define-obsolete-variable-alias
 205  '(obsolete-name current-name when &optional docstring) "23.1")
 206
 207 ;; FIXME This is only defined in this file because the variable- and
 208 ;; function- versions are too.  Unlike those two, this one is not used
 209 ;; by the byte-compiler (would be nice if it could warn about obsolete
 210 ;; faces, but it doesn't really do anything special with faces).
 211 ;; It only really affects M-x describe-face output.
 212 (defmacro define-obsolete-face-alias (obsolete-face current-face when)
 213   "Make OBSOLETE-FACE a face alias for CURRENT-FACE and mark it obsolete.
 214 The string WHEN gives the Emacs version where OBSOLETE-FACE became
 215 obsolete."
 216   `(progn
 217      (put ,obsolete-face 'face-alias ,current-face)
 218      ;; Used by M-x describe-face.
 219      (put ,obsolete-face 'obsolete-face (or (purecopy ,when) t))))
 220
 221 (defmacro dont-compile (&rest body)
 222   "Like `progn', but the body always runs interpreted (not compiled).
 223 If you think you need this, you're probably making a mistake somewhere."
 224   (declare (debug t) (indent 0))
 225   (list 'eval (list 'quote (if (cdr body) (cons 'progn body) (car body)))))
 226
 227 \f
 228 ;; interface to evaluating things at compile time and/or load time
 229 ;; these macro must come after any uses of them in this file, as their
 230 ;; definition in the file overrides the magic definitions on the
 231 ;; byte-compile-macro-environment.
 232
 233 (defmacro eval-when-compile (&rest body)
 234   "Like `progn', but evaluates the body at compile time if you're compiling.
 235 Thus, the result of the body appears to the compiler as a quoted constant.
 236 In interpreted code, this is entirely equivalent to `progn'."
 237   (declare (debug t) (indent 0))
 238   ;; Not necessary because we have it in b-c-initial-macro-environment
 239   ;; (list 'quote (eval (cons 'progn body)))
 240   (cons 'progn body))
 241
 242 (defmacro eval-and-compile (&rest body)
 243   "Like `progn', but evaluates the body at compile time and at load time."
 244   (declare (debug t) (indent 0))
 245   ;; Remember, it's magic.
 246   (cons 'progn body))
 247
 248 (put 'with-no-warnings 'lisp-indent-function 0)
 249 (defun with-no-warnings (&rest body)
 250   "Like `progn', but prevents compiler warnings in the body."
 251   ;; The implementation for the interpreter is basically trivial.
 252   (car (last body)))
 253
 254 \f
 255 ;; I nuked this because it's not a good idea for users to think of using it.
 256 ;; These options are a matter of installation preference, and have nothing to
 257 ;; with particular source files; it's a mistake to suggest to users
 258 ;; they should associate these with particular source files.
 259 ;; There is hardly any reason to change these parameters, anyway.
 260 ;; --rms.
 261
 262 ;; (put 'byte-compiler-options 'lisp-indent-function 0)
 263 ;; (defmacro byte-compiler-options (&rest args)
 264 ;;   "Set some compilation-parameters for this file.  This will affect only the
 265 ;; file in which it appears; this does nothing when evaluated, and when loaded
 266 ;; from a .el file.
 267 ;;
 268 ;; Each argument to this macro must be a list of a key and a value.
 269 ;;
 270 ;;   Keys:                Values:               Corresponding variable:
 271 ;;
 272 ;;   verbose      t, nil                byte-compile-verbose
 273 ;;   optimize     t, nil, source, byte  byte-compile-optimize
 274 ;;   warnings     list of warnings      byte-compile-warnings
 275 ;;                    Valid elements: (callargs redefine free-vars unresolved)
 276 ;;   file-format          emacs18, emacs19      byte-compile-compatibility
 277 ;;
 278 ;; For example, this might appear at the top of a source file:
 279 ;;
 280 ;;     (byte-compiler-options
 281 ;;       (optimize t)
 282 ;;       (warnings (- free-vars))               ; Don't warn about free variables
 283 ;;       (file-format emacs19))"
 284 ;;   nil)
 285
 286 ;;; byte-run.el ends here