lisp/net/tramp-gvfs.el

   1 ;;; tramp-gvfs.el --- Tramp access functions for GVFS daemon
   2
   3 ;; Copyright (C) 2009-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Michael Albinus <michael.albinus@gmx.de>
   6 ;; Keywords: comm, processes
   7 ;; Package: tramp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Access functions for the GVFS daemon from Tramp.  Tested with GVFS
  27 ;; 1.0 (Ubuntu 8.10, Gnome 2.24).  It has been reported also to run
  28 ;; with GVFS 0.2.5 (Ubuntu 8.04, Gnome 2.22), but there is an
  29 ;; incompatibility with the mount_info structure, which has been
  30 ;; worked around.
  31
  32 ;; It has also been tested with GVFS 1.6 (Ubuntu 10.04, Gnome 2.30),
  33 ;; where the default_location has been added to mount_info (see
  34 ;; <https://bugzilla.gnome.org/show_bug.cgi?id=561998>.
  35
  36 ;; With GVFS 1.14 (Ubuntu 12.10, Gnome 3.6) the interfaces have been
  37 ;; changed, again.  So we must introspect the D-Bus interfaces.
  38
  39 ;; All actions to mount a remote location, and to retrieve mount
  40 ;; information, are performed by D-Bus messages.  File operations
  41 ;; themselves are performed via the mounted filesystem in ~/.gvfs.
  42 ;; Consequently, GNU Emacs 23.1 with enabled D-Bus bindings is a
  43 ;; precondition.
  44
  45 ;; The GVFS D-Bus interface is said to be unstable.  There were even
  46 ;; no introspection data before GVFS 1.14.  The interface, as
  47 ;; discovered during development time, is given in respective
  48 ;; comments.
  49
  50 ;; The customer option `tramp-gvfs-methods' contains the list of
  51 ;; supported connection methods.  Per default, these are "dav",
  52 ;; "davs", "obex", "sftp" and "synce".  Note that with "obex" it might
  53 ;; be necessary to pair with the other bluetooth device, if it hasn't
  54 ;; been done already.  There might be also some few seconds delay in
  55 ;; discovering available bluetooth devices.
  56
  57 ;; Other possible connection methods are "ftp" and "smb".  When one of
  58 ;; these methods is added to the list, the remote access for that
  59 ;; method is performed via GVFS instead of the native Tramp
  60 ;; implementation.
  61
  62 ;; GVFS offers even more connection methods.  The complete list of
  63 ;; connection methods of the actual GVFS implementation can be
  64 ;; retrieved by:
  65 ;;
  66 ;; (message
  67 ;;  "%s"
  68 ;;  (mapcar
  69 ;;   'car
  70 ;;   (dbus-call-method
  71 ;;    :session tramp-gvfs-service-daemon tramp-gvfs-path-mounttracker
  72 ;;    tramp-gvfs-interface-mounttracker "listMountableInfo")))
  73
  74 ;; Note that all other connection methods are not tested, beside the
  75 ;; ones offered for customization in `tramp-gvfs-methods'.  If you
  76 ;; request an additional connection method to be supported, please
  77 ;; drop me a note.
  78
  79 ;; For hostname completion, information is retrieved either from the
  80 ;; bluez daemon (for the "obex" method), the hal daemon (for the
  81 ;; "synce" method), or from the zeroconf daemon (for the "dav",
  82 ;; "davs", and "sftp" methods).  The zeroconf daemon is pre-configured
  83 ;; to discover services in the "local" domain.  If another domain
  84 ;; shall be used for discovering services, the customer option
  85 ;; `tramp-gvfs-zeroconf-domain' can be set accordingly.
  86
  87 ;; Restrictions:
  88
  89 ;; * The current GVFS implementation does not allow to write on the
  90 ;;   remote bluetooth device via OBEX.
  91 ;;
  92 ;; * Two shares of the same SMB server cannot be mounted in parallel.
  93
  94 ;;; Code:
  95
  96 ;; D-Bus support in the Emacs core can be disabled with configuration
  97 ;; option "--without-dbus".  Declare used subroutines and variables.
  98 (declare-function dbus-get-unique-name "dbusbind.c")
  99
 100 (require 'tramp)
 101
 102 (require 'dbus)
 103 (require 'url-parse)
 104 (require 'url-util)
 105 (require 'zeroconf)
 106
 107 ;; Pacify byte-compiler.
 108 (eval-when-compile
 109   (require 'cl)
 110   (require 'custom))
 111
 112 ;;;###tramp-autoload
 113 (defcustom tramp-gvfs-methods '("dav" "davs" "obex" "sftp" "synce")
 114   "List of methods for remote files, accessed with GVFS."
 115   :group 'tramp
 116   :version "23.2"
 117   :type '(repeat (choice (const "dav")
 118                          (const "davs")
 119                          (const "ftp")
 120                          (const "obex")
 121                          (const "sftp")
 122                          (const "smb")
 123                          (const "synce"))))
 124
 125 ;; Add a default for `tramp-default-user-alist'.  Rule: For the SYNCE
 126 ;; method, no user is chosen.
 127 ;;;###tramp-autoload
 128 (add-to-list 'tramp-default-user-alist '("\\`synce\\'" nil nil))
 129
 130 ;;;###tramp-autoload
 131 (defcustom tramp-gvfs-zeroconf-domain "local"
 132   "Zeroconf domain to be used for discovering services, like host names."
 133   :group 'tramp
 134   :version "23.2"
 135   :type 'string)
 136
 137 ;; Add the methods to `tramp-methods', in order to allow minibuffer
 138 ;; completion.
 139 ;;;###tramp-autoload
 140 (when (featurep 'dbusbind)
 141   (dolist (elt tramp-gvfs-methods)
 142     (unless (assoc elt tramp-methods)
 143       (add-to-list 'tramp-methods (cons elt nil)))))
 144
 145 (defconst tramp-gvfs-path-tramp (concat dbus-path-emacs "/Tramp")
 146   "The preceding object path for own objects.")
 147
 148 (defconst tramp-gvfs-service-daemon "org.gtk.vfs.Daemon"
 149   "The well known name of the GVFS daemon.")
 150
 151 ;; D-Bus integration is available since Emacs 23 on some system types.
 152 ;; We don't call `dbus-ping', because this would load dbus.el.
 153 (defconst tramp-gvfs-enabled
 154   (ignore-errors
 155     (and (featurep 'dbusbind)
 156          (tramp-compat-funcall 'dbus-get-unique-name :system)
 157          (tramp-compat-funcall 'dbus-get-unique-name :session)
 158          (or (tramp-compat-process-running-p "gvfs-fuse-daemon")
 159              (tramp-compat-process-running-p "gvfsd-fuse"))))
 160   "Non-nil when GVFS is available.")
 161
 162 (defconst tramp-gvfs-path-mounttracker "/org/gtk/vfs/mounttracker"
 163   "The object path of the GVFS daemon.")
 164
 165 (defconst tramp-gvfs-interface-mounttracker "org.gtk.vfs.MountTracker"
 166   "The mount tracking interface in the GVFS daemon.")
 167
 168 ;; Introspection data exist since GVFS 1.14.  If there are no such
 169 ;; data, we expect an earlier interface.
 170 (defconst tramp-gvfs-methods-mounttracker
 171   (and tramp-gvfs-enabled
 172        (dbus-introspect-get-method-names
 173         :session tramp-gvfs-service-daemon tramp-gvfs-path-mounttracker
 174         tramp-gvfs-interface-mounttracker))
 175   "The list of supported methods of the mount tracking interface.")
 176
 177 (defconst tramp-gvfs-listmounts
 178   (if (member "ListMounts" tramp-gvfs-methods-mounttracker)
 179       "ListMounts"
 180     "listMounts")
 181   "The name of the \"listMounts\" method.
 182 It has been changed in GVFS 1.14.")
 183
 184 (defconst tramp-gvfs-mountlocation
 185   (if (member "MountLocation" tramp-gvfs-methods-mounttracker)
 186       "MountLocation"
 187     "mountLocation")
 188   "The name of the \"mountLocation\" method.
 189 It has been changed in GVFS 1.14.")
 190
 191 (defconst tramp-gvfs-mountlocation-signature
 192   (and tramp-gvfs-enabled
 193        (dbus-introspect-get-signature
 194         :session tramp-gvfs-service-daemon tramp-gvfs-path-mounttracker
 195         tramp-gvfs-interface-mounttracker tramp-gvfs-mountlocation))
 196   "The D-Bus signature of the \"mountLocation\" method.
 197 It has been changed in GVFS 1.14.")
 198
 199 ;; <interface name='org.gtk.vfs.MountTracker'>
 200 ;;   <method name='listMounts'>
 201 ;;     <arg name='mount_info_list'
 202 ;;          type='a{sosssssbay{aya{say}}ay}'
 203 ;;          direction='out'/>
 204 ;;   </method>
 205 ;;   <method name='mountLocation'>
 206 ;;     <arg name='mount_spec'  type='{aya{say}}' direction='in'/>
 207 ;;     <arg name='dbus_id'     type='s'          direction='in'/>
 208 ;;     <arg name='object_path' type='o'          direction='in'/>
 209 ;;   </method>
 210 ;;   <signal name='mounted'>
 211 ;;     <arg name='mount_info'
 212 ;;          type='{sosssssbay{aya{say}}ay}'/>
 213 ;;   </signal>
 214 ;;   <signal name='unmounted'>
 215 ;;     <arg name='mount_info'
 216 ;;          type='{sosssssbay{aya{say}}ay}'/>
 217 ;;   </signal>
 218 ;; </interface>
 219 ;;
 220 ;; STRUCT               mount_info
 221 ;;   STRING               dbus_id
 222 ;;   OBJECT_PATH          object_path
 223 ;;   STRING               display_name
 224 ;;   STRING               stable_name
 225 ;;   STRING               x_content_types       Since GVFS 1.0 only !!!
 226 ;;   STRING               icon
 227 ;;   STRING               preferred_filename_encoding
 228 ;;   BOOLEAN              user_visible
 229 ;;   ARRAY BYTE           fuse_mountpoint
 230 ;;   STRUCT               mount_spec
 231 ;;     ARRAY BYTE           mount_prefix
 232 ;;     ARRAY
 233 ;;       STRUCT             mount_spec_item
 234 ;;         STRING             key (server, share, type, user, host, port)
 235 ;;         ARRAY BYTE         value
 236 ;;   ARRAY BYTE           default_location      Since GVFS 1.5 only !!!
 237
 238 (defconst tramp-gvfs-interface-mountoperation "org.gtk.vfs.MountOperation"
 239   "Used by the dbus-proxying implementation of GMountOperation.")
 240
 241 ;; <interface name='org.gtk.vfs.MountOperation'>
 242 ;;   <method name='askPassword'>
 243 ;;     <arg name='message'        type='s' direction='in'/>
 244 ;;     <arg name='default_user'   type='s' direction='in'/>
 245 ;;     <arg name='default_domain' type='s' direction='in'/>
 246 ;;     <arg name='flags'          type='u' direction='in'/>
 247 ;;     <arg name='handled'        type='b' direction='out'/>
 248 ;;     <arg name='aborted'        type='b' direction='out'/>
 249 ;;     <arg name='password'       type='s' direction='out'/>
 250 ;;     <arg name='username'       type='s' direction='out'/>
 251 ;;     <arg name='domain'         type='s' direction='out'/>
 252 ;;     <arg name='anonymous'      type='b' direction='out'/>
 253 ;;     <arg name='password_save'  type='u' direction='out'/>
 254 ;;   </method>
 255 ;;   <method name='askQuestion'>
 256 ;;     <arg name='message' type='s'  direction='in'/>
 257 ;;     <arg name='choices' type='as' direction='in'/>
 258 ;;     <arg name='handled' type='b'  direction='out'/>
 259 ;;     <arg name='aborted' type='b'  direction='out'/>
 260 ;;     <arg name='choice'  type='u'  direction='out'/>
 261 ;;   </method>
 262 ;; </interface>
 263
 264 ;; The following flags are used in "askPassword".  They are defined in
 265 ;; /usr/include/glib-2.0/gio/gioenums.h.
 266
 267 (defconst tramp-gvfs-password-need-password 1
 268   "Operation requires a password.")
 269
 270 (defconst tramp-gvfs-password-need-username 2
 271   "Operation requires a username.")
 272
 273 (defconst tramp-gvfs-password-need-domain 4
 274   "Operation requires a domain.")
 275
 276 (defconst tramp-gvfs-password-saving-supported 8
 277   "Operation supports saving settings.")
 278
 279 (defconst tramp-gvfs-password-anonymous-supported 16
 280   "Operation supports anonymous users.")
 281
 282 (defconst tramp-bluez-service "org.bluez"
 283   "The well known name of the BLUEZ service.")
 284
 285 (defconst tramp-bluez-interface-manager "org.bluez.Manager"
 286   "The manager interface of the BLUEZ daemon.")
 287
 288 ;; <interface name='org.bluez.Manager'>
 289 ;;   <method name='DefaultAdapter'>
 290 ;;     <arg type='o' direction='out'/>
 291 ;;   </method>
 292 ;;   <method name='FindAdapter'>
 293 ;;     <arg type='s' direction='in'/>
 294 ;;     <arg type='o' direction='out'/>
 295 ;;   </method>
 296 ;;   <method name='ListAdapters'>
 297 ;;     <arg type='ao' direction='out'/>
 298 ;;   </method>
 299 ;;   <signal name='AdapterAdded'>
 300 ;;     <arg type='o'/>
 301 ;;   </signal>
 302 ;;   <signal name='AdapterRemoved'>
 303 ;;     <arg type='o'/>
 304 ;;   </signal>
 305 ;;   <signal name='DefaultAdapterChanged'>
 306 ;;     <arg type='o'/>
 307 ;;   </signal>
 308 ;; </interface>
 309
 310 (defconst tramp-bluez-interface-adapter "org.bluez.Adapter"
 311   "The adapter interface of the BLUEZ daemon.")
 312
 313 ;; <interface name='org.bluez.Adapter'>
 314 ;;   <method name='GetProperties'>
 315 ;;     <arg type='a{sv}' direction='out'/>
 316 ;;   </method>
 317 ;;   <method name='SetProperty'>
 318 ;;     <arg type='s' direction='in'/>
 319 ;;     <arg type='v' direction='in'/>
 320 ;;   </method>
 321 ;;   <method name='RequestMode'>
 322 ;;     <arg type='s' direction='in'/>
 323 ;;   </method>
 324 ;;   <method name='ReleaseMode'/>
 325 ;;   <method name='RequestSession'/>
 326 ;;   <method name='ReleaseSession'/>
 327 ;;   <method name='StartDiscovery'/>
 328 ;;   <method name='StopDiscovery'/>
 329 ;;   <method name='ListDevices'>
 330 ;;     <arg type='ao' direction='out'/>
 331 ;;   </method>
 332 ;;   <method name='CreateDevice'>
 333 ;;     <arg type='s' direction='in'/>
 334 ;;     <arg type='o' direction='out'/>
 335 ;;   </method>
 336 ;;   <method name='CreatePairedDevice'>
 337 ;;     <arg type='s' direction='in'/>
 338 ;;     <arg type='o' direction='in'/>
 339 ;;     <arg type='s' direction='in'/>
 340 ;;     <arg type='o' direction='out'/>
 341 ;;   </method>
 342 ;;   <method name='CancelDeviceCreation'>
 343 ;;     <arg type='s' direction='in'/>
 344 ;;   </method>
 345 ;;   <method name='RemoveDevice'>
 346 ;;     <arg type='o' direction='in'/>
 347 ;;   </method>
 348 ;;   <method name='FindDevice'>
 349 ;;     <arg type='s' direction='in'/>
 350 ;;     <arg type='o' direction='out'/>
 351 ;;   </method>
 352 ;;   <method name='RegisterAgent'>
 353 ;;     <arg type='o' direction='in'/>
 354 ;;     <arg type='s' direction='in'/>
 355 ;;   </method>
 356 ;;   <method name='UnregisterAgent'>
 357 ;;     <arg type='o' direction='in'/>
 358 ;;   </method>
 359 ;;   <signal name='DeviceCreated'>
 360 ;;     <arg type='o'/>
 361 ;;   </signal>
 362 ;;   <signal name='DeviceRemoved'>
 363 ;;     <arg type='o'/>
 364 ;;   </signal>
 365 ;;   <signal name='DeviceFound'>
 366 ;;     <arg type='s'/>
 367 ;;     <arg type='a{sv}'/>
 368 ;;   </signal>
 369 ;;   <signal name='PropertyChanged'>
 370 ;;     <arg type='s'/>
 371 ;;     <arg type='v'/>
 372 ;;   </signal>
 373 ;;   <signal name='DeviceDisappeared'>
 374 ;;     <arg type='s'/>
 375 ;;   </signal>
 376 ;; </interface>
 377
 378 ;;;###tramp-autoload
 379 (defcustom tramp-bluez-discover-devices-timeout 60
 380   "Defines seconds since last bluetooth device discovery before rescanning.
 381 A value of 0 would require an immediate discovery during hostname
 382 completion, nil means to use always cached values for discovered
 383 devices."
 384   :group 'tramp
 385   :version "23.2"
 386   :type '(choice (const nil) integer))
 387
 388 (defvar tramp-bluez-discovery nil
 389   "Indicator for a running bluetooth device discovery.
 390 It keeps the timestamp of last discovery.")
 391
 392 (defvar tramp-bluez-devices nil
 393   "Alist of detected bluetooth devices.
 394 Every entry is a list (NAME ADDRESS).")
 395
 396 (defconst tramp-hal-service "org.freedesktop.Hal"
 397   "The well known name of the HAL service.")
 398
 399 (defconst tramp-hal-path-manager "/org/freedesktop/Hal/Manager"
 400   "The object path of the HAL daemon manager.")
 401
 402 (defconst tramp-hal-interface-manager "org.freedesktop.Hal.Manager"
 403   "The manager interface of the HAL daemon.")
 404
 405 (defconst tramp-hal-interface-device "org.freedesktop.Hal.Device"
 406   "The device interface of the HAL daemon.")
 407
 408 \f
 409 ;; New handlers should be added here.
 410 (defconst tramp-gvfs-file-name-handler-alist
 411   '((access-file . ignore)
 412     (add-name-to-file . tramp-gvfs-handle-copy-file)
 413     ;; `byte-compiler-base-file-name' performed by default handler.
 414     ;; `copy-directory' performed by default handler.
 415     (copy-file . tramp-gvfs-handle-copy-file)
 416     (delete-directory . tramp-gvfs-handle-delete-directory)
 417     (delete-file . tramp-gvfs-handle-delete-file)
 418     ;; `diff-latest-backup-file' performed by default handler.
 419     (directory-file-name . tramp-handle-directory-file-name)
 420     (directory-files . tramp-handle-directory-files)
 421     (directory-files-and-attributes
 422      . tramp-handle-directory-files-and-attributes)
 423     (dired-call-process . ignore)
 424     (dired-compress-file . ignore)
 425     (dired-uncache . tramp-handle-dired-uncache)
 426     (expand-file-name . tramp-gvfs-handle-expand-file-name)
 427     (file-accessible-directory-p . tramp-handle-file-accessible-directory-p)
 428     (file-acl . ignore)
 429     (file-attributes . tramp-gvfs-handle-file-attributes)
 430     (file-directory-p . tramp-gvfs-handle-file-directory-p)
 431     ;; `file-equal-p' performed by default handler.
 432     (file-executable-p . tramp-gvfs-handle-file-executable-p)
 433     (file-exists-p . tramp-handle-file-exists-p)
 434     ;; `file-in-directory-p' performed by default handler.
 435     (file-local-copy . tramp-gvfs-handle-file-local-copy)
 436     (file-modes . tramp-handle-file-modes)
 437     (file-name-all-completions . tramp-gvfs-handle-file-name-all-completions)
 438     (file-name-as-directory . tramp-handle-file-name-as-directory)
 439     (file-name-completion . tramp-handle-file-name-completion)
 440     (file-name-directory . tramp-handle-file-name-directory)
 441     (file-name-nondirectory . tramp-handle-file-name-nondirectory)
 442     ;; `file-name-sans-versions' performed by default handler.
 443     (file-newer-than-file-p . tramp-handle-file-newer-than-file-p)
 444     (file-notify-add-watch . tramp-gvfs-handle-file-notify-add-watch)
 445     (file-notify-rm-watch . tramp-handle-file-notify-rm-watch)
 446     (file-notify-valid-p . tramp-handle-file-notify-valid-p)
 447     (file-ownership-preserved-p . ignore)
 448     (file-readable-p . tramp-gvfs-handle-file-readable-p)
 449     (file-regular-p . tramp-handle-file-regular-p)
 450     (file-remote-p . tramp-handle-file-remote-p)
 451     (file-selinux-context . ignore)
 452     (file-symlink-p . tramp-handle-file-symlink-p)
 453     ;; `file-truename' performed by default handler.
 454     (file-writable-p . tramp-gvfs-handle-file-writable-p)
 455     (find-backup-file-name . tramp-handle-find-backup-file-name)
 456     ;; `find-file-noselect' performed by default handler.
 457     ;; `get-file-buffer' performed by default handler.
 458     (insert-directory . tramp-handle-insert-directory)
 459     (insert-file-contents . tramp-handle-insert-file-contents)
 460     (load . tramp-handle-load)
 461     (make-auto-save-file-name . tramp-handle-make-auto-save-file-name)
 462     (make-directory . tramp-gvfs-handle-make-directory)
 463     (make-directory-internal . ignore)
 464     (make-symbolic-link . tramp-handle-make-symbolic-link)
 465     (process-file . ignore)
 466     (rename-file . tramp-gvfs-handle-rename-file)
 467     (set-file-acl . ignore)
 468     (set-file-modes . ignore)
 469     (set-file-selinux-context . ignore)
 470     (set-file-times . ignore)
 471     (set-visited-file-modtime . tramp-handle-set-visited-file-modtime)
 472     (shell-command . ignore)
 473     (start-file-process . ignore)
 474     (substitute-in-file-name . tramp-handle-substitute-in-file-name)
 475     (unhandled-file-name-directory . tramp-handle-unhandled-file-name-directory)
 476     (vc-registered . ignore)
 477     (verify-visited-file-modtime . tramp-handle-verify-visited-file-modtime)
 478     (write-region . tramp-gvfs-handle-write-region))
 479   "Alist of handler functions for Tramp GVFS method.
 480 Operations not mentioned here will be handled by the default Emacs primitives.")
 481
 482 ;; It must be a `defsubst' in order to push the whole code into
 483 ;; tramp-loaddefs.el.  Otherwise, there would be recursive autoloading.
 484 ;;;###tramp-autoload
 485 (defsubst tramp-gvfs-file-name-p (filename)
 486   "Check if it's a filename handled by the GVFS daemon."
 487   (and (tramp-tramp-file-p filename)
 488        (let ((method
 489               (tramp-file-name-method (tramp-dissect-file-name filename))))
 490          (and (stringp method) (member method tramp-gvfs-methods)))))
 491
 492 ;;;###tramp-autoload
 493 (defun tramp-gvfs-file-name-handler (operation &rest args)
 494   "Invoke the GVFS related OPERATION.
 495 First arg specifies the OPERATION, second arg is a list of arguments to
 496 pass to the OPERATION."
 497   (unless tramp-gvfs-enabled
 498     (tramp-user-error nil "Package `tramp-gvfs' not supported"))
 499   (let ((fn (assoc operation tramp-gvfs-file-name-handler-alist)))
 500     (if fn
 501         (save-match-data (apply (cdr fn) args))
 502       (tramp-run-real-handler operation args))))
 503
 504 ;; This might be moved to tramp.el.  It shall be the first file name
 505 ;; handler.
 506 ;;;###tramp-autoload
 507 (when (featurep 'dbusbind)
 508   (add-to-list 'tramp-foreign-file-name-handler-alist
 509                (cons 'tramp-gvfs-file-name-p 'tramp-gvfs-file-name-handler)))
 510
 511 \f
 512 ;; D-Bus helper function.
 513
 514 (defun tramp-gvfs-dbus-string-to-byte-array (string)
 515   "Like `dbus-string-to-byte-array' but add trailing \\0 if needed."
 516   (dbus-string-to-byte-array
 517    (if (string-match "^(aya{sv})" tramp-gvfs-mountlocation-signature)
 518        (concat string (string 0)) string)))
 519
 520 (defun tramp-gvfs-dbus-byte-array-to-string (byte-array)
 521   "Like `dbus-byte-array-to-string' but remove trailing \\0 if exists."
 522   ;; The byte array could be a variant.  Take care.
 523   (let ((byte-array
 524          (if (and (consp byte-array) (atom (car byte-array)))
 525              byte-array (car byte-array))))
 526     (dbus-byte-array-to-string
 527      (if (and (consp byte-array) (zerop (car (last byte-array))))
 528          (butlast byte-array) byte-array))))
 529
 530 (defun tramp-gvfs-stringify-dbus-message (message)
 531   "Convert a D-Bus message into readable UTF8 strings, used for traces."
 532   (cond
 533    ((and (consp message) (characterp (car message)))
 534     (format "%S" (tramp-gvfs-dbus-byte-array-to-string message)))
 535    ((consp message)
 536     (mapcar 'tramp-gvfs-stringify-dbus-message message))
 537    ((stringp message)
 538     (format "%S" message))
 539    (t message)))
 540
 541 (defmacro with-tramp-dbus-call-method
 542   (vec synchronous bus service path interface method &rest args)
 543   "Apply a D-Bus call on bus BUS.
 544
 545 If SYNCHRONOUS is non-nil, the call is synchronously.  Otherwise,
 546 it is an asynchronous call, with `ignore' as callback function.
 547
 548 The other arguments have the same meaning as with `dbus-call-method'
 549 or `dbus-call-method-asynchronously'.  Additionally, the call
 550 will be traced by Tramp with trace level 6."
 551   `(let ((func (if ,synchronous
 552                    'dbus-call-method 'dbus-call-method-asynchronously))
 553          (args (append (list ,bus ,service ,path ,interface ,method)
 554                        (if ,synchronous (list ,@args) (list 'ignore ,@args))))
 555          result)
 556      (tramp-message ,vec 6 "%s %s" func args)
 557      (setq result (apply func args))
 558      (tramp-message ,vec 6 "%s" (tramp-gvfs-stringify-dbus-message result))
 559      result))
 560
 561 (put 'with-tramp-dbus-call-method 'lisp-indent-function 2)
 562 (put 'with-tramp-dbus-call-method 'edebug-form-spec '(form symbolp body))
 563 (tramp-compat-font-lock-add-keywords
 564  'emacs-lisp-mode '("\\<with-tramp-dbus-call-method\\>"))
 565
 566 (defvar tramp-gvfs-dbus-event-vector nil
 567   "Current Tramp file name to be used, as vector.
 568 It is needed when D-Bus signals or errors arrive, because there
 569 is no information where to trace the message.")
 570
 571 (defun tramp-gvfs-dbus-event-error (event err)
 572   "Called when a D-Bus error message arrives, see `dbus-event-error-functions'."
 573   (when tramp-gvfs-dbus-event-vector
 574     (tramp-message tramp-gvfs-dbus-event-vector 10 "%S" event)
 575     (tramp-error tramp-gvfs-dbus-event-vector 'file-error "%s" (cadr err))))
 576
 577 ;; `dbus-event-error-hooks' has been renamed to `dbus-event-error-functions'.
 578 (add-hook
 579  (if (boundp 'dbus-event-error-functions)
 580      'dbus-event-error-functions 'dbus-event-error-hooks)
 581  'tramp-gvfs-dbus-event-error)
 582
 583 \f
 584 ;; File name primitives.
 585
 586 (defun tramp-gvfs-do-copy-or-rename-file
 587   (op filename newname &optional ok-if-already-exists keep-date
 588       preserve-uid-gid preserve-extended-attributes)
 589   "Copy or rename a remote file.
 590 OP must be `copy' or `rename' and indicates the operation to perform.
 591 FILENAME specifies the file to copy or rename, NEWNAME is the name of
 592 the new file (for copy) or the new name of the file (for rename).
 593 OK-IF-ALREADY-EXISTS means don't barf if NEWNAME exists already.
 594 KEEP-DATE means to make sure that NEWNAME has the same timestamp
 595 as FILENAME.  PRESERVE-UID-GID, when non-nil, instructs to keep
 596 the uid and gid if both files are on the same host.
 597 PRESERVE-EXTENDED-ATTRIBUTES is ignored.
 598
 599 This function is invoked by `tramp-gvfs-handle-copy-file' and
 600 `tramp-gvfs-handle-rename-file'.  It is an error if OP is neither
 601 of `copy' and `rename'.  FILENAME and NEWNAME must be absolute
 602 file names."
 603   (unless (memq op '(copy rename))
 604     (error "Unknown operation `%s', must be `copy' or `rename'" op))
 605
 606     (let ((t1 (tramp-tramp-file-p filename))
 607           (t2 (tramp-tramp-file-p newname))
 608           (equal-remote (tramp-equal-remote filename newname))
 609           (file-operation (intern (format "%s-file" op)))
 610           (gvfs-operation (if (eq op 'copy) "gvfs-copy" "gvfs-move"))
 611           (msg-operation (if (eq op 'copy) "Copying" "Renaming")))
 612
 613       (with-parsed-tramp-file-name (if t1 filename newname) nil
 614         (when (and (not ok-if-already-exists) (file-exists-p newname))
 615           (tramp-error
 616            v 'file-already-exists "File %s already exists" newname))
 617
 618         (if (or (and equal-remote
 619                      (tramp-get-connection-property v "direct-copy-failed" nil))
 620                 (and t1 (not (tramp-gvfs-file-name-p filename)))
 621                 (and t2 (not (tramp-gvfs-file-name-p newname))))
 622
 623             ;; We cannot copy or rename directly.
 624             (let ((tmpfile (tramp-compat-make-temp-file filename)))
 625               (cond
 626                (preserve-extended-attributes
 627                 (tramp-compat-funcall
 628                  file-operation
 629                  filename tmpfile t keep-date preserve-uid-gid
 630                  preserve-extended-attributes))
 631                (preserve-uid-gid
 632                 (tramp-compat-funcall
 633                  file-operation filename tmpfile t keep-date preserve-uid-gid))
 634                (t
 635                 (tramp-compat-funcall
 636                  file-operation filename tmpfile t keep-date)))
 637               (rename-file tmpfile newname ok-if-already-exists))
 638
 639           ;; Direct action.
 640           (with-tramp-progress-reporter
 641               v 0 (format "%s %s to %s" msg-operation filename newname)
 642             (unless
 643                 (apply
 644                  'tramp-gvfs-send-command v gvfs-operation
 645                  (append
 646                   (and (eq op 'copy) (or keep-date preserve-uid-gid)
 647                        (list "--preserve"))
 648                   (list
 649                    (tramp-gvfs-url-file-name filename)
 650                    (tramp-gvfs-url-file-name newname))))
 651
 652               (if (or (not equal-remote)
 653                       (and equal-remote
 654                            (tramp-get-connection-property
 655                             v "direct-copy-failed" nil)))
 656                   ;; Propagate the error.
 657                   (with-current-buffer (tramp-get-connection-buffer v)
 658                     (goto-char (point-min))
 659                     (tramp-error-with-buffer
 660                      nil v 'file-error
 661                      "%s failed, see buffer `%s' for details."
 662                      msg-operation (buffer-name)))
 663
 664                 ;; Some WebDAV server, like the one from QNAP, do not
 665                 ;; support direct copy/move.  Try a fallback.
 666                 (tramp-set-connection-property v "direct-copy-failed" t)
 667                 (tramp-gvfs-do-copy-or-rename-file
 668                  op filename newname ok-if-already-exists keep-date
 669                  preserve-uid-gid preserve-extended-attributes))))
 670
 671           (when (and t1 (eq op 'rename))
 672             (with-parsed-tramp-file-name filename nil
 673               (tramp-flush-file-property v (file-name-directory localname))
 674               (tramp-flush-file-property v localname)))
 675
 676           (when t2
 677             (with-parsed-tramp-file-name newname nil
 678               (tramp-flush-file-property v (file-name-directory localname))
 679               (tramp-flush-file-property v localname)))))))
 680
 681 (defun tramp-gvfs-handle-copy-file
 682   (filename newname &optional ok-if-already-exists keep-date
 683             preserve-uid-gid preserve-extended-attributes)
 684   "Like `copy-file' for Tramp files."
 685   (setq filename (expand-file-name filename))
 686   (setq newname (expand-file-name newname))
 687   (cond
 688    ;; At least one file a Tramp file?
 689    ((or (tramp-tramp-file-p filename)
 690         (tramp-tramp-file-p newname))
 691     (tramp-gvfs-do-copy-or-rename-file
 692      'copy filename newname ok-if-already-exists keep-date
 693      preserve-uid-gid preserve-extended-attributes))
 694    ;; Compat section.
 695    (preserve-extended-attributes
 696     (tramp-run-real-handler
 697      'copy-file
 698      (list filename newname ok-if-already-exists keep-date
 699            preserve-uid-gid preserve-extended-attributes)))
 700    (preserve-uid-gid
 701     (tramp-run-real-handler
 702      'copy-file
 703      (list filename newname ok-if-already-exists keep-date preserve-uid-gid)))
 704    (t
 705     (tramp-run-real-handler
 706      'copy-file (list filename newname ok-if-already-exists keep-date)))))
 707
 708 (defun tramp-gvfs-handle-delete-directory (directory &optional recursive trash)
 709   "Like `delete-directory' for Tramp files."
 710   (when (and recursive (not (file-symlink-p directory)))
 711     (mapc (lambda (file)
 712             (if (eq t (car (file-attributes file)))
 713                 (tramp-compat-delete-directory file recursive trash)
 714               (tramp-compat-delete-file file trash)))
 715           (directory-files
 716            directory 'full "^\\([^.]\\|\\.\\([^.]\\|\\..\\)\\).*")))
 717   (with-parsed-tramp-file-name directory nil
 718     (tramp-flush-file-property v (file-name-directory localname))
 719     (tramp-flush-directory-property v localname)
 720     (unless
 721         (tramp-gvfs-send-command
 722          v (if (and trash delete-by-moving-to-trash) "gvfs-trash" "gvfs-rm")
 723          (tramp-gvfs-url-file-name directory))
 724       ;; Propagate the error.
 725       (with-current-buffer (tramp-get-connection-buffer v)
 726         (goto-char (point-min))
 727         (tramp-error-with-buffer
 728          nil v 'file-error "Couldn't delete %s" directory)))))
 729
 730 (defun tramp-gvfs-handle-delete-file (filename &optional trash)
 731   "Like `delete-file' for Tramp files."
 732   (with-parsed-tramp-file-name filename nil
 733     (tramp-flush-file-property v (file-name-directory localname))
 734     (tramp-flush-file-property v localname)
 735     (unless
 736         (tramp-gvfs-send-command
 737          v (if (and trash delete-by-moving-to-trash) "gvfs-trash" "gvfs-rm")
 738          (tramp-gvfs-url-file-name filename))
 739       ;; Propagate the error.
 740       (with-current-buffer (tramp-get-connection-buffer v)
 741         (goto-char (point-min))
 742         (tramp-error-with-buffer
 743          nil v 'file-error "Couldn't delete %s" filename)))))
 744
 745 (defun tramp-gvfs-handle-expand-file-name (name &optional dir)
 746   "Like `expand-file-name' for Tramp files."
 747   ;; If DIR is not given, use DEFAULT-DIRECTORY or "/".
 748   (setq dir (or dir default-directory "/"))
 749   ;; Unless NAME is absolute, concat DIR and NAME.
 750   (unless (file-name-absolute-p name)
 751     (setq name (concat (file-name-as-directory dir) name)))
 752   ;; If NAME is not a Tramp file, run the real handler.
 753   (if (not (tramp-tramp-file-p name))
 754       (tramp-run-real-handler 'expand-file-name (list name nil))
 755     ;; Dissect NAME.
 756     (with-parsed-tramp-file-name name nil
 757       ;; If there is a default location, expand tilde.
 758       (when (string-match "\\`\\(~\\)\\(/\\|\\'\\)" localname)
 759         (save-match-data
 760           (tramp-gvfs-maybe-open-connection (vector method user host "/" hop)))
 761         (setq localname
 762               (replace-match
 763                (tramp-get-file-property  v "/" "default-location" "~")
 764                nil t localname 1)))
 765       ;; Tilde expansion is not possible.
 766       (when (string-match "\\`\\(~[^/]*\\)\\(.*\\)\\'" localname)
 767         (tramp-error
 768          v 'file-error
 769          "Cannot expand tilde in file `%s'" name))
 770       (unless (tramp-run-real-handler 'file-name-absolute-p (list localname))
 771         (setq localname (concat "/" localname)))
 772       ;; We do not pass "/..".
 773       (if (string-equal "smb" method)
 774           (when (string-match "^/[^/]+\\(/\\.\\./?\\)" localname)
 775             (setq localname (replace-match "/" t t localname 1)))
 776         (when (string-match "^/\\.\\./?" localname)
 777           (setq localname (replace-match "/" t t localname))))
 778       ;; There might be a double slash.  Remove this.
 779       (while (string-match "//" localname)
 780         (setq localname (replace-match "/" t t localname)))
 781       ;; No tilde characters in file name, do normal
 782       ;; `expand-file-name' (this does "/./" and "/../").
 783       (tramp-make-tramp-file-name
 784        method user host
 785        (tramp-run-real-handler
 786         'expand-file-name (list localname))))))
 787
 788 (defun tramp-gvfs-handle-file-attributes (filename &optional id-format)
 789   "Like `file-attributes' for Tramp files."
 790   (unless id-format (setq id-format 'integer))
 791   (ignore-errors
 792     ;; Don't modify `last-coding-system-used' by accident.
 793     (let ((last-coding-system-used last-coding-system-used)
 794           dirp res-symlink-target res-numlinks res-uid res-gid res-access
 795           res-mod res-change res-size res-filemodes res-inode res-device)
 796       (with-parsed-tramp-file-name filename nil
 797         (with-tramp-file-property
 798             v localname (format "file-attributes-%s" id-format)
 799           (tramp-message v 5 "file attributes: %s" localname)
 800           (tramp-gvfs-send-command
 801            v "gvfs-info" (tramp-gvfs-url-file-name filename))
 802           ;; Parse output ...
 803           (with-current-buffer (tramp-get-connection-buffer v)
 804             (goto-char (point-min))
 805             (when (re-search-forward "attributes:" nil t)
 806               ;; ... directory or symlink
 807               (goto-char (point-min))
 808               (setq dirp (if (re-search-forward "type:\\s-+directory" nil t) t))
 809               (goto-char (point-min))
 810               (setq res-symlink-target
 811                     (if (re-search-forward
 812                          "standard::symlink-target:\\s-+\\(\\S-+\\)" nil t)
 813                         (match-string 1)))
 814               ;; ... number links
 815               (goto-char (point-min))
 816               (setq res-numlinks
 817                     (if (re-search-forward
 818                          "unix::nlink:\\s-+\\([0-9]+\\)" nil t)
 819                         (string-to-number (match-string 1)) 0))
 820               ;; ... uid and gid
 821               (goto-char (point-min))
 822               (setq res-uid
 823                     (or (if (eq id-format 'integer)
 824                             (if (re-search-forward
 825                                  "unix::uid:\\s-+\\([0-9]+\\)" nil t)
 826                                 (string-to-number (match-string 1)))
 827                           (if (re-search-forward
 828                                "owner::user:\\s-+\\(\\S-+\\)" nil t)
 829                               (match-string 1)))
 830                         (tramp-get-local-uid id-format)))
 831               (setq res-gid
 832                     (or (if (eq id-format 'integer)
 833                             (if (re-search-forward
 834                                  "unix::gid:\\s-+\\([0-9]+\\)" nil t)
 835                                 (string-to-number (match-string 1)))
 836                           (if (re-search-forward
 837                                "owner::group:\\s-+\\(\\S-+\\)" nil t)
 838                               (match-string 1)))
 839                         (tramp-get-local-gid id-format)))
 840               ;; ... last access, modification and change time
 841               (goto-char (point-min))
 842               (setq res-access
 843                     (if (re-search-forward
 844                          "time::access:\\s-+\\([0-9]+\\)" nil t)
 845                         (seconds-to-time (string-to-number (match-string 1)))
 846                       '(0 0)))
 847               (goto-char (point-min))
 848               (setq res-mod
 849                     (if (re-search-forward
 850                          "time::modified:\\s-+\\([0-9]+\\)" nil t)
 851                         (seconds-to-time (string-to-number (match-string 1)))
 852                       '(0 0)))
 853               (goto-char (point-min))
 854               (setq res-change
 855                     (if (re-search-forward
 856                          "time::changed:\\s-+\\([0-9]+\\)" nil t)
 857                         (seconds-to-time (string-to-number (match-string 1)))
 858                       '(0 0)))
 859               ;; ... size
 860               (goto-char (point-min))
 861               (setq res-size
 862                     (if (re-search-forward
 863                          "standard::size:\\s-+\\([0-9]+\\)" nil t)
 864                         (string-to-number (match-string 1)) 0))
 865               ;; ... file mode flags
 866               (goto-char (point-min))
 867               (setq res-filemodes
 868                     (if (re-search-forward "unix::mode:\\s-+\\([0-9]+\\)" nil t)
 869                         (tramp-file-mode-from-int
 870                          (string-to-number (match-string 1)))
 871                       (if dirp "drwx------" "-rwx------")))
 872               ;; ... inode and device
 873               (goto-char (point-min))
 874               (setq res-inode
 875                     (if (re-search-forward
 876                          "unix::inode:\\s-+\\([0-9]+\\)" nil t)
 877                         (string-to-number (match-string 1))
 878                       (tramp-get-inode v)))
 879               (goto-char (point-min))
 880               (setq res-device
 881                     (if (re-search-forward
 882                          "unix::device:\\s-+\\([0-9]+\\)" nil t)
 883                         (string-to-number (match-string 1))
 884                       (tramp-get-device v)))
 885
 886               ;; Return data gathered.
 887               (list
 888                ;; 0. t for directory, string (name linked to) for
 889                ;; symbolic link, or nil.
 890                (or dirp res-symlink-target)
 891                ;; 1. Number of links to file.
 892                res-numlinks
 893                ;; 2. File uid.
 894                res-uid
 895                ;; 3. File gid.
 896                res-gid
 897                ;; 4. Last access time, as a list of integers.
 898                ;; 5. Last modification time, likewise.
 899                ;; 6. Last status change time, likewise.
 900                res-access res-mod res-change
 901                ;; 7. Size in bytes (-1, if number is out of range).
 902                res-size
 903                ;; 8. File modes.
 904                res-filemodes
 905                ;; 9. t if file's gid would change if file were deleted
 906                ;; and recreated.
 907                nil
 908                ;; 10. Inode number.
 909                res-inode
 910                ;; 11. Device number.
 911                res-device
 912                ))))))))
 913
 914 (defun tramp-gvfs-handle-file-directory-p (filename)
 915   "Like `file-directory-p' for Tramp files."
 916   (eq t (car (file-attributes filename))))
 917
 918 (defun tramp-gvfs-handle-file-executable-p (filename)
 919   "Like `file-executable-p' for Tramp files."
 920   (with-parsed-tramp-file-name filename nil
 921     (with-tramp-file-property v localname "file-executable-p"
 922       (tramp-check-cached-permissions v ?x))))
 923
 924 (defun tramp-gvfs-handle-file-local-copy (filename)
 925   "Like `file-local-copy' for Tramp files."
 926   (with-parsed-tramp-file-name filename nil
 927     (let ((tmpfile (tramp-compat-make-temp-file filename)))
 928       (unless (file-exists-p filename)
 929         (tramp-error
 930          v 'file-error
 931          "Cannot make local copy of non-existing file `%s'" filename))
 932       (copy-file filename tmpfile t t)
 933       tmpfile)))
 934
 935 (defun tramp-gvfs-handle-file-name-all-completions (filename directory)
 936   "Like `file-name-all-completions' for Tramp files."
 937   (unless (save-match-data (string-match "/" filename))
 938     (with-parsed-tramp-file-name (expand-file-name directory) nil
 939
 940       (all-completions
 941        filename
 942        (mapcar
 943         'list
 944         (or
 945          ;; Try cache entries for filename, filename with last
 946          ;; character removed, filename with last two characters
 947          ;; removed, ..., and finally the empty string - all
 948          ;; concatenated to the local directory name.
 949          (let ((remote-file-name-inhibit-cache
 950                 (or remote-file-name-inhibit-cache
 951                     tramp-completion-reread-directory-timeout)))
 952
 953            ;; This is inefficient for very long filenames, pity
 954            ;; `reduce' is not available...
 955            (car
 956             (apply
 957              'append
 958              (mapcar
 959               (lambda (x)
 960                 (let ((cache-hit
 961                        (tramp-get-file-property
 962                         v
 963                         (concat localname (substring filename 0 x))
 964                         "file-name-all-completions"
 965                         nil)))
 966                   (when cache-hit (list cache-hit))))
 967               ;; We cannot use a length of 0, because file properties
 968               ;; for "foo" and "foo/" are identical.
 969               (tramp-compat-number-sequence (length filename) 1 -1)))))
 970
 971          ;; Cache expired or no matching cache entry found so we need
 972          ;; to perform a remote operation.
 973          (let ((result '("." ".."))
 974                entry)
 975            ;; Get a list of directories and files.
 976            (tramp-gvfs-send-command
 977             v "gvfs-ls" "-h" (tramp-gvfs-url-file-name directory))
 978
 979            ;; Now grab the output.
 980            (with-temp-buffer
 981              (insert-buffer-substring (tramp-get-connection-buffer v))
 982              (goto-char (point-max))
 983              (while (zerop (forward-line -1))
 984                (setq entry (buffer-substring (point) (point-at-eol)))
 985                (when (string-match filename entry)
 986                  (if (file-directory-p (expand-file-name entry directory))
 987                      (push (concat entry "/") result)
 988                    (push entry result)))))
 989
 990            ;; Because the remote op went through OK we know the
 991            ;; directory we `cd'-ed to exists.
 992            (tramp-set-file-property v localname "file-exists-p" t)
 993
 994            ;; Because the remote op went through OK we know every
 995            ;; file listed by `ls' exists.
 996            (mapc (lambda (entry)
 997                    (tramp-set-file-property
 998                     v (concat localname entry) "file-exists-p" t))
 999                  result)
1000
1001            ;; Store result in the cache.
1002            (tramp-set-file-property
1003             v (concat localname filename)
1004             "file-name-all-completions" result))))))))
1005
1006 (defun tramp-gvfs-handle-file-notify-add-watch (file-name flags _callback)
1007   "Like `file-notify-add-watch' for Tramp files."
1008   (setq file-name (expand-file-name file-name))
1009   (with-parsed-tramp-file-name file-name nil
1010     ;; We cannot watch directories, because `gvfs-monitor-dir' is not
1011     ;; supported for gvfs-mounted directories.
1012     (when (file-directory-p file-name)
1013       (tramp-error
1014        v 'file-notify-error "Monitoring not supported for `%s'" file-name))
1015     (let* ((default-directory (file-name-directory file-name))
1016            (events
1017             (cond
1018              ((and (memq 'change flags) (memq 'attribute-change flags))
1019               '(created changed changes-done-hint moved deleted
1020                         attribute-changed))
1021              ((memq 'change flags)
1022               '(created changed changes-done-hint moved deleted))
1023              ((memq 'attribute-change flags) '(attribute-changed))))
1024            (p (start-process
1025                "gvfs-monitor-file" (generate-new-buffer " *gvfs-monitor-file*")
1026                "gvfs-monitor-file" (tramp-gvfs-url-file-name file-name))))
1027       (if (not (processp p))
1028           (tramp-error
1029            v 'file-notify-error "Monitoring not supported for `%s'" file-name)
1030         (tramp-message
1031          v 6 "Run `%s', %S" (mapconcat 'identity (process-command p) " ") p)
1032         (tramp-set-connection-property p "vector" v)
1033         (tramp-compat-process-put p 'events events)
1034         (tramp-compat-process-put p 'watch-name localname)
1035         (tramp-compat-set-process-query-on-exit-flag p nil)
1036         (set-process-filter p 'tramp-gvfs-monitor-file-process-filter)
1037         ;; There might be an error if the monitor is not supported.
1038         ;; Give the filter a chance to read the output.
1039         (tramp-accept-process-output p 1)
1040         (unless (memq (process-status p) '(run open))
1041           (tramp-error
1042            v 'file-notify-error "Monitoring not supported for `%s'" file-name))
1043         p))))
1044
1045 (defun tramp-gvfs-monitor-file-process-filter (proc string)
1046   "Read output from \"gvfs-monitor-file\" and add corresponding \
1047 file-notify events."
1048   (let* ((rest-string (tramp-compat-process-get proc 'rest-string))
1049          (dd (with-current-buffer (process-buffer proc) default-directory))
1050          (ddu (regexp-quote (tramp-gvfs-url-file-name dd))))
1051     (when rest-string
1052       (tramp-message proc 10 "Previous string:\n%s" rest-string))
1053     (tramp-message proc 6 "%S\n%s" proc string)
1054     (setq string (concat rest-string string)
1055           ;; Attribute change is returned in unused wording.
1056           string (tramp-compat-replace-regexp-in-string
1057                   "ATTRIB CHANGED" "ATTRIBUTE_CHANGED" string))
1058     (when (string-match "Monitoring not supported" string)
1059       (delete-process proc))
1060
1061     (while (string-match
1062             (concat "^[\n\r]*"
1063                     "File Monitor Event:[\n\r]+"
1064                     "File = \\([^\n\r]+\\)[\n\r]+"
1065                     "Event = \\([^[:blank:]]+\\)[\n\r]+")
1066             string)
1067       (let ((file (match-string 1 string))
1068             (action (intern-soft
1069                      (tramp-compat-replace-regexp-in-string
1070                       "_" "-" (downcase (match-string 2 string))))))
1071         (setq string (replace-match "" nil nil string))
1072         ;; File names are returned as URL paths.  We must convert them.
1073         (when (string-match ddu file)
1074           (setq file (replace-match dd nil nil file)))
1075         (while (string-match "%\\([0-9A-F]\\{2\\}\\)" file)
1076           (setq file
1077                 (replace-match
1078                  (char-to-string (string-to-number (match-string 1 file) 16))
1079                  nil nil file)))
1080         ;; Usually, we would add an Emacs event now.  Unfortunately,
1081         ;; `unread-command-events' does not accept several events at
1082         ;; once.  Therefore, we apply the callback directly.
1083         (tramp-compat-funcall 'file-notify-callback (list proc action file))))
1084
1085     ;; Save rest of the string.
1086     (when (zerop (length string)) (setq string nil))
1087     (when string (tramp-message proc 10 "Rest string:\n%s" string))
1088     (tramp-compat-process-put proc 'rest-string string)))
1089
1090 (defun tramp-gvfs-handle-file-readable-p (filename)
1091   "Like `file-readable-p' for Tramp files."
1092   (with-parsed-tramp-file-name filename nil
1093     (with-tramp-file-property v localname "file-executable-p"
1094       (tramp-check-cached-permissions v ?r))))
1095
1096 (defun tramp-gvfs-handle-file-writable-p (filename)
1097   "Like `file-writable-p' for Tramp files."
1098   (with-parsed-tramp-file-name filename nil
1099     (with-tramp-file-property v localname "file-writable-p"
1100       (if (file-exists-p filename)
1101           (tramp-check-cached-permissions v ?w)
1102         ;; If file doesn't exist, check if directory is writable.
1103         (and (file-directory-p (file-name-directory filename))
1104              (file-writable-p (file-name-directory filename)))))))
1105
1106 (defun tramp-gvfs-handle-make-directory (dir &optional parents)
1107   "Like `make-directory' for Tramp files."
1108   (setq dir (directory-file-name (expand-file-name dir)))
1109   (with-parsed-tramp-file-name dir nil
1110     (tramp-flush-file-property v (file-name-directory localname))
1111     (tramp-flush-directory-property v localname)
1112     (save-match-data
1113       (let ((ldir (file-name-directory dir)))
1114         ;; Make missing directory parts.  "gvfs-mkdir -p ..." does not
1115         ;; work robust.
1116         (when (and parents (not (file-directory-p ldir)))
1117           (make-directory ldir parents))
1118         ;; Just do it.
1119         (unless (tramp-gvfs-send-command
1120                  v "gvfs-mkdir" (tramp-gvfs-url-file-name dir))
1121           (tramp-error v 'file-error "Couldn't make directory %s" dir))))))
1122
1123 (defun tramp-gvfs-handle-rename-file
1124   (filename newname &optional ok-if-already-exists)
1125   "Like `rename-file' for Tramp files."
1126   ;; Check if both files are local -- invoke normal rename-file.
1127   ;; Otherwise, use Tramp from local system.
1128   (setq filename (expand-file-name filename))
1129   (setq newname (expand-file-name newname))
1130   ;; At least one file a Tramp file?
1131   (if (or (tramp-tramp-file-p filename)
1132           (tramp-tramp-file-p newname))
1133       (tramp-gvfs-do-copy-or-rename-file
1134        'rename filename newname ok-if-already-exists t t)
1135     (tramp-run-real-handler
1136      'rename-file (list filename newname ok-if-already-exists))))
1137
1138 (defun tramp-gvfs-handle-write-region
1139   (start end filename &optional append visit lockname confirm)
1140   "Like `write-region' for Tramp files."
1141   (with-parsed-tramp-file-name filename nil
1142     ;; XEmacs takes a coding system as the seventh argument, not `confirm'.
1143     (when (and (not (featurep 'xemacs)) confirm (file-exists-p filename))
1144       (unless (y-or-n-p (format "File %s exists; overwrite anyway? " filename))
1145         (tramp-error v 'file-error "File not overwritten")))
1146
1147     (let ((tmpfile (tramp-compat-make-temp-file filename)))
1148       (when (and append (file-exists-p filename))
1149         (copy-file filename tmpfile 'ok))
1150       ;; We say `no-message' here because we don't want the visited file
1151       ;; modtime data to be clobbered from the temp file.  We call
1152       ;; `set-visited-file-modtime' ourselves later on.
1153       (tramp-run-real-handler
1154        'write-region
1155        (if confirm ; don't pass this arg unless defined for backward compat.
1156            (list start end tmpfile append 'no-message lockname confirm)
1157          (list start end tmpfile append 'no-message lockname)))
1158       (condition-case nil
1159           (rename-file tmpfile filename 'ok-if-already-exists)
1160         (error
1161          (delete-file tmpfile)
1162          (tramp-error
1163           v 'file-error "Couldn't write region to `%s'" filename))))
1164
1165     (tramp-flush-file-property v (file-name-directory localname))
1166     (tramp-flush-file-property v localname)
1167
1168     ;; Set file modification time.
1169     (when (or (eq visit t) (stringp visit))
1170       (set-visited-file-modtime (nth 5 (file-attributes filename))))
1171
1172     ;; The end.
1173     (when (or (eq visit t) (null visit) (stringp visit))
1174       (tramp-message v 0 "Wrote %s" filename))
1175     (run-hooks 'tramp-handle-write-region-hook)))
1176
1177 \f
1178 ;; File name conversions.
1179
1180 (defun tramp-gvfs-url-file-name (filename)
1181   "Return FILENAME in URL syntax."
1182   ;; "/" must NOT be hexlified.
1183   (let ((url-unreserved-chars (cons ?/ url-unreserved-chars))
1184         result)
1185     (setq
1186      result
1187      (url-recreate-url
1188       (if (tramp-tramp-file-p filename)
1189           (with-parsed-tramp-file-name filename nil
1190             (when (and user (string-match tramp-user-with-domain-regexp user))
1191               (setq user
1192                     (concat (match-string 2 user) ";" (match-string 1 user))))
1193             (url-parse-make-urlobj
1194              method (and user (url-hexify-string user)) nil
1195              (tramp-file-name-real-host v) (tramp-file-name-port v)
1196              (and localname (url-hexify-string localname)) nil nil t))
1197         (url-parse-make-urlobj
1198          "file" nil nil nil nil
1199          (url-hexify-string (file-truename filename)) nil nil t))))
1200     (when (tramp-tramp-file-p filename)
1201       (with-parsed-tramp-file-name filename nil
1202         (tramp-message v 10 "remote file `%s' is URL `%s'" filename result)))
1203     result))
1204
1205 (defun tramp-gvfs-object-path (filename)
1206   "Create a D-Bus object path from FILENAME."
1207   (expand-file-name (dbus-escape-as-identifier filename) tramp-gvfs-path-tramp))
1208
1209 (defun tramp-gvfs-file-name (object-path)
1210   "Retrieve file name from D-Bus OBJECT-PATH."
1211   (dbus-unescape-from-identifier
1212    (tramp-compat-replace-regexp-in-string
1213     "^.*/\\([^/]+\\)$" "\\1" object-path)))
1214
1215 (defun tramp-bluez-address (device)
1216   "Return bluetooth device address from a given bluetooth DEVICE name."
1217   (when (stringp device)
1218     (if (string-match tramp-ipv6-regexp device)
1219         (match-string 0 device)
1220       (cadr (assoc device (tramp-bluez-list-devices))))))
1221
1222 (defun tramp-bluez-device (address)
1223   "Return bluetooth device name from a given bluetooth device ADDRESS.
1224 ADDRESS can have the form \"xx:xx:xx:xx:xx:xx\" or \"[xx:xx:xx:xx:xx:xx]\"."
1225   (when (stringp address)
1226     (while (string-match "[][]" address)
1227       (setq address (replace-match "" t t address)))
1228     (let (result)
1229       (dolist (item (tramp-bluez-list-devices) result)
1230         (when (string-match address (cadr item))
1231           (setq result (car item)))))))
1232
1233 \f
1234 ;; D-Bus GVFS functions.
1235
1236 (defun tramp-gvfs-handler-askpassword (message user domain flags)
1237   "Implementation for the \"org.gtk.vfs.MountOperation.askPassword\" method."
1238   (let* ((filename
1239           (tramp-gvfs-file-name (dbus-event-path-name last-input-event)))
1240          (pw-prompt
1241           (format
1242            "%s for %s "
1243            (if (string-match "\\([pP]assword\\|[pP]assphrase\\)" message)
1244                (capitalize (match-string 1 message))
1245              "Password")
1246            filename))
1247          password)
1248
1249     (condition-case nil
1250         (with-parsed-tramp-file-name filename l
1251           (when (and (zerop (length user))
1252                      (not
1253                       (zerop (logand flags tramp-gvfs-password-need-username))))
1254             (setq user (read-string "User name: ")))
1255           (when (and (zerop (length domain))
1256                      (not
1257                       (zerop (logand flags tramp-gvfs-password-need-domain))))
1258             (setq domain (read-string "Domain name: ")))
1259
1260           (tramp-message l 6 "%S %S %S %d" message user domain flags)
1261           (unless (tramp-get-connection-property l "first-password-request" nil)
1262             (tramp-clear-passwd l))
1263
1264           (setq tramp-current-method l-method
1265                 tramp-current-user user
1266                 tramp-current-host l-host
1267                 password (tramp-read-passwd
1268                           (tramp-get-connection-process l) pw-prompt))
1269
1270           ;; Return result.
1271           (if (stringp password)
1272               (list
1273                t ;; password handled.
1274                nil ;; no abort of D-Bus.
1275                password
1276                (tramp-file-name-real-user l)
1277                domain
1278                nil ;; not anonymous.
1279                0) ;; no password save.
1280             ;; No password provided.
1281             (list nil t "" (tramp-file-name-real-user l) domain nil 0)))
1282
1283       ;; When QUIT is raised, we shall return this information to D-Bus.
1284       (quit (list nil t "" "" "" nil 0)))))
1285
1286 (defun tramp-gvfs-handler-askquestion (message choices)
1287   "Implementation for the \"org.gtk.vfs.MountOperation.askQuestion\" method."
1288   (save-window-excursion
1289     (let ((enable-recursive-minibuffers t)
1290           choice)
1291
1292       (condition-case nil
1293           (with-parsed-tramp-file-name
1294               (tramp-gvfs-file-name (dbus-event-path-name last-input-event)) nil
1295             (tramp-message v 6 "%S %S" message choices)
1296
1297             ;; In theory, there can be several choices.  Until now,
1298             ;; there is only the question whether to accept an unknown
1299             ;; host signature.
1300             (with-temp-buffer
1301               ;; Preserve message for `progress-reporter'.
1302               (tramp-compat-with-temp-message ""
1303                 (insert message)
1304                 (pop-to-buffer (current-buffer))
1305                 (setq choice (if (yes-or-no-p (concat (car choices) " ")) 0 1))
1306                 (tramp-message v 6 "%d" choice)))
1307
1308             ;; When the choice is "no", we set a dummy fuse-mountpoint
1309             ;; in order to leave the timeout.
1310             (unless (zerop choice)
1311               (tramp-set-file-property v "/" "fuse-mountpoint" "/"))
1312
1313             (list
1314              t ;; handled.
1315              nil ;; no abort of D-Bus.
1316              choice))
1317
1318         ;; When QUIT is raised, we shall return this information to D-Bus.
1319         (quit (list nil t 0))))))
1320
1321 (defun tramp-gvfs-handler-mounted-unmounted (mount-info)
1322   "Signal handler for the \"org.gtk.vfs.MountTracker.mounted\" and
1323 \"org.gtk.vfs.MountTracker.unmounted\" signals."
1324   (ignore-errors
1325     (let ((signal-name (dbus-event-member-name last-input-event))
1326           (elt mount-info))
1327       ;; Jump over the first elements of the mount info. Since there
1328       ;; were changes in the entries, we cannot access dedicated
1329       ;; elements.
1330       (while (stringp (car elt)) (setq elt (cdr elt)))
1331       (let* ((fuse-mountpoint (tramp-gvfs-dbus-byte-array-to-string (cadr elt)))
1332              (mount-spec (caddr elt))
1333              (default-location (tramp-gvfs-dbus-byte-array-to-string
1334                                 (cadddr elt)))
1335              (method (tramp-gvfs-dbus-byte-array-to-string
1336                       (cadr (assoc "type" (cadr mount-spec)))))
1337              (user (tramp-gvfs-dbus-byte-array-to-string
1338                     (cadr (assoc "user" (cadr mount-spec)))))
1339              (domain (tramp-gvfs-dbus-byte-array-to-string
1340                       (cadr (assoc "domain" (cadr mount-spec)))))
1341              (host (tramp-gvfs-dbus-byte-array-to-string
1342                     (cadr (or (assoc "host" (cadr mount-spec))
1343                               (assoc "server" (cadr mount-spec))))))
1344              (port (tramp-gvfs-dbus-byte-array-to-string
1345                     (cadr (assoc "port" (cadr mount-spec)))))
1346              (ssl (tramp-gvfs-dbus-byte-array-to-string
1347                    (cadr (assoc "ssl" (cadr mount-spec)))))
1348              (prefix (concat (tramp-gvfs-dbus-byte-array-to-string
1349                               (car mount-spec))
1350                              (tramp-gvfs-dbus-byte-array-to-string
1351                               (cadr (assoc "share" (cadr mount-spec)))))))
1352         (when (string-match "^smb" method)
1353           (setq method "smb"))
1354         (when (string-equal "obex" method)
1355           (setq host (tramp-bluez-device host)))
1356         (when (and (string-equal "dav" method) (string-equal "true" ssl))
1357           (setq method "davs"))
1358         (unless (zerop (length domain))
1359           (setq user (concat user tramp-prefix-domain-format domain)))
1360         (unless (zerop (length port))
1361           (setq host (concat host tramp-prefix-port-format port)))
1362         (with-parsed-tramp-file-name
1363             (tramp-make-tramp-file-name method user host "") nil
1364           (tramp-message
1365            v 6 "%s %s"
1366            signal-name (tramp-gvfs-stringify-dbus-message mount-info))
1367           (tramp-set-file-property v "/" "list-mounts" 'undef)
1368           (if (string-equal (downcase signal-name) "unmounted")
1369               (tramp-set-file-property v "/" "fuse-mountpoint" nil)
1370             ;; Set prefix, mountpoint and location.
1371             (unless (string-equal prefix "/")
1372               (tramp-set-file-property v "/" "prefix" prefix))
1373             (tramp-set-file-property v "/" "fuse-mountpoint" fuse-mountpoint)
1374             (tramp-set-file-property
1375              v "/" "default-location" default-location)))))))
1376
1377 (when tramp-gvfs-enabled
1378   (dbus-register-signal
1379    :session nil tramp-gvfs-path-mounttracker
1380    tramp-gvfs-interface-mounttracker "mounted"
1381    'tramp-gvfs-handler-mounted-unmounted)
1382   (dbus-register-signal
1383    :session nil tramp-gvfs-path-mounttracker
1384    tramp-gvfs-interface-mounttracker "Mounted"
1385    'tramp-gvfs-handler-mounted-unmounted)
1386
1387   (dbus-register-signal
1388    :session nil tramp-gvfs-path-mounttracker
1389    tramp-gvfs-interface-mounttracker "unmounted"
1390    'tramp-gvfs-handler-mounted-unmounted)
1391   (dbus-register-signal
1392    :session nil tramp-gvfs-path-mounttracker
1393    tramp-gvfs-interface-mounttracker "Unmounted"
1394    'tramp-gvfs-handler-mounted-unmounted))
1395
1396 (defun tramp-gvfs-connection-mounted-p (vec)
1397   "Check, whether the location is already mounted."
1398   (or
1399    (tramp-get-file-property vec "/" "fuse-mountpoint" nil)
1400    (catch 'mounted
1401      (dolist
1402          (elt
1403           (with-tramp-file-property vec "/" "list-mounts"
1404             (with-tramp-dbus-call-method vec t
1405               :session tramp-gvfs-service-daemon tramp-gvfs-path-mounttracker
1406               tramp-gvfs-interface-mounttracker tramp-gvfs-listmounts))
1407           nil)
1408        ;; Jump over the first elements of the mount info. Since there
1409        ;; were changes in the entries, we cannot access dedicated
1410        ;; elements.
1411        (while (stringp (car elt)) (setq elt (cdr elt)))
1412        (let* ((fuse-mountpoint (tramp-gvfs-dbus-byte-array-to-string
1413                                 (cadr elt)))
1414               (mount-spec (caddr elt))
1415               (default-location (tramp-gvfs-dbus-byte-array-to-string
1416                                  (cadddr elt)))
1417               (method (tramp-gvfs-dbus-byte-array-to-string
1418                        (cadr (assoc "type" (cadr mount-spec)))))
1419               (user (tramp-gvfs-dbus-byte-array-to-string
1420                      (cadr (assoc "user" (cadr mount-spec)))))
1421               (domain (tramp-gvfs-dbus-byte-array-to-string
1422                        (cadr (assoc "domain" (cadr mount-spec)))))
1423               (host (tramp-gvfs-dbus-byte-array-to-string
1424                      (cadr (or (assoc "host" (cadr mount-spec))
1425                                (assoc "server" (cadr mount-spec))))))
1426               (port (tramp-gvfs-dbus-byte-array-to-string
1427                      (cadr (assoc "port" (cadr mount-spec)))))
1428               (ssl (tramp-gvfs-dbus-byte-array-to-string
1429                     (cadr (assoc "ssl" (cadr mount-spec)))))
1430               (prefix (concat (tramp-gvfs-dbus-byte-array-to-string
1431                                (car mount-spec))
1432                               (tramp-gvfs-dbus-byte-array-to-string
1433                                (cadr (assoc "share" (cadr mount-spec)))))))
1434          (when (string-match "^smb" method)
1435            (setq method "smb"))
1436          (when (string-equal "obex" method)
1437            (setq host (tramp-bluez-device host)))
1438          (when (and (string-equal "dav" method) (string-equal "true" ssl))
1439            (setq method "davs"))
1440          (when (and (string-equal "synce" method) (zerop (length user)))
1441            (setq user (or (tramp-file-name-user vec) "")))
1442          (unless (zerop (length domain))
1443            (setq user (concat user tramp-prefix-domain-format domain)))
1444          (unless (zerop (length port))
1445            (setq host (concat host tramp-prefix-port-format port)))
1446          (when (and
1447                 (string-equal method (tramp-file-name-method vec))
1448                 (string-equal user (or (tramp-file-name-user vec) ""))
1449                 (string-equal host (tramp-file-name-host vec))
1450                 (string-match (concat "^" (regexp-quote prefix))
1451                               (tramp-file-name-localname vec)))
1452            ;; Set prefix, mountpoint and location.
1453            (unless (string-equal prefix "/")
1454              (tramp-set-file-property vec "/" "prefix" prefix))
1455            (tramp-set-file-property vec "/" "fuse-mountpoint" fuse-mountpoint)
1456            (tramp-set-file-property vec "/" "default-location" default-location)
1457            (throw 'mounted t)))))))
1458
1459 (defun tramp-gvfs-mount-spec-entry (key value)
1460   "Construct a mount-spec entry to be used in a mount_spec.
1461 It was \"a(say)\", but has changed to \"a{sv})\"."
1462   (if (string-match "^(aya{sv})" tramp-gvfs-mountlocation-signature)
1463       (list :dict-entry key
1464             (list :variant (tramp-gvfs-dbus-string-to-byte-array value)))
1465     (list :struct key (tramp-gvfs-dbus-string-to-byte-array value))))
1466
1467 (defun tramp-gvfs-mount-spec (vec)
1468   "Return a mount-spec for \"org.gtk.vfs.MountTracker.mountLocation\"."
1469   (let* ((method (tramp-file-name-method vec))
1470          (user (tramp-file-name-real-user vec))
1471          (domain (tramp-file-name-domain vec))
1472          (host (tramp-file-name-real-host vec))
1473          (port (tramp-file-name-port vec))
1474          (localname (tramp-file-name-localname vec))
1475          (ssl (if (string-match "^davs" method) "true" "false"))
1476          (mount-spec
1477           `(:array
1478             ,@(cond
1479                ((string-equal "smb" method)
1480                 (string-match "^/?\\([^/]+\\)" localname)
1481                 (list (tramp-gvfs-mount-spec-entry "type" "smb-share")
1482                       (tramp-gvfs-mount-spec-entry "server" host)
1483                       (tramp-gvfs-mount-spec-entry
1484                        "share" (match-string 1 localname))))
1485                ((string-equal "obex" method)
1486                 (list (tramp-gvfs-mount-spec-entry "type" method)
1487                       (tramp-gvfs-mount-spec-entry
1488                        "host" (concat "[" (tramp-bluez-address host) "]"))))
1489                ((string-match "\\`dav" method)
1490                 (list (tramp-gvfs-mount-spec-entry "type" "dav")
1491                       (tramp-gvfs-mount-spec-entry "host" host)
1492                       (tramp-gvfs-mount-spec-entry "ssl" ssl)))
1493                (t
1494                 (list (tramp-gvfs-mount-spec-entry "type" method)
1495                       (tramp-gvfs-mount-spec-entry "host" host))))
1496             ,@(when user
1497                 (list (tramp-gvfs-mount-spec-entry "user" user)))
1498             ,@(when domain
1499                 (list (tramp-gvfs-mount-spec-entry "domain" domain)))
1500             ,@(when port
1501                 (list (tramp-gvfs-mount-spec-entry
1502                        "port" (number-to-string port))))))
1503          (mount-pref
1504           (if (and (string-match "\\`dav" method)
1505                    (string-match "^/?[^/]+" localname))
1506               (match-string 0 localname)
1507             "/")))
1508
1509     ;; Return.
1510     `(:struct ,(tramp-gvfs-dbus-string-to-byte-array mount-pref) ,mount-spec)))
1511
1512 \f
1513 ;; Connection functions.
1514
1515 (defun tramp-gvfs-maybe-open-connection (vec)
1516   "Maybe open a connection VEC.
1517 Does not do anything if a connection is already open, but re-opens the
1518 connection if a previous connection has died for some reason."
1519   (tramp-check-proper-method-and-host vec)
1520
1521   ;; We set the file name, in case there are incoming D-Bus signals or
1522   ;; D-Bus errors.
1523   (setq tramp-gvfs-dbus-event-vector vec)
1524
1525   ;; For password handling, we need a process bound to the connection
1526   ;; buffer.  Therefore, we create a dummy process.  Maybe there is a
1527   ;; better solution?
1528   (unless (get-buffer-process (tramp-get-connection-buffer vec))
1529     (let ((p (make-network-process
1530               :name (tramp-buffer-name vec)
1531               :buffer (tramp-get-connection-buffer vec)
1532               :server t :host 'local :service t)))
1533       (tramp-compat-set-process-query-on-exit-flag p nil)))
1534
1535   (unless (tramp-gvfs-connection-mounted-p vec)
1536     (let* ((method (tramp-file-name-method vec))
1537            (user (tramp-file-name-user vec))
1538            (host (tramp-file-name-host vec))
1539            (localname (tramp-file-name-localname vec))
1540            (object-path
1541             (tramp-gvfs-object-path
1542              (tramp-make-tramp-file-name method user host ""))))
1543
1544       (when (and (string-equal method "smb")
1545                  (string-equal localname "/"))
1546         (tramp-error vec 'file-error "Filename must contain a Windows share"))
1547
1548       (with-tramp-progress-reporter
1549           vec 3
1550           (if (zerop (length user))
1551               (format "Opening connection for %s using %s" host method)
1552             (format "Opening connection for %s@%s using %s" user host method))
1553
1554         ;; Enable `auth-source'.
1555         (tramp-set-connection-property vec "first-password-request" t)
1556
1557         ;; There will be a callback of "askPassword" when a password is
1558         ;; needed.
1559         (dbus-register-method
1560          :session dbus-service-emacs object-path
1561          tramp-gvfs-interface-mountoperation "askPassword"
1562          'tramp-gvfs-handler-askpassword)
1563         (dbus-register-method
1564          :session dbus-service-emacs object-path
1565          tramp-gvfs-interface-mountoperation "AskPassword"
1566          'tramp-gvfs-handler-askpassword)
1567
1568         ;; There could be a callback of "askQuestion" when adding fingerprint.
1569         (dbus-register-method
1570          :session dbus-service-emacs object-path
1571          tramp-gvfs-interface-mountoperation "askQuestion"
1572          'tramp-gvfs-handler-askquestion)
1573         (dbus-register-method
1574          :session dbus-service-emacs object-path
1575          tramp-gvfs-interface-mountoperation "AskQuestion"
1576          'tramp-gvfs-handler-askquestion)
1577
1578         ;; The call must be asynchronously, because of the "askPassword"
1579         ;; or "askQuestion"callbacks.
1580         (if (string-match "(so)$" tramp-gvfs-mountlocation-signature)
1581             (with-tramp-dbus-call-method vec nil
1582               :session tramp-gvfs-service-daemon tramp-gvfs-path-mounttracker
1583               tramp-gvfs-interface-mounttracker tramp-gvfs-mountlocation
1584               (tramp-gvfs-mount-spec vec)
1585               `(:struct :string ,(dbus-get-unique-name :session)
1586                         :object-path ,object-path))
1587           (with-tramp-dbus-call-method vec nil
1588             :session tramp-gvfs-service-daemon tramp-gvfs-path-mounttracker
1589             tramp-gvfs-interface-mounttracker tramp-gvfs-mountlocation
1590             (tramp-gvfs-mount-spec vec)
1591             :string (dbus-get-unique-name :session) :object-path object-path))
1592
1593         ;; We must wait, until the mount is applied.  This will be
1594         ;; indicated by the "mounted" signal, i.e. the "fuse-mountpoint"
1595         ;; file property.
1596         (with-timeout
1597             ((or (tramp-get-method-parameter vec 'tramp-connection-timeout)
1598                  tramp-connection-timeout)
1599              (if (zerop (length (tramp-file-name-user vec)))
1600                  (tramp-error
1601                   vec 'file-error
1602                   "Timeout reached mounting %s using %s" host method)
1603                (tramp-error
1604                 vec 'file-error
1605                 "Timeout reached mounting %s@%s using %s" user host method)))
1606           (while (not (tramp-get-file-property vec "/" "fuse-mountpoint" nil))
1607             (read-event nil nil 0.1)))
1608
1609         ;; If `tramp-gvfs-handler-askquestion' has returned "No", it
1610         ;; is marked with the fuse-mountpoint "/".  We shall react.
1611         (when (string-equal
1612                (tramp-get-file-property vec "/" "fuse-mountpoint" "") "/")
1613           (tramp-error vec 'file-error "FUSE mount denied")))))
1614
1615   ;; In `tramp-check-cached-permissions', the connection properties
1616   ;; {uig,gid}-{integer,string} are used.  We set them to their local
1617   ;; counterparts.
1618   (with-tramp-connection-property
1619    vec "uid-integer" (tramp-get-local-uid 'integer))
1620   (with-tramp-connection-property
1621    vec "gid-integer" (tramp-get-local-gid 'integer))
1622   (with-tramp-connection-property
1623    vec "uid-string" (tramp-get-local-uid 'string))
1624   (with-tramp-connection-property
1625    vec "gid-string" (tramp-get-local-gid 'string)))
1626
1627 (defun tramp-gvfs-send-command (vec command &rest args)
1628   "Send the COMMAND with its ARGS to connection VEC.
1629 COMMAND is usually a command from the gvfs-* utilities.
1630 `call-process' is applied, and it returns t if the return code is zero."
1631   (with-current-buffer (tramp-get-connection-buffer vec)
1632     (tramp-gvfs-maybe-open-connection vec)
1633     (erase-buffer)
1634     (zerop (apply 'tramp-call-process vec command nil t nil args))))
1635
1636 \f
1637 ;; D-Bus BLUEZ functions.
1638
1639 (defun tramp-bluez-list-devices ()
1640   "Return all discovered bluetooth devices as list.
1641 Every entry is a list (NAME ADDRESS).
1642
1643 If `tramp-bluez-discover-devices-timeout' is an integer, and the last
1644 discovery happened more time before indicated there, a rescan will be
1645 started, which lasts some ten seconds.  Otherwise, cached results will
1646 be used."
1647   ;; Reset the scanned devices list if time has passed.
1648   (and (integerp tramp-bluez-discover-devices-timeout)
1649        (integerp tramp-bluez-discovery)
1650        (> (tramp-time-diff (current-time) tramp-bluez-discovery)
1651           tramp-bluez-discover-devices-timeout)
1652        (setq tramp-bluez-devices nil))
1653
1654   ;; Rescan if needed.
1655   (unless tramp-bluez-devices
1656     (let ((object-path
1657            (with-tramp-dbus-call-method tramp-gvfs-dbus-event-vector t
1658              :system tramp-bluez-service "/"
1659              tramp-bluez-interface-manager "DefaultAdapter")))
1660       (setq tramp-bluez-devices nil
1661             tramp-bluez-discovery t)
1662       (with-tramp-dbus-call-method tramp-gvfs-dbus-event-vector nil
1663         :system tramp-bluez-service object-path
1664         tramp-bluez-interface-adapter "StartDiscovery")
1665       (while tramp-bluez-discovery
1666         (read-event nil nil 0.1))))
1667   (setq tramp-bluez-discovery (current-time))
1668   (tramp-message tramp-gvfs-dbus-event-vector 10 "%s" tramp-bluez-devices)
1669   tramp-bluez-devices)
1670
1671 (defun tramp-bluez-property-changed (property value)
1672   "Signal handler for the \"org.bluez.Adapter.PropertyChanged\" signal."
1673   (tramp-message tramp-gvfs-dbus-event-vector 6 "%s %s" property value)
1674   (cond
1675    ((string-equal property "Discovering")
1676     (unless (car value)
1677       ;; "Discovering" FALSE means discovery run has been completed.
1678       ;; We stop it, because we don't need another run.
1679       (setq tramp-bluez-discovery nil)
1680       (with-tramp-dbus-call-method tramp-gvfs-dbus-event-vector t
1681         :system tramp-bluez-service (dbus-event-path-name last-input-event)
1682         tramp-bluez-interface-adapter "StopDiscovery")))))
1683
1684 (when tramp-gvfs-enabled
1685   (dbus-register-signal
1686    :system nil nil tramp-bluez-interface-adapter "PropertyChanged"
1687    'tramp-bluez-property-changed))
1688
1689 (defun tramp-bluez-device-found (device args)
1690   "Signal handler for the \"org.bluez.Adapter.DeviceFound\" signal."
1691   (tramp-message tramp-gvfs-dbus-event-vector 6 "%s %s" device args)
1692   (let ((alias (car (cadr (assoc "Alias" args))))
1693         (address (car (cadr (assoc "Address" args)))))
1694     ;; Maybe we shall check the device class for being a proper
1695     ;; device, and call also SDP in order to find the obex service.
1696     (add-to-list 'tramp-bluez-devices (list alias address))))
1697
1698 (when tramp-gvfs-enabled
1699   (dbus-register-signal
1700    :system nil nil tramp-bluez-interface-adapter "DeviceFound"
1701    'tramp-bluez-device-found))
1702
1703 (defun tramp-bluez-parse-device-names (_ignore)
1704   "Return a list of (nil host) tuples allowed to access."
1705   (mapcar
1706    (lambda (x) (list nil (car x)))
1707    (tramp-bluez-list-devices)))
1708
1709 ;; Add completion function for OBEX method.
1710 (when (and tramp-gvfs-enabled
1711            (member tramp-bluez-service (dbus-list-known-names :system)))
1712   (tramp-set-completion-function
1713    "obex" '((tramp-bluez-parse-device-names ""))))
1714
1715 \f
1716 ;; D-Bus zeroconf functions.
1717
1718 (defun tramp-zeroconf-parse-workstation-device-names (_ignore)
1719   "Return a list of (user host) tuples allowed to access."
1720   (mapcar
1721    (lambda (x)
1722      (list nil (zeroconf-service-host x)))
1723    (zeroconf-list-services "_workstation._tcp")))
1724
1725 (defun tramp-zeroconf-parse-webdav-device-names (_ignore)
1726   "Return a list of (user host) tuples allowed to access."
1727   (mapcar
1728    (lambda (x)
1729      (let ((host (zeroconf-service-host x))
1730            (port (zeroconf-service-port x))
1731            (text (zeroconf-service-txt x))
1732            user)
1733        (when port
1734          (setq host (format "%s%s%d" host tramp-prefix-port-regexp port)))
1735        ;; A user is marked in a TXT field like "u=guest".
1736        (while text
1737          (when (string-match "u=\\(.+\\)$" (car text))
1738            (setq user (match-string 1 (car text))))
1739          (setq text (cdr text)))
1740        (list user host)))
1741    (zeroconf-list-services "_webdav._tcp")))
1742
1743 ;; Add completion function for SFTP, DAV and DAVS methods.
1744 (when (and tramp-gvfs-enabled
1745            (member zeroconf-service-avahi (dbus-list-known-names :system)))
1746   (zeroconf-init tramp-gvfs-zeroconf-domain)
1747   (tramp-set-completion-function
1748    "sftp" '((tramp-zeroconf-parse-workstation-device-names "")))
1749   (tramp-set-completion-function
1750    "dav" '((tramp-zeroconf-parse-webdav-device-names "")))
1751   (tramp-set-completion-function
1752    "davs" '((tramp-zeroconf-parse-webdav-device-names ""))))
1753
1754 \f
1755 ;; D-Bus SYNCE functions.
1756
1757 (defun tramp-synce-list-devices ()
1758   "Return all discovered synce devices as list.
1759 They are retrieved from the hal daemon."
1760   (let (tramp-synce-devices)
1761     (dolist (device
1762              (with-tramp-dbus-call-method tramp-gvfs-dbus-event-vector t
1763                :system tramp-hal-service tramp-hal-path-manager
1764                tramp-hal-interface-manager "GetAllDevices"))
1765       (when (with-tramp-dbus-call-method tramp-gvfs-dbus-event-vector t
1766               :system tramp-hal-service device tramp-hal-interface-device
1767               "PropertyExists" "sync.plugin")
1768         (let ((prop
1769                (with-tramp-dbus-call-method
1770                 tramp-gvfs-dbus-event-vector t
1771                 :system tramp-hal-service device tramp-hal-interface-device
1772                 "GetPropertyString" "pda.pocketpc.name")))
1773           (unless (member prop tramp-synce-devices)
1774             (push prop tramp-synce-devices)))))
1775     (tramp-message tramp-gvfs-dbus-event-vector 10 "%s" tramp-synce-devices)
1776     tramp-synce-devices))
1777
1778 (defun tramp-synce-parse-device-names (_ignore)
1779   "Return a list of (nil host) tuples allowed to access."
1780   (mapcar
1781    (lambda (x) (list nil x))
1782    (tramp-synce-list-devices)))
1783
1784 ;; Add completion function for SYNCE method.
1785 (when tramp-gvfs-enabled
1786   (tramp-set-completion-function
1787    "synce" '((tramp-synce-parse-device-names ""))))
1788
1789 (add-hook 'tramp-unload-hook
1790           (lambda ()
1791             (unload-feature 'tramp-gvfs 'force)))
1792
1793 (provide 'tramp-gvfs)
1794
1795 ;;; TODO:
1796
1797 ;; * Host name completion via smb-server or smb-network.
1798 ;; * Check how two shares of the same SMB server can be mounted in
1799 ;;   parallel.
1800 ;; * Apply SDP on bluetooth devices, in order to filter out obex
1801 ;;   capability.
1802 ;; * Implement obex for other serial communication but bluetooth.
1803
1804 ;;; tramp-gvfs.el ends here