lisp/log-view.el

   1 ;;; log-view.el --- Major mode for browsing RCS/CVS/SCCS log output
   2
   3 ;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
   7 ;; Keywords: rcs sccs cvs log version-control
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Major mode to browse revision log histories.
  27 ;; Currently supports the format output by:
  28 ;;  RCS, SCCS, CVS, Subversion, and DaRCS.
  29
  30 ;; Examples of log output:
  31
  32 ;;;; RCS/CVS:
  33
  34 ;; ----------------------------
  35 ;; revision 1.35        locked by: turlutut
  36 ;; date: 2005-03-22 18:48:38 +0000;  author: monnier;  state: Exp;  lines: +6 -8
  37 ;; (gnus-display-time-event-handler):
  38 ;; Check display-time-timer at runtime rather than only at load time
  39 ;; in case display-time-mode is turned off in the mean time.
  40 ;; ----------------------------
  41 ;; revision 1.34
  42 ;; date: 2005-02-09 15:50:38 +0000;  author: kfstorm;  state: Exp;  lines: +7 -7
  43 ;; branches:  1.34.2;
  44 ;; Change release version from 21.4 to 22.1 throughout.
  45 ;; Change development version from 21.3.50 to 22.0.50.
  46
  47 ;;;; SCCS:
  48
  49 ;;;; Subversion:
  50
  51 ;; ------------------------------------------------------------------------
  52 ;; r4622 | ckuethe | 2007-12-23 18:18:01 -0500 (Sun, 23 Dec 2007) | 2 lines
  53 ;;
  54 ;; uBlox AEK-4T in binary mode. Added to unstable because it breaks gpsfake
  55 ;;
  56 ;; ------------------------------------------------------------------------
  57 ;; r4621 | ckuethe | 2007-12-23 16:48:11 -0500 (Sun, 23 Dec 2007) | 3 lines
  58 ;;
  59 ;; Add a note about requiring usbfs to use the garmin gps18 (usb)
  60 ;; Mention firmware testing the AC12 with firmware BQ00 and BQ04
  61 ;;
  62 ;; ------------------------------------------------------------------------
  63 ;; r4620 | ckuethe | 2007-12-23 15:52:34 -0500 (Sun, 23 Dec 2007) | 1 line
  64 ;;
  65 ;; add link to latest hardware reference
  66 ;; ------------------------------------------------------------------------
  67 ;; r4619 | ckuethe | 2007-12-23 14:37:31 -0500 (Sun, 23 Dec 2007) | 1 line
  68 ;;
  69 ;; there is now a regression test for AC12 without raw data output
  70
  71 ;;;; Darcs:
  72
  73 ;; Changes to darcsum.el:
  74 ;;
  75 ;; Mon Nov 28 15:19:38 GMT 2005  Dave Love <fx@gnu.org>
  76 ;;   * Abstract process startup into darcsum-start-process.  Use TERM=dumb.
  77 ;;   TERM=dumb avoids escape characters, at least, for any old darcs that
  78 ;;   doesn't understand DARCS_DONT_COLOR & al.
  79 ;;
  80 ;; Thu Nov 24 15:20:45 GMT 2005  Dave Love <fx@gnu.org>
  81 ;;   * darcsum-mode-related changes.
  82 ;;   Don't call font-lock-mode (unnecessary) or use-local-map (redundant).
  83 ;;   Use mode-class 'special.  Add :group.
  84 ;;   Add trailing-whitespace option to mode hook and fix
  85 ;;   darcsum-display-changeset not to use trailing whitespace.
  86
  87 ;;;; Mercurial
  88
  89 ;; changeset:   11:8ff1a4166444
  90 ;; tag:         tip
  91 ;; user:        Eric S. Raymond <esr@thyrsus.com>
  92 ;; date:        Wed Dec 26 12:18:58 2007 -0500
  93 ;; summary:     Explain keywords.  Add markup fixes.
  94 ;;
  95 ;; changeset:   10:20abc7ab09c3
  96 ;; user:        Eric S. Raymond <esr@thyrsus.com>
  97 ;; date:        Wed Dec 26 11:37:28 2007 -0500
  98 ;; summary:     Typo fixes.
  99 ;;
 100 ;; changeset:   9:ada9f4da88aa
 101 ;; user:        Eric S. Raymond <esr@thyrsus.com>
 102 ;; date:        Wed Dec 26 11:23:00 2007 -0500
 103 ;; summary:     Add RCS example session.
 104
 105 ;;; Todo:
 106
 107 ;; - add ability to modify a log-entry (via cvs-mode-admin ;-)
 108 ;; - remove references to cvs-*
 109 ;; - make it easier to add support for new backends without changing the code.
 110
 111 ;;; Code:
 112
 113 (eval-when-compile (require 'cl))
 114 (require 'pcvs-util)
 115 (autoload 'vc-find-revision "vc")
 116 (autoload 'vc-version-diff "vc")
 117
 118 (defvar cvs-minor-wrap-function)
 119
 120 (defgroup log-view nil
 121   "Major mode for browsing log output of RCS/CVS/SCCS."
 122   :group 'pcl-cvs
 123   :prefix "log-view-")
 124
 125 (easy-mmode-defmap log-view-mode-map
 126   '(("q" . quit-window)
 127     ("z" . kill-this-buffer)
 128     ("m" . log-view-toggle-mark-entry)
 129     ("e" . log-view-modify-change-comment)
 130     ("d" . log-view-diff)
 131     ("D" . log-view-diff-changeset)
 132     ("a" . log-view-annotate-version)
 133     ("f" . log-view-find-revision)
 134     ("n" . log-view-msg-next)
 135     ("p" . log-view-msg-prev)
 136     ("\t" . log-view-msg-next)
 137     ([backtab] . log-view-msg-prev)
 138     ("N" . log-view-file-next)
 139     ("P" . log-view-file-prev)
 140     ("\M-n" . log-view-file-next)
 141     ("\M-p" . log-view-file-prev))
 142   "Log-View's keymap."
 143   :group 'log-view
 144   ;; Here I really need either buffer-local keymap-inheritance
 145   ;; or a minor-mode-map with lower precedence than the local map.
 146   :inherit (if (boundp 'cvs-mode-map) cvs-mode-map))
 147
 148 (easy-menu-define log-view-mode-menu log-view-mode-map
 149   "Log-View Display Menu"
 150   `("Log-View"
 151     ;; XXX Do we need menu entries for these?
 152     ;; ["Quit"  quit-window]
 153     ;; ["Kill This Buffer"  kill-this-buffer]
 154     ["Mark Log Entry for Diff"  set-mark-command
 155      :help ""]
 156     ["Diff Revisions"  log-view-diff
 157      :help "Get the diff between two revisions"]
 158     ["Changeset Diff"  log-view-diff-changeset
 159      :help "Get the changeset diff between two revisions"]
 160     ["Visit Version"  log-view-find-revision
 161      :help "Visit the version at point"]
 162     ["Annotate Version"  log-view-annotate-version
 163      :help "Annotate the version at point"]
 164     ["Modify Log Comment" log-view-modify-change-comment
 165      :help "Edit the change comment displayed at point"]
 166     "-----"
 167     ["Next Log Entry"  log-view-msg-next
 168      :help "Go to the next count'th log message"]
 169     ["Previous Log Entry"  log-view-msg-prev
 170      :help "Go to the previous count'th log message"]
 171     ["Next File"  log-view-file-next
 172      :help "Go to the next count'th file"]
 173     ["Previous File"  log-view-file-prev
 174      :help "Go to the previous count'th file"]))
 175
 176 (defvar log-view-mode-hook nil
 177   "Hook run at the end of `log-view-mode'.")
 178
 179 (defface log-view-file
 180   '((((class color) (background light))
 181      (:background "grey70" :weight bold))
 182     (t (:weight bold)))
 183   "Face for the file header line in `log-view-mode'."
 184   :group 'log-view)
 185 ;; backward-compatibility alias
 186 (put 'log-view-file-face 'face-alias 'log-view-file)
 187 (defvar log-view-file-face 'log-view-file)
 188
 189 (defface log-view-message
 190   '((((class color) (background light))
 191      (:background "grey85"))
 192     (t (:weight bold)))
 193   "Face for the message header line in `log-view-mode'."
 194   :group 'log-view)
 195 ;; backward-compatibility alias
 196 (put 'log-view-message-face 'face-alias 'log-view-message)
 197 (defvar log-view-message-face 'log-view-message)
 198
 199 (defvar log-view-file-re
 200   (concat "^\\(?:Working file: \\(?1:.+\\)"                ;RCS and CVS.
 201           ;; Subversion has no such thing??
 202           "\\|\\(?:SCCS/s\\.\\|Changes to \\)\\(?1:.+\\):" ;SCCS and Darcs.
 203           "\\)\n")                    ;Include the \n for font-lock reasons.
 204   "Regexp matching the text identifying the file.
 205 The match group number 1 should match the file name itself.")
 206
 207 (defvar log-view-per-file-logs t
 208   "Set if to t if the logs are shown one file at a time.")
 209
 210 (defvar log-view-message-re
 211   (concat "^\\(?:revision \\(?1:[.0-9]+\\)\\(?:\t.*\\)?" ; RCS and CVS.
 212           "\\|r\\(?1:[0-9]+\\) | .* | .*"                ; Subversion.
 213           "\\|D \\(?1:[.0-9]+\\) .*"                     ; SCCS.
 214           ;; Darcs doesn't have revision names.  VC-darcs uses patch names
 215           ;; instead.  Darcs patch names are hashcodes, which do not appear
 216           ;; in the log output :-(, but darcs accepts any prefix of the log
 217           ;; message as a patch name, so we match the first line of the log
 218           ;; message.
 219           ;; First loosely match the date format.
 220           (concat "\\|[^ \n].*[^0-9\n][0-9][0-9]:[0-9][0-9][^0-9\n].*[^ \n]"
 221                   ;;Email of user and finally Msg, used as revision name.
 222                   "  .*@.*\n\\(?:  \\* \\(?1:.*\\)\\)?")
 223           "\\)$")
 224   "Regexp matching the text identifying a revision.
 225 The match group number 1 should match the revision number itself.")
 226
 227 (defvar log-view-font-lock-keywords
 228   ;; We use `eval' so as to use the buffer-local value of log-view-file-re
 229   ;; and log-view-message-re, if applicable.
 230   '((eval . `(,log-view-file-re
 231               (1 (if (boundp 'cvs-filename-face) cvs-filename-face))
 232               (0 log-view-file-face append)))
 233     (eval . `(,log-view-message-re . log-view-message-face))))
 234
 235 (defconst log-view-font-lock-defaults
 236   '(log-view-font-lock-keywords t nil nil nil))
 237
 238 (defvar log-view-vc-fileset nil
 239   "Set this to the fileset corresponding to the current log.")
 240
 241 (defvar log-view-vc-backend nil
 242   "Set this to the VC backend that created the current log.")
 243
 244 ;;;;
 245 ;;;; Actual code
 246 ;;;;
 247
 248 ;;;###autoload
 249 (define-derived-mode log-view-mode fundamental-mode "Log-View"
 250   "Major mode for browsing CVS log output."
 251   (setq buffer-read-only t)
 252   (set (make-local-variable 'font-lock-defaults) log-view-font-lock-defaults)
 253   (set (make-local-variable 'beginning-of-defun-function)
 254        'log-view-beginning-of-defun)
 255   (set (make-local-variable 'end-of-defun-function)
 256        'log-view-end-of-defun)
 257   (set (make-local-variable 'cvs-minor-wrap-function) 'log-view-minor-wrap))
 258
 259 ;;;;
 260 ;;;; Navigation
 261 ;;;;
 262
 263 ;; define log-view-{msg,file}-{next,prev}
 264 (easy-mmode-define-navigation log-view-msg log-view-message-re "log message")
 265 (easy-mmode-define-navigation log-view-file log-view-file-re "file")
 266
 267 (defun log-view-goto-rev (rev)
 268   (goto-char (point-min))
 269   (ignore-errors
 270     (while (not (equal rev (log-view-current-tag)))
 271       (log-view-msg-next))
 272     t))
 273
 274 ;;;;
 275 ;;;; Linkage to PCL-CVS (mostly copied from cvs-status.el)
 276 ;;;;
 277
 278 (defconst log-view-dir-re "^cvs[.ex]* [a-z]+: Logging \\(.+\\)$")
 279
 280 (defun log-view-current-file ()
 281   (save-excursion
 282     (forward-line 1)
 283     (or (re-search-backward log-view-file-re nil t)
 284         (re-search-forward log-view-file-re nil t)
 285         (error "Unable to determine the current file"))
 286     (let* ((file (match-string 1))
 287            (cvsdir (and (re-search-backward log-view-dir-re nil t)
 288                         (match-string 1)))
 289            (pcldir (and (boundp 'cvs-pcl-cvs-dirchange-re)
 290                         (re-search-backward cvs-pcl-cvs-dirchange-re nil t)
 291                         (match-string 1)))
 292            (dir ""))
 293       (let ((default-directory ""))
 294         (when pcldir (setq dir (expand-file-name pcldir dir)))
 295         (when cvsdir (setq dir (expand-file-name cvsdir dir))))
 296       (expand-file-name file dir))))
 297
 298 (defun log-view-current-tag (&optional where)
 299   (save-excursion
 300     (when where (goto-char where))
 301     (forward-line 1)
 302     (let ((pt (point)))
 303       (when (re-search-backward log-view-message-re nil t)
 304         (let ((rev (match-string-no-properties 1)))
 305           (unless (re-search-forward log-view-file-re pt t)
 306             rev))))))
 307
 308 (defun log-view-toggle-mark-entry ()
 309   "Toggle the marked state for the log entry at point.
 310 Individual log entries can be marked and unmarked. The marked
 311 entries are denoted by changing their background color.
 312 `log-view-get-marked' returns the list of tags for the marked
 313 log entries."
 314   (interactive)
 315   (save-excursion
 316     (forward-line 1)
 317     (let ((pt (point)))
 318       (when (re-search-backward log-view-message-re nil t)
 319         (let ((beg (match-beginning 0))
 320               end ov ovlist found tag)
 321           (unless (re-search-forward log-view-file-re pt t)
 322             ;; Look to see if the current entry is marked.
 323             (setq found (get-char-property (point) 'log-view-self))
 324             (if found
 325                 (delete-overlay found)
 326               ;; Create an overlay that covers this entry and change
 327               ;; its color.
 328               (setq tag (log-view-current-tag (point)))
 329               (forward-line 1)
 330               (setq end
 331                     (if (re-search-forward log-view-message-re nil t)
 332                         (match-beginning 0)
 333                       (point-max)))
 334               (setq ov (make-overlay beg end))
 335               (overlay-put ov 'face 'log-view-file)
 336               ;; This is used to check if the overlay is present.
 337               (overlay-put ov 'log-view-self ov)
 338               (overlay-put ov 'log-view-marked tag))))))))
 339
 340 (defun log-view-get-marked ()
 341   "Return the list of tags for the marked log entries."
 342   (save-excursion
 343     (let ((pos (point-min))
 344           marked-list ov)
 345       (while (setq pos (next-single-property-change pos 'face))
 346         (when (setq ov (get-char-property pos 'log-view-self))
 347           (push (overlay-get ov 'log-view-marked) marked-list)
 348           (setq pos (overlay-end ov))))
 349       marked-list)))
 350
 351 (defun log-view-beginning-of-defun ()
 352   ;; This assumes that a log entry starts with a line matching
 353   ;; `log-view-message-re'.  Modes that derive from `log-view-mode'
 354   ;; for which this assumption is not valid will have to provide
 355   ;; another implementation of this function.  `log-view-msg-prev'
 356   ;; does a similar job to this function, we can't use it here
 357   ;; directly because it prints messages that are not appropriate in
 358   ;; this context and it does not move to the beginning of the buffer
 359   ;; when the point is before the first log entry.
 360
 361   ;; `log-view-beginning-of-defun' and `log-view-end-of-defun' have
 362   ;; been checked to work with logs produced by RCS, CVS, git,
 363   ;; mercurial and subversion.
 364
 365   (re-search-backward log-view-message-re nil 'move))
 366
 367 (defun log-view-end-of-defun ()
 368   ;; The idea in this function is to search for the beginning of the
 369   ;; next log entry using `log-view-message-re' and then go back one
 370   ;; line when finding it.  Modes that derive from `log-view-mode' for
 371   ;; which this assumption is not valid will have to provide another
 372   ;; implementation of this function.
 373
 374   ;; Look back and if there is no entry there it means we are before
 375   ;; the first log entry, so go forward until finding one.
 376   (unless (save-excursion (re-search-backward log-view-message-re nil t))
 377     (re-search-forward log-view-message-re nil t))
 378
 379   ;; In case we are at the end of log entry going forward a line will
 380   ;; make us find the next entry when searching. If we are inside of
 381   ;; an entry going forward a line will still keep the point inside
 382   ;; the same entry.
 383   (forward-line 1)
 384
 385   ;; In case we are at the beginning of an entry, move past it.
 386   (when (looking-at log-view-message-re)
 387     (goto-char (match-end 0))
 388     (forward-line 1))
 389
 390   ;; Search for the start of the next log entry.  Go to the end of the
 391   ;; buffer if we could not find a next entry.
 392   (when (re-search-forward log-view-message-re nil 'move)
 393     (goto-char (match-beginning 0))
 394     (forward-line -1)))
 395
 396 (defvar cvs-minor-current-files)
 397 (defvar cvs-branch-prefix)
 398 (defvar cvs-secondary-branch-prefix)
 399
 400 (defun log-view-minor-wrap (buf f)
 401   (let ((data (with-current-buffer buf
 402                 (let* ((beg (point))
 403                        (end (if mark-active (mark) (point)))
 404                        (fr (log-view-current-tag beg))
 405                        (to (log-view-current-tag end)))
 406                   (when (string-equal fr to)
 407                     (save-excursion
 408                       (goto-char end)
 409                       (log-view-msg-next)
 410                       (setq to (log-view-current-tag))))
 411                   (cons
 412                    ;; The first revision has to be the one at point, for
 413                    ;; operations that only take one revision
 414                    ;; (e.g. cvs-mode-edit).
 415                    (cons (log-view-current-file) fr)
 416                    (cons (log-view-current-file) to))))))
 417     (let ((cvs-branch-prefix (cdar data))
 418           (cvs-secondary-branch-prefix (and (cdar data) (cddr data)))
 419           (cvs-minor-current-files
 420            (cons (caar data)
 421                  (when (and (cadr data) (not (equal (caar data) (cadr data))))
 422                    (list (cadr data)))))
 423           ;; FIXME:  I need to force because the fileinfos are UNKNOWN
 424           (cvs-force-command "/F"))
 425       (funcall f))))
 426
 427 (defun log-view-find-revision (pos)
 428   "Visit the version at point."
 429   (interactive "d")
 430   (unless log-view-per-file-logs
 431     (when (> (length log-view-vc-fileset) 1)
 432       (error "Multiple files shown in this buffer, cannot use this command here")))
 433   (save-excursion
 434     (goto-char pos)
 435     (switch-to-buffer (vc-find-revision (if log-view-per-file-logs
 436                                             (log-view-current-file)
 437                                           (car log-view-vc-fileset))
 438                                         (log-view-current-tag)))))
 439
 440
 441 (defun log-view-extract-comment ()
 442   "Parse comment from around the current point in the log."
 443   (save-excursion
 444     (let (st en (backend (vc-backend (log-view-current-file))))
 445       (log-view-end-of-defun)
 446       (cond ((eq backend 'SVN)
 447              (forward-line -1)))
 448       (setq en (point))
 449       (log-view-beginning-of-defun)
 450       (cond ((memq backend '(SCCS RCS CVS MCVS SVN))
 451              (forward-line 2))
 452             ((eq backend 'Hg)
 453              (forward-line 4)
 454              (re-search-forward "summary: *" nil t)))
 455       (setq st (point))
 456       (buffer-substring st en))))
 457
 458 (declare-function vc-modify-change-comment "vc" (files rev oldcomment))
 459
 460 (defun log-view-modify-change-comment ()
 461   "Edit the change comment displayed at point."
 462   (interactive)
 463   (vc-modify-change-comment (list (if log-view-per-file-logs
 464                                       (log-view-current-file)
 465                                     (car log-view-vc-fileset)))
 466                             (log-view-current-tag)
 467                             (log-view-extract-comment)))
 468
 469 (defun log-view-annotate-version (pos)
 470   "Annotate the version at point."
 471   (interactive "d")
 472   (unless log-view-per-file-logs
 473     (when (> (length log-view-vc-fileset) 1)
 474       (error "Multiple files shown in this buffer, cannot use this command here")))
 475   (save-excursion
 476     (goto-char pos)
 477     (vc-annotate (if log-view-per-file-logs
 478                      (log-view-current-file)
 479                    (car log-view-vc-fileset))
 480                  (log-view-current-tag))))
 481
 482 ;;
 483 ;; diff
 484 ;;
 485
 486 (defun log-view-diff (beg end)
 487   "Get the diff between two revisions.
 488 If the mark is not active or the mark is on the revision at point,
 489 get the diff between the revision at point and its previous revision.
 490 Otherwise, get the diff between the revisions where the region starts
 491 and ends."
 492   (interactive
 493    (list (if mark-active (region-beginning) (point))
 494          (if mark-active (region-end) (point))))
 495   (let ((fr (log-view-current-tag beg))
 496         (to (log-view-current-tag end)))
 497     (when (string-equal fr to)
 498       (save-excursion
 499         (goto-char end)
 500         (log-view-msg-next)
 501         (setq to (log-view-current-tag))))
 502     (vc-version-diff
 503      (if log-view-per-file-logs
 504          (list (log-view-current-file))
 505        log-view-vc-fileset)
 506        to fr)))
 507
 508 (declare-function vc-diff-internal "vc"
 509                   (async vc-fileset rev1 rev2 &optional verbose))
 510
 511 (defun log-view-diff-changeset (beg end)
 512   "Get the diff between two revisions.
 513 If the mark is not active or the mark is on the revision at point,
 514 get the diff between the revision at point and its previous revision.
 515 Otherwise, get the diff between the revisions where the region starts
 516 and ends."
 517   (interactive
 518    (list (if mark-active (region-beginning) (point))
 519          (if mark-active (region-end) (point))))
 520   (when (eq (vc-call-backend log-view-vc-backend 'revision-granularity) 'file)
 521     (error "The %s backend does not support changeset diffs" log-view-vc-backend))
 522   (let ((fr (log-view-current-tag beg))
 523         (to (log-view-current-tag end)))
 524     (when (string-equal fr to)
 525       ;; TO and FR are the same, look at the previous revision.
 526       (setq to (vc-call-backend log-view-vc-backend 'previous-revision nil fr)))
 527     (vc-diff-internal
 528      t
 529      ;; We want to see the diff for all the files in the changeset, so
 530      ;; pass NIL for the file list.  The value passed here should
 531      ;; follow what `vc-deduce-fileset' returns.
 532      (list log-view-vc-backend nil)
 533      to fr)))
 534
 535 (provide 'log-view)
 536
 537 ;; arch-tag: 0d64220b-ce7e-4f62-9c2a-6b04c2f81f4f
 538 ;;; log-view.el ends here