| blob | c3e36975decaa431e2ffedb03e87b37e72d2dffd |
1 @echo off\r
2 rem ----------------------------------------------------------------------\r
3 rem Configuration script for MSDOS\r
4 rem Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2001, 2004\r
5 rem Free Software Foundation, Inc.\r
6 \r
7 rem This file is part of GNU Emacs.\r
8 \r
9 rem GNU Emacs is free software; you can redistribute it and/or modify\r
10 rem it under the terms of the GNU General Public License as published by\r
11 rem the Free Software Foundation; either version 2, or (at your option)\r
12 rem any later version.\r
13 \r
14 rem GNU Emacs is distributed in the hope that it will be useful,\r
15 rem but WITHOUT ANY WARRANTY; without even the implied warranty of\r
16 rem MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the\r
17 rem GNU General Public License for more details.\r
18 \r
19 rem You should have received a copy of the GNU General Public License\r
20 rem along with GNU Emacs; see the file COPYING. If not, write to the\r
21 rem Free Software Foundation, Inc., 59 Temple Place - Suite 330,\r
22 rem Boston, MA 02111-1307, USA.\r
23 rem ----------------------------------------------------------------------\r
24 rem YOU'LL NEED THE FOLLOWING UTILITIES TO MAKE EMACS:\r
25 rem\r
26 rem + msdos version 3 or better.\r
27 rem + DJGPP version 1.12maint1 or later (version 2.03 or later recommended).\r
28 rem + make utility that allows breaking of the 128 chars limit on\r
29 rem command lines. ndmake (as of version 4.5) won't work due to a\r
30 rem line length limit. The make that comes with DJGPP does work.\r
31 rem + rm and mv (from GNU file utilities).\r
32 rem + sed (you can use the port that comes with DJGPP).\r
33 rem\r
34 rem You should be able to get all the above utilities from the DJGPP FTP\r
35 rem site, ftp.delorie.com, in the directory "pub/djgpp/current/v2gnu".\r
36 rem ----------------------------------------------------------------------\r
37 set X11=\r
38 set nodebug=\r
39 set djgpp_ver=\r
40 if "%1" == "" goto usage\r
41 rem ----------------------------------------------------------------------\r
42 rem See if their environment is large enough. We need 28 bytes.\r
43 set $foo$=789012345678901234567\r
44 if not "%$foo$%" == "789012345678901234567" goto SmallEnv\r
45 set $foo$=\r
46 :again\r
47 if "%1" == "" goto usage\r
48 if "%1" == "--with-x" goto withx\r
49 if "%1" == "--no-debug" goto nodebug\r
50 if "%1" == "msdos" goto msdos\r
51 :usage\r
52 echo Usage: config [--with-x] [--no-debug] msdos\r
53 echo [Read the script before you run it.]\r
54 goto end\r
55 rem ----------------------------------------------------------------------\r
56 :withx\r
57 set X11=Y\r
58 shift\r
59 goto again\r
60 rem ----------------------------------------------------------------------\r
61 :nodebug\r
62 set nodebug=Y\r
63 shift\r
64 goto again\r
65 rem ----------------------------------------------------------------------\r
66 :msdos\r
67 Echo Checking whether 'sed' is available...\r
68 sed -e "w junk.$$$" <Nul\r
69 If Exist junk.$$$ Goto sedOk\r
70 Echo To configure 'Emacs' you need to have 'sed'!\r
71 Goto End\r
72 :sedOk\r
73 Echo Checking whether 'rm' is available...\r
74 rm -f junk.$$$\r
75 If Not Exist junk.$$$ Goto rmOk\r
76 Echo To configure 'Emacs' you need to have 'rm'!\r
77 Goto End\r
78 :rmOk\r
79 Echo Checking whether 'mv' is available...\r
80 rm -f junk.1 junk.2\r
81 echo foo >junk.1\r
82 mv junk.1 ./junk.2\r
83 If Exist junk.2 Goto mvOk\r
84 Echo To configure 'Emacs' you need to have 'mv'!\r
85 rm -f junk.1\r
86 Goto End\r
87 :mvOk\r
88 rm -f junk.2\r
89 Echo Checking whether 'gcc' is available...\r
90 echo main(){} >junk.c\r
91 gcc -c junk.c\r
92 if exist junk.o goto gccOk\r
93 Echo To configure 'Emacs' you need to have 'gcc'!\r
94 rm -f junk.c\r
95 Goto End\r
96 :gccOk\r
97 rm -f junk.c junk.o junk junk.exe\r
98 Echo Checking what version of DJGPP is installed...\r
99 If Not "%DJGPP%" == "" goto djgppOk\r
100 Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!\r
101 Goto End\r
102 :djgppOk\r
103 echo int main() >junk.c\r
104 echo #ifdef __DJGPP__ >>junk.c\r
105 echo {return (__DJGPP__)*10;} >>junk.c\r
106 echo #else >>junk.c\r
107 echo #ifdef __GO32__ >>junk.c\r
108 echo {return 10;} >>junk.c\r
109 echo #else >>junk.c\r
110 echo {return 0;} >>junk.c\r
111 echo #endif >>junk.c\r
112 echo #endif >>junk.c\r
113 gcc -o junk junk.c\r
114 if not exist junk.exe coff2exe junk\r
115 junk\r
116 If ErrorLevel 10 Goto go32Ok\r
117 rm -f junk.c junk junk.exe\r
118 Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!\r
119 Goto End\r
120 :go32Ok\r
121 set djgpp_ver=1\r
122 If ErrorLevel 20 set djgpp_ver=2\r
123 rm -f junk.c junk junk.exe\r
124 rem DJECHO is used by the top-level Makefile\r
125 Echo Checking whether 'djecho' is available...\r
126 redir -o Nul -eo djecho -o junk.$$$ foo\r
127 If Exist junk.$$$ Goto djechoOk\r
128 Echo To build 'Emacs' you need the 'djecho.exe' program!\r
129 Echo 'djecho.exe' is part of 'djdevNNN.zip' basic DJGPP development kit.\r
130 Echo Versions of DJGPP before 2.02 called this program 'echo.exe'.\r
131 Echo Either unpack 'djecho.exe' from the 'djdevNNN.zip' archive,\r
132 Echo or, if you have 'echo.exe', copy it to 'djecho.exe'.\r
133 Echo Then run CONFIG.BAT again with the same arguments you did now.\r
134 Goto End\r
135 :djechoOk\r
136 rm -f junk.$$$\r
137 Echo Configuring for DJGPP Version %DJGPP_VER% ...\r
138 Rem ----------------------------------------------------------------------\r
139 Echo Configuring the source directory...\r
140 cd src\r
141 \r
142 rem Create "epaths.h"\r
143 sed -f ../msdos/sed4.inp <epaths.in >epaths.tmp\r
144 update epaths.tmp epaths.h >nul\r
145 rm -f epaths.tmp\r
146 \r
147 rem Create "config.h"\r
148 rm -f config.h2 config.tmp\r
149 sed -e '' config.in > config.tmp\r
150 if "%X11%" == "" goto src4\r
151 sed -f ../msdos/sed2x.inp <config.in >config.tmp\r
152 :src4\r
153 if "%DJGPP_VER%" == "2" Goto src41\r
154 sed -f ../msdos/sed2.inp <config.tmp >config.h2\r
155 goto src42\r
156 :src41\r
157 sed -f ../msdos/sed2v2.inp <config.tmp >config.h2\r
158 :src42\r
159 update config.h2 config.h >nul\r
160 rm -f config.tmp config.h2\r
161 \r
162 rem On my system dir.h gets in the way. It's a VMS file so who cares.\r
163 if exist dir.h ren dir.h vmsdir.h\r
164 \r
165 rem Create "makefile" from "makefile.in".\r
166 rm -f Makefile junk.c\r
167 sed -e "1,/== start of cpp stuff ==/s@^# .*$@@" <Makefile.in >junk.c\r
168 If "%DJGPP_VER%" == "1" Goto mfV1\r
169 gcc -E -traditional junk.c | sed -f ../msdos/sed1v2.inp >Makefile\r
170 goto mfDone\r
171 :mfV1\r
172 gcc -E -traditional junk.c | sed -f ../msdos/sed1.inp >Makefile\r
173 :mfDone\r
174 rm -f junk.c\r
175 \r
176 if "%X11%" == "" goto src5\r
177 mv Makefile makefile.tmp\r
178 sed -f ../msdos/sed1x.inp <makefile.tmp >Makefile\r
179 rm -f makefile.tmp\r
180 :src5\r
181 \r
182 if "%nodebug%" == "" goto src6\r
183 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp\r
184 sed -e "/^LDFLAGS *=/s/=/=-s/" <makefile.tmp >Makefile\r
185 rm -f makefile.tmp\r
186 :src6\r
187 cd ..\r
188 rem ----------------------------------------------------------------------\r
189 Echo Configuring the library source directory...\r
190 cd lib-src\r
191 rem Create "makefile" from "makefile.in".\r
192 sed -e "1,/== start of cpp stuff ==/s@^#[ ].*$@@" <Makefile.in >junk.c\r
193 gcc -E -traditional -I. -I../src junk.c | sed -e "s/^ / /" -e "/^#/d" -e "/^[ \f]*$/d" >makefile.new\r
194 If "%DJGPP_VER%" == "2" goto libsrc-v2\r
195 sed -f ../msdos/sed3.inp <makefile.new >Makefile\r
196 Goto libsrc2\r
197 :libsrc-v2\r
198 sed -f ../msdos/sed3v2.inp <makefile.new >Makefile\r
199 :libsrc2\r
200 rm -f makefile.new junk.c\r
201 if "%nodebug%" == "" goto libsrc3\r
202 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp\r
203 sed -e "/^ALL_CFLAGS *=/s/=/= -s/" <makefile.tmp >Makefile\r
204 rm -f makefile.tmp\r
205 :libsrc3\r
206 cd ..\r
207 rem ----------------------------------------------------------------------\r
208 if "%X11%" == "" goto oldx1\r
209 Echo Configuring the oldxmenu directory...\r
210 cd oldxmenu\r
211 sed -f ../msdos/sed5x.inp <Makefile.in >Makefile\r
212 if "%nodebug%" == "" goto oldx2\r
213 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp\r
214 mv -f makefile.tmp Makefile\r
215 :oldx2\r
216 cd ..\r
217 :oldx1\r
218 rem ----------------------------------------------------------------------\r
219 Echo Configuring the manual directory...\r
220 cd man\r
221 sed -f ../msdos/sed6.inp < Makefile.in > Makefile\r
222 cd ..\r
223 rem ----------------------------------------------------------------------\r
224 Echo Configuring the ELisp manual directory...\r
225 cd lispref\r
226 sed -f ../msdos/sed6.inp < Makefile.in > Makefile\r
227 cd ..\r
228 rem ----------------------------------------------------------------------\r
229 Echo Configuring the ELisp Introduction manual directory...\r
230 Rem The two variants for the line below is for when the shell\r
231 Rem supports long file names but DJGPP does not\r
232 if exist lispintro\Makefile.in cd lispintro\r
233 if exist lispintr\Makefile.in cd lispintr\r
234 sed -f ../msdos/sed6.inp < Makefile.in > Makefile\r
235 cd ..\r
236 rem ----------------------------------------------------------------------\r
237 Echo Configuring the lisp directory...\r
238 cd lisp\r
239 sed -f ../msdos/sedlisp.inp < Makefile.in > Makefile\r
240 cd ..\r
241 rem ----------------------------------------------------------------------\r
242 If not Exist leim\quail\latin-pre.el goto maindir\r
243 Echo Configuring the leim directory...\r
244 cd leim\r
245 sed -f ../msdos/sedleim.inp < Makefile.in > Makefile\r
246 cd ..\r
247 rem ----------------------------------------------------------------------\r
248 :maindir\r
249 Echo Configuring the main directory...\r
250 If "%DJGPP_VER%" == "1" goto mainv1\r
251 Echo Looking for the GDB init file...\r
252 If Exist src\.gdbinit update src/.gdbinit src/_gdbinit\r
253 If Exist src\_gdbinit goto gdbinitOk\r
254 Echo ERROR:\r
255 Echo I cannot find the GDB init file. It was called ".gdbinit" in\r
256 Echo the Emacs distribution, but was probably renamed to some other\r
257 Echo name without the leading dot when you untarred the archive.\r
258 Echo It should be in the "src/" subdirectory. Please make sure this\r
259 Echo file exists and is called "_gdbinit" with a leading underscore.\r
260 Echo Then run CONFIG.BAT again with the same arguments you did now.\r
261 goto End\r
262 :gdbinitOk\r
263 Echo Looking for the GDB init file...found\r
264 copy msdos\mainmake.v2 Makefile >nul\r
265 :mainv1\r
266 If "%DJGPP_VER%" == "1" copy msdos\mainmake Makefile >nul\r
267 rem ----------------------------------------------------------------------\r
268 goto End\r
269 :SmallEnv\r
270 echo Your environment size is too small. Please enlarge it and run me again.\r
271 echo For example, type "command.com /e:2048" to have 2048 bytes available.\r
272 set $foo$=\r
273 :end\r
274 set X11=\r
275 set nodebug=\r
276 set djgpp_ver=\r
277 \r
278 goto skipArchTag\r
279 arch-tag: 2d2fed23-4dc6-4006-a2e4-49daf0031f33\r
280 :skipArchTag\r