lisp/wdired.el

   1 ;;; wdired.el --- Rename files editing their names in dired buffers
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   4
   5 ;; Filename: wdired.el
   6 ;; Author: Juan León Lahoz García <juanleon1@gmail.com>
   7 ;; Version: 2.0
   8 ;; Keywords: dired, environment, files, renaming
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or
  13 ;; modify it under the terms of the GNU General Public License as
  14 ;; published by the Free Software Foundation; either version 3, or (at
  15 ;; your option) any later version.
  16
  17 ;; This program is distributed in the hope that it will be useful, but
  18 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  20 ;; General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; wdired.el (the "w" is for writable) provides an alternative way of
  30 ;; renaming files.
  31 ;;
  32 ;; Have you ever wished to use C-x r t (string-rectangle), M-%
  33 ;; (query-replace), M-c (capitalize-word), etc... to change the name of
  34 ;; the files in a "dired" buffer? Now you can do this.  All the power
  35 ;; of Emacs commands are available to renaming files!
  36 ;;
  37 ;; This package provides a function that makes the filenames of a a
  38 ;; dired buffer editable, by changing the buffer mode (which inhibits
  39 ;; all of the commands of dired mode). Here you can edit the names of
  40 ;; one or more files and directories, and when you press C-c C-c, the
  41 ;; renaming takes effect and you are back to dired mode.
  42 ;;
  43 ;; Another things you can do with WDired:
  44 ;;
  45 ;; - To move files to another directory (by typing their path,
  46 ;;   absolute or relative, as a part of the new filename).
  47 ;;
  48 ;; - To change the target of symbolic links.
  49 ;;
  50 ;; - To change the permission bits of the filenames (in systems with a
  51 ;;   working unix-alike `dired-chmod-program'). See and customize the
  52 ;;   variable `wdired-allow-to-change-permissions'.  To change a single
  53 ;;   char (toggling between its two more usual values) you can press
  54 ;;   the space bar over it or left-click the mouse.  To set any char to
  55 ;;   an specific value (this includes the SUID, SGID and STI bits) you
  56 ;;   can use the key labeled as the letter you want.  Please note that
  57 ;;   permissions of the links cannot be changed in that way, because
  58 ;;   the change would affect to their targets, and this would not be
  59 ;;   WYSIWYG :-).
  60 ;;
  61 ;; - To mark files for deletion, by deleting their whole filename.
  62
  63 ;;; Installation:
  64
  65 ;; Add this file (byte-compiling it is recommended) to your load-path.
  66 ;; Then add one of these set of lines (or similar ones) to your config:
  67 ;;
  68 ;; This is the easy way:
  69 ;;
  70 ;; (require 'wdired)
  71 ;; (define-key dired-mode-map "r" 'wdired-change-to-wdired-mode)
  72 ;;
  73 ;; This is the recommended way for faster Emacs startup time and lower
  74 ;; memory consumption:
  75 ;;
  76 ;; (autoload 'wdired-change-to-wdired-mode "wdired")
  77 ;; (eval-after-load "dired"
  78 ;;           '(lambda ()
  79 ;;              (define-key dired-mode-map "r" 'wdired-change-to-wdired-mode)
  80 ;;              (define-key dired-mode-map
  81 ;;                [menu-bar immediate wdired-change-to-wdired-mode]
  82 ;;                '("Edit File Names" . wdired-change-to-wdired-mode))))
  83 ;;
  84 ;; Type "M-x customize-group RET wdired" if you want to make changes
  85 ;; to the default behavior.
  86
  87 ;;; Usage:
  88
  89 ;; Then, you can start editing the names of the files by typing "r"
  90 ;; (or whatever key you choose, or M-x wdired-change-to-wdired-mode).
  91 ;; Use C-c C-c when finished or C-c C-k to abort. You can use also the
  92 ;; menu options: in dired mode, "Edit File Names" under "Immediate".
  93 ;; While editing the names, a new submenu "WDired" is available at top
  94 ;; level. You can customize the behavior of this package from this
  95 ;; menu.
  96
  97 ;;; Change Log:
  98
  99 ;; Google is your friend (previous versions with complete changelogs
 100 ;; were posted to gnu.emacs.sources)
 101
 102 ;;; Code:
 103
 104 (defvar dired-backup-overwrite) ; Only in Emacs 20.x this is a custom var
 105
 106 (eval-when-compile (require 'cl))
 107 (require 'dired)
 108 (autoload 'dired-do-create-files-regexp "dired-aux")
 109
 110 (defgroup wdired nil
 111   "Mode to rename files by editing their names in dired buffers."
 112   :group 'dired)
 113
 114 (defcustom wdired-use-interactive-rename nil
 115   "If non-nil, WDired requires confirmation before actually renaming files.
 116 If nil, WDired doesn't require confirmation to change the file names,
 117 and the variable `wdired-confirm-overwrite' controls whether it is ok
 118 to overwrite files without asking."
 119   :type 'boolean
 120   :group 'wdired)
 121
 122 (defcustom wdired-confirm-overwrite t
 123   "If nil the renames can overwrite files without asking.
 124 This variable has no effect at all if `wdired-use-interactive-rename'
 125 is not nil."
 126   :type 'boolean
 127   :group 'wdired)
 128
 129 (defcustom wdired-use-dired-vertical-movement nil
 130   "If t, the \"up\" and \"down\" movement works as in Dired mode.
 131 That is, always move the point to the beginning of the filename at line.
 132
 133 If `sometimes', only move to the beginning of filename if the point is
 134 before it, and `track-eol' is non-nil.  This behavior is very handy
 135 when editing several filenames.
 136
 137 If nil, \"up\" and \"down\" movement is done as in any other buffer."
 138   :type '(choice (const :tag "As in any other mode" nil)
 139                  (const :tag "Smart cursor placement" sometimes)
 140                  (other :tag "As in dired mode" t))
 141   :group 'wdired)
 142
 143 (defcustom wdired-allow-to-redirect-links t
 144   "If non-nil, the target of the symbolic links are editable.
 145 In systems without symbolic links support, this variable has no effect
 146 at all."
 147   :type 'boolean
 148   :group 'wdired)
 149
 150 (defcustom wdired-allow-to-change-permissions nil
 151   "If non-nil, the permissions bits of the files are editable.
 152
 153 If t, to change a single bit, put the cursor over it and press the
 154 space bar, or left click over it.  You can also hit the letter you want
 155 to set: if this value is allowed, the character in the buffer will be
 156 changed.  Anyway, the point is advanced one position, so, for example,
 157 you can keep the <x> key pressed to give execution permissions to
 158 everybody to that file.
 159
 160 If `advanced', the bits are freely editable.  You can use
 161 `string-rectangle', `query-replace', etc.  You can put any value (even
 162 newlines), but if you want your changes to be useful, you better put a
 163 intelligible value.
 164
 165 Anyway, the real change of the permissions is done by the external
 166 program `dired-chmod-program', which must exist."
 167   :type '(choice (const :tag "Not allowed" nil)
 168                  (const :tag "Toggle/set bits" t)
 169                  (other :tag "Bits freely editable" advanced))
 170   :group 'wdired)
 171
 172 (defvar wdired-mode-map
 173   (let ((map (make-sparse-keymap)))
 174     (define-key map "\C-x\C-s" 'wdired-finish-edit)
 175     (define-key map "\C-c\C-c" 'wdired-finish-edit)
 176     (define-key map "\C-c\C-k" 'wdired-abort-changes)
 177     (define-key map "\C-c\C-[" 'wdired-abort-changes)
 178     (define-key map "\C-x\C-q" 'wdired-exit)
 179     (define-key map "\C-m"     'ignore)
 180     (define-key map "\C-j"     'ignore)
 181     (define-key map "\C-o"     'ignore)
 182     (define-key map [up]       'wdired-previous-line)
 183     (define-key map "\C-p"     'wdired-previous-line)
 184     (define-key map [down]     'wdired-next-line)
 185     (define-key map "\C-n"     'wdired-next-line)
 186
 187     (define-key map [menu-bar wdired]
 188       (cons "WDired" (make-sparse-keymap "WDired")))
 189     (define-key map [menu-bar wdired wdired-customize]
 190       '("Options" . wdired-customize))
 191     (define-key map [menu-bar wdired dashes]
 192       '("--"))
 193     (define-key map [menu-bar wdired wdired-abort-changes]
 194       '(menu-item "Abort Changes" wdired-abort-changes
 195                   :help "Abort changes and return to dired mode"))
 196     (define-key map [menu-bar wdired wdired-finish-edit]
 197       '("Commit Changes" . wdired-finish-edit))
 198
 199     (define-key map [remap upcase-word] 'wdired-upcase-word)
 200     (define-key map [remap capitalize-word] 'wdired-capitalize-word)
 201     (define-key map [remap downcase-word] 'wdired-downcase-word)
 202
 203     map))
 204
 205 (defvar wdired-mode-hook nil
 206   "Hooks run when changing to WDired mode.")
 207
 208 ;; Local variables (put here to avoid compilation gripes)
 209 (defvar wdired-col-perm) ;; Column where the permission bits start
 210 (defvar wdired-old-content)
 211 (defvar wdired-old-point)
 212
 213
 214 (defun wdired-mode ()
 215   "\\<wdired-mode-map>File Names Editing mode.
 216
 217 Press \\[wdired-finish-edit] to make the changes to take effect
 218 and exit.  To abort the edit, use \\[wdired-abort-changes].
 219
 220 In this mode you can edit the names of the files, the target of
 221 the links and the permission bits of the files.  You can use
 222 \\[customize-group] RET wdired to customize WDired behavior.
 223
 224 The only editable texts in a WDired buffer are filenames,
 225 symbolic link targets, and filenames permission."
 226   (interactive)
 227   (error "This mode can be enabled only by `wdired-change-to-wdired-mode'"))
 228 (put 'wdired-mode 'mode-class 'special)
 229
 230
 231 ;;;###autoload
 232 (defun wdired-change-to-wdired-mode ()
 233   "Put a dired buffer in a mode in which filenames are editable.
 234 \\<wdired-mode-map>
 235 This mode allows the user to change the names of the files, and after
 236 typing \\[wdired-finish-edit] Emacs renames the files and directories
 237 in disk.
 238
 239 See `wdired-mode'."
 240   (interactive)
 241   (or (eq major-mode 'dired-mode)
 242       (error "Not a Dired buffer"))
 243   (set (make-local-variable 'wdired-old-content)
 244        (buffer-substring (point-min) (point-max)))
 245   (set (make-local-variable 'wdired-old-point) (point))
 246   (set (make-local-variable 'query-replace-skip-read-only) t)
 247   (use-local-map wdired-mode-map)
 248   (force-mode-line-update)
 249   (setq buffer-read-only nil)
 250   (dired-unadvertise default-directory)
 251   (add-hook 'kill-buffer-hook 'wdired-check-kill-buffer nil t)
 252   (setq major-mode 'wdired-mode)
 253   (setq mode-name "Editable Dired")
 254   (setq revert-buffer-function 'wdired-revert)
 255   ;; I temp disable undo for performance: since I'm going to clear the
 256   ;; undo list, it can save more than a 9% of time with big
 257   ;; directories because setting properties modify the undo-list.
 258   (buffer-disable-undo)
 259   (wdired-preprocess-files)
 260   (if wdired-allow-to-change-permissions
 261       (wdired-preprocess-perms))
 262   (if (and wdired-allow-to-redirect-links (fboundp 'make-symbolic-link))
 263       (wdired-preprocess-symlinks))
 264   (buffer-enable-undo) ; Performance hack. See above.
 265   (set-buffer-modified-p nil)
 266   (setq buffer-undo-list nil)
 267   (run-mode-hooks 'wdired-mode-hook)
 268   (message "%s" (substitute-command-keys
 269                  "Press \\[wdired-finish-edit] when finished \
 270 or \\[wdired-abort-changes] to abort changes")))
 271
 272
 273 ;; Protect the buffer so only the filenames can be changed, and put
 274 ;; properties so filenames (old and new) can be easily found.
 275 (defun wdired-preprocess-files ()
 276   (put-text-property 1 2 'front-sticky t)
 277   (save-excursion
 278     (goto-char (point-min))
 279     (let ((b-protection (point))
 280           filename)
 281       (while (not (eobp))
 282         (setq filename (dired-get-filename nil t))
 283         (when (and filename
 284                    (not (member (file-name-nondirectory filename) '("." ".."))))
 285           (dired-move-to-filename)
 286           ;; The rear-nonsticky property below shall ensure that text preceding
 287           ;; the filename can't be modified.
 288           (add-text-properties
 289            (1- (point)) (point) `(old-name ,filename rear-nonsticky (read-only)))
 290           (put-text-property b-protection (point) 'read-only t)
 291           (setq b-protection (dired-move-to-end-of-filename t))
 292           (put-text-property (point) (1+ (point)) 'end-name t))
 293         (forward-line))
 294       (put-text-property b-protection (point-max) 'read-only t))))
 295
 296 ;; This code is a copy of some dired-get-filename lines.
 297 (defsubst wdired-normalize-filename (file)
 298   (setq file
 299         ;; FIXME: shouldn't we check for a `b' argument or somesuch before
 300         ;; doing such unquoting?  --Stef
 301         (read (concat
 302                "\"" (replace-regexp-in-string
 303                      "\\([^\\]\\|\\`\\)\"" "\\1\\\\\"" file)
 304                "\"")))
 305   (and file buffer-file-coding-system
 306        (not file-name-coding-system)
 307        (not default-file-name-coding-system)
 308        (setq file (encode-coding-string file buffer-file-coding-system)))
 309   file)
 310
 311 (defun wdired-get-filename (&optional no-dir old)
 312   "Return the filename at line.
 313 Similar to `dired-get-filename' but it doesn't rely on regexps.  It
 314 relies on WDired buffer's properties.  Optional arg NO-DIR with value
 315 non-nil means don't include directory.  Optional arg OLD with value
 316 non-nil means return old filename."
 317   ;; FIXME: Use dired-get-filename's new properties.
 318   (let (beg end file)
 319     (save-excursion
 320       (setq end (line-end-position))
 321       (beginning-of-line)
 322       (setq beg (next-single-property-change (point) 'old-name nil end))
 323       (unless (eq beg end)
 324         (if old
 325             (setq file (get-text-property beg 'old-name))
 326           ;; In the following form changed `(1+ beg)' to `beg' so that
 327           ;; the filename end is found even when the filename is empty.
 328           ;; Fixes error and spurious newlines when marking files for
 329           ;; deletion.
 330           (setq end (next-single-property-change beg 'end-name))
 331           (setq file (buffer-substring-no-properties (1+ beg) end)))
 332         (and file (setq file (wdired-normalize-filename file))))
 333       (if (or no-dir old)
 334           file
 335         (and file (> (length file) 0)
 336              (concat (dired-current-directory) file))))))
 337
 338
 339 (defun wdired-change-to-dired-mode ()
 340   "Change the mode back to dired."
 341   (or (eq major-mode 'wdired-mode)
 342       (error "Not a Wdired buffer"))
 343   (let ((inhibit-read-only t))
 344     (remove-text-properties
 345      (point-min) (point-max)
 346      '(front-sticky nil rear-nonsticky nil read-only nil keymap nil)))
 347   (use-local-map dired-mode-map)
 348   (force-mode-line-update)
 349   (setq buffer-read-only t)
 350   (setq major-mode 'dired-mode)
 351   (setq mode-name "Dired")
 352   (dired-advertise)
 353   (remove-hook 'kill-buffer-hook 'wdired-check-kill-buffer t)
 354   (set (make-local-variable 'revert-buffer-function) 'dired-revert))
 355
 356
 357 (defun wdired-abort-changes ()
 358   "Abort changes and return to dired mode."
 359   (interactive)
 360   (let ((inhibit-read-only t))
 361     (erase-buffer)
 362     (insert wdired-old-content)
 363     (goto-char wdired-old-point))
 364   (wdired-change-to-dired-mode)
 365   (set-buffer-modified-p nil)
 366   (setq buffer-undo-list nil)
 367   (message "Changes aborted"))
 368
 369 (defun wdired-finish-edit ()
 370   "Actually rename files based on your editing in the Dired buffer."
 371   (interactive)
 372   (wdired-change-to-dired-mode)
 373   (let ((overwrite (or (not wdired-confirm-overwrite) 1))
 374         (changes nil)
 375         (files-deleted nil)
 376         (errors 0)
 377         file-ori file-new tmp-value)
 378     (save-excursion
 379       (when (and wdired-allow-to-redirect-links
 380                  (fboundp 'make-symbolic-link))
 381         (setq tmp-value (wdired-do-symlink-changes))
 382         (setq errors (cdr tmp-value))
 383         (setq changes (car tmp-value)))
 384       (when (and wdired-allow-to-change-permissions
 385                  (boundp 'wdired-col-perm)) ; could have been changed
 386         (setq tmp-value (wdired-do-perm-changes))
 387         (setq errors (+ errors (cdr tmp-value)))
 388         (setq changes (or changes (car tmp-value))))
 389       (goto-char (point-max))
 390       (while (not (bobp))
 391         (setq file-ori (wdired-get-filename nil t))
 392         (when file-ori
 393           (setq file-new (wdired-get-filename)))
 394         (when (and file-ori (not (equal file-new file-ori)))
 395           (setq changes t)
 396           (if (not file-new)            ;empty filename!
 397               (setq files-deleted (cons file-ori files-deleted))
 398             (setq file-new (substitute-in-file-name file-new))
 399             (if wdired-use-interactive-rename
 400                 (wdired-search-and-rename file-ori file-new)
 401               ;; If dired-rename-file autoloads dired-aux while
 402               ;; dired-backup-overwrite is locally bound,
 403               ;; dired-backup-overwrite won't be initialized.
 404               ;; So we must ensure dired-aux is loaded.
 405               (require 'dired-aux)
 406               (condition-case err
 407                   (let ((dired-backup-overwrite nil))
 408                     (dired-rename-file file-ori file-new
 409                                        overwrite))
 410                 (error
 411                  (setq errors (1+ errors))
 412                  (dired-log (concat "Rename `" file-ori "' to `"
 413                                     file-new "' failed:\n%s\n")
 414                             err))))))
 415         (forward-line -1)))
 416     (if changes
 417         (revert-buffer) ;The "revert" is necessary to re-sort the buffer
 418       (let ((inhibit-read-only t))
 419         (remove-text-properties (point-min) (point-max)
 420                                 '(old-name nil end-name nil old-link nil
 421                                            end-link nil end-perm nil
 422                                            old-perm nil perm-changed nil))
 423         (message "(No changes to be performed)")))
 424     (when files-deleted
 425       (wdired-flag-for-deletion files-deleted))
 426     (when (> errors 0)
 427       (dired-log-summary (format "%d rename actions failed" errors) nil)))
 428   (set-buffer-modified-p nil)
 429   (setq buffer-undo-list nil))
 430
 431 (defun wdired-exit ()
 432   "Exit wdired and return to dired mode.
 433 Just return to dired mode if there are no changes.  Otherwise,
 434 ask a yes-or-no question whether to save or cancel changes,
 435 and proceed depending on the answer."
 436   (interactive)
 437   (if (buffer-modified-p)
 438       (if (y-or-n-p (format "Buffer %s modified; save changes? "
 439                             (current-buffer)))
 440           (wdired-finish-edit)
 441         (wdired-abort-changes))
 442     (wdired-change-to-dired-mode)
 443     (set-buffer-modified-p nil)
 444     (setq buffer-undo-list nil)
 445     (message "(No changes need to be saved)")))
 446
 447 ;; Rename a file, searching it in a modified dired buffer, in order
 448 ;; to be able to use `dired-do-create-files-regexp' and get its
 449 ;; "benefits".
 450 (defun wdired-search-and-rename (filename-ori filename-new)
 451   (save-excursion
 452     (goto-char (point-max))
 453     (forward-line -1)
 454     (let ((exit-while nil)
 455           curr-filename)
 456       (while (not exit-while)
 457         (setq curr-filename (wdired-get-filename))
 458         (if (and curr-filename
 459                  (equal (substitute-in-file-name curr-filename) filename-new))
 460             (progn
 461               (setq exit-while t)
 462               (let ((inhibit-read-only t))
 463                 (dired-move-to-filename)
 464                 (search-forward (wdired-get-filename t) nil t)
 465                 (replace-match (file-name-nondirectory filename-ori) t t))
 466               (dired-do-create-files-regexp
 467                (function dired-rename-file)
 468                "Move" 1 ".*" filename-new nil t))
 469           (forward-line -1)
 470           (beginning-of-line)
 471           (setq exit-while (bobp)))))))
 472
 473 ;; marks a list of files for deletion
 474 (defun wdired-flag-for-deletion (filenames-ori)
 475   (save-excursion
 476     (goto-char (point-min))
 477     (while (not (eobp))
 478       (if (member (dired-get-filename nil t) filenames-ori)
 479           (dired-flag-file-deletion 1)
 480         (forward-line)))))
 481
 482 (defun wdired-customize ()
 483   "Customize WDired options."
 484   (interactive)
 485   (customize-apropos "wdired" 'groups))
 486
 487 (defun wdired-revert (&optional arg noconfirm)
 488   "Discard changes in the buffer and update it based on changes on disk.
 489 Optional arguments are ignored."
 490   (wdired-change-to-dired-mode)
 491   (revert-buffer)
 492   (wdired-change-to-wdired-mode))
 493
 494 (defun wdired-check-kill-buffer ()
 495   ;; FIXME: Can't we use the normal mechanism for that?  --Stef
 496   (if (and
 497        (buffer-modified-p)
 498        (not (y-or-n-p "Buffer changed. Discard changes and kill buffer? ")))
 499       (error "Error.")))
 500
 501 (defun wdired-next-line (arg)
 502   "Move down lines then position at filename or the current column.
 503 See `wdired-use-dired-vertical-movement'.  Optional prefix ARG
 504 says how many lines to move; default is one line."
 505   (interactive "p")
 506   (with-no-warnings (next-line arg))
 507   (if (or (eq wdired-use-dired-vertical-movement t)
 508           (and wdired-use-dired-vertical-movement
 509                (< (current-column)
 510                   (save-excursion (dired-move-to-filename)
 511                                   (current-column)))))
 512       (dired-move-to-filename)))
 513
 514 (defun wdired-previous-line (arg)
 515   "Move up lines then position at filename or the current column.
 516 See `wdired-use-dired-vertical-movement'.  Optional prefix ARG
 517 says how many lines to move; default is one line."
 518   (interactive "p")
 519   (with-no-warnings (previous-line arg))
 520   (if (or (eq wdired-use-dired-vertical-movement t)
 521           (and wdired-use-dired-vertical-movement
 522                (< (current-column)
 523                   (save-excursion (dired-move-to-filename)
 524                                   (current-column)))))
 525       (dired-move-to-filename)))
 526
 527 ;; Put the needed properties to allow the user to change links' targets
 528 (defun wdired-preprocess-symlinks ()
 529   (let ((inhibit-read-only t))
 530     (save-excursion
 531       (goto-char (point-min))
 532       (while (not (eobp))
 533         (if (looking-at dired-re-sym)
 534             (progn
 535               (re-search-forward " -> \\(.*\\)$")
 536               (put-text-property (- (match-beginning 1) 2)
 537                                  (1- (match-beginning 1)) 'old-link
 538                                  (match-string-no-properties 1))
 539               (put-text-property (match-end 1) (1+ (match-end 1)) 'end-link t)
 540               (put-text-property (1- (match-beginning 1))
 541                                  (match-beginning 1)
 542                                  'rear-nonsticky '(read-only))
 543               (put-text-property (match-beginning 1)
 544                                  (match-end 1) 'read-only nil)))
 545         (forward-line)
 546         (beginning-of-line)))))
 547
 548
 549 (defun wdired-get-previous-link (&optional old move)
 550   "Return the next symlink target.
 551 If OLD, return the old target.  If MOVE, move point before it."
 552   (let (beg end target)
 553     (setq beg (previous-single-property-change (point) 'old-link nil))
 554     (if beg
 555         (progn
 556           (if old
 557               (setq target (get-text-property (1- beg) 'old-link))
 558             (setq end (next-single-property-change beg 'end-link))
 559             (setq target (buffer-substring-no-properties (1+ beg) end)))
 560           (if move (goto-char (1- beg)))))
 561     (and target (wdired-normalize-filename target))))
 562
 563 (declare-function make-symbolic-link "fileio.c")
 564
 565 ;; Perform the changes in the target of the changed links.
 566 (defun wdired-do-symlink-changes ()
 567   (let ((changes nil)
 568         (errors 0)
 569         link-to-ori link-to-new link-from)
 570     (goto-char (point-max))
 571     (while (setq link-to-new (wdired-get-previous-link))
 572       (setq link-to-ori (wdired-get-previous-link t t))
 573       (setq link-from (wdired-get-filename nil t))
 574       (unless (equal link-to-new link-to-ori)
 575         (setq changes t)
 576         (if (equal link-to-new "") ;empty filename!
 577             (setq link-to-new "/dev/null"))
 578         (condition-case err
 579             (progn
 580               (delete-file link-from)
 581               (make-symbolic-link
 582                (substitute-in-file-name link-to-new) link-from))
 583           (error
 584            (setq errors (1+ errors))
 585            (dired-log (concat "Link `" link-from "' to `"
 586                               link-to-new "' failed:\n%s\n")
 587                       err)))))
 588     (cons changes errors)))
 589
 590 ;; Perform a "case command" skipping read-only words.
 591 (defun wdired-xcase-word (command arg)
 592   (if (< arg 0)
 593       (funcall command arg)
 594     (while (> arg 0)
 595       (condition-case err
 596           (progn
 597             (funcall command 1)
 598             (setq arg (1- arg)))
 599         (error
 600          (if (forward-word)
 601              ;; Skip any non-word characters to avoid triggering a read-only
 602              ;; error which would cause skipping the next word characters too.
 603              (skip-syntax-forward "^w")
 604            (setq arg 0)))))))
 605
 606 (defun wdired-downcase-word (arg)
 607   "WDired version of `downcase-word'.
 608 Like original function but it skips read-only words."
 609   (interactive "p")
 610   (wdired-xcase-word 'downcase-word arg))
 611
 612 (defun wdired-upcase-word (arg)
 613   "WDired version of `upcase-word'.
 614 Like original function but it skips read-only words."
 615   (interactive "p")
 616   (wdired-xcase-word 'upcase-word arg))
 617
 618 (defun wdired-capitalize-word (arg)
 619   "WDired version of `capitalize-word'.
 620 Like original function but it skips read-only words."
 621   (interactive "p")
 622   (wdired-xcase-word 'capitalize-word arg))
 623
 624
 625 ;; The following code deals with changing the access bits (or
 626 ;; permissions) of the files.
 627
 628 (defvar wdired-perm-mode-map
 629   (let ((map (make-sparse-keymap)))
 630     (define-key map " " 'wdired-toggle-bit)
 631     (define-key map "r" 'wdired-set-bit)
 632     (define-key map "w" 'wdired-set-bit)
 633     (define-key map "x" 'wdired-set-bit)
 634     (define-key map "-" 'wdired-set-bit)
 635     (define-key map "S" 'wdired-set-bit)
 636     (define-key map "s" 'wdired-set-bit)
 637     (define-key map "T" 'wdired-set-bit)
 638     (define-key map "t" 'wdired-set-bit)
 639     (define-key map "s" 'wdired-set-bit)
 640     (define-key map "l" 'wdired-set-bit)
 641     (define-key map [down-mouse-1] 'wdired-mouse-toggle-bit)
 642     map))
 643
 644 ;; Put a keymap property to the permission bits of the files, and store the
 645 ;; original name and permissions as a property
 646 (defun wdired-preprocess-perms ()
 647   (let ((inhibit-read-only t))
 648     (set (make-local-variable 'wdired-col-perm) nil)
 649     (save-excursion
 650       (goto-char (point-min))
 651       (while (not (eobp))
 652         (when (and (not (looking-at dired-re-sym))
 653                    (wdired-get-filename)
 654                    (re-search-forward dired-re-perms (line-end-position) 'eol))
 655           (let ((begin (match-beginning 0))
 656                 (end (match-end 0)))
 657             (unless wdired-col-perm
 658               (setq wdired-col-perm (- (current-column) 9)))
 659             (if (eq wdired-allow-to-change-permissions 'advanced)
 660                 (progn
 661                   (put-text-property begin end 'read-only nil)
 662                   ;; make first permission bit writable
 663                   (put-text-property
 664                    (1- begin) begin 'rear-nonsticky '(read-only)))
 665               ;; avoid that keymap applies to text following permissions
 666               (add-text-properties
 667                (1+ begin) end
 668                `(keymap ,wdired-perm-mode-map rear-nonsticky (keymap))))
 669             (put-text-property end (1+ end) 'end-perm t)
 670             (put-text-property
 671              begin (1+ begin) 'old-perm (match-string-no-properties 0))))
 672         (forward-line)
 673         (beginning-of-line)))))
 674
 675 (defun wdired-perm-allowed-in-pos (char pos)
 676   (cond
 677    ((= char ?-)          t)
 678    ((= char ?r)          (= (% pos 3) 0))
 679    ((= char ?w)          (= (% pos 3) 1))
 680    ((= char ?x)          (= (% pos 3) 2))
 681    ((memq char '(?s ?S)) (memq pos '(2 5)))
 682    ((memq char '(?t ?T)) (= pos 8))
 683    ((= char ?l)          (= pos 5))))
 684
 685 (defun wdired-set-bit ()
 686   "Set a permission bit character."
 687   (interactive)
 688   (if (wdired-perm-allowed-in-pos last-command-char
 689                                   (- (current-column) wdired-col-perm))
 690       (let ((new-bit (char-to-string last-command-char))
 691             (inhibit-read-only t)
 692             (pos-prop (- (point) (- (current-column) wdired-col-perm))))
 693         (put-text-property 0 1 'keymap wdired-perm-mode-map new-bit)
 694         (put-text-property 0 1 'read-only t new-bit)
 695         (insert new-bit)
 696         (delete-char 1)
 697         (put-text-property (1- pos-prop) pos-prop 'perm-changed t)
 698         (put-text-property (1- (point)) (point) 'rear-nonsticky '(keymap)))
 699     (forward-char 1)))
 700
 701 (defun wdired-toggle-bit ()
 702   "Toggle the permission bit at point."
 703   (interactive)
 704   (let ((inhibit-read-only t)
 705         (new-bit "-")
 706         (pos-prop (- (point) (- (current-column) wdired-col-perm))))
 707     (if (eq (char-after (point)) ?-)
 708         (setq new-bit
 709               (if (= (% (- (current-column) wdired-col-perm) 3) 0) "r"
 710                 (if (= (% (- (current-column) wdired-col-perm) 3) 1) "w"
 711                   "x"))))
 712     (put-text-property 0 1 'keymap wdired-perm-mode-map new-bit)
 713     (put-text-property 0 1 'read-only t new-bit)
 714     (insert new-bit)
 715     (delete-char 1)
 716     (put-text-property (1- pos-prop) pos-prop 'perm-changed t)
 717     (put-text-property (1- (point)) (point) 'rear-nonsticky '(keymap))))
 718
 719 (defun wdired-mouse-toggle-bit (event)
 720   "Toggle the permission bit that was left clicked."
 721   (interactive "e")
 722   (mouse-set-point event)
 723   (wdired-toggle-bit))
 724
 725 ;; Allowed chars for 4000 bit are Ss  in position 3
 726 ;; Allowed chars for 2000 bit are Ssl in position 6
 727 ;; Allowed chars for 1000 bit are Tt  in position 9
 728 (defun wdired-perms-to-number (perms)
 729   (let ((nperm 0777))
 730     (if (= (elt perms 1) ?-) (setq nperm (- nperm 400)))
 731     (if (= (elt perms 2) ?-) (setq nperm (- nperm 200)))
 732     (let ((p-bit (elt perms 3)))
 733       (if (memq p-bit '(?- ?S)) (setq nperm (- nperm 100)))
 734       (if (memq p-bit '(?s ?S)) (setq nperm (+ nperm 4000))))
 735     (if (= (elt perms 4) ?-) (setq nperm (- nperm 40)))
 736     (if (= (elt perms 5) ?-) (setq nperm (- nperm 20)))
 737     (let ((p-bit (elt perms 6)))
 738       (if (memq p-bit '(?- ?S ?l)) (setq nperm (- nperm 10)))
 739       (if (memq p-bit '(?s ?S ?l)) (setq nperm (+ nperm 2000))))
 740     (if (= (elt perms 7) ?-) (setq nperm (- nperm 4)))
 741     (if (= (elt perms 8) ?-) (setq nperm (- nperm 2)))
 742     (let ((p-bit (elt perms 9)))
 743       (if (memq p-bit '(?- ?T)) (setq nperm (- nperm 1)))
 744       (if (memq p-bit '(?t ?T)) (setq nperm (+ nperm 1000))))
 745     nperm))
 746
 747 ;; Perform the changes in the permissions of the files that have
 748 ;; changed.
 749 (defun wdired-do-perm-changes ()
 750   (let ((changes nil)
 751         (errors 0)
 752         (prop-wanted (if (eq wdired-allow-to-change-permissions 'advanced)
 753                          'old-perm 'perm-changed))
 754         filename perms-ori perms-new perm-tmp)
 755     (goto-char (next-single-property-change (point-min) prop-wanted
 756                                             nil (point-max)))
 757     (while (not (eobp))
 758       (setq perms-ori (get-text-property (point) 'old-perm))
 759       (setq perms-new (buffer-substring-no-properties
 760                        (point) (next-single-property-change (point) 'end-perm)))
 761       (unless (equal perms-ori perms-new)
 762         (setq changes t)
 763         (setq filename (wdired-get-filename nil t))
 764         (if (= (length perms-new) 10)
 765             (progn
 766               (setq perm-tmp
 767                     (int-to-string (wdired-perms-to-number perms-new)))
 768               (unless (equal 0 (process-file dired-chmod-program
 769                                              nil nil nil perm-tmp filename))
 770                 (setq errors (1+ errors))
 771                 (dired-log (concat dired-chmod-program " " perm-tmp
 772                                    " `" filename "' failed\n\n"))))
 773           (setq errors (1+ errors))
 774           (dired-log (concat "Cannot parse permission `" perms-new
 775                              "' for file `" filename "'\n\n"))))
 776       (goto-char (next-single-property-change (1+ (point)) prop-wanted
 777                                               nil (point-max))))
 778     (cons changes errors)))
 779
 780 (provide 'wdired)
 781
 782 ;; Local Variables:
 783 ;; coding: latin-1
 784 ;; byte-compile-dynamic: t
 785 ;; End:
 786
 787 ;; arch-tag: bc00902e-526f-4305-bc7f-8862a559184f
 788 ;;; wdired.el ends here