lisp/password-cache.el

   1 ;;; password-cache.el --- Read passwords, possibly using a password cache.
   2
   3 ;; Copyright (C) 1999, 2000, 2003, 2004, 2005, 2006, 2007, 2008
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Simon Josefsson <simon@josefsson.org>
   7 ;; Created: 2003-12-21
   8 ;; Keywords: password cache passphrase key
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Greatly influenced by pgg.el written by Daiki Ueno, with timer
  28 ;; fixes for XEmacs by Katsumi Yamaoka.  In fact, this is mostly just
  29 ;; a rip-off.
  30 ;;
  31 ;; (password-read "Password? " "test")
  32 ;; ;; Minibuffer prompt for password.
  33 ;;  => "foo"
  34 ;;
  35 ;; (password-cache-add "test" "foo")
  36 ;;  => nil
  37
  38 ;; (password-read "Password? " "test")
  39 ;; ;; No minibuffer prompt
  40 ;;  => "foo"
  41 ;;
  42 ;; (password-read "Password? " "test")
  43 ;; ;; No minibuffer prompt
  44 ;;  => "foo"
  45 ;;
  46 ;; ;; Wait `password-cache-expiry' seconds.
  47 ;;
  48 ;; (password-read "Password? " "test")
  49 ;; ;; Minibuffer prompt for password is back.
  50 ;;  => "foo"
  51
  52 ;;; Code:
  53
  54 (defcustom password-cache t
  55   "Whether to cache passwords."
  56   :group 'password
  57   :type 'boolean)
  58
  59 (defcustom password-cache-expiry 16
  60   "How many seconds passwords are cached, or nil to disable expiring.
  61 Whether passwords are cached at all is controlled by `password-cache'."
  62   :group 'password
  63   :type '(choice (const :tag "Never" nil)
  64                  (integer :tag "Seconds")))
  65
  66 (defvar password-data (make-vector 7 0))
  67
  68 (defun password-read-from-cache (key)
  69   "Obtain passphrase for KEY from time-limited passphrase cache.
  70 Custom variables `password-cache' and `password-cache-expiry'
  71 regulate cache behavior."
  72   (and password-cache
  73        key
  74        (symbol-value (intern-soft key password-data))))
  75
  76 (defun password-read (prompt &optional key)
  77   "Read password, for use with KEY, from user, or from cache if wanted.
  78 KEY indicate the purpose of the password, so the cache can
  79 separate passwords.  The cache is not used if KEY is nil.  It is
  80 typically a string.
  81 The variable `password-cache' control whether the cache is used."
  82   (or (password-read-from-cache key)
  83       (read-passwd prompt)))
  84
  85 (defun password-read-and-add (prompt &optional key)
  86   "Read password, for use with KEY, from user, or from cache if wanted.
  87 Then store the password in the cache.  Uses `password-read' and
  88 `password-cache-add'.  Custom variables `password-cache' and
  89 `password-cache-expiry' regulate cache behavior.
  90
  91 Warning: the password is cached without checking that it is
  92 correct.  It is better to check the password before caching.  If
  93 you must use this function, take care to check passwords and
  94 remove incorrect ones from the cache."
  95   (let ((password (password-read prompt key)))
  96     (when (and password key)
  97       (password-cache-add key password))
  98     password))
  99
 100 (make-obsolete 'password-read-and-add 'password-read "23.1")
 101
 102 (defun password-cache-remove (key)
 103   "Remove password indexed by KEY from password cache.
 104 This is typically run be a timer setup from `password-cache-add',
 105 but can be invoked at any time to forcefully remove passwords
 106 from the cache.  This may be useful when it has been detected
 107 that a password is invalid, so that `password-read' query the
 108 user again."
 109   (let ((password (symbol-value (intern-soft key password-data))))
 110     (when password
 111       (if (fboundp 'clear-string)
 112           (clear-string password)
 113         (fillarray password ?_))
 114       (unintern key password-data))))
 115
 116 (defun password-cache-add (key password)
 117   "Add password to cache.
 118 The password is removed by a timer after `password-cache-expiry' seconds."
 119   (when (and password-cache-expiry (null (intern-soft key password-data)))
 120     (run-at-time password-cache-expiry nil
 121                  #'password-cache-remove
 122                  key))
 123   (set (intern key password-data) password)
 124   nil)
 125
 126 (defun password-reset ()
 127   "Clear the password cache."
 128   (interactive)
 129   (fillarray password-data 0))
 130
 131 (provide 'password-cache)
 132
 133 ;; arch-tag: ab160494-16c8-4c68-a4a1-73eebf6686e5
 134 ;;; password-cache.el ends here