lisp/help-mode.el

   1 ;;; help-mode.el --- `help-mode' used by *Help* buffers
   2
   3 ;; Copyright (C) 1985-1986, 1993-1994, 1998-2016 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: help, internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Defines `help-mode', which is the mode used by *Help* buffers, and
  28 ;; associated support machinery, such as adding hyperlinks, etc.,
  29
  30 ;;; Code:
  31
  32 (require 'button)
  33 (require 'cl-lib)
  34 (eval-when-compile (require 'easymenu))
  35
  36 (defvar help-mode-map
  37   (let ((map (make-sparse-keymap)))
  38     (set-keymap-parent map (make-composed-keymap button-buffer-map
  39                                                  special-mode-map))
  40     (define-key map [mouse-2] 'help-follow-mouse)
  41     (define-key map "l" 'help-go-back)
  42     (define-key map "r" 'help-go-forward)
  43     (define-key map "\C-c\C-b" 'help-go-back)
  44     (define-key map "\C-c\C-f" 'help-go-forward)
  45     (define-key map [XF86Back] 'help-go-back)
  46     (define-key map [XF86Forward] 'help-go-forward)
  47     (define-key map "\C-c\C-c" 'help-follow-symbol)
  48     (define-key map "\r" 'help-follow)
  49     map)
  50   "Keymap for help mode.")
  51
  52 (easy-menu-define help-mode-menu help-mode-map
  53   "Menu for Help Mode."
  54   '("Help-Mode"
  55     ["Show Help for Symbol" help-follow-symbol
  56      :help "Show the docs for the symbol at point"]
  57     ["Previous Topic" help-go-back
  58      :help "Go back to previous topic in this help buffer"]
  59     ["Next Topic" help-go-forward
  60      :help "Go back to next topic in this help buffer"]
  61     ["Move to Previous Button" backward-button
  62      :help "Move to the Next Button in the help buffer"]
  63     ["Move to Next Button" forward-button
  64       :help "Move to the Next Button in the help buffer"]))
  65
  66 (defvar help-xref-stack nil
  67   "A stack of ways by which to return to help buffers after following xrefs.
  68 Used by `help-follow' and `help-xref-go-back'.
  69 An element looks like (POSITION FUNCTION ARGS...).
  70 To use the element, do (apply FUNCTION ARGS) then goto the point.")
  71 (put 'help-xref-stack 'permanent-local t)
  72 (make-variable-buffer-local 'help-xref-stack)
  73
  74 (defvar help-xref-forward-stack nil
  75   "A stack used to navigate help forwards after using the back button.
  76 Used by `help-follow' and `help-xref-go-forward'.
  77 An element looks like (POSITION FUNCTION ARGS...).
  78 To use the element, do (apply FUNCTION ARGS) then goto the point.")
  79 (put 'help-xref-forward-stack 'permanent-local t)
  80 (make-variable-buffer-local 'help-xref-forward-stack)
  81
  82 (defvar help-xref-stack-item nil
  83   "An item for `help-follow' in this buffer to push onto `help-xref-stack'.
  84 The format is (FUNCTION ARGS...).")
  85 (put 'help-xref-stack-item 'permanent-local t)
  86 (make-variable-buffer-local 'help-xref-stack-item)
  87
  88 (defvar help-xref-stack-forward-item nil
  89   "An item for `help-go-back' to push onto `help-xref-forward-stack'.
  90 The format is (FUNCTION ARGS...).")
  91 (put 'help-xref-stack-forward-item 'permanent-local t)
  92 (make-variable-buffer-local 'help-xref-stack-forward-item)
  93
  94 (setq-default help-xref-stack nil help-xref-stack-item nil)
  95 (setq-default help-xref-forward-stack nil help-xref-forward-stack-item nil)
  96
  97 (defcustom help-mode-hook nil
  98   "Hook run by `help-mode'."
  99   :type 'hook
 100   :group 'help)
 101 \f
 102 ;; Button types used by help
 103
 104 (define-button-type 'help-xref
 105   'follow-link t
 106   'action #'help-button-action)
 107
 108 (defun help-button-action (button)
 109   "Call BUTTON's help function."
 110   (help-do-xref nil
 111                 (button-get button 'help-function)
 112                 (button-get button 'help-args)))
 113
 114 ;; These 6 calls to define-button-type were generated in a dolist
 115 ;; loop, but that is bad because it means these button types don't
 116 ;; have an easily found definition.
 117
 118 (define-button-type 'help-function
 119   :supertype 'help-xref
 120   'help-function 'describe-function
 121   'help-echo (purecopy "mouse-2, RET: describe this function"))
 122
 123 (define-button-type 'help-variable
 124   :supertype 'help-xref
 125   'help-function 'describe-variable
 126   'help-echo (purecopy "mouse-2, RET: describe this variable"))
 127
 128 (define-button-type 'help-face
 129   :supertype 'help-xref
 130   'help-function 'describe-face
 131   'help-echo (purecopy "mouse-2, RET: describe this face"))
 132
 133 (define-button-type 'help-coding-system
 134   :supertype 'help-xref
 135   'help-function 'describe-coding-system
 136   'help-echo (purecopy "mouse-2, RET: describe this coding system"))
 137
 138 (define-button-type 'help-input-method
 139   :supertype 'help-xref
 140   'help-function 'describe-input-method
 141   'help-echo (purecopy "mouse-2, RET: describe this input method"))
 142
 143 (define-button-type 'help-character-set
 144   :supertype 'help-xref
 145   'help-function 'describe-character-set
 146   'help-echo (purecopy "mouse-2, RET: describe this character set"))
 147
 148 ;; Make some more idiosyncratic button types.
 149
 150 (define-button-type 'help-symbol
 151   :supertype 'help-xref
 152   'help-function #'describe-symbol
 153   'help-echo (purecopy "mouse-2, RET: describe this symbol"))
 154
 155 (define-button-type 'help-back
 156   :supertype 'help-xref
 157   'help-function #'help-xref-go-back
 158   'help-echo (purecopy "mouse-2, RET: go back to previous help buffer"))
 159
 160 (define-button-type 'help-forward
 161   :supertype 'help-xref
 162   'help-function #'help-xref-go-forward
 163   'help-echo (purecopy "mouse-2, RET: move forward to next help buffer"))
 164
 165 (define-button-type 'help-info-variable
 166   :supertype 'help-xref
 167   ;; the name of the variable is put before the argument to Info
 168   'help-function (lambda (_a v) (info v))
 169   'help-echo (purecopy "mouse-2, RET: read this Info node"))
 170
 171 (define-button-type 'help-info
 172   :supertype 'help-xref
 173   'help-function #'info
 174   'help-echo (purecopy "mouse-2, RET: read this Info node"))
 175
 176 (define-button-type 'help-url
 177   :supertype 'help-xref
 178   'help-function #'browse-url
 179   'help-echo (purecopy "mouse-2, RET: view this URL in a browser"))
 180
 181 (define-button-type 'help-customize-variable
 182   :supertype 'help-xref
 183   'help-function (lambda (v)
 184                    (customize-variable v))
 185   'help-echo (purecopy "mouse-2, RET: customize variable"))
 186
 187 (define-button-type 'help-customize-face
 188   :supertype 'help-xref
 189   'help-function (lambda (v)
 190                    (customize-face v))
 191   'help-echo (purecopy "mouse-2, RET: customize face"))
 192
 193 (define-button-type 'help-function-def
 194   :supertype 'help-xref
 195   'help-function (lambda (fun file &optional type)
 196                    (require 'find-func)
 197                    (when (eq file 'C-source)
 198                      (setq file
 199                            (help-C-file-name (indirect-function fun) 'fun)))
 200                    ;; Don't use find-function-noselect because it follows
 201                    ;; aliases (which fails for built-in functions).
 202                    (let ((location
 203                           (find-function-search-for-symbol fun type file)))
 204                      (pop-to-buffer (car location))
 205                      (if (cdr location)
 206                          (goto-char (cdr location))
 207                        (message "Unable to find location in file"))))
 208   'help-echo (purecopy "mouse-2, RET: find function's definition"))
 209
 210 (define-button-type 'help-function-cmacro ; FIXME: Obsolete since 24.4.
 211   :supertype 'help-xref
 212   'help-function (lambda (fun file)
 213                    (setq file (locate-library file t))
 214                    (if (and file (file-readable-p file))
 215                        (progn
 216                          (pop-to-buffer (find-file-noselect file))
 217                          (goto-char (point-min))
 218                          (if (re-search-forward
 219                               (format "^[ \t]*(\\(cl-\\)?define-compiler-macro[ \t]+%s"
 220                                       (regexp-quote (symbol-name fun)))
 221                               nil t)
 222                              (forward-line 0)
 223                            (message "Unable to find location in file")))
 224                      (message "Unable to find file")))
 225   'help-echo (purecopy "mouse-2, RET: find function's compiler macro"))
 226
 227 (define-button-type 'help-variable-def
 228   :supertype 'help-xref
 229   'help-function (lambda (var &optional file)
 230                    (when (eq file 'C-source)
 231                      (setq file (help-C-file-name var 'var)))
 232                    (let ((location (find-variable-noselect var file)))
 233                      (pop-to-buffer (car location))
 234                      (if (cdr location)
 235                        (goto-char (cdr location))
 236                        (message "Unable to find location in file"))))
 237   'help-echo (purecopy "mouse-2, RET: find variable's definition"))
 238
 239 (define-button-type 'help-face-def
 240   :supertype 'help-xref
 241   'help-function (lambda (fun file)
 242                    (require 'find-func)
 243                    ;; Don't use find-function-noselect because it follows
 244                    ;; aliases (which fails for built-in functions).
 245                    (let ((location
 246                           (find-function-search-for-symbol fun 'defface file)))
 247                      (pop-to-buffer (car location))
 248                      (if (cdr location)
 249                          (goto-char (cdr location))
 250                        (message "Unable to find location in file"))))
 251   'help-echo (purecopy "mouse-2, RET: find face's definition"))
 252
 253 (define-button-type 'help-package
 254   :supertype 'help-xref
 255   'help-function 'describe-package
 256   'help-echo (purecopy "mouse-2, RET: Describe package"))
 257
 258 (define-button-type 'help-package-def
 259   :supertype 'help-xref
 260   'help-function (lambda (file) (dired file))
 261   'help-echo (purecopy "mouse-2, RET: visit package directory"))
 262
 263 (define-button-type 'help-theme-def
 264   :supertype 'help-xref
 265   'help-function 'find-file
 266   'help-echo (purecopy "mouse-2, RET: visit theme file"))
 267
 268 (define-button-type 'help-theme-edit
 269   :supertype 'help-xref
 270   'help-function 'customize-create-theme
 271   'help-echo (purecopy "mouse-2, RET: edit this theme file"))
 272
 273 (define-button-type 'help-dir-local-var-def
 274   :supertype 'help-xref
 275   'help-function (lambda (_var &optional file)
 276                    ;; FIXME: this should go to the point where the
 277                    ;; local variable was defined.
 278                    (find-file file))
 279   'help-echo (purecopy "mouse-2, RET: open directory-local variables file"))
 280
 281 \f
 282 (defvar bookmark-make-record-function)
 283
 284 ;;;###autoload
 285 (define-derived-mode help-mode special-mode "Help"
 286   "Major mode for viewing help text and navigating references in it.
 287 Entry to this mode runs the normal hook `help-mode-hook'.
 288 Commands:
 289 \\{help-mode-map}"
 290   (set (make-local-variable 'revert-buffer-function)
 291        'help-mode-revert-buffer)
 292   (set (make-local-variable 'bookmark-make-record-function)
 293        'help-bookmark-make-record))
 294
 295 ;;;###autoload
 296 (defun help-mode-setup ()
 297   "Enter Help Mode in the current buffer."
 298   (help-mode)
 299   (setq buffer-read-only nil))
 300
 301 ;;;###autoload
 302 (defun help-mode-finish ()
 303   "Finalize Help Mode setup in current buffer."
 304   (when (derived-mode-p 'help-mode)
 305     (setq buffer-read-only t)
 306     (help-make-xrefs (current-buffer))))
 307 \f
 308 ;; Grokking cross-reference information in doc strings and
 309 ;; hyperlinking it.
 310
 311 ;; This may have some scope for extension and the same or something
 312 ;; similar should be done for widget doc strings, which currently use
 313 ;; another mechanism.
 314
 315 (defvar help-back-label (purecopy "[back]")
 316   "Label to use by `help-make-xrefs' for the go-back reference.")
 317
 318 (defvar help-forward-label (purecopy "[forward]")
 319   "Label to use by `help-make-xrefs' for the go-forward reference.")
 320
 321 (defconst help-xref-symbol-regexp
 322   (purecopy (concat "\\(\\<\\(\\(variable\\|option\\)\\|"  ; Link to var
 323                     "\\(function\\|command\\|call\\)\\|"   ; Link to function
 324                     "\\(face\\)\\|"                        ; Link to face
 325                     "\\(symbol\\|program\\|property\\)\\|" ; Don't link
 326                     "\\(source \\(?:code \\)?\\(?:of\\|for\\)\\)\\)"
 327                     "[ \t\n]+\\)?"
 328                     ;; Note starting with word-syntax character:
 329                     "['`‘]\\(\\sw\\(\\sw\\|\\s_\\)+\\)['’]"))
 330   "Regexp matching doc string references to symbols.
 331
 332 The words preceding the quoted symbol can be used in doc strings to
 333 distinguish references to variables, functions and symbols.")
 334
 335 (defvar help-xref-mule-regexp nil
 336   "Regexp matching doc string references to MULE-related keywords.
 337
 338 It is usually nil, and is temporarily bound to an appropriate regexp
 339 when help commands related to multilingual environment (e.g.,
 340 `describe-coding-system') are invoked.")
 341
 342
 343 (defconst help-xref-info-regexp
 344   (purecopy
 345    "\\<[Ii]nfo[ \t\n]+\\(node\\|anchor\\)[ \t\n]+['`‘]\\([^'’]+\\)['’]")
 346   "Regexp matching doc string references to an Info node.")
 347
 348 (defconst help-xref-url-regexp
 349   (purecopy "\\<[Uu][Rr][Ll][ \t\n]+['`‘]\\([^'’]+\\)['’]")
 350   "Regexp matching doc string references to a URL.")
 351
 352 ;;;###autoload
 353 (defun help-setup-xref (item interactive-p)
 354   "Invoked from commands using the \"*Help*\" buffer to install some xref info.
 355
 356 ITEM is a (FUNCTION . ARGS) pair appropriate for recreating the help
 357 buffer after following a reference.  INTERACTIVE-P is non-nil if the
 358 calling command was invoked interactively.  In this case the stack of
 359 items for help buffer \"back\" buttons is cleared.
 360
 361 This should be called very early, before the output buffer is cleared,
 362 because we want to record the \"previous\" position of point so we can
 363 restore it properly when going back."
 364   (with-current-buffer (help-buffer)
 365     (when help-xref-stack-item
 366       (push (cons (point) help-xref-stack-item) help-xref-stack)
 367       (setq help-xref-forward-stack nil))
 368     (when interactive-p
 369       (let ((tail (nthcdr 10 help-xref-stack)))
 370         ;; Truncate the stack.
 371         (if tail (setcdr tail nil))))
 372     (setq help-xref-stack-item item)))
 373
 374 (defvar help-xref-following nil
 375   "Non-nil when following a help cross-reference.")
 376
 377 ;;;###autoload
 378 (defun help-buffer ()
 379   "Return the name of a buffer for inserting help.
 380 If `help-xref-following' is non-nil, this is the name of the
 381 current buffer.  Signal an error if this buffer is not derived
 382 from `help-mode'.
 383 Otherwise, return \"*Help*\", creating a buffer with that name if
 384 it does not already exist."
 385   (buffer-name                          ;for with-output-to-temp-buffer
 386    (if (not help-xref-following)
 387        (get-buffer-create "*Help*")
 388      (unless (derived-mode-p 'help-mode)
 389        (error "Current buffer is not in Help mode"))
 390      (current-buffer))))
 391
 392 (defvar describe-symbol-backends
 393   `((nil ,#'fboundp ,(lambda (s _b _f) (describe-function s)))
 394     ("face" ,#'facep ,(lambda (s _b _f) (describe-face s)))
 395     (nil
 396      ,(lambda (symbol)
 397         (or (and (boundp symbol) (not (keywordp symbol)))
 398             (get symbol 'variable-documentation)))
 399      ,#'describe-variable)))
 400
 401 ;;;###autoload
 402 (defun help-make-xrefs (&optional buffer)
 403   "Parse and hyperlink documentation cross-references in the given BUFFER.
 404
 405 Find cross-reference information in a buffer and activate such cross
 406 references for selection with `help-follow'.  Cross-references have
 407 the canonical form `...'  and the type of reference may be
 408 disambiguated by the preceding word(s) used in
 409 `help-xref-symbol-regexp'.  Faces only get cross-referenced if
 410 preceded or followed by the word `face'.  Variables without
 411 variable documentation do not get cross-referenced, unless
 412 preceded by the word `variable' or `option'.
 413
 414 If the variable `help-xref-mule-regexp' is non-nil, find also
 415 cross-reference information related to multilingual environment
 416 \(e.g., coding-systems).  This variable is also used to disambiguate
 417 the type of reference as the same way as `help-xref-symbol-regexp'.
 418
 419 A special reference `back' is made to return back through a stack of
 420 help buffers.  Variable `help-back-label' specifies the text for
 421 that."
 422   (interactive "b")
 423   (with-current-buffer (or buffer (current-buffer))
 424     (save-excursion
 425       (goto-char (point-min))
 426       ;; Skip the header-type info, though it might be useful to parse
 427       ;; it at some stage (e.g. "function in `library'").
 428       (forward-paragraph)
 429       (let ((old-modified (buffer-modified-p)))
 430         (let ((stab (syntax-table))
 431               (case-fold-search t)
 432               (inhibit-read-only t))
 433           (set-syntax-table emacs-lisp-mode-syntax-table)
 434           ;; The following should probably be abstracted out.
 435           (unwind-protect
 436               (progn
 437                 ;; Info references
 438                 (save-excursion
 439                   (while (re-search-forward help-xref-info-regexp nil t)
 440                     (let ((data (match-string 2)))
 441                       (save-match-data
 442                         (unless (string-match "^([^)]+)" data)
 443                           (setq data (concat "(emacs)" data)))
 444                         (setq data ;; possible newlines if para filled
 445                               (replace-regexp-in-string "[ \t\n]+" " " data t t)))
 446                       (help-xref-button 2 'help-info data))))
 447                 ;; URLs
 448                 (save-excursion
 449                   (while (re-search-forward help-xref-url-regexp nil t)
 450                     (let ((data (match-string 1)))
 451                       (help-xref-button 1 'help-url data))))
 452                 ;; Mule related keywords.  Do this before trying
 453                 ;; `help-xref-symbol-regexp' because some of Mule
 454                 ;; keywords have variable or function definitions.
 455                 (if help-xref-mule-regexp
 456                     (save-excursion
 457                       (while (re-search-forward help-xref-mule-regexp nil t)
 458                         (let* ((data (match-string 7))
 459                                (sym (intern-soft data)))
 460                           (cond
 461                            ((match-string 3) ; coding system
 462                             (and sym (coding-system-p sym)
 463                                  (help-xref-button 6 'help-coding-system sym)))
 464                            ((match-string 4) ; input method
 465                             (and (assoc data input-method-alist)
 466                                  (help-xref-button 7 'help-input-method data)))
 467                            ((or (match-string 5) (match-string 6)) ; charset
 468                             (and sym (charsetp sym)
 469                                  (help-xref-button 7 'help-character-set sym)))
 470                            ((assoc data input-method-alist)
 471                             (help-xref-button 7 'help-character-set data))
 472                            ((and sym (coding-system-p sym))
 473                             (help-xref-button 7 'help-coding-system sym))
 474                            ((and sym (charsetp sym))
 475                             (help-xref-button 7 'help-character-set sym)))))))
 476                 ;; Quoted symbols
 477                 (save-excursion
 478                   (while (re-search-forward help-xref-symbol-regexp nil t)
 479                     (let* ((data (match-string 8))
 480                            (sym (intern-soft data)))
 481                       (if sym
 482                           (cond
 483                            ((match-string 3) ; `variable' &c
 484                             (and (or (boundp sym) ; `variable' doesn't ensure
 485                                         ; it's actually bound
 486                                      (get sym 'variable-documentation))
 487                                  (help-xref-button 8 'help-variable sym)))
 488                            ((match-string 4) ; `function' &c
 489                             (and (fboundp sym) ; similarly
 490                                  (help-xref-button 8 'help-function sym)))
 491                            ((match-string 5) ; `face'
 492                             (and (facep sym)
 493                                  (help-xref-button 8 'help-face sym)))
 494                            ((match-string 6)) ; nothing for `symbol'
 495                            ((match-string 7)
 496                             ;; this used:
 497                             ;; #'(lambda (arg)
 498                             ;;     (let ((location
 499                             ;;            (find-function-noselect arg)))
 500                             ;;       (pop-to-buffer (car location))
 501                             ;;  (goto-char (cdr location))))
 502                             (help-xref-button 8 'help-function-def sym))
 503                            ((cl-some (lambda (x) (funcall (nth 1 x) sym))
 504                                      describe-symbol-backends)
 505                             (help-xref-button 8 'help-symbol sym)))))))
 506                 ;; An obvious case of a key substitution:
 507                 (save-excursion
 508                   (while (re-search-forward
 509                           ;; Assume command name is only word and symbol
 510                           ;; characters to get things like `use M-x foo->bar'.
 511                           ;; Command required to end with word constituent
 512                           ;; to avoid `.' at end of a sentence.
 513                           "\\<M-x\\s-+\\(\\sw\\(\\sw\\|\\s_\\)*\\sw\\)" nil t)
 514                     (let ((sym (intern-soft (match-string 1))))
 515                       (if (fboundp sym)
 516                           (help-xref-button 1 'help-function sym)))))
 517                 ;; Look for commands in whole keymap substitutions:
 518                 (save-excursion
 519                   ;; Make sure to find the first keymap.
 520                   (goto-char (point-min))
 521                   ;; Find a header and the column at which the command
 522                   ;; name will be found.
 523
 524                   ;; If the keymap substitution isn't the last thing in
 525                   ;; the doc string, and if there is anything on the same
 526                   ;; line after it, this code won't recognize the end of it.
 527                   (while (re-search-forward "^key +binding\n\\(-+ +\\)-+\n\n"
 528                                             nil t)
 529                     (let ((col (- (match-end 1) (match-beginning 1))))
 530                       (while
 531                           (and (not (eobp))
 532                                ;; Stop at a pair of blank lines.
 533                                (not (looking-at-p "\n\\s-*\n")))
 534                         ;; Skip a single blank line.
 535                         (and (eolp) (forward-line))
 536                         (end-of-line)
 537                         (skip-chars-backward "^ \t\n")
 538                         (if (and (>= (current-column) col)
 539                                  (looking-at "\\(\\sw\\|\\s_\\)+$"))
 540                             (let ((sym (intern-soft (match-string 0))))
 541                               (if (fboundp sym)
 542                                   (help-xref-button 0 'help-function sym))))
 543                         (forward-line))))))
 544             (set-syntax-table stab))
 545           ;; Delete extraneous newlines at the end of the docstring
 546           (goto-char (point-max))
 547           (while (and (not (bobp)) (bolp))
 548             (delete-char -1))
 549           (insert "\n")
 550           (when (or help-xref-stack help-xref-forward-stack)
 551             (insert "\n"))
 552           ;; Make a back-reference in this buffer if appropriate.
 553           (when help-xref-stack
 554             (help-insert-xref-button help-back-label 'help-back
 555                                      (current-buffer)))
 556           ;; Make a forward-reference in this buffer if appropriate.
 557           (when help-xref-forward-stack
 558             (when help-xref-stack
 559               (insert "\t"))
 560             (help-insert-xref-button help-forward-label 'help-forward
 561                                      (current-buffer)))
 562           (when (or help-xref-stack help-xref-forward-stack)
 563             (insert "\n")))
 564         (set-buffer-modified-p old-modified)))))
 565
 566 ;;;###autoload
 567 (defun help-xref-button (match-number type &rest args)
 568   "Make a hyperlink for cross-reference text previously matched.
 569 MATCH-NUMBER is the subexpression of interest in the last matched
 570 regexp.  TYPE is the type of button to use.  Any remaining arguments are
 571 passed to the button's help-function when it is invoked.
 572 See `help-make-xrefs'."
 573   ;; Don't mung properties we've added specially in some instances.
 574   (unless (button-at (match-beginning match-number))
 575     (make-text-button (match-beginning match-number)
 576                       (match-end match-number)
 577                       'type type 'help-args args)))
 578
 579 ;;;###autoload
 580 (defun help-insert-xref-button (string type &rest args)
 581   "Insert STRING and make a hyperlink from cross-reference text on it.
 582 TYPE is the type of button to use.  Any remaining arguments are passed
 583 to the button's help-function when it is invoked.
 584 See `help-make-xrefs'."
 585   (unless (button-at (point))
 586     (insert-text-button string 'type type 'help-args args)))
 587
 588 ;;;###autoload
 589 (defun help-xref-on-pp (from to)
 590   "Add xrefs for symbols in `pp's output between FROM and TO."
 591   (if (> (- to from) 5000) nil
 592     (with-syntax-table emacs-lisp-mode-syntax-table
 593       (save-excursion
 594         (save-restriction
 595           (narrow-to-region from to)
 596           (goto-char (point-min))
 597           (ignore-errors
 598             (while (not (eobp))
 599               (cond
 600                ((looking-at-p "\"") (forward-sexp 1))
 601                ((looking-at-p "#<") (search-forward ">" nil 'move))
 602                ((looking-at "\\(\\(\\sw\\|\\s_\\)+\\)")
 603                 (let* ((sym (intern-soft (match-string 1)))
 604                        (type (cond ((fboundp sym) 'help-function)
 605                                    ((or (memq sym '(t nil))
 606                                         (keywordp sym))
 607                                     nil)
 608                                    ((and sym
 609                                          (or (boundp sym)
 610                                              (get sym
 611                                                   'variable-documentation)))
 612                                     'help-variable))))
 613                   (when type (help-xref-button 1 type sym)))
 614                 (goto-char (match-end 1)))
 615                (t (forward-char 1))))))))))
 616
 617 \f
 618 ;; Additional functions for (re-)creating types of help buffers.
 619
 620 ;;;###autoload
 621 (define-obsolete-function-alias 'help-xref-interned 'describe-symbol "25.1")
 622
 623 \f
 624 ;; Navigation/hyperlinking with xrefs
 625
 626 (defun help-xref-go-back (buffer)
 627   "From BUFFER, go back to previous help buffer text using `help-xref-stack'."
 628   (let (item position method args)
 629     (with-current-buffer buffer
 630       (push (cons (point) help-xref-stack-item) help-xref-forward-stack)
 631       (when help-xref-stack
 632         (setq item (pop help-xref-stack)
 633               ;; Clear the current item so that it won't get pushed
 634               ;; by the function we're about to call.  TODO: We could also
 635               ;; push it onto a "forward" stack and add a `forw' button.
 636               help-xref-stack-item nil
 637               position (car item)
 638               method (cadr item)
 639               args (cddr item))))
 640     (apply method args)
 641     (with-current-buffer buffer
 642       (if (get-buffer-window buffer)
 643           (set-window-point (get-buffer-window buffer) position)
 644         (goto-char position)))))
 645
 646 (defun help-xref-go-forward (buffer)
 647   "From BUFFER, go forward to next help buffer."
 648   (let (item position method args)
 649     (with-current-buffer buffer
 650       (push (cons (point) help-xref-stack-item) help-xref-stack)
 651       (when help-xref-forward-stack
 652         (setq item (pop help-xref-forward-stack)
 653               ;; Clear the current item so that it won't get pushed
 654               ;; by the function we're about to call.  TODO: We could also
 655               ;; push it onto a "forward" stack and add a `forw' button.
 656               help-xref-stack-item nil
 657               position (car item)
 658               method (cadr item)
 659               args (cddr item))))
 660     (apply method args)
 661     (with-current-buffer buffer
 662       (if (get-buffer-window buffer)
 663           (set-window-point (get-buffer-window buffer) position)
 664         (goto-char position)))))
 665
 666 (defun help-go-back ()
 667   "Go back to previous topic in this help buffer."
 668   (interactive)
 669   (if help-xref-stack
 670       (help-xref-go-back (current-buffer))
 671     (user-error "No previous help buffer")))
 672
 673 (defun help-go-forward ()
 674   "Go to the next topic in this help buffer."
 675   (interactive)
 676   (if help-xref-forward-stack
 677       (help-xref-go-forward (current-buffer))
 678     (user-error "No next help buffer")))
 679
 680 (defun help-do-xref (_pos function args)
 681   "Call the help cross-reference function FUNCTION with args ARGS.
 682 Things are set up properly so that the resulting help-buffer has
 683 a proper [back] button."
 684   ;; There is a reference at point.  Follow it.
 685   (let ((help-xref-following t))
 686     (apply function (if (eq function 'info)
 687                         (append args (list (generate-new-buffer-name "*info*"))) args))))
 688
 689 ;; The doc string is meant to explain what buttons do.
 690 (defun help-follow-mouse ()
 691   "Follow the cross-reference that you click on."
 692   (interactive)
 693   (error "No cross-reference here"))
 694
 695 ;; The doc string is meant to explain what buttons do.
 696 (defun help-follow ()
 697   "Follow cross-reference at point.
 698
 699 For the cross-reference format, see `help-make-xrefs'."
 700   (interactive)
 701   (user-error "No cross-reference here"))
 702
 703 (defun help-follow-symbol (&optional pos)
 704   "In help buffer, show docs for symbol at POS, defaulting to point.
 705 Show all docs for that symbol as either a variable, function or face."
 706   (interactive "d")
 707   (unless pos
 708     (setq pos (point)))
 709   ;; check if the symbol under point is a function, variable or face
 710   (let ((sym
 711          (intern
 712           (save-excursion
 713             (goto-char pos) (skip-syntax-backward "w_")
 714             (buffer-substring (point)
 715                               (progn (skip-syntax-forward "w_")
 716                                      (point)))))))
 717     (when (or (boundp sym)
 718               (get sym 'variable-documentation)
 719               (fboundp sym) (facep sym))
 720       (help-do-xref pos #'describe-symbol (list sym)))))
 721
 722 (defun help-mode-revert-buffer (_ignore-auto noconfirm)
 723   (when (or noconfirm (yes-or-no-p "Revert help buffer? "))
 724     (let ((pos (point))
 725           (item help-xref-stack-item)
 726           ;; Pretend there is no current item to add to the history.
 727           (help-xref-stack-item nil)
 728           ;; Use the current buffer.
 729           (help-xref-following t))
 730       (apply (car item) (cdr item))
 731       (goto-char pos))))
 732
 733 (defun help-insert-string (string)
 734   "Insert STRING to the help buffer and install xref info for it.
 735 This function can be used to restore the old contents of the help buffer
 736 when going back to the previous topic in the xref stack.  It is needed
 737 in case when it is impossible to recompute the old contents of the
 738 help buffer by other means."
 739   (setq help-xref-stack-item (list #'help-insert-string string))
 740   (with-output-to-temp-buffer (help-buffer)
 741     (insert string)))
 742
 743 \f
 744 ;; Bookmark support
 745
 746 (declare-function bookmark-prop-get "bookmark" (bookmark prop))
 747 (declare-function bookmark-make-record-default "bookmark"
 748                   (&optional no-file no-context posn))
 749
 750 (defun help-bookmark-make-record ()
 751   "Create and return a help-mode bookmark record.
 752 Implements `bookmark-make-record-function' for help-mode buffers."
 753   (unless (car help-xref-stack-item)
 754     (error "Cannot create bookmark - help command not known"))
 755   `(,@(bookmark-make-record-default 'NO-FILE 'NO-CONTEXT)
 756       (help-fn     . ,(car help-xref-stack-item))
 757       (help-args   . ,(cdr help-xref-stack-item))
 758       (position    . ,(point))
 759       (handler     . help-bookmark-jump)))
 760
 761 ;;;###autoload
 762 (defun help-bookmark-jump (bookmark)
 763   "Jump to help-mode bookmark BOOKMARK.
 764 Handler function for record returned by `help-bookmark-make-record'.
 765 BOOKMARK is a bookmark name or a bookmark record."
 766   (let ((help-fn    (bookmark-prop-get bookmark 'help-fn))
 767         (help-args  (bookmark-prop-get bookmark 'help-args))
 768         (position   (bookmark-prop-get bookmark 'position)))
 769     (apply help-fn help-args)
 770     (pop-to-buffer "*Help*")
 771     (goto-char position)))
 772
 773
 774 (provide 'help-mode)
 775
 776 ;;; help-mode.el ends here