lisp/find-cmd.el

   1 ;;; find-cmd.el --- Build a valid find(1) command with sexps
   2
   3 ;; Copyright (C) 2008, 2009, 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Philip Jackson <phil@shellarchive.co.uk>
   6 ;; Version: 0.6
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; With this module you can build up a (hopefully) valid find(1)
  26 ;; string ready for the command line.  For example:
  27
  28 ;; (find-cmd '(prune (name ".svn" ".git" ".CVS"))
  29 ;;           '(and (or (name "*.pl" "*.pm" "*.t")
  30 ;;                     (mtime "+1"))
  31 ;;                 (fstype "nfs" "ufs"))))
  32
  33 ;; will become (un-wrapped):
  34
  35 ;;     "find '/home/phil/' \\( \\( -name '.svn' -or -name '.git' -or
  36 ;;      -name '.CVS' \\) -prune -or -true \\) \\( \\( \\( -name '*.pl'
  37 ;;      -or -name '*.pm' -or -name '*.t' \\) -or -mtime '+1' \\) -and \\(
  38 ;;      -fstype 'nfs' -or -fstype 'ufs' \\) \\)"
  39
  40 ;;; Code:
  41
  42 (defconst find-constituents
  43   '((and . find-and)
  44     (not . find-not)
  45     (or  . find-or)
  46
  47     (a . find-and)
  48     (n . find-not)
  49     (o . find-or)
  50
  51     (prune . find-prune)
  52
  53     ;; switches
  54     (L . (0))
  55     (P . (0))
  56     (H . (0))
  57
  58     ;; generic tests
  59     (amin       . (1))
  60     (anewer     . (1))
  61     (atime      . (1))
  62     (cmin       . (1))
  63     (cnewer     . (1))
  64     (ctime      . (1))
  65     (empty      . (0))
  66     (false      . (0))
  67     (fstype     . (1))
  68     (gid        . (1))
  69     (group      . (1))
  70     (ilname     . (1))
  71     (iname      . (1))
  72     (inum       . (1))
  73     (iwholename . (1))
  74     (iregex     . (1))
  75     (links      . (1))
  76     (lname      . (1))
  77     (mmin       . (1))
  78     (mtime      . (1))
  79     (name       . (1))
  80     (newer      . (1))
  81     (nouser     . (0))
  82     (nogroup    . (0))
  83     (path       . (1))
  84     (perm       . (0))
  85     (regex      . (1))
  86     (wholename  . (1))
  87     (size       . (1))
  88     (true       . (0))
  89     (type       . (1))
  90     (uid        . (1))
  91     (used       . (1))
  92     (user       . (1))
  93     (xtype      . (nil))
  94
  95     ;; normal options (always true)
  96     (depth                 . (0))
  97     (maxdepth              . (1))
  98     (mindepth              . (1))
  99     (mount                 . (0))
 100     (noleaf                . (0))
 101     (xdev                  . (0))
 102     (ignore_readdir_race   . (0))
 103     (noignore_readdir_race . (0))
 104
 105     ;; actions
 106     (delete  . (0))
 107     (print0  . (0))
 108     (printf  . (1))
 109     (fprintf . (2))
 110     (print   . (0))
 111     (fprint0 . (1))
 112     (fprint  . (1))
 113     (ls      . (0))
 114     (fls     . (1))
 115     (prune   . (0))
 116     (quit    . (0))
 117
 118     ;; these need to be terminated with a ;
 119     (exec    . (1 find-command t))
 120     (ok      . (1 find-command t))
 121     (execdir . (1 find-command t))
 122     (okdir   . (1 find-command t)))
 123   "Holds details of each of the find options.
 124 The car of each alist is the name.  The cdr is minimum args, the
 125 function used to join many occurrences of the argument together,
 126 and whether or not to leave quotes off the string (non-nil means
 127 the string will be quoted).")
 128
 129 ;;;###autoload
 130 (defun find-cmd (&rest subfinds)
 131   "Initiate the building of a find command.
 132 For example:
 133
 134 \(find-cmd '\(prune \(name \".svn\" \".git\" \".CVS\"\)\)
 135           '\(and \(or \(name \"*.pl\" \"*.pm\" \"*.t\"\)
 136                     \(mtime \"+1\"\)\)
 137                 \(fstype \"nfs\" \"ufs\"\)\)\)\)
 138
 139 `default-directory' is used as the initial search path.  The
 140 result is a string that should be ready for the command line."
 141   (concat
 142    "find " (shell-quote-argument (expand-file-name default-directory)) " "
 143            (cond
 144             ((cdr subfinds)
 145              (mapconcat 'find-to-string subfinds ""))
 146             (t
 147              (find-to-string (car subfinds))))))
 148
 149 (defun find-and (form)
 150   "And FORMs together, so:
 151   \(and \(mtime \"+1\"\) \(name \"something\"\)\)
 152 will produce:
 153   find . \\\( -mtime '+1' -and -name 'something' \\\)"
 154   (if (< (length form) 2)
 155       (find-to-string (car form))
 156       (concat "\\( "
 157               (mapconcat 'find-to-string form "-and ")
 158               "\\) ")))
 159
 160 (defun find-or (form)
 161   "Or FORMs together, so:
 162   \(or \(mtime \"+1\"\) \(name \"something\"\)\)
 163 will produce:
 164   find . \\\( -mtime '+1' -or -name 'something' \\\)"
 165   (if (< (length form) 2)
 166       (find-to-string (car form))
 167       (concat "\\( "
 168               (mapconcat 'find-to-string form "-or ")
 169               "\\) ")))
 170
 171 (defun find-not (form)
 172   "Or FORMs together and prefix with a -not, so:
 173   \(not \(mtime \"+1\"\) \(name \"something\"\)\)
 174 will produce:
 175   -not \\\( -mtime '+1' -or -name 'something' \\\)
 176 If you wanted the FORMs -and(ed) together instead then this would
 177 suffice:
 178   \(not \(and \(mtime \"+1\"\) \(name \"something\"\)\)\)"
 179   (concat "-not " (find-or (mapcar 'find-to-string form))))
 180
 181 (defun find-prune (form)
 182   "-or together FORMs postfix '-prune' and then -or that with a
 183 -true, so:
 184   \(prune \(name \".svn\" \".git\"\)\) \(name \"*.pm\"\)
 185 will produce (unwrapped):
 186   \\\( \\\( \\\( -name '.svn' -or -name '.git' \\\) /
 187   -prune -or -true \\\) -and -name '*.pm' \\\)"
 188   (find-or
 189    (list
 190     (concat (find-or (mapcar 'find-to-string form)) (find-generic "prune"))
 191     (find-generic "true"))))
 192
 193 (defun find-generic (option &optional oper argcount args dont-quote)
 194   "Allow an arbitrary string to be used as a form.
 195 OPTION is the name of the form, OPER is the function used to either
 196 OR or AND multiple results together.  ARGCOUNT is the minimum of
 197 args that OPTION can receive and ARGS are the arguments for OPTION.
 198 If DONT-QUOTE is non-nil, arguments are quoted for passing them to
 199 the shell."
 200   (when (and (numberp argcount) (< (length args) argcount))
 201     (error "'%s' needs at least %d arguments" option argcount))
 202   (let ((oper (or oper 'find-or)))
 203     (if (and args (length args))
 204         (funcall oper (mapcar (lambda (x)
 205                                 (concat "-" option
 206                                         (if dont-quote
 207                                             (concat " " x " ")
 208                                             (concat " "
 209                                                     (shell-quote-argument x)
 210                                                     " "))))
 211                               args))
 212         (concat "-" option " "))))
 213
 214 (defun find-command (form)
 215   "For each item in FORM add a terminating semi-colon and turn
 216 them into valid switches.  The result is -and(ed) together."
 217   (find-and (mapcar (lambda (x)
 218                       (concat (find-to-string x) "\\; "))
 219                     form)))
 220
 221 (defun find-to-string (form)
 222   "Parse FORM to produce a set of valid find arguments."
 223   (cond
 224     ((stringp form)
 225      form)
 226     ((consp form)
 227      (let ((option (cdr (assoc (car form) find-constituents))))
 228        (cond
 229          ((and (symbolp option) (fboundp option))
 230           (funcall option (cdr form)))
 231          ((consp option)
 232           (let ((option (symbol-name (car form)))
 233                 (argcnt (car option))
 234                 (oper (cadr option))
 235                 (dont-quote (car (cddr option))))
 236             (find-to-string
 237              (find-generic option oper argcnt (cdr form) dont-quote))))
 238          (t
 239           (error "Sorry I don't know how to handle '%s'" (car form))))))))
 240
 241 (provide 'find-cmd)
 242
 243 ;; arch-tag: 9687fd9e-4e90-4022-864a-f904526e2046
 244 ;;; find-cmd.el ends here