lisp/epg-config.el

   1 ;;; epg-config.el --- configuration of the EasyPG Library
   2
   3 ;; Copyright (C) 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Daiki Ueno <ueno@unixuser.org>
   6 ;; Keywords: PGP, GnuPG
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Code:
  24
  25 (defconst epg-package-name "epg"
  26   "Name of this package.")
  27
  28 (defconst epg-version-number "1.0.0"
  29   "Version number of this package.")
  30
  31 (defconst epg-bug-report-address "ueno@unixuser.org"
  32   "Report bugs to this address.")
  33
  34 (defgroup epg ()
  35   "The EasyPG library."
  36   :version "23.1"
  37   :group 'data)
  38
  39 (defcustom epg-gpg-program "gpg"
  40   "The `gpg' executable."
  41   :group 'epg
  42   :type 'string)
  43
  44 (defcustom epg-gpgsm-program "gpgsm"
  45   "The `gpgsm' executable."
  46   :group 'epg
  47   :type 'string)
  48
  49 (defcustom epg-gpg-home-directory nil
  50   "The directory which contains the configuration files of `epg-gpg-program'."
  51   :group 'epg
  52   :type '(choice (const :tag "Default" nil) directory))
  53
  54 (defcustom epg-passphrase-coding-system nil
  55   "Coding system to use with messages from `epg-gpg-program'."
  56   :group 'epg
  57   :type 'symbol)
  58
  59 (defcustom epg-debug nil
  60   "If non-nil, debug output goes to the \" *epg-debug*\" buffer.
  61 Note that the buffer name starts with a space."
  62   :group 'epg
  63   :type 'boolean)
  64
  65 (defconst epg-gpg-minimum-version "1.4.3")
  66
  67 ;;;###autoload
  68 (defun epg-configuration ()
  69   "Return a list of internal configuration parameters of `epg-gpg-program'."
  70   (let (config groups type args)
  71     (with-temp-buffer
  72       (apply #'call-process epg-gpg-program nil (list t nil) nil
  73              (append (if epg-gpg-home-directory
  74                          (list "--homedir" epg-gpg-home-directory))
  75                      '("--with-colons" "--list-config")))
  76       (goto-char (point-min))
  77       (while (re-search-forward "^cfg:\\([^:]+\\):\\(.*\\)" nil t)
  78         (setq type (intern (match-string 1))
  79               args (match-string 2))
  80         (cond
  81          ((eq type 'group)
  82           (if (string-match "\\`\\([^:]+\\):" args)
  83                   (setq groups
  84                         (cons (cons (downcase (match-string 1 args))
  85                                     (delete "" (split-string
  86                                                 (substring args
  87                                                            (match-end 0))
  88                                                 ";")))
  89                               groups))
  90             (if epg-debug
  91                 (message "Invalid group configuration: %S" args))))
  92          ((memq type '(pubkey cipher digest compress))
  93           (if (string-match "\\`\\([0-9]+\\)\\(;[0-9]+\\)*" args)
  94               (setq config
  95                     (cons (cons type
  96                                 (mapcar #'string-to-number
  97                                         (delete "" (split-string args ";"))))
  98                           config))
  99             (if epg-debug
 100                 (message "Invalid %S algorithm configuration: %S"
 101                          type args))))
 102          (t
 103           (setq config (cons (cons type args) config))))))
 104     (if groups
 105         (cons (cons 'groups groups) config)
 106       config)))
 107
 108 (defun epg-config--parse-version (string)
 109   (let ((index 0)
 110         version)
 111     (while (eq index (string-match "\\([0-9]+\\)\\.?" string index))
 112       (setq version (cons (string-to-number (match-string 1 string))
 113                           version)
 114             index (match-end 0)))
 115     (nreverse version)))
 116
 117 (defun epg-config--compare-version (v1 v2)
 118   (while (and v1 v2 (= (car v1) (car v2)))
 119     (setq v1 (cdr v1) v2 (cdr v2)))
 120   (- (or (car v1) 0) (or (car v2) 0)))
 121
 122 ;;;###autoload
 123 (defun epg-check-configuration (config &optional minimum-version)
 124   "Verify that a sufficient version of GnuPG is installed."
 125   (let ((entry (assq 'version config))
 126         version)
 127     (unless (and entry
 128                  (stringp (cdr entry)))
 129       (error "Undetermined version: %S" entry))
 130     (setq version (epg-config--parse-version (cdr entry))
 131           minimum-version (epg-config--parse-version
 132                            (or minimum-version
 133                                epg-gpg-minimum-version)))
 134     (unless (>= (epg-config--compare-version version minimum-version) 0)
 135       (error "Unsupported version: %s" (cdr entry)))))
 136
 137 ;;;###autoload
 138 (defun epg-expand-group (config group)
 139   "Look at CONFIG and try to expand GROUP."
 140   (let ((entry (assq 'groups config)))
 141     (if (and entry
 142              (setq entry (assoc (downcase group) (cdr entry))))
 143         (cdr entry))))
 144
 145 (provide 'epg-config)
 146
 147 ;; arch-tag: 9aca7cb8-5f63-4bcb-84ee-46fd2db0763f
 148 ;;; epg-config.el ends here