lisp/ibuf-ext.el

   1 ;;; ibuf-ext.el --- extensions for ibuffer
   2
   3 ;; Copyright (C) 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
   4 ;;   2009, 2010  Free Software Foundation, Inc.
   5
   6 ;; Author: Colin Walters <walters@verbum.org>
   7 ;; Maintainer: John Paul Wallington <jpw@gnu.org>
   8 ;; Created: 2 Dec 2001
   9 ;; Keywords: buffer, convenience
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; These functions should be automatically loaded when called, but you
  29 ;; can explicity (require 'ibuf-ext) in your ~/.emacs to have them
  30 ;; preloaded.
  31
  32 ;;; Code:
  33
  34 (require 'ibuffer)
  35
  36 (eval-when-compile
  37   (require 'ibuf-macs)
  38   (require 'cl))
  39
  40 ;;; Utility functions
  41 (defun ibuffer-delete-alist (key alist)
  42   "Delete all entries in ALIST that have a key equal to KEY."
  43   (let (entry)
  44     (while (setq entry (assoc key alist))
  45       (setq alist (delete entry alist)))
  46     alist))
  47
  48 ;; borrowed from Gnus
  49 (defun ibuffer-remove-duplicates (list)
  50   "Return a copy of LIST with duplicate elements removed."
  51   (let ((new nil)
  52         (tail list))
  53     (while tail
  54       (or (member (car tail) new)
  55           (setq new (cons (car tail) new)))
  56       (setq tail (cdr tail)))
  57     (nreverse new)))
  58
  59 (defun ibuffer-split-list (ibuffer-split-list-fn ibuffer-split-list-elts)
  60   (let ((hip-crowd nil)
  61         (lamers nil))
  62     (dolist (ibuffer-split-list-elt ibuffer-split-list-elts)
  63       (if (funcall ibuffer-split-list-fn ibuffer-split-list-elt)
  64           (push ibuffer-split-list-elt hip-crowd)
  65         (push ibuffer-split-list-elt lamers)))
  66     ;; Too bad Emacs Lisp doesn't have multiple values.
  67     (list (nreverse hip-crowd) (nreverse lamers))))
  68
  69 (defcustom ibuffer-never-show-predicates nil
  70   "A list of predicates (a regexp or function) for buffers not to display.
  71 If a regexp, then it will be matched against the buffer's name.
  72 If a function, it will be called with the buffer as an argument, and
  73 should return non-nil if this buffer should not be shown."
  74   :type '(repeat (choice regexp function))
  75   :require 'ibuf-ext
  76   :group 'ibuffer)
  77
  78 (defcustom ibuffer-always-show-predicates nil
  79   "A list of predicates (a regexp or function) for buffers to always display.
  80 If a regexp, then it will be matched against the buffer's name.
  81 If a function, it will be called with the buffer as an argument, and
  82 should return non-nil if this buffer should be shown.
  83 Note that buffers matching one of these predicates will be shown
  84 regardless of any active filters in this buffer."
  85   :type '(repeat (choice regexp function))
  86   :group 'ibuffer)
  87
  88 (defvar ibuffer-tmp-hide-regexps nil
  89   "A list of regexps which should match buffer names to not show.")
  90
  91 (defvar ibuffer-tmp-show-regexps nil
  92   "A list of regexps which should match buffer names to always show.")
  93
  94 (defvar ibuffer-auto-buffers-changed nil)
  95
  96 (defcustom ibuffer-saved-filters '(("gnus"
  97                                     ((or (mode . message-mode)
  98                                          (mode . mail-mode)
  99                                          (mode . gnus-group-mode)
 100                                          (mode . gnus-summary-mode)
 101                                          (mode . gnus-article-mode))))
 102                                    ("programming"
 103                                     ((or (mode . emacs-lisp-mode)
 104                                          (mode . cperl-mode)
 105                                          (mode . c-mode)
 106                                          (mode . java-mode)
 107                                          (mode . idl-mode)
 108                                          (mode . lisp-mode)))))
 109
 110   "An alist of filter qualifiers to switch between.
 111
 112 This variable should look like ((\"STRING\" QUALIFIERS)
 113                                 (\"STRING\" QUALIFIERS) ...), where
 114 QUALIFIERS is a list of the same form as
 115 `ibuffer-filtering-qualifiers'.
 116 See also the variables `ibuffer-filtering-qualifiers',
 117 `ibuffer-filtering-alist', and the functions
 118 `ibuffer-switch-to-saved-filters', `ibuffer-save-filters'."
 119   :type '(repeat sexp)
 120   :group 'ibuffer)
 121
 122 (defvar ibuffer-filtering-qualifiers nil
 123   "A list like (SYMBOL . QUALIFIER) which filters the current buffer list.
 124 See also `ibuffer-filtering-alist'.")
 125
 126 ;; This is now frobbed by `define-ibuffer-filter'.
 127 (defvar ibuffer-filtering-alist nil
 128   "An alist of (SYMBOL DESCRIPTION FUNCTION) which describes a filter.
 129
 130 You most likely do not want to modify this variable directly; see
 131 `define-ibuffer-filter'.
 132
 133 SYMBOL is the symbolic name of the filter.  DESCRIPTION is used when
 134 displaying information to the user.  FUNCTION is given a buffer and
 135 the value of the qualifier, and returns non-nil if and only if the
 136 buffer should be displayed.")
 137
 138 (defcustom ibuffer-filter-format-alist nil
 139   "An alist which has special formats used when a filter is active.
 140 The contents of this variable should look like:
 141  ((FILTER (FORMAT FORMAT ...)) (FILTER (FORMAT FORMAT ...)) ...)
 142
 143 For example, suppose that when you add a filter for buffers whose
 144 major mode is `emacs-lisp-mode', you only want to see the mark and the
 145 name of the buffer.  You could accomplish that by adding:
 146  (mode ((mark \" \" name)))
 147 to this variable."
 148   :type '(repeat (list :tag "Association" (symbol :tag "Filter")
 149                        (list :tag "Formats" (repeat (sexp :tag "Format")))))
 150   :group 'ibuffer)
 151
 152 (defvar ibuffer-cached-filter-formats nil)
 153 (defvar ibuffer-compiled-filter-formats nil)
 154
 155 (defvar ibuffer-filter-groups nil
 156   "A list like ((\"NAME\" ((SYMBOL . QUALIFIER) ...) ...) which groups buffers.
 157 The SYMBOL should be one from `ibuffer-filtering-alist'.
 158 The QUALIFIER should be the same as QUALIFIER in
 159 `ibuffer-filtering-qualifiers'.")
 160
 161 (defcustom ibuffer-show-empty-filter-groups t
 162   "If non-nil, then show the names of filter groups which are empty."
 163   :type 'boolean
 164   :group 'ibuffer)
 165
 166 (defcustom ibuffer-saved-filter-groups nil
 167   "An alist of filtering groups to switch between.
 168
 169 This variable should look like ((\"STRING\" QUALIFIERS)
 170                                 (\"STRING\" QUALIFIERS) ...), where
 171 QUALIFIERS is a list of the same form as
 172 `ibuffer-filtering-qualifiers'.
 173
 174 See also the variables `ibuffer-filter-groups',
 175 `ibuffer-filtering-qualifiers', `ibuffer-filtering-alist', and the
 176 functions `ibuffer-switch-to-saved-filter-groups',
 177 `ibuffer-save-filter-groups'."
 178   :type '(repeat sexp)
 179   :group 'ibuffer)
 180
 181 (defvar ibuffer-hidden-filter-groups nil
 182   "A list of filtering groups which are currently hidden.")
 183
 184 (defvar ibuffer-filter-group-kill-ring nil)
 185
 186 (defcustom ibuffer-old-time 72
 187   "The number of hours before a buffer is considered \"old\"."
 188   :type '(choice (const :tag "72 hours (3 days)" 72)
 189                  (const :tag "48 hours (2 days)" 48)
 190                  (const :tag "24 hours (1 day)" 24)
 191                  (integer :tag "hours"))
 192   :group 'ibuffer)
 193
 194 (defcustom ibuffer-save-with-custom t
 195   "If non-nil, then use Custom to save interactively changed variables.
 196 Currently, this only applies to `ibuffer-saved-filters' and
 197 `ibuffer-saved-filter-groups'."
 198   :type 'boolean
 199   :group 'ibuffer)
 200
 201 (defun ibuffer-ext-visible-p (buf all &optional ibuffer-buf)
 202   (or
 203    (ibuffer-buf-matches-predicates buf ibuffer-tmp-show-regexps)
 204    (and (not
 205          (or
 206           (ibuffer-buf-matches-predicates buf ibuffer-tmp-hide-regexps)
 207           (ibuffer-buf-matches-predicates buf ibuffer-never-show-predicates)))
 208         (or all
 209             (not
 210              (ibuffer-buf-matches-predicates buf ibuffer-maybe-show-predicates)))
 211         (or ibuffer-view-ibuffer
 212             (and ibuffer-buf
 213                  (not (eq ibuffer-buf buf))))
 214         (or
 215          (ibuffer-included-in-filters-p buf ibuffer-filtering-qualifiers)
 216          (ibuffer-buf-matches-predicates buf ibuffer-always-show-predicates)))))
 217
 218 ;;;###autoload
 219 (define-minor-mode ibuffer-auto-mode
 220   "Toggle use of Ibuffer's auto-update facility.
 221 With numeric ARG, enable auto-update if and only if ARG is positive."
 222   nil nil nil
 223   (unless (derived-mode-p 'ibuffer-mode)
 224     (error "This buffer is not in Ibuffer mode"))
 225   (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed) ; Initialize state vector
 226   (add-hook 'post-command-hook 'ibuffer-auto-update-changed))
 227
 228 (defun ibuffer-auto-update-changed ()
 229   (when (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed)
 230     (dolist (buf (buffer-list))
 231       (ignore-errors
 232         (with-current-buffer buf
 233           (when (and ibuffer-auto-mode
 234                      (derived-mode-p 'ibuffer-mode))
 235             (ibuffer-update nil t)))))))
 236
 237 ;;;###autoload
 238 (defun ibuffer-mouse-filter-by-mode (event)
 239   "Enable or disable filtering by the major mode chosen via mouse."
 240   (interactive "e")
 241   (ibuffer-interactive-filter-by-mode event))
 242
 243 ;;;###autoload
 244 (defun ibuffer-interactive-filter-by-mode (event-or-point)
 245   "Enable or disable filtering by the major mode at point."
 246   (interactive "d")
 247   (if (eventp event-or-point)
 248       (posn-set-point (event-end event-or-point))
 249     (goto-char event-or-point))
 250   (let ((buf (ibuffer-current-buffer)))
 251     (if (assq 'mode ibuffer-filtering-qualifiers)
 252         (setq ibuffer-filtering-qualifiers
 253               (ibuffer-delete-alist 'mode ibuffer-filtering-qualifiers))
 254       (ibuffer-push-filter (cons 'mode (buffer-local-value 'major-mode buf)))))
 255   (ibuffer-update nil t))
 256
 257 ;;;###autoload
 258 (defun ibuffer-mouse-toggle-filter-group (event)
 259   "Toggle the display status of the filter group chosen with the mouse."
 260   (interactive "e")
 261   (ibuffer-toggle-filter-group-1 (save-excursion
 262                                    (mouse-set-point event)
 263                                    (point))))
 264
 265 ;;;###autoload
 266 (defun ibuffer-toggle-filter-group ()
 267   "Toggle the display status of the filter group on this line."
 268   (interactive)
 269   (ibuffer-toggle-filter-group-1 (point)))
 270
 271 (defun ibuffer-toggle-filter-group-1 (posn)
 272   (let ((name (get-text-property posn 'ibuffer-filter-group-name)))
 273     (unless (stringp name)
 274       (error "No filtering group name present"))
 275     (if (member name ibuffer-hidden-filter-groups)
 276         (setq ibuffer-hidden-filter-groups
 277               (delete name ibuffer-hidden-filter-groups))
 278       (push name ibuffer-hidden-filter-groups))
 279     (ibuffer-update nil t)))
 280
 281 ;;;###autoload
 282 (defun ibuffer-forward-filter-group (&optional count)
 283   "Move point forwards by COUNT filtering groups."
 284   (interactive "P")
 285   (unless count
 286     (setq count 1))
 287   (when (> count 0)
 288     (when (get-text-property (point) 'ibuffer-filter-group-name)
 289       (goto-char (next-single-property-change
 290                   (point) 'ibuffer-filter-group-name
 291                   nil (point-max))))
 292     (goto-char (next-single-property-change
 293                 (point) 'ibuffer-filter-group-name
 294                 nil (point-max)))
 295     (ibuffer-forward-filter-group (1- count)))
 296   (ibuffer-forward-line 0))
 297
 298 ;;;###autoload
 299 (defun ibuffer-backward-filter-group (&optional count)
 300   "Move point backwards by COUNT filtering groups."
 301   (interactive "P")
 302   (unless count
 303     (setq count 1))
 304   (when (> count 0)
 305     (when (get-text-property (point) 'ibuffer-filter-group-name)
 306       (goto-char (previous-single-property-change
 307                   (point) 'ibuffer-filter-group-name
 308                   nil (point-min))))
 309     (goto-char (previous-single-property-change
 310                 (point) 'ibuffer-filter-group-name
 311                 nil (point-min)))
 312     (ibuffer-backward-filter-group (1- count)))
 313   (when (= (point) (point-min))
 314     (goto-char (point-max))
 315     (ibuffer-backward-filter-group 1))
 316   (ibuffer-forward-line 0))
 317
 318 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe "ibuf-ext")
 319 (define-ibuffer-op shell-command-pipe (command)
 320   "Pipe the contents of each marked buffer to shell command COMMAND."
 321   (:interactive "sPipe to shell command: "
 322    :opstring "Shell command executed on"
 323    :modifier-p nil)
 324   (shell-command-on-region
 325    (point-min) (point-max) command
 326    (get-buffer-create "* ibuffer-shell-output*")))
 327
 328 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe-replace "ibuf-ext")
 329 (define-ibuffer-op shell-command-pipe-replace (command)
 330   "Replace the contents of marked buffers with output of pipe to COMMAND."
 331   (:interactive "sPipe to shell command (replace): "
 332    :opstring "Buffer contents replaced in"
 333    :active-opstring "replace buffer contents in"
 334    :dangerous t
 335    :modifier-p t)
 336   (with-current-buffer buf
 337     (shell-command-on-region (point-min) (point-max)
 338                              command nil t)))
 339
 340 ;;;###autoload (autoload 'ibuffer-do-shell-command-file "ibuf-ext")
 341 (define-ibuffer-op shell-command-file (command)
 342   "Run shell command COMMAND separately on files of marked buffers."
 343   (:interactive "sShell command on buffer's file: "
 344    :opstring "Shell command executed on"
 345    :modifier-p nil)
 346   (shell-command (concat command " "
 347                          (shell-quote-argument
 348                           (if buffer-file-name
 349                               buffer-file-name
 350                             (make-temp-file
 351                              (substring (buffer-name) 0 (min 10 (length (buffer-name))))))))))
 352
 353 ;;;###autoload (autoload 'ibuffer-do-eval "ibuf-ext")
 354 (define-ibuffer-op eval (form)
 355   "Evaluate FORM in each of the buffers.
 356 Does not display the buffer during evaluation. See
 357 `ibuffer-do-view-and-eval' for that."
 358   (:interactive
 359    (list
 360     (read-from-minibuffer
 361      "Eval in buffers (form): "
 362      nil read-expression-map t 'read-expression-history))
 363    :opstring "evaluated in"
 364    :modifier-p :maybe)
 365   (eval form))
 366
 367 ;;;###autoload (autoload 'ibuffer-do-view-and-eval "ibuf-ext")
 368 (define-ibuffer-op view-and-eval (form)
 369   "Evaluate FORM while displaying each of the marked buffers.
 370 To evaluate a form without viewing the buffer, see `ibuffer-do-eval'."
 371   (:interactive
 372    (list
 373     (read-from-minibuffer
 374      "Eval viewing in buffers (form): "
 375      nil read-expression-map t 'read-expression-history))
 376    :opstring "evaluated in"
 377    :complex t
 378    :modifier-p :maybe)
 379   (let ((ibuffer-buf (current-buffer)))
 380     (unwind-protect
 381         (progn
 382           (switch-to-buffer buf)
 383           (eval form))
 384       (switch-to-buffer ibuffer-buf))))
 385
 386 ;;;###autoload (autoload 'ibuffer-do-rename-uniquely "ibuf-ext")
 387 (define-ibuffer-op rename-uniquely ()
 388   "Rename marked buffers as with `rename-uniquely'."
 389   (:opstring "renamed"
 390    :modifier-p t)
 391   (rename-uniquely))
 392
 393 ;;;###autoload (autoload 'ibuffer-do-revert "ibuf-ext")
 394 (define-ibuffer-op revert ()
 395   "Revert marked buffers as with `revert-buffer'."
 396   (:dangerous t
 397    :opstring "reverted"
 398    :active-opstring "revert"
 399    :modifier-p :maybe)
 400   (revert-buffer t t))
 401
 402 ;;;###autoload (autoload 'ibuffer-do-isearch "ibuf-ext")
 403 (define-ibuffer-op ibuffer-do-isearch ()
 404   "Perform a `isearch-forward' in marked buffers."
 405   (:interactive ()
 406    :opstring "searched in"
 407    :complex t
 408    :modifier-p :maybe)
 409   (multi-isearch-buffers (ibuffer-get-marked-buffers)))
 410
 411 ;;;###autoload (autoload 'ibuffer-do-isearch-regexp "ibuf-ext")
 412 (define-ibuffer-op ibuffer-do-isearch-regexp ()
 413   "Perform a `isearch-forward-regexp' in marked buffers."
 414   (:interactive ()
 415    :opstring "searched regexp in"
 416    :complex t
 417    :modifier-p :maybe)
 418   (multi-isearch-buffers-regexp (ibuffer-get-marked-buffers)))
 419
 420 ;;;###autoload (autoload 'ibuffer-do-replace-regexp "ibuf-ext")
 421 (define-ibuffer-op replace-regexp (from-str to-str)
 422   "Perform a `replace-regexp' in marked buffers."
 423   (:interactive
 424    (let* ((from-str (read-from-minibuffer "Replace regexp: "))
 425           (to-str (read-from-minibuffer (concat "Replace " from-str
 426                                                 " with: "))))
 427      (list from-str to-str))
 428    :opstring "replaced in"
 429    :complex t
 430    :modifier-p :maybe)
 431   (save-window-excursion
 432     (switch-to-buffer buf)
 433     (save-excursion
 434       (goto-char (point-min))
 435       (let ((case-fold-search ibuffer-case-fold-search))
 436         (while (re-search-forward from-str nil t)
 437           (replace-match to-str))))
 438     t))
 439
 440 ;;;###autoload (autoload 'ibuffer-do-query-replace "ibuf-ext")
 441 (define-ibuffer-op query-replace (&rest args)
 442   "Perform a `query-replace' in marked buffers."
 443   (:interactive
 444    (query-replace-read-args "Query replace" t t)
 445    :opstring "replaced in"
 446    :complex t
 447    :modifier-p :maybe)
 448   (save-window-excursion
 449     (switch-to-buffer buf)
 450     (save-excursion
 451       (let ((case-fold-search ibuffer-case-fold-search))
 452         (goto-char (point-min))
 453         (apply #'query-replace args)))
 454     t))
 455
 456 ;;;###autoload (autoload 'ibuffer-do-query-replace-regexp "ibuf-ext")
 457 (define-ibuffer-op query-replace-regexp (&rest args)
 458   "Perform a `query-replace-regexp' in marked buffers."
 459   (:interactive
 460    (query-replace-read-args "Query replace regexp" t t)
 461    :opstring "replaced in"
 462    :complex t
 463    :modifier-p :maybe)
 464   (save-window-excursion
 465     (switch-to-buffer buf)
 466     (save-excursion
 467       (let ((case-fold-search ibuffer-case-fold-search))
 468         (goto-char (point-min))
 469         (apply #'query-replace-regexp args)))
 470     t))
 471
 472 ;;;###autoload (autoload 'ibuffer-do-print "ibuf-ext")
 473 (define-ibuffer-op print ()
 474   "Print marked buffers as with `print-buffer'."
 475   (:opstring "printed"
 476    :modifier-p nil)
 477   (print-buffer))
 478
 479 ;;;###autoload
 480 (defun ibuffer-included-in-filters-p (buf filters)
 481   (not
 482    (memq nil ;; a filter will return nil if it failed
 483          (mapcar
 484           ;; filter should be like (TYPE . QUALIFIER), or
 485           ;; (or (TYPE . QUALIFIER) (TYPE . QUALIFIER) ...)
 486           #'(lambda (qual)
 487               (ibuffer-included-in-filter-p buf qual))
 488           filters))))
 489
 490 (defun ibuffer-included-in-filter-p (buf filter)
 491   (if (eq (car filter) 'not)
 492       (not (ibuffer-included-in-filter-p-1 buf (cdr filter)))
 493     (ibuffer-included-in-filter-p-1 buf filter)))
 494
 495 (defun ibuffer-included-in-filter-p-1 (buf filter)
 496   (not
 497    (not
 498     (case (car filter)
 499       (or
 500        (memq t (mapcar #'(lambda (x)
 501                            (ibuffer-included-in-filter-p buf x))
 502                        (cdr filter))))
 503       (saved
 504        (let ((data
 505               (assoc (cdr filter)
 506                      ibuffer-saved-filters)))
 507          (unless data
 508            (ibuffer-filter-disable)
 509            (error "Unknown saved filter %s" (cdr filter)))
 510          (ibuffer-included-in-filters-p buf (cadr data))))
 511       (t
 512        (let ((filterdat (assq (car filter)
 513                               ibuffer-filtering-alist)))
 514          ;; filterdat should be like (TYPE DESCRIPTION FUNC)
 515          ;; just a sanity check
 516         (unless filterdat
 517           (ibuffer-filter-disable)
 518           (error "Undefined filter %s" (car filter)))
 519         (not
 520          (not
 521           (funcall (caddr filterdat)
 522                    buf
 523                    (cdr filter))))))))))
 524
 525 (defun ibuffer-generate-filter-groups (bmarklist &optional noempty nodefault)
 526   (let ((filter-group-alist (if nodefault
 527                                 ibuffer-filter-groups
 528                               (append ibuffer-filter-groups
 529                                       (list (cons "Default" nil))))))
 530 ;;     (dolist (hidden ibuffer-hidden-filter-groups)
 531 ;;       (setq filter-group-alist (ibuffer-delete-alist
 532 ;;                                 hidden filter-group-alist)))
 533     (let ((vec (make-vector (length filter-group-alist) nil))
 534           (i 0))
 535       (dolist (filtergroup filter-group-alist)
 536         (let ((filterset (cdr filtergroup)))
 537           (multiple-value-bind (hip-crowd lamers)
 538               (values-list
 539                (ibuffer-split-list (lambda (bufmark)
 540                                      (ibuffer-included-in-filters-p (car bufmark)
 541                                                                     filterset))
 542                                    bmarklist))
 543             (aset vec i hip-crowd)
 544             (incf i)
 545             (setq bmarklist lamers))))
 546       (let (ret)
 547         (dotimes (j i ret)
 548           (let ((bufs (aref vec j)))
 549             (unless (and noempty (null bufs))
 550               (push (cons (car (nth j filter-group-alist))
 551                           bufs)
 552                     ret))))))))
 553
 554 ;;;###autoload
 555 (defun ibuffer-filters-to-filter-group (name)
 556   "Make the current filters into a filtering group."
 557   (interactive "sName for filtering group: ")
 558   (when (null ibuffer-filtering-qualifiers)
 559     (error "No filters in effect"))
 560   (push (cons name ibuffer-filtering-qualifiers) ibuffer-filter-groups)
 561   (ibuffer-filter-disable))
 562
 563 ;;;###autoload
 564 (defun ibuffer-set-filter-groups-by-mode ()
 565   "Set the current filter groups to filter by mode."
 566   (interactive)
 567   (setq ibuffer-filter-groups
 568         (mapcar (lambda (mode)
 569                   (cons (format "%s" mode) `((mode . ,mode))))
 570                 (let ((modes
 571                        (ibuffer-remove-duplicates
 572                         (mapcar (lambda (buf)
 573                                   (buffer-local-value 'major-mode buf))
 574                                 (buffer-list)))))
 575                   (if ibuffer-view-ibuffer
 576                       modes
 577                     (delq 'ibuffer-mode modes)))))
 578   (ibuffer-update nil t))
 579
 580 ;;;###autoload
 581 (defun ibuffer-pop-filter-group ()
 582   "Remove the first filter group."
 583   (interactive)
 584   (when (null ibuffer-filter-groups)
 585     (error "No filter groups active"))
 586   (setq ibuffer-hidden-filter-groups
 587         (delete (pop ibuffer-filter-groups)
 588                 ibuffer-hidden-filter-groups))
 589   (ibuffer-update nil t))
 590
 591 (defun ibuffer-read-filter-group-name (msg &optional nodefault noerror)
 592   (when (and (not noerror) (null ibuffer-filter-groups))
 593     (error "No filter groups active"))
 594   ;; `ibuffer-generate-filter-groups' returns all non-hidden filter
 595   ;; groups, possibly excluding empty groups or Default.
 596   ;; We add `ibuffer-hidden-filter-groups' to the list, excluding
 597   ;; Default if necessary.
 598   (completing-read msg (nconc
 599                         (ibuffer-generate-filter-groups
 600                          (ibuffer-current-state-list)
 601                          (not ibuffer-show-empty-filter-groups)
 602                          nodefault)
 603                         (if nodefault
 604                             (remove "Default" ibuffer-hidden-filter-groups)
 605                           ibuffer-hidden-filter-groups))
 606                    nil t))
 607
 608 ;;;###autoload
 609 (defun ibuffer-decompose-filter-group (group)
 610   "Decompose the filter group GROUP into active filters."
 611   (interactive
 612    (list (ibuffer-read-filter-group-name "Decompose filter group: " t)))
 613   (let ((data (cdr (assoc group ibuffer-filter-groups))))
 614     (setq ibuffer-filter-groups (ibuffer-delete-alist
 615                                  group ibuffer-filter-groups)
 616           ibuffer-filtering-qualifiers data))
 617   (ibuffer-update nil t))
 618
 619 ;;;###autoload
 620 (defun ibuffer-clear-filter-groups ()
 621   "Remove all filter groups."
 622   (interactive)
 623   (setq ibuffer-filter-groups nil
 624         ibuffer-hidden-filter-groups nil)
 625   (ibuffer-update nil t))
 626
 627 (defun ibuffer-current-filter-groups-with-position ()
 628   (save-excursion
 629     (goto-char (point-min))
 630     (let ((pos nil)
 631           (result nil))
 632       (while (and (not (eobp))
 633                   (setq pos (next-single-property-change
 634                              (point) 'ibuffer-filter-group-name)))
 635         (goto-char pos)
 636         (push (cons (get-text-property (point) 'ibuffer-filter-group-name)
 637                     pos)
 638               result)
 639         (goto-char (next-single-property-change
 640                     pos 'ibuffer-filter-group-name)))
 641       (nreverse result))))
 642
 643 ;;;###autoload
 644 (defun ibuffer-jump-to-filter-group (name)
 645   "Move point to the filter group whose name is NAME."
 646   (interactive
 647    (list (ibuffer-read-filter-group-name "Jump to filter group: ")))
 648   (ibuffer-aif (assoc name (ibuffer-current-filter-groups-with-position))
 649       (goto-char (cdr it))
 650     (error "No filter group with name %s" name)))
 651
 652 ;;;###autoload
 653 (defun ibuffer-kill-filter-group (name)
 654   "Kill the filter group named NAME.
 655 The group will be added to `ibuffer-filter-group-kill-ring'."
 656   (interactive (list (ibuffer-read-filter-group-name "Kill filter group: " t)))
 657   (when (equal name "Default")
 658     (error "Can't kill default filter group"))
 659   (ibuffer-aif (assoc name ibuffer-filter-groups)
 660       (progn
 661         (push (copy-tree it) ibuffer-filter-group-kill-ring)
 662         (setq ibuffer-filter-groups (ibuffer-delete-alist
 663                                      name ibuffer-filter-groups))
 664         (setq ibuffer-hidden-filter-groups
 665               (delete name ibuffer-hidden-filter-groups)))
 666     (error "No filter group with name \"%s\"" name))
 667   (ibuffer-update nil t))
 668
 669 ;;;###autoload
 670 (defun ibuffer-kill-line (&optional arg interactive-p)
 671   "Kill the filter group at point.
 672 See also `ibuffer-kill-filter-group'."
 673   (interactive "P\np")
 674   (ibuffer-aif (save-excursion
 675                  (ibuffer-forward-line 0)
 676                  (get-text-property (point) 'ibuffer-filter-group-name))
 677       (progn
 678         (ibuffer-kill-filter-group it))
 679       (funcall (if interactive-p #'call-interactively #'funcall)
 680                #'kill-line arg)))
 681
 682 (defun ibuffer-insert-filter-group-before (newgroup group)
 683   (let* ((found nil)
 684          (pos (let ((groups (mapcar #'car ibuffer-filter-groups))
 685                     (res 0))
 686                 (while groups
 687                   (if (equal (car groups) group)
 688                       (setq found t
 689                             groups nil)
 690                     (incf res)
 691                     (setq groups (cdr groups))))
 692                 res)))
 693     (cond ((not found)
 694            (setq ibuffer-filter-groups
 695                  (nconc ibuffer-filter-groups (list newgroup))))
 696           ((zerop pos)
 697            (push newgroup ibuffer-filter-groups))
 698           (t
 699            (let ((cell (nthcdr pos ibuffer-filter-groups)))
 700              (setf (cdr cell) (cons (car cell) (cdr cell)))
 701              (setf (car cell) newgroup))))))
 702
 703 ;;;###autoload
 704 (defun ibuffer-yank ()
 705   "Yank the last killed filter group before group at point."
 706   (interactive)
 707   (ibuffer-yank-filter-group
 708    (or (get-text-property (point) 'ibuffer-filter-group-name)
 709        (get-text-property (point) 'ibuffer-filter-group)
 710        (error "No filter group at point"))))
 711
 712 ;;;###autoload
 713 (defun ibuffer-yank-filter-group (name)
 714   "Yank the last killed filter group before group named NAME."
 715   (interactive (list (ibuffer-read-filter-group-name
 716                         "Yank filter group before group: ")))
 717   (unless ibuffer-filter-group-kill-ring
 718     (error "The Ibuffer filter group kill-ring is empty"))
 719   (save-excursion
 720     (ibuffer-forward-line 0)
 721     (ibuffer-insert-filter-group-before (pop ibuffer-filter-group-kill-ring)
 722                                         name))
 723   (ibuffer-update nil t))
 724
 725 ;;;###autoload
 726 (defun ibuffer-save-filter-groups (name groups)
 727   "Save all active filter groups GROUPS as NAME.
 728 They are added to `ibuffer-saved-filter-groups'.  Interactively,
 729 prompt for NAME, and use the current filters."
 730   (interactive
 731    (if (null ibuffer-filter-groups)
 732        (error "No filter groups active")
 733      (list
 734       (read-from-minibuffer "Save current filter groups as: ")
 735       ibuffer-filter-groups)))
 736   (ibuffer-aif (assoc name ibuffer-saved-filter-groups)
 737       (setcdr it groups)
 738     (push (cons name groups) ibuffer-saved-filter-groups))
 739   (ibuffer-maybe-save-stuff))
 740
 741 ;;;###autoload
 742 (defun ibuffer-delete-saved-filter-groups (name)
 743   "Delete saved filter groups with NAME.
 744 They are removed from `ibuffer-saved-filter-groups'."
 745   (interactive
 746    (list
 747     (if (null ibuffer-saved-filter-groups)
 748         (error "No saved filter groups")
 749       (completing-read "Delete saved filter group: "
 750                        ibuffer-saved-filter-groups nil t))))
 751   (setq ibuffer-saved-filter-groups
 752         (ibuffer-delete-alist name ibuffer-saved-filter-groups))
 753   (ibuffer-maybe-save-stuff)
 754   (ibuffer-update nil t))
 755
 756 ;;;###autoload
 757 (defun ibuffer-switch-to-saved-filter-groups (name)
 758   "Set this buffer's filter groups to saved version with NAME.
 759 The value from `ibuffer-saved-filter-groups' is used."
 760   (interactive
 761    (list
 762     (if (null ibuffer-saved-filter-groups)
 763         (error "No saved filters")
 764       (completing-read "Switch to saved filter group: "
 765                        ibuffer-saved-filter-groups nil t))))
 766   (setq ibuffer-filter-groups (cdr (assoc name ibuffer-saved-filter-groups))
 767         ibuffer-hidden-filter-groups nil)
 768   (ibuffer-update nil t))
 769
 770 ;;;###autoload
 771 (defun ibuffer-filter-disable ()
 772   "Disable all filters currently in effect in this buffer."
 773   (interactive)
 774   (setq ibuffer-filtering-qualifiers nil)
 775   (let ((buf (ibuffer-current-buffer)))
 776     (ibuffer-update nil t)
 777     (when buf
 778       (ibuffer-jump-to-buffer (buffer-name buf)))))
 779
 780 ;;;###autoload
 781 (defun ibuffer-pop-filter ()
 782   "Remove the top filter in this buffer."
 783   (interactive)
 784   (when (null ibuffer-filtering-qualifiers)
 785     (error "No filters in effect"))
 786   (pop ibuffer-filtering-qualifiers)
 787   (let ((buf (ibuffer-current-buffer)))
 788     (ibuffer-update nil t)
 789     (when buf
 790       (ibuffer-jump-to-buffer (buffer-name buf)))))
 791
 792 (defun ibuffer-push-filter (qualifier)
 793   "Add QUALIFIER to `ibuffer-filtering-qualifiers'."
 794   (push qualifier ibuffer-filtering-qualifiers))
 795
 796 ;;;###autoload
 797 (defun ibuffer-decompose-filter ()
 798   "Separate the top compound filter (OR, NOT, or SAVED) in this buffer.
 799
 800 This means that the topmost filter on the filtering stack, which must
 801 be a complex filter like (OR [name: foo] [mode: bar-mode]), will be
 802 turned into two separate filters [name: foo] and [mode: bar-mode]."
 803   (interactive)
 804   (when (null ibuffer-filtering-qualifiers)
 805     (error "No filters in effect"))
 806   (let ((lim (pop ibuffer-filtering-qualifiers)))
 807     (case (car lim)
 808       (or
 809        (setq ibuffer-filtering-qualifiers (append
 810                                           (cdr lim)
 811                                           ibuffer-filtering-qualifiers)))
 812       (saved
 813        (let ((data
 814               (assoc (cdr lim)
 815                      ibuffer-saved-filters)))
 816          (unless data
 817            (ibuffer-filter-disable)
 818            (error "Unknown saved filter %s" (cdr lim)))
 819          (setq ibuffer-filtering-qualifiers (append
 820                                             (cadr data)
 821                                             ibuffer-filtering-qualifiers))))
 822       (not
 823        (push (cdr lim)
 824              ibuffer-filtering-qualifiers))
 825       (t
 826        (error "Filter type %s is not compound" (car lim)))))
 827   (ibuffer-update nil t))
 828
 829 ;;;###autoload
 830 (defun ibuffer-exchange-filters ()
 831   "Exchange the top two filters on the stack in this buffer."
 832   (interactive)
 833   (when (< (length ibuffer-filtering-qualifiers)
 834            2)
 835     (error "Need two filters to exchange"))
 836   (let ((first (pop ibuffer-filtering-qualifiers))
 837         (second (pop ibuffer-filtering-qualifiers)))
 838     (push first ibuffer-filtering-qualifiers)
 839     (push second ibuffer-filtering-qualifiers))
 840   (ibuffer-update nil t))
 841
 842 ;;;###autoload
 843 (defun ibuffer-negate-filter ()
 844   "Negate the sense of the top filter in the current buffer."
 845   (interactive)
 846   (when (null ibuffer-filtering-qualifiers)
 847     (error "No filters in effect"))
 848   (let ((lim (pop ibuffer-filtering-qualifiers)))
 849     (push (if (eq (car lim) 'not)
 850               (cdr lim)
 851             (cons 'not lim))
 852           ibuffer-filtering-qualifiers))
 853   (ibuffer-update nil t))
 854
 855 ;;;###autoload
 856 (defun ibuffer-or-filter (&optional reverse)
 857   "Replace the top two filters in this buffer with their logical OR.
 858 If optional argument REVERSE is non-nil, instead break the top OR
 859 filter into parts."
 860   (interactive "P")
 861   (if reverse
 862       (progn
 863         (when (or (null ibuffer-filtering-qualifiers)
 864                   (not (eq 'or (caar ibuffer-filtering-qualifiers))))
 865           (error "Top filter is not an OR"))
 866         (let ((lim (pop ibuffer-filtering-qualifiers)))
 867           (setq ibuffer-filtering-qualifiers
 868                 (nconc (cdr lim) ibuffer-filtering-qualifiers))))
 869     (when (< (length ibuffer-filtering-qualifiers) 2)
 870       (error "Need two filters to OR"))
 871     ;; If the second filter is an OR, just add to it.
 872     (let ((first (pop ibuffer-filtering-qualifiers))
 873           (second (pop ibuffer-filtering-qualifiers)))
 874       (if (eq 'or (car second))
 875           (push (nconc (list 'or first) (cdr second))
 876                 ibuffer-filtering-qualifiers)
 877         (push (list 'or first second)
 878               ibuffer-filtering-qualifiers))))
 879   (ibuffer-update nil t))
 880
 881 (defun ibuffer-maybe-save-stuff ()
 882   (when ibuffer-save-with-custom
 883     (if (fboundp 'customize-save-variable)
 884         (progn
 885           (customize-save-variable 'ibuffer-saved-filters
 886                                    ibuffer-saved-filters)
 887           (customize-save-variable 'ibuffer-saved-filter-groups
 888                                    ibuffer-saved-filter-groups))
 889       (message "Not saved permanently: Customize not available"))))
 890
 891 ;;;###autoload
 892 (defun ibuffer-save-filters (name filters)
 893   "Save FILTERS in this buffer with name NAME in `ibuffer-saved-filters'.
 894 Interactively, prompt for NAME, and use the current filters."
 895   (interactive
 896    (if (null ibuffer-filtering-qualifiers)
 897        (error "No filters currently in effect")
 898      (list
 899       (read-from-minibuffer "Save current filters as: ")
 900       ibuffer-filtering-qualifiers)))
 901   (ibuffer-aif (assoc name ibuffer-saved-filters)
 902       (setcdr it filters)
 903     (push (list name filters) ibuffer-saved-filters))
 904   (ibuffer-maybe-save-stuff))
 905
 906 ;;;###autoload
 907 (defun ibuffer-delete-saved-filters (name)
 908   "Delete saved filters with NAME from `ibuffer-saved-filters'."
 909   (interactive
 910    (list
 911     (if (null ibuffer-saved-filters)
 912         (error "No saved filters")
 913       (completing-read "Delete saved filters: "
 914                        ibuffer-saved-filters nil t))))
 915   (setq ibuffer-saved-filters
 916         (ibuffer-delete-alist name ibuffer-saved-filters))
 917   (ibuffer-maybe-save-stuff)
 918   (ibuffer-update nil t))
 919
 920 ;;;###autoload
 921 (defun ibuffer-add-saved-filters (name)
 922   "Add saved filters from `ibuffer-saved-filters' to this buffer's filters."
 923   (interactive
 924    (list
 925     (if (null ibuffer-saved-filters)
 926         (error "No saved filters")
 927       (completing-read "Add saved filters: "
 928                        ibuffer-saved-filters nil t))))
 929   (push (cons 'saved name) ibuffer-filtering-qualifiers)
 930   (ibuffer-update nil t))
 931
 932 ;;;###autoload
 933 (defun ibuffer-switch-to-saved-filters (name)
 934   "Set this buffer's filters to filters with NAME from `ibuffer-saved-filters'."
 935   (interactive
 936    (list
 937     (if (null ibuffer-saved-filters)
 938         (error "No saved filters")
 939       (completing-read "Switch to saved filters: "
 940                        ibuffer-saved-filters nil t))))
 941   (setq ibuffer-filtering-qualifiers (list (cons 'saved name)))
 942   (ibuffer-update nil t))
 943
 944 (defun ibuffer-format-filter-group-data (filter)
 945   (if (equal filter "Default")
 946       ""
 947     (concat "Filter:" (mapconcat #'ibuffer-format-qualifier
 948                                  (cdr (assq filter ibuffer-filter-groups))
 949                                  " "))))
 950
 951 (defun ibuffer-format-qualifier (qualifier)
 952   (if (eq (car-safe qualifier) 'not)
 953       (concat " [NOT" (ibuffer-format-qualifier-1 (cdr qualifier)) "]")
 954     (ibuffer-format-qualifier-1 qualifier)))
 955
 956 (defun ibuffer-format-qualifier-1 (qualifier)
 957   (case (car qualifier)
 958     (saved
 959      (concat " [filter: " (cdr qualifier) "]"))
 960     (or
 961      (concat " [OR" (mapconcat #'ibuffer-format-qualifier
 962                                (cdr qualifier) "") "]"))
 963     (t
 964      (let ((type (assq (car qualifier) ibuffer-filtering-alist)))
 965        (unless qualifier
 966          (error "Ibuffer: bad qualifier %s" qualifier))
 967        (concat " [" (cadr type) ": " (format "%s]" (cdr qualifier)))))))
 968
 969
 970 (defun ibuffer-list-buffer-modes ()
 971   "Create an alist of buffer modes currently in use.
 972 The list returned will be of the form (\"MODE-NAME\" . MODE-SYMBOL)."
 973   (let ((bufs (buffer-list))
 974         (modes)
 975         (this-mode))
 976     (while bufs
 977       (setq this-mode (buffer-local-value 'major-mode (car bufs))
 978             bufs (cdr bufs))
 979       (add-to-list
 980        'modes
 981        `(,(symbol-name this-mode) .
 982          ,this-mode)))
 983     modes))
 984
 985
 986 ;;; Extra operation definitions
 987
 988 ;;;###autoload (autoload 'ibuffer-filter-by-mode "ibuf-ext")
 989 (define-ibuffer-filter mode
 990   "Toggle current view to buffers with major mode QUALIFIER."
 991   (:description "major mode"
 992    :reader
 993    (intern
 994     (completing-read "Filter by major mode: " obarray
 995                      #'(lambda (e)
 996                          (string-match "-mode$"
 997                                        (symbol-name e)))
 998                      t
 999                      (let ((buf (ibuffer-current-buffer)))
1000                        (if (and buf (buffer-live-p buf))
1001                            (symbol-name (buffer-local-value 'major-mode buf))
1002                          "")))))
1003   (eq qualifier (buffer-local-value 'major-mode buf)))
1004
1005 ;;;###autoload (autoload 'ibuffer-filter-by-used-mode "ibuf-ext")
1006 (define-ibuffer-filter used-mode
1007   "Toggle current view to buffers with major mode QUALIFIER.
1008 Called interactively, this function allows selection of modes
1009 currently used by buffers."
1010   (:description "major mode in use"
1011                 :reader
1012                 (intern
1013                  (completing-read "Filter by major mode: "
1014                                   (ibuffer-list-buffer-modes)
1015                                   nil
1016                                   t
1017                                   (let ((buf (ibuffer-current-buffer)))
1018                                     (if (and buf (buffer-live-p buf))
1019                                         (symbol-name (buffer-local-value
1020                                                       'major-mode buf))
1021                                       "")))))
1022   (eq qualifier (buffer-local-value 'major-mode buf)))
1023
1024 ;;;###autoload (autoload 'ibuffer-filter-by-name "ibuf-ext")
1025 (define-ibuffer-filter name
1026   "Toggle current view to buffers with name matching QUALIFIER."
1027   (:description "buffer name"
1028    :reader (read-from-minibuffer "Filter by name (regexp): "))
1029   (string-match qualifier (buffer-name buf)))
1030
1031 ;;;###autoload (autoload 'ibuffer-filter-by-filename "ibuf-ext")
1032 (define-ibuffer-filter filename
1033   "Toggle current view to buffers with filename matching QUALIFIER."
1034   (:description "filename"
1035    :reader (read-from-minibuffer "Filter by filename (regexp): "))
1036   (ibuffer-awhen (buffer-local-value 'buffer-file-name buf)
1037     (string-match qualifier it)))
1038
1039 ;;;###autoload (autoload 'ibuffer-filter-by-size-gt  "ibuf-ext")
1040 (define-ibuffer-filter size-gt
1041   "Toggle current view to buffers with size greater than QUALIFIER."
1042   (:description "size greater than"
1043    :reader
1044    (string-to-number (read-from-minibuffer "Filter by size greater than: ")))
1045   (> (with-current-buffer buf (buffer-size))
1046      qualifier))
1047
1048 ;;;###autoload (autoload 'ibuffer-filter-by-size-lt  "ibuf-ext")
1049 (define-ibuffer-filter size-lt
1050    "Toggle current view to buffers with size less than QUALIFIER."
1051   (:description "size less than"
1052    :reader
1053    (string-to-number (read-from-minibuffer "Filter by size less than: ")))
1054   (< (with-current-buffer buf (buffer-size))
1055      qualifier))
1056
1057 ;;;###autoload (autoload 'ibuffer-filter-by-content "ibuf-ext")
1058 (define-ibuffer-filter content
1059    "Toggle current view to buffers whose contents match QUALIFIER."
1060   (:description "content"
1061    :reader (read-from-minibuffer "Filter by content (regexp): "))
1062   (with-current-buffer buf
1063     (save-excursion
1064       (goto-char (point-min))
1065       (re-search-forward qualifier nil t))))
1066
1067 ;;;###autoload (autoload 'ibuffer-filter-by-predicate "ibuf-ext")
1068 (define-ibuffer-filter predicate
1069    "Toggle current view to buffers for which QUALIFIER returns non-nil."
1070   (:description "predicate"
1071    :reader (read-minibuffer "Filter by predicate (form): "))
1072   (with-current-buffer buf
1073     (eval qualifier)))
1074
1075 ;;; Sorting
1076
1077 ;;;###autoload
1078 (defun ibuffer-toggle-sorting-mode ()
1079   "Toggle the current sorting mode.
1080 Default sorting modes are:
1081  Recency - the last time the buffer was viewed
1082  Name - the name of the buffer
1083  Major Mode - the name of the major mode of the buffer
1084  Size - the size of the buffer"
1085   (interactive)
1086   (let ((modes (mapcar 'car ibuffer-sorting-functions-alist)))
1087     (add-to-list 'modes 'recency)
1088     (setq modes (sort modes 'string-lessp))
1089     (let ((next (or (car-safe (cdr-safe (memq ibuffer-sorting-mode modes)))
1090                     (car modes))))
1091       (setq ibuffer-sorting-mode next)
1092       (message "Sorting by %s" next)))
1093   (ibuffer-redisplay t))
1094
1095 ;;;###autoload
1096 (defun ibuffer-invert-sorting ()
1097   "Toggle whether or not sorting is in reverse order."
1098   (interactive)
1099   (setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep))
1100   (message "Sorting order %s"
1101            (if ibuffer-sorting-reversep
1102                "reversed"
1103              "normal"))
1104   (ibuffer-redisplay t))
1105
1106 ;;;###autoload (autoload 'ibuffer-do-sort-by-major-mode "ibuf-ext")
1107 (define-ibuffer-sorter major-mode
1108   "Sort the buffers by major modes.
1109 Ordering is lexicographic."
1110   (:description "major mode")
1111   (string-lessp (downcase
1112                  (symbol-name (buffer-local-value 'major-mode (car a))))
1113                 (downcase
1114                  (symbol-name (buffer-local-value 'major-mode (car b))))))
1115
1116 ;;;###autoload (autoload 'ibuffer-do-sort-by-mode-name "ibuf-ext")
1117 (define-ibuffer-sorter mode-name
1118   "Sort the buffers by their mode name.
1119 Ordering is lexicographic."
1120   (:description "major mode name")
1121   (string-lessp (downcase
1122                  (with-current-buffer
1123                      (car a)
1124                    (format-mode-line mode-name)))
1125                 (downcase
1126                  (with-current-buffer
1127                      (car b)
1128                    (format-mode-line mode-name)))))
1129
1130 ;;;###autoload (autoload 'ibuffer-do-sort-by-alphabetic "ibuf-ext")
1131 (define-ibuffer-sorter alphabetic
1132   "Sort the buffers by their names.
1133 Ordering is lexicographic."
1134   (:description "buffer name")
1135   (string-lessp
1136    (buffer-name (car a))
1137    (buffer-name (car b))))
1138
1139 ;;;###autoload (autoload 'ibuffer-do-sort-by-size "ibuf-ext")
1140 (define-ibuffer-sorter size
1141  "Sort the buffers by their size."
1142   (:description "size")
1143   (< (with-current-buffer (car a)
1144        (buffer-size))
1145      (with-current-buffer (car b)
1146        (buffer-size))))
1147
1148 ;;;###autoload (autoload 'ibuffer-do-sort-by-filename/process "ibuf-ext")
1149 (define-ibuffer-sorter filename/process
1150  "Sort the buffers by their file name/process name."
1151   (:description "file name")
1152   (string-lessp
1153    ;; FIXME: For now just compare the file name and the process name
1154    ;; (if it exists).  Is there a better way to do this?
1155    (or (buffer-file-name (car a))
1156        (let ((pr-a (get-buffer-process (car a))))
1157          (and (processp pr-a) (process-name pr-a))))
1158    (or (buffer-file-name (car b))
1159        (let ((pr-b (get-buffer-process (car b))))
1160          (and (processp pr-b) (process-name pr-b))))))
1161
1162 ;;; Functions to emulate bs.el
1163
1164 ;;;###autoload
1165 (defun ibuffer-bs-show ()
1166   "Emulate `bs-show' from the bs.el package."
1167   (interactive)
1168   (ibuffer t "*Ibuffer-bs*" '((filename . ".*")) nil t)
1169   (define-key (current-local-map) "a" 'ibuffer-bs-toggle-all))
1170
1171 (defun ibuffer-bs-toggle-all ()
1172   "Emulate `bs-toggle-show-all' from the bs.el package."
1173   (interactive)
1174   (if ibuffer-filtering-qualifiers
1175       (ibuffer-pop-filter)
1176     (progn (ibuffer-push-filter '(filename . ".*"))
1177            (ibuffer-update nil t))))
1178
1179 ;;; Handy functions
1180
1181 ;;;###autoload
1182 (defun ibuffer-add-to-tmp-hide (regexp)
1183   "Add REGEXP to `ibuffer-tmp-hide-regexps'.
1184 This means that buffers whose name matches REGEXP will not be shown
1185 for this Ibuffer session."
1186   (interactive
1187    (list
1188     (read-from-minibuffer "Never show buffers matching: "
1189                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1190   (push regexp ibuffer-tmp-hide-regexps))
1191
1192 ;;;###autoload
1193 (defun ibuffer-add-to-tmp-show (regexp)
1194   "Add REGEXP to `ibuffer-tmp-show-regexps'.
1195 This means that buffers whose name matches REGEXP will always be shown
1196 for this Ibuffer session."
1197   (interactive
1198    (list
1199     (read-from-minibuffer "Always show buffers matching: "
1200                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1201   (push regexp ibuffer-tmp-show-regexps))
1202
1203 ;;;###autoload
1204 (defun ibuffer-forward-next-marked (&optional count mark direction)
1205   "Move forward by COUNT marked buffers (default 1).
1206
1207 If MARK is non-nil, it should be a character denoting the type of mark
1208 to move by.  The default is `ibuffer-marked-char'.
1209
1210 If DIRECTION is non-nil, it should be an integer; negative integers
1211 mean move backwards, non-negative integers mean move forwards."
1212   (interactive "P")
1213   (unless count
1214     (setq count 1))
1215   (unless mark
1216     (setq mark ibuffer-marked-char))
1217   (unless direction
1218     (setq direction 1))
1219   ;; Skip the title
1220   (ibuffer-forward-line 0)
1221   (let ((opos (point))
1222         curmark)
1223     (ibuffer-forward-line direction)
1224     (while (not (or (= (point) opos)
1225                     (eq (setq curmark (ibuffer-current-mark))
1226                         mark)))
1227       (ibuffer-forward-line direction))
1228     (when (and (= (point) opos)
1229                (not (eq (ibuffer-current-mark) mark)))
1230       (error "No buffers with mark %c" mark))))
1231
1232 ;;;###autoload
1233 (defun ibuffer-backwards-next-marked (&optional count mark)
1234    "Move backwards by COUNT marked buffers (default 1).
1235
1236 If MARK is non-nil, it should be a character denoting the type of mark
1237 to move by.  The default is `ibuffer-marked-char'."
1238    (interactive "P")
1239    (ibuffer-forward-next-marked count mark -1))
1240
1241 ;;;###autoload
1242 (defun ibuffer-do-kill-lines ()
1243   "Hide all of the currently marked lines."
1244   (interactive)
1245   (if (= (ibuffer-count-marked-lines) 0)
1246       (message "No buffers marked; use 'm' to mark a buffer")
1247     (let ((count
1248            (ibuffer-map-marked-lines
1249             #'(lambda (buf mark)
1250                 'kill))))
1251       (message "Killed %s lines" count))))
1252
1253 ;;;###autoload
1254 (defun ibuffer-jump-to-buffer (name)
1255   "Move point to the buffer whose name is NAME.
1256
1257 If called interactively, prompt for a buffer name and go to the
1258 corresponding line in the Ibuffer buffer.  If said buffer is in a
1259 hidden group filter, open it.
1260
1261 If `ibuffer-jump-offer-only-visible-buffers' is non-nil, only offer
1262 visible buffers in the completion list.  Calling the command with
1263 a prefix argument reverses the meaning of that variable."
1264   (interactive (list
1265                 (let ((only-visible ibuffer-jump-offer-only-visible-buffers))
1266                   (when current-prefix-arg
1267                     (setq only-visible (not only-visible)))
1268                   (if only-visible
1269                       (let ((table (mapcar #'(lambda (x)
1270                                                (buffer-name (car x)))
1271                                            (ibuffer-current-state-list))))
1272                         (when (null table)
1273                           (error "No buffers!"))
1274                         (completing-read "Jump to buffer: "
1275                                          table nil t))
1276                     (read-buffer "Jump to buffer: " nil t)))))
1277   (when (not (string= "" name))
1278     (let (buf-point)
1279       ;; Blindly search for our buffer: it is very likely that it is
1280       ;; not in a hidden filter group.
1281       (ibuffer-map-lines #'(lambda (buf marks)
1282                              (when (string= (buffer-name buf) name)
1283                                (setq buf-point (point))
1284                                nil))
1285                          t nil)
1286       (when (and
1287              (null buf-point)
1288              (not (null ibuffer-hidden-filter-groups)))
1289         ;; We did not find our buffer.  It must be in a hidden filter
1290         ;; group, so go through all hidden filter groups to find it.
1291         (catch 'found
1292           (dolist (group ibuffer-hidden-filter-groups)
1293             (ibuffer-jump-to-filter-group group)
1294             (ibuffer-toggle-filter-group)
1295             (ibuffer-map-lines #'(lambda (buf marks)
1296                                    (when (string= (buffer-name buf) name)
1297                                      (setq buf-point (point))
1298                                      nil))
1299                                t group)
1300             (if buf-point
1301                 (throw 'found nil)
1302               (ibuffer-toggle-filter-group)))))
1303       (if (null buf-point)
1304           ;; Still not found even though we expanded all hidden filter
1305           ;; groups: that must be because it's hidden by predicate:
1306           ;; we won't bother trying to display it.
1307           (error "No buffer with name %s" name)
1308         (goto-char buf-point)))))
1309
1310 (declare-function diff-sentinel "diff" (code))
1311
1312 (defun ibuffer-diff-buffer-with-file-1 (buffer)
1313   (let ((bufferfile (buffer-local-value 'buffer-file-name buffer))
1314         (tempfile (make-temp-file "buffer-content-")))
1315     (when bufferfile
1316       (unwind-protect
1317           (progn
1318             (with-current-buffer buffer
1319               (write-region nil nil tempfile nil 'nomessage))
1320             (let* ((old (expand-file-name bufferfile))
1321                    (new (expand-file-name tempfile))
1322                    (oldtmp (file-local-copy old))
1323                    (newtmp (file-local-copy new))
1324                    (switches diff-switches)
1325                    (command
1326                     (mapconcat
1327                      'identity
1328                      `(,diff-command
1329                        ;; Use explicitly specified switches
1330                        ,@(if (listp switches) switches (list switches))
1331                        ,@(if (or old new)
1332                              (list "-L" (shell-quote-argument old)
1333                                    "-L" (shell-quote-argument
1334                                          (format "Buffer %s" (buffer-name buffer)))))
1335                        ,(shell-quote-argument (or oldtmp old))
1336                        ,(shell-quote-argument (or newtmp new)))
1337                      " "))
1338                    proc)
1339               (let ((inhibit-read-only t))
1340                 (insert command "\n")
1341                 (diff-sentinel
1342                  (call-process shell-file-name nil
1343                                (current-buffer) nil
1344                                shell-command-switch command)))
1345               (insert "\n"))))
1346       (sit-for 0)
1347       (when (file-exists-p tempfile)
1348         (delete-file tempfile)))))
1349
1350 ;;;###autoload
1351 (defun ibuffer-diff-with-file ()
1352   "View the differences between marked buffers and their associated files.
1353 If no buffers are marked, use buffer at point.
1354 This requires the external program \"diff\" to be in your `exec-path'."
1355   (interactive)
1356   (require 'diff)
1357   (let ((marked-bufs (ibuffer-get-marked-buffers)))
1358     (when (null marked-bufs)
1359       (setq marked-bufs (list (ibuffer-current-buffer t))))
1360     (with-current-buffer (get-buffer-create "*Ibuffer Diff*")
1361       (setq buffer-read-only nil)
1362       (buffer-disable-undo (current-buffer))
1363       (erase-buffer)
1364       (buffer-enable-undo (current-buffer))
1365       (diff-mode)
1366       (dolist (buf marked-bufs)
1367         (unless (buffer-live-p buf)
1368           (error "Buffer %s has been killed" buf))
1369         (ibuffer-diff-buffer-with-file-1 buf))
1370       (setq buffer-read-only t)))
1371   (switch-to-buffer "*Ibuffer Diff*"))
1372
1373 ;;;###autoload
1374 (defun ibuffer-copy-filename-as-kill (&optional arg)
1375   "Copy filenames of marked buffers into the kill ring.
1376
1377 The names are separated by a space.
1378 If a buffer has no filename, it is ignored.
1379
1380 With no prefix arg, use the filename sans its directory of each marked file.
1381 With a zero prefix arg, use the complete filename of each marked file.
1382 With \\[universal-argument], use the filename of each marked file relative
1383 to `ibuffer-default-directory' if non-nil, otherwise `default-directory'.
1384
1385 You can then feed the file name(s) to other commands with \\[yank]."
1386   (interactive "p")
1387   (if (zerop (ibuffer-count-marked-lines))
1388       (message "No buffers marked; use 'm' to mark a buffer")
1389     (let ((ibuffer-copy-filename-as-kill-result "")
1390           (type (cond ((zerop arg)
1391                        'full)
1392                       ((= arg 4)
1393                        'relative)
1394                       (t
1395                        'name))))
1396       (ibuffer-map-marked-lines
1397        #'(lambda (buf mark)
1398            (setq ibuffer-copy-filename-as-kill-result
1399                  (concat ibuffer-copy-filename-as-kill-result
1400                          (let ((name (buffer-file-name buf)))
1401                            (if name
1402                                (case type
1403                                  (full
1404                                   name)
1405                                  (relative
1406                                   (file-relative-name
1407                                    name (or ibuffer-default-directory
1408                                             default-directory)))
1409                                  (t
1410                                   (file-name-nondirectory name)))
1411                              ""))
1412                          " "))))
1413       (kill-new ibuffer-copy-filename-as-kill-result))))
1414
1415 (defun ibuffer-mark-on-buffer (func &optional ibuffer-mark-on-buffer-mark group)
1416   (let ((count
1417          (ibuffer-map-lines
1418           #'(lambda (buf mark)
1419               (when (funcall func buf)
1420                 (ibuffer-set-mark-1 (or ibuffer-mark-on-buffer-mark
1421                                         ibuffer-marked-char))
1422                 t))
1423           nil
1424           group)))
1425     (ibuffer-redisplay t)
1426     (unless (eq ibuffer-mark-on-buffer-mark ?\s)
1427       (message "Marked %s buffers" count))))
1428
1429 ;;;###autoload
1430 (defun ibuffer-mark-by-name-regexp (regexp)
1431   "Mark all buffers whose name matches REGEXP."
1432   (interactive "sMark by name (regexp): ")
1433   (ibuffer-mark-on-buffer
1434    #'(lambda (buf)
1435        (string-match regexp (buffer-name buf)))))
1436
1437 ;;;###autoload
1438 (defun ibuffer-mark-by-mode-regexp (regexp)
1439   "Mark all buffers whose major mode matches REGEXP."
1440   (interactive "sMark by major mode (regexp): ")
1441   (ibuffer-mark-on-buffer
1442    #'(lambda (buf)
1443        (with-current-buffer buf
1444          (string-match regexp (format-mode-line mode-name nil nil buf))))))
1445
1446 ;;;###autoload
1447 (defun ibuffer-mark-by-file-name-regexp (regexp)
1448   "Mark all buffers whose file name matches REGEXP."
1449   (interactive "sMark by file name (regexp): ")
1450   (ibuffer-mark-on-buffer
1451    #'(lambda (buf)
1452        (let ((name (or (buffer-file-name buf)
1453                        (with-current-buffer buf
1454                          (and
1455                           (boundp 'dired-directory)
1456                           (stringp dired-directory)
1457                           dired-directory)))))
1458          (when name
1459            (string-match regexp name))))))
1460
1461 ;;;###autoload
1462 (defun ibuffer-mark-by-mode (mode)
1463   "Mark all buffers whose major mode equals MODE."
1464   (interactive
1465    (list (intern (completing-read "Mark by major mode: " obarray
1466                                   #'(lambda (e)
1467                                       ;; kind of a hack...
1468                                       (and (fboundp e)
1469                                            (string-match "-mode$"
1470                                                          (symbol-name e))))
1471                                   t
1472                                   (let ((buf (ibuffer-current-buffer)))
1473                                     (if (and buf (buffer-live-p buf))
1474                                         (with-current-buffer buf
1475                                           (cons (symbol-name major-mode)
1476                                                 0))
1477                                       ""))))))
1478   (ibuffer-mark-on-buffer
1479    #'(lambda (buf)
1480        (eq (buffer-local-value 'major-mode buf) mode))))
1481
1482 ;;;###autoload
1483 (defun ibuffer-mark-modified-buffers ()
1484   "Mark all modified buffers."
1485   (interactive)
1486   (ibuffer-mark-on-buffer
1487    #'(lambda (buf) (buffer-modified-p buf))))
1488
1489 ;;;###autoload
1490 (defun ibuffer-mark-unsaved-buffers ()
1491   "Mark all modified buffers that have an associated file."
1492   (interactive)
1493   (ibuffer-mark-on-buffer
1494    #'(lambda (buf) (and (buffer-local-value 'buffer-file-name buf)
1495                         (buffer-modified-p buf)))))
1496
1497 ;;;###autoload
1498 (defun ibuffer-mark-dissociated-buffers ()
1499   "Mark all buffers whose associated file does not exist."
1500   (interactive)
1501   (ibuffer-mark-on-buffer
1502    #'(lambda (buf)
1503        (with-current-buffer buf
1504          (or
1505           (and buffer-file-name
1506                (not (file-exists-p buffer-file-name)))
1507           (and (eq major-mode 'dired-mode)
1508                (boundp 'dired-directory)
1509                (stringp dired-directory)
1510                (not (file-exists-p (file-name-directory dired-directory)))))))))
1511
1512 ;;;###autoload
1513 (defun ibuffer-mark-help-buffers ()
1514   "Mark buffers like *Help*, *Apropos*, *Info*."
1515   (interactive)
1516   (ibuffer-mark-on-buffer
1517    #'(lambda (buf)
1518        (with-current-buffer buf
1519          (memq major-mode ibuffer-help-buffer-modes)))))
1520
1521 ;;;###autoload
1522 (defun ibuffer-mark-compressed-file-buffers ()
1523   "Mark buffers whose associated file is compressed."
1524   (interactive)
1525   (ibuffer-mark-on-buffer
1526    #'(lambda (buf)
1527        (with-current-buffer buf
1528          (and buffer-file-name
1529               (string-match ibuffer-compressed-file-name-regexp
1530                            buffer-file-name))))))
1531
1532 ;;;###autoload
1533 (defun ibuffer-mark-old-buffers ()
1534   "Mark buffers which have not been viewed in `ibuffer-old-time' hours."
1535   (interactive)
1536   (ibuffer-mark-on-buffer
1537    #'(lambda (buf)
1538        (with-current-buffer buf
1539          ;; hacked from midnight.el
1540          (when buffer-display-time
1541            (let* ((tm (current-time))
1542                   (now (+ (* (float (ash 1 16)) (car tm))
1543                           (float (cadr tm)) (* 0.0000001 (caddr tm))))
1544                   (then (+ (* (float (ash 1 16))
1545                               (car buffer-display-time))
1546                            (float (cadr buffer-display-time))
1547                            (* 0.0000001 (caddr buffer-display-time)))))
1548              (> (- now then) (* 60 60 ibuffer-old-time))))))))
1549
1550 ;;;###autoload
1551 (defun ibuffer-mark-special-buffers ()
1552   "Mark all buffers whose name begins and ends with '*'."
1553   (interactive)
1554   (ibuffer-mark-on-buffer
1555    #'(lambda (buf) (string-match "^\\*.+\\*$"
1556                                  (buffer-name buf)))))
1557
1558 ;;;###autoload
1559 (defun ibuffer-mark-read-only-buffers ()
1560   "Mark all read-only buffers."
1561   (interactive)
1562   (ibuffer-mark-on-buffer
1563    #'(lambda (buf) (buffer-local-value 'buffer-read-only buf))))
1564
1565 ;;;###autoload
1566 (defun ibuffer-mark-dired-buffers ()
1567   "Mark all `dired' buffers."
1568   (interactive)
1569   (ibuffer-mark-on-buffer
1570    #'(lambda (buf) (eq (buffer-local-value 'major-mode buf) 'dired-mode))))
1571
1572 ;;;###autoload
1573 (defun ibuffer-do-occur (regexp &optional nlines)
1574   "View lines which match REGEXP in all marked buffers.
1575 Optional argument NLINES says how many lines of context to display: it
1576 defaults to one."
1577   (interactive (occur-read-primary-args))
1578   (if (or (not (integerp nlines))
1579           (< nlines 0))
1580       (setq nlines 0))
1581   (when (zerop (ibuffer-count-marked-lines))
1582     (ibuffer-set-mark ibuffer-marked-char))
1583   (let ((ibuffer-do-occur-bufs nil))
1584     ;; Accumulate a list of marked buffers
1585     (ibuffer-map-marked-lines
1586      #'(lambda (buf mark)
1587          (push buf ibuffer-do-occur-bufs)))
1588     (occur-1 regexp nlines ibuffer-do-occur-bufs)))
1589
1590 (provide 'ibuf-ext)
1591
1592 ;; Local Variables:
1593 ;; generated-autoload-file: "ibuffer.el"
1594 ;; End:
1595
1596 ;; arch-tag: 9af21953-deda-4c30-b76d-f81d9128e76d
1597 ;;; ibuf-ext.el ends here