lisp/xml.el

   1 ;;; xml.el --- XML parser
   2
   3 ;; Copyright (C) 2000, 2001, 2003 Free Software Foundation, Inc.
   4
   5 ;; Author: Emmanuel Briot  <briot@gnat.com>
   6 ;; Maintainer: Mark A. Hershberger <mah@everybody.org>
   7 ;; Keywords: xml, data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file contains a somewhat incomplete non-validating XML parser.  It
  29 ;; parses a file, and returns a list that can be used internally by
  30 ;; any other lisp libraries.
  31
  32 ;;; FILE FORMAT
  33
  34 ;; The document type declaration may either be ignored or (optionally)
  35 ;; parsed, but currently the parsing will only accept element
  36 ;; declarations.  The XML file is assumed to be well-formed. In case
  37 ;; of error, the parsing stops and the XML file is shown where the
  38 ;; parsing stopped.
  39 ;;
  40 ;; It also knows how to ignore comments and processing instructions.
  41 ;;
  42 ;; The XML file should have the following format:
  43 ;;    <node1 attr1="name1" attr2="name2" ...>value
  44 ;;       <node2 attr3="name3" attr4="name4">value2</node2>
  45 ;;       <node3 attr5="name5" attr6="name6">value3</node3>
  46 ;;    </node1>
  47 ;; Of course, the name of the nodes and attributes can be anything. There can
  48 ;; be any number of attributes (or none), as well as any number of children
  49 ;; below the nodes.
  50 ;;
  51 ;; There can be only top level node, but with any number of children below.
  52
  53 ;;; LIST FORMAT
  54
  55 ;; The functions `xml-parse-file' and `xml-parse-tag' return a list with
  56 ;; the following format:
  57 ;;
  58 ;;    xml-list   ::= (node node ...)
  59 ;;    node       ::= (tag_name attribute-list . child_node_list)
  60 ;;    child_node_list ::= child_node child_node ...
  61 ;;    child_node ::= node | string
  62 ;;    tag_name   ::= string
  63 ;;    attribute_list ::= (("attribute" . "value") ("attribute" . "value") ...)
  64 ;;                       | nil
  65 ;;    string     ::= "..."
  66 ;;
  67 ;; Some macros are provided to ease the parsing of this list.
  68 ;; Whitespace is preserved.  Fixme: There should be a tree-walker that
  69 ;; can remove it.
  70
  71 ;;; Code:
  72
  73 ;; Note that {buffer-substring,match-string}-no-properties were
  74 ;; formerly used in several places, but that removes composition info.
  75
  76 ;;*******************************************************************
  77 ;;**
  78 ;;**  Macros to parse the list
  79 ;;**
  80 ;;*******************************************************************
  81
  82 (defsubst xml-node-name (node)
  83   "Return the tag associated with NODE.
  84 The tag is a lower-case symbol."
  85   (car node))
  86
  87 (defsubst xml-node-attributes (node)
  88   "Return the list of attributes of NODE.
  89 The list can be nil."
  90   (nth 1 node))
  91
  92 (defsubst xml-node-children (node)
  93   "Return the list of children of NODE.
  94 This is a list of nodes, and it can be nil."
  95   (cddr node))
  96
  97 (defun xml-get-children (node child-name)
  98   "Return the children of NODE whose tag is CHILD-NAME.
  99 CHILD-NAME should be a lower case symbol."
 100   (let ((match ()))
 101     (dolist (child (xml-node-children node))
 102       (if child
 103           (if (equal (xml-node-name child) child-name)
 104               (push child match))))
 105     (nreverse match)))
 106
 107 (defun xml-get-attribute (node attribute)
 108   "Get from NODE the value of ATTRIBUTE.
 109 An empty string is returned if the attribute was not found."
 110   (if (xml-node-attributes node)
 111       (let ((value (assoc attribute (xml-node-attributes node))))
 112         (if value
 113             (cdr value)
 114           ""))
 115     ""))
 116
 117 ;;*******************************************************************
 118 ;;**
 119 ;;**  Creating the list
 120 ;;**
 121 ;;*******************************************************************
 122
 123 ;;;###autoload
 124 (defun xml-parse-file (file &optional parse-dtd parse-ns)
 125   "Parse the well-formed XML file FILE.
 126 If FILE is already visited, use its buffer and don't kill it.
 127 Returns the top node with all its children.
 128 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped.
 129 If PARSE-NS is non-nil, then QNAMES are expanded."
 130   (let ((keep))
 131     (if (get-file-buffer file)
 132         (progn
 133           (set-buffer (get-file-buffer file))
 134           (setq keep (point)))
 135       (let (auto-mode-alist)            ; no need for xml-mode
 136         (find-file file)))
 137
 138     (let ((xml (xml-parse-region (point-min)
 139                                  (point-max)
 140                                  (current-buffer)
 141                                  parse-dtd parse-ns)))
 142       (if keep
 143           (goto-char keep)
 144         (kill-buffer (current-buffer)))
 145       xml)))
 146
 147 ;; Note that this is setup so that we can do whitespace-skipping with
 148 ;; `(skip-syntax-forward " ")', inter alia.  Previously this was slow
 149 ;; compared with `re-search-forward', but that has been fixed.  Also
 150 ;; note that the standard syntax table contains other characters with
 151 ;; whitespace syntax, like NBSP, but they are invalid in contexts in
 152 ;; which we might skip whitespace -- specifically, they're not
 153 ;; NameChars [XML 4].
 154
 155 (defvar xml-syntax-table
 156   (let ((table (make-syntax-table)))
 157     ;; Get space syntax correct per XML [3].
 158     (dotimes (c 31)
 159       (modify-syntax-entry c "." table)) ; all are space in standard table
 160     (dolist (c '(?\t ?\n ?\r))          ; these should be space
 161       (modify-syntax-entry c " " table))
 162     ;; For skipping attributes.
 163     (modify-syntax-entry ?\" "\"" table)
 164     (modify-syntax-entry ?' "\"" table)
 165     ;; Non-alnum name chars should be symbol constituents (`-' and `_'
 166     ;; are OK by default).
 167     (modify-syntax-entry ?. "_" table)
 168     (modify-syntax-entry ?: "_" table)
 169     ;; XML [89]
 170     (dolist (c '(#x00B7 #x02D0 #x02D1 #x0387 #x0640 #x0E46 #x0EC6 #x3005
 171                  #x3031 #x3032 #x3033 #x3034 #x3035 #x309D #x309E #x30FC
 172                  #x30FD #x30FE))
 173       (modify-syntax-entry (decode-char 'ucs c) "w" table))
 174     ;; Fixme: rest of [4]
 175     table)
 176   "Syntax table used by `xml-parse-region'.")
 177
 178 ;; XML [5]
 179 ;; Note that [:alpha:] matches all multibyte chars with word syntax.
 180 (eval-and-compile
 181   (defconst xml-name-regexp "[[:alpha:]_:][[:alnum:]._:-]*"))
 182
 183 ;; Fixme:  This needs re-writing to deal with the XML grammar properly, i.e.
 184 ;;   document    ::=    prolog element Misc*
 185 ;;   prolog    ::=    XMLDecl? Misc* (doctypedecl Misc*)?
 186
 187 ;;;###autoload
 188 (defun xml-parse-region (beg end &optional buffer parse-dtd parse-ns)
 189   "Parse the region from BEG to END in BUFFER.
 190 If BUFFER is nil, it defaults to the current buffer.
 191 Returns the XML list for the region, or raises an error if the region
 192 is not well-formed XML.
 193 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped,
 194 and returned as the first element of the list.
 195 If PARSE-NS is non-nil, then QNAMES are expanded."
 196   (save-restriction
 197     (narrow-to-region beg end)
 198     ;; Use fixed syntax table to ensure regexp char classes and syntax
 199     ;; specs DTRT.
 200     (with-syntax-table (standard-syntax-table)
 201       (let ((case-fold-search nil)      ; XML is case-sensitive.
 202             xml result dtd)
 203         (save-excursion
 204           (if buffer
 205               (set-buffer buffer))
 206           (goto-char (point-min))
 207           (while (not (eobp))
 208             (if (search-forward "<" nil t)
 209                 (progn
 210                   (forward-char -1)
 211                   (setq result (xml-parse-tag parse-dtd parse-ns))
 212                   (if (and xml result)
 213                       ;;  translation of rule [1] of XML specifications
 214                       (error "XML files can have only one toplevel tag")
 215                     (cond
 216                      ((null result))
 217                      ((and (listp (car result))
 218                            parse-dtd)
 219                       (setq dtd (car result))
 220                       (if (cdr result)  ; possible leading comment
 221                           (add-to-list 'xml (cdr result))))
 222                      (t
 223                       (add-to-list 'xml result)))))
 224               (goto-char (point-max))))
 225           (if parse-dtd
 226               (cons dtd (nreverse xml))
 227             (nreverse xml)))))))
 228
 229 (defun xml-ns-parse-ns-attrs (attr-list &optional xml-ns)
 230   "Parse the namespace attributes and return a list of cons in the form:
 231 \(namespace . prefix)"
 232
 233   (mapcar
 234    (lambda (attr)
 235      (let* ((splitup (split-string (car attr) ":"))
 236             (prefix (nth 0 splitup))
 237             (lname (nth 1 splitup)))
 238        (when (string= "xmlns" prefix)
 239          (push (cons (if lname
 240                          lname
 241                        "")
 242                      (cdr attr))
 243                xml-ns)))) attr-list)
 244   xml-ns)
 245
 246 ;; expand element names
 247 (defun xml-ns-expand-el (el xml-ns)
 248   "Expand the XML elements from \"prefix:local-name\" to a cons in the form
 249 \"(namespace . local-name)\"."
 250
 251   (let* ((splitup (split-string el ":"))
 252          (lname (or (nth 1 splitup)
 253                     (nth 0 splitup)))
 254          (prefix (if (nth 1 splitup)
 255                      (nth 0 splitup)
 256                    (if (string= lname "xmlns")
 257                        "xmlns"
 258                      "")))
 259          (ns (cdr (assoc-string prefix xml-ns))))
 260     (if (string= "" ns)
 261         lname
 262       (cons (intern (concat ":" ns))
 263             lname))))
 264
 265 ;; expand attribute names
 266 (defun xml-ns-expand-attr (attr-list xml-ns)
 267   "Expand the attribute list for a particular element from the form
 268 \"prefix:local-name\" to the form \"{namespace}:local-name\"."
 269
 270   (mapcar
 271    (lambda (attr)
 272      (let* ((splitup (split-string (car attr) ":"))
 273             (lname (or (nth 1 splitup)
 274                        (nth 0 splitup)))
 275             (prefix (if (nth 1 splitup)
 276                         (nth 0 splitup)
 277                       (if (string= (car attr) "xmlns")
 278                           "xmlns"
 279                         "")))
 280             (ns (cdr (assoc-string prefix xml-ns))))
 281        (setcar attr
 282                (if (string= "" ns)
 283                    lname
 284                  (cons (intern (concat ":" ns))
 285                        lname)))))
 286    attr-list)
 287   attr-list)
 288
 289
 290 (defun xml-intern-attrlist (attr-list)
 291   "Convert attribute names to symbols for backward compatibility."
 292   (mapcar (lambda (attr)
 293             (setcar attr (intern (car attr))))
 294           attr-list)
 295   attr-list)
 296
 297 (defun xml-parse-tag (&optional parse-dtd parse-ns)
 298   "Parse the tag at point.
 299 If PARSE-DTD is non-nil, the DTD of the document, if any, is parsed and
 300 returned as the first element in the list.
 301 If PARSE-NS is non-nil, then QNAMES are expanded.
 302 Returns one of:
 303  - a list : the matching node
 304  - nil    : the point is not looking at a tag.
 305  - a pair : the first element is the DTD, the second is the node."
 306   (let ((xml-ns (if (consp parse-ns)
 307                     parse-ns
 308                   (if parse-ns
 309                       (list
 310                        ;; Default no namespace
 311                        (cons "" "")
 312                        ;; We need to seed the xmlns namespace
 313                        (cons "xmlns" "http://www.w3.org/2000/xmlns/"))))))
 314     (cond
 315      ;; Processing instructions (like the <?xml version="1.0"?> tag at the
 316      ;; beginning of a document).
 317      ((looking-at "<\\?")
 318       (search-forward "?>")
 319       (skip-syntax-forward " ")
 320       (xml-parse-tag parse-dtd xml-ns))
 321      ;;  Character data (CDATA) sections, in which no tag should be interpreted
 322      ((looking-at "<!\\[CDATA\\[")
 323       (let ((pos (match-end 0)))
 324         (unless (search-forward "]]>" nil t)
 325           (error "CDATA section does not end anywhere in the document"))
 326         (buffer-substring pos (match-beginning 0))))
 327      ;;  DTD for the document
 328      ((looking-at "<!DOCTYPE")
 329       (let (dtd)
 330         (if parse-dtd
 331             (setq dtd (xml-parse-dtd))
 332           (xml-skip-dtd))
 333       (skip-syntax-forward " ")
 334       (if dtd
 335           (cons dtd (xml-parse-tag nil xml-ns))
 336         (xml-parse-tag nil xml-ns))))
 337      ;;  skip comments
 338      ((looking-at "<!--")
 339       (search-forward "-->")
 340       nil)
 341      ;;  end tag
 342      ((looking-at "</")
 343       '())
 344      ;;  opening tag
 345      ((looking-at "<\\([^/>[:space:]]+\\)")
 346       (goto-char (match-end 1))
 347
 348       ;; Parse this node
 349       (let* ((node-name (match-string 1))
 350              (attr-list (xml-parse-attlist))
 351              (children (if  (consp xml-ns) ;; take care of namespace parsing
 352                             (progn
 353                               (setq xml-ns (xml-ns-parse-ns-attrs
 354                                             attr-list xml-ns))
 355                               (list (xml-ns-expand-attr
 356                                      attr-list xml-ns)
 357                                     (xml-ns-expand-el
 358                                      node-name xml-ns)))
 359                             (list (xml-intern-attrlist attr-list)
 360                                   (intern node-name))))
 361              pos)
 362
 363         ;; is this an empty element ?
 364         (if (looking-at "/>")
 365         (progn
 366           (forward-char 2)
 367           (nreverse children))
 368
 369         ;; is this a valid start tag ?
 370         (if (eq (char-after) ?>)
 371             (progn
 372               (forward-char 1)
 373               ;;  Now check that we have the right end-tag. Note that this
 374               ;;  one might contain spaces after the tag name
 375               (let ((end (concat "</" node-name "\\s-*>")))
 376                 (while (not (looking-at end))
 377                   (cond
 378                    ((looking-at "</")
 379                     (error "XML: Invalid end tag (expecting %s) at pos %d"
 380                            node-name (point)))
 381                    ((= (char-after) ?<)
 382                     (let ((tag (xml-parse-tag nil xml-ns)))
 383                       (when tag
 384                         (push tag children))))
 385                    (t
 386                     (setq pos (point))
 387                     (search-forward "<")
 388                     (forward-char -1)
 389                     (let ((string (buffer-substring pos (point)))
 390                           (pos 0))
 391
 392                       ;; Clean up the string.  As per XML
 393                       ;; specifications, the XML processor should
 394                       ;; always pass the whole string to the
 395                       ;; application.  But \r's should be replaced:
 396                       ;; http://www.w3.org/TR/2000/REC-xml-20001006#sec-line-ends
 397                       (while (string-match "\r\n?" string pos)
 398                         (setq string (replace-match "\n" t t string))
 399                         (setq pos (1+ (match-beginning 0))))
 400
 401                       (setq string (xml-substitute-special string))
 402                       (setq children
 403                             (if (stringp (car children))
 404                                 ;; The two strings were separated by a comment.
 405                                 (cons (concat (car children) string)
 406                                       (cdr children))
 407                               (cons string children))))))))
 408
 409               (goto-char (match-end 0))
 410               (nreverse children))
 411           ;;  This was an invalid start tag
 412           (error "XML: Invalid attribute list")))))
 413      (t ;; This is not a tag.
 414       (error "XML: Invalid character")))))
 415
 416 (defun xml-parse-attlist ()
 417   "Return the attribute-list after point.  Leave point at the
 418 first non-blank character after the tag."
 419   (let ((attlist ())
 420         end-pos name)
 421     (skip-syntax-forward " ")
 422     (while (looking-at (eval-when-compile
 423                          (concat "\\(" xml-name-regexp "\\)\\s-*=\\s-*")))
 424       (setq name (match-string 1))
 425       (goto-char (match-end 0))
 426
 427       ;; See also: http://www.w3.org/TR/2000/REC-xml-20001006#AVNormalize
 428
 429       ;; Do we have a string between quotes (or double-quotes),
 430       ;;  or a simple word ?
 431       (if (looking-at "\"\\([^\"]*\\)\"")
 432           (setq end-pos (match-end 0))
 433         (if (looking-at "'\\([^']*\\)'")
 434             (setq end-pos (match-end 0))
 435           (error "XML: Attribute values must be given between quotes")))
 436
 437       ;; Each attribute must be unique within a given element
 438       (if (assoc name attlist)
 439           (error "XML: each attribute must be unique within an element"))
 440
 441       ;; Multiple whitespace characters should be replaced with a single one
 442       ;; in the attributes
 443       (let ((string (match-string 1))
 444             (pos 0))
 445         (replace-regexp-in-string "\\s-\\{2,\\}" " " string)
 446         (push (cons name (xml-substitute-special string)) attlist))
 447
 448       (goto-char end-pos)
 449       (skip-syntax-forward " "))
 450     (nreverse attlist)))
 451
 452 ;;*******************************************************************
 453 ;;**
 454 ;;**  The DTD (document type declaration)
 455 ;;**  The following functions know how to skip or parse the DTD of
 456 ;;**  a document
 457 ;;**
 458 ;;*******************************************************************
 459
 460 ;; Fixme: This fails at least if the DTD contains conditional sections.
 461
 462 (defun xml-skip-dtd ()
 463   "Skip the DTD at point.
 464 This follows the rule [28] in the XML specifications."
 465   (forward-char (length "<!DOCTYPE"))
 466   (if (looking-at "\\s-*>")
 467       (error "XML: invalid DTD (excepting name of the document)"))
 468   (condition-case nil
 469       (progn
 470         (forward-sexp)
 471         (skip-syntax-forward " ")
 472         (if (looking-at "\\[")
 473             (re-search-forward "]\\s-*>")
 474           (search-forward ">")))
 475     (error (error "XML: No end to the DTD"))))
 476
 477 (defun xml-parse-dtd ()
 478   "Parse the DTD at point."
 479   (forward-char (eval-when-compile (length "<!DOCTYPE")))
 480   (skip-syntax-forward " ")
 481   (if (looking-at ">")
 482       (error "XML: invalid DTD (excepting name of the document)"))
 483
 484   ;;  Get the name of the document
 485   (looking-at xml-name-regexp)
 486   (let ((dtd (list (match-string 0) 'dtd))
 487         type element end-pos)
 488     (goto-char (match-end 0))
 489
 490     (skip-syntax-forward " ")
 491     ;; XML [75]
 492     (cond ((looking-at "PUBLIC\\s-+")
 493            (goto-char (match-end 0))
 494            (unless (or (re-search-forward
 495                         "\\=\"\\([[:space:][:alnum:]-'()+,./:=?;!*#@$_%]*\\)\""
 496                         nil t)
 497                        (re-search-forward
 498                         "\\='\\([[:space:][:alnum:]-()+,./:=?;!*#@$_%]*\\)'"
 499                         nil t))
 500              (error "XML: missing public id"))
 501            (let ((pubid (match-string 1)))
 502              (unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
 503                          (re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
 504                (error "XML: missing system id"))
 505              (push (list pubid (match-string 1) 'public) dtd)))
 506           ((looking-at "SYSTEM\\s-+")
 507            (goto-char (match-end 0))
 508            (unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
 509                        (re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
 510              (error "XML: missing system id"))
 511            (push (list (match-string 1) 'system) dtd)))
 512     (skip-syntax-forward " ")
 513     (if (eq ?> (char-after))
 514         (forward-char)
 515       (skip-syntax-forward " ")
 516       (if (not (eq (char-after) ?\[))
 517           (error "XML: bad DTD")
 518         (forward-char)
 519         ;;  Parse the rest of the DTD
 520         ;;  Fixme: Deal with ENTITY, ATTLIST, NOTATION, PIs.
 521         (while (not (looking-at "\\s-*\\]"))
 522           (skip-syntax-forward " ")
 523           (cond
 524
 525            ;;  Translation of rule [45] of XML specifications
 526            ((looking-at
 527              "<!ELEMENT\\s-+\\([[:alnum:].%;]+\\)\\s-+\\([^>]+\\)>")
 528
 529             (setq element (match-string 1)
 530                   type    (match-string-no-properties 2))
 531             (setq end-pos (match-end 0))
 532
 533             ;;  Translation of rule [46] of XML specifications
 534             (cond
 535              ((string-match "^EMPTY[ \t\n\r]*$" type) ;; empty declaration
 536               (setq type 'empty))
 537              ((string-match "^ANY[ \t\n\r]*$" type) ;; any type of contents
 538               (setq type 'any))
 539              ((string-match "^(\\(.*\\))[ \t\n\r]*$" type) ;; children ([47])
 540               (setq type (xml-parse-elem-type (match-string 1 type))))
 541              ((string-match "^%[^;]+;[ \t\n\r]*$" type) ;; substitution
 542               nil)
 543              (t
 544               (error "XML: Invalid element type in the DTD")))
 545
 546             ;;  rule [45]: the element declaration must be unique
 547             (if (assoc element dtd)
 548                 (error "XML: element declarations must be unique in a DTD (<%s>)"
 549                        element))
 550
 551             ;;  Store the element in the DTD
 552             (push (list element type) dtd)
 553             (goto-char end-pos))
 554            ((looking-at "<!--")
 555             (search-forward "-->"))
 556
 557            (t
 558             (error "XML: Invalid DTD item")))
 559
 560           ;;  Skip the end of the DTD
 561           (search-forward ">"))))
 562     (nreverse dtd)))
 563
 564 (defun xml-parse-elem-type (string)
 565   "Convert element type STRING into a Lisp structure."
 566
 567   (let (elem modifier)
 568     (if (string-match "(\\([^)]+\\))\\([+*?]?\\)" string)
 569         (progn
 570           (setq elem     (match-string 1 string)
 571                 modifier (match-string 2 string))
 572           (if (string-match "|" elem)
 573               (setq elem (cons 'choice
 574                                (mapcar 'xml-parse-elem-type
 575                                        (split-string elem "|"))))
 576             (if (string-match "," elem)
 577                 (setq elem (cons 'seq
 578                                  (mapcar 'xml-parse-elem-type
 579                                          (split-string elem ",")))))))
 580       (if (string-match "[ \t\n\r]*\\([^+*?]+\\)\\([+*?]?\\)" string)
 581           (setq elem     (match-string 1 string)
 582                 modifier (match-string 2 string))))
 583
 584     (if (and (stringp elem) (string= elem "#PCDATA"))
 585         (setq elem 'pcdata))
 586
 587     (cond
 588      ((string= modifier "+")
 589       (list '+ elem))
 590      ((string= modifier "*")
 591       (list '* elem))
 592      ((string= modifier "?")
 593       (list '\? elem))
 594      (t
 595       elem))))
 596
 597 ;;*******************************************************************
 598 ;;**
 599 ;;**  Substituting special XML sequences
 600 ;;**
 601 ;;*******************************************************************
 602
 603 (eval-when-compile
 604   (defvar str))                ; dynamic from replace-regexp-in-string
 605
 606 ;; Fixme:  Take declared entities from the DTD when they're available.
 607 (defun xml-substitute-entity (match)
 608   "Subroutine of xml-substitute-special."
 609   (save-match-data
 610     (let ((match1 (match-string 1 str)))
 611       (cond ((string= match1 "lt") "<")
 612             ((string= match1 "gt") ">")
 613             ((string= match1 "apos") "'")
 614             ((string= match1 "quot") "\"")
 615             ((string= match1 "amp") "&")
 616             ((and (string-match "#\\([0-9]+\\)" match1)
 617                   (let ((c (decode-char
 618                             'ucs
 619                             (string-to-number (match-string 1 match1)))))
 620                     (if c (string c))))) ; else unrepresentable
 621             ((and (string-match "#x\\([[:xdigit:]]+\\)" match1)
 622                   (let ((c (decode-char
 623                             'ucs
 624                             (string-to-number (match-string 1 match1) 16))))
 625                     (if c (string c)))))
 626             ;; Default to asis.  Arguably, unrepresentable code points
 627             ;; might be best replaced with U+FFFD.
 628             (t match)))))
 629
 630 (defun xml-substitute-special (string)
 631   "Return STRING, after subsituting entity references."
 632   ;; This originally made repeated passes through the string from the
 633   ;; beginning, which isn't correct, since then either "&amp;amp;" or
 634   ;; "&#38;amp;" won't DTRT.
 635   (replace-regexp-in-string "&\\([^;]+\\);"
 636                             #'xml-substitute-entity string t t))
 637
 638 ;;*******************************************************************
 639 ;;**
 640 ;;**  Printing a tree.
 641 ;;**  This function is intended mainly for debugging purposes.
 642 ;;**
 643 ;;*******************************************************************
 644
 645 (defun xml-debug-print (xml)
 646   (dolist (node xml)
 647     (xml-debug-print-internal node "")))
 648
 649 (defun xml-debug-print-internal (xml indent-string)
 650   "Outputs the XML tree in the current buffer.
 651 The first line is indented with INDENT-STRING."
 652   (let ((tree xml)
 653         attlist)
 654     (insert indent-string ?< (symbol-name (xml-node-name tree)))
 655
 656     ;;  output the attribute list
 657     (setq attlist (xml-node-attributes tree))
 658     (while attlist
 659       (insert ?\  (symbol-name (caar attlist)) "=\"" (cdar attlist) ?\")
 660       (setq attlist (cdr attlist)))
 661
 662     (insert ?>)
 663
 664     (setq tree (xml-node-children tree))
 665
 666     ;;  output the children
 667     (dolist (node tree)
 668       (cond
 669        ((listp node)
 670         (insert ?\n)
 671         (xml-debug-print-internal node (concat indent-string "  ")))
 672        ((stringp node) (insert node))
 673        (t
 674         (error "Invalid XML tree"))))
 675
 676     (insert ?\n indent-string
 677             ?< ?/ (symbol-name (xml-node-name xml)) ?>)))
 678
 679 (provide 'xml)
 680
 681 ;;; arch-tag: 5864b283-5a68-4b59-a20d-36a72b353b9b
 682 ;;; xml.el ends here