lisp/disp-table.el

   1 ;;; disp-table.el --- functions for dealing with char tables
   2
   3 ;; Copyright (C) 1987, 1994, 1995, 1999, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Erik Naggum <erik@naggum.no>
   7 ;; Based on a previous version by Howard Gayle
   8 ;; Maintainer: FSF
   9 ;; Keywords: i18n
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (put 'display-table 'char-table-extra-slots 6)
  31
  32 ;;;###autoload
  33 (defun make-display-table ()
  34   "Return a new, empty display table."
  35   (make-char-table 'display-table nil))
  36
  37 (or standard-display-table
  38     (setq standard-display-table (make-display-table)))
  39
  40 ;;; Display-table slot names.  The property value says which slot.
  41
  42 (put 'truncation 'display-table-slot 0)
  43 (put 'wrap 'display-table-slot 1)
  44 (put 'escape 'display-table-slot 2)
  45 (put 'control 'display-table-slot 3)
  46 (put 'selective-display 'display-table-slot 4)
  47 (put 'vertical-border 'display-table-slot 5)
  48
  49 ;;;###autoload
  50 (defun display-table-slot (display-table slot)
  51   "Return the value of the extra slot in DISPLAY-TABLE named SLOT.
  52 SLOT may be a number from 0 to 5 inclusive, or a slot name (symbol).
  53 Valid symbols are `truncation', `wrap', `escape', `control',
  54 `selective-display', and `vertical-border'."
  55   (let ((slot-number
  56          (if (numberp slot) slot
  57            (or (get slot 'display-table-slot)
  58                (error "Invalid display-table slot name: %s" slot)))))
  59     (char-table-extra-slot display-table slot-number)))
  60
  61 ;;;###autoload
  62 (defun set-display-table-slot (display-table slot value)
  63   "Set the value of the extra slot in DISPLAY-TABLE named SLOT to VALUE.
  64 SLOT may be a number from 0 to 5 inclusive, or a name (symbol).
  65 Valid symbols are `truncation', `wrap', `escape', `control',
  66 `selective-display', and `vertical-border'."
  67   (let ((slot-number
  68          (if (numberp slot) slot
  69            (or (get slot 'display-table-slot)
  70                (error "Invalid display-table slot name: %s" slot)))))
  71     (set-char-table-extra-slot display-table slot-number value)))
  72
  73 ;;;###autoload
  74 (defun describe-display-table (dt)
  75   "Describe the display table DT in a help buffer."
  76   (with-help-window "*Help*"
  77     (princ "\nTruncation glyph: ")
  78     (prin1 (display-table-slot dt 'truncation))
  79     (princ "\nWrap glyph: ")
  80     (prin1 (display-table-slot dt 'wrap))
  81     (princ "\nEscape glyph: ")
  82     (prin1 (display-table-slot dt 'escape))
  83     (princ "\nCtrl glyph: ")
  84     (prin1 (display-table-slot dt 'control))
  85     (princ "\nSelective display glyph sequence: ")
  86     (prin1 (display-table-slot dt 'selective-display))
  87     (princ "\nVertical window border glyph: ")
  88     (prin1 (display-table-slot dt 'vertical-border))
  89     (princ "\nCharacter display glyph sequences:\n")
  90     (with-current-buffer standard-output
  91       (let ((vector (make-vector 256 nil))
  92             (i 0))
  93         (while (< i 256)
  94           (aset vector i (aref dt i))
  95           (setq i (1+ i)))
  96         (describe-vector vector))
  97       (help-mode))))
  98
  99 ;;;###autoload
 100 (defun describe-current-display-table ()
 101   "Describe the display table in use in the selected window and buffer."
 102   (interactive)
 103   (let ((disptab (or (window-display-table (selected-window))
 104                      buffer-display-table
 105                      standard-display-table)))
 106     (if disptab
 107         (describe-display-table disptab)
 108       (message "No display table"))))
 109
 110 ;;;###autoload
 111 (defun standard-display-8bit (l h)
 112   "Display characters in the range L to H literally."
 113   (or standard-display-table
 114       (setq standard-display-table (make-display-table)))
 115   (while (<= l h)
 116     (aset standard-display-table l (if (or (< l ?\s) (>= l 127)) (vector l)))
 117     (setq l (1+ l))))
 118
 119 ;;;###autoload
 120 (defun standard-display-default (l h)
 121   "Display characters in the range L to H using the default notation."
 122   (or standard-display-table
 123       (setq standard-display-table (make-display-table)))
 124   (while (<= l h)
 125     (if (and (>= l ?\s) (characterp l))
 126         (aset standard-display-table l nil))
 127     (setq l (1+ l))))
 128
 129 ;; This function does NOT take terminal-dependent escape sequences.
 130 ;; For that, you need to go through create-glyph.  Use one of the
 131 ;; other functions below, or roll your own.
 132 ;;;###autoload
 133 (defun standard-display-ascii (c s)
 134   "Display character C using printable string S."
 135   (or standard-display-table
 136       (setq standard-display-table (make-display-table)))
 137   (aset standard-display-table c (vconcat s)))
 138
 139 ;;;###autoload
 140 (defun standard-display-g1 (c sc)
 141   "Display character C as character SC in the g1 character set.
 142 This function assumes that your terminal uses the SO/SI characters;
 143 it is meaningless for an X frame."
 144   (if (memq window-system '(x w32 ns))
 145       (error "Cannot use string glyphs in a windowing system"))
 146   (or standard-display-table
 147       (setq standard-display-table (make-display-table)))
 148   (aset standard-display-table c
 149         (vector (create-glyph (concat "\016" (char-to-string sc) "\017")))))
 150
 151 ;;;###autoload
 152 (defun standard-display-graphic (c gc)
 153   "Display character C as character GC in graphics character set.
 154 This function assumes VT100-compatible escapes; it is meaningless for an
 155 X frame."
 156   (if (memq window-system '(x w32 ns))
 157       (error "Cannot use string glyphs in a windowing system"))
 158   (or standard-display-table
 159       (setq standard-display-table (make-display-table)))
 160   (aset standard-display-table c
 161         (vector (create-glyph (concat "\e(0" (char-to-string gc) "\e(B")))))
 162
 163 ;;;###autoload
 164 (defun standard-display-underline (c uc)
 165   "Display character C as character UC plus underlining."
 166   (or standard-display-table
 167       (setq standard-display-table (make-display-table)))
 168   (aset standard-display-table c
 169         (vector
 170          (if window-system
 171              (make-glyph-code uc 'underline)
 172            (create-glyph (concat "\e[4m" (char-to-string uc) "\e[m"))))))
 173
 174 ;;;###autoload
 175 (defun create-glyph (string)
 176   "Allocate a glyph code to display by sending STRING to the terminal."
 177   (if (= (length glyph-table) 65536)
 178       (error "No free glyph codes remain"))
 179   ;; Don't use slots that correspond to ASCII characters.
 180   (if (= (length glyph-table) 32)
 181       (setq glyph-table (vconcat glyph-table (make-vector 224 nil))))
 182   (setq glyph-table (vconcat glyph-table (list string)))
 183   (1- (length glyph-table)))
 184
 185 ;;;###autoload
 186 (defun make-glyph-code (char &optional face)
 187   "Return a glyph code representing char CHAR with face FACE."
 188   ;; Due to limitations on Emacs integer values, faces with
 189   ;; face id greater that 512 are silently ignored.
 190   (if (not face)
 191       char
 192     (let ((fid (face-id face)))
 193       (if (< fid 64) ; we have 32 - 3(LSB) - 1(SIGN) - 22(CHAR) = 6 bits for face id
 194           (logior char (lsh fid 22))
 195         (cons char fid)))))
 196
 197 ;;;###autoload
 198 (defun glyph-char (glyph)
 199   "Return the character of glyph code GLYPH."
 200   (if (consp glyph)
 201       (car glyph)
 202     (logand glyph #x3fffff)))
 203
 204 ;;;###autoload
 205 (defun glyph-face (glyph)
 206   "Return the face of glyph code GLYPH, or nil if glyph has default face."
 207   (let ((face-id (if (consp glyph) (cdr glyph) (lsh glyph -22))))
 208     (and (> face-id 0)
 209          (catch 'face
 210            (dolist (face (face-list))
 211              (when (eq (face-id face) face-id)
 212                (throw 'face face)))))))
 213
 214 ;;;###autoload
 215 (defun standard-display-european (arg)
 216   "Semi-obsolete way to toggle display of ISO 8859 European characters.
 217
 218 This function is semi-obsolete; you probably don't need it, or else you
 219 probably should use `set-language-environment' or `set-locale-environment'.
 220
 221 This function enables European character display if ARG is positive,
 222 disables it if negative.  Otherwise, it toggles European character display.
 223
 224 When this mode is enabled, characters in the range of 160 to 255
 225 display not as octal escapes, but as accented characters.  Codes 146
 226 and 160 display as apostrophe and space, even though they are not the
 227 ASCII codes for apostrophe and space.
 228
 229 Enabling European character display with this command noninteractively
 230 from Lisp code also selects Latin-1 as the language environment.
 231 This provides increased compatibility for users who call this function
 232 in `.emacs'."
 233
 234   (if (or (<= (prefix-numeric-value arg) 0)
 235           (and (null arg)
 236                (char-table-p standard-display-table)
 237                ;; Test 161, because 160 displays as a space.
 238                (equal (aref standard-display-table 161) [161])))
 239       (progn
 240         (standard-display-default 160 255)
 241         (unless (or (memq window-system '(x w32 ns)))
 242           (and (terminal-coding-system)
 243                (set-terminal-coding-system nil))))
 244
 245     (display-warning 'i18n
 246                      "`standard-display-european' is semi-obsolete; see its doc string for details"
 247                      :warning)
 248
 249     ;; Switch to Latin-1 language environment
 250     ;; unless some other has been specified.
 251     (if (equal current-language-environment "English")
 252         (set-language-environment "latin-1"))
 253     (unless (or noninteractive (memq window-system '(x w32 ns)))
 254       ;; Send those codes literally to a character-based terminal.
 255       ;; If we are using single-byte characters,
 256       ;; it doesn't matter which coding system we use.
 257       (set-terminal-coding-system
 258        (let ((c (intern (downcase current-language-environment))))
 259          (if (coding-system-p c) c 'latin-1))))
 260     (standard-display-european-internal)))
 261
 262 (provide 'disp-table)
 263
 264 ;; arch-tag: ffe4c28c-960c-47aa-b8a8-ae89d371ffc7
 265 ;;; disp-table.el ends here