lisp/cmuscheme.el

   1 ;;; cmuscheme.el --- Scheme process in a buffer. Adapted from tea.el
   2
   3 ;; Copyright (C) 1988, 1994, 1997, 2001-2016 Free Software Foundation,
   4 ;; Inc.
   5
   6 ;; Author: Olin Shivers <olin.shivers@cs.cmu.edu>
   7 ;; Maintainer: emacs-devel@gnu.org
   8 ;; Keywords: processes, lisp
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;    This is a customization of comint-mode (see comint.el)
  28 ;;
  29 ;; Written by Olin Shivers (olin.shivers@cs.cmu.edu). With bits and pieces
  30 ;; lifted from scheme.el, shell.el, clisp.el, newclisp.el, cobol.el, et al..
  31 ;; 8/88
  32 ;;
  33 ;; Please send me bug reports, bug fixes, and extensions, so that I can
  34 ;; merge them into the master source.
  35 ;;
  36 ;; The changelog is at the end of this file.
  37 ;;
  38 ;; NOTE: MIT Cscheme, when invoked with the -emacs flag, has a special user
  39 ;; interface that communicates process state back to the superior emacs by
  40 ;; outputting special control sequences. The Emacs package, xscheme.el, has
  41 ;; lots and lots of special purpose code to read these control sequences, and
  42 ;; so is very tightly integrated with the cscheme process. The cscheme
  43 ;; interrupt handler and debugger read single character commands in cbreak
  44 ;; mode; when this happens, xscheme.el switches to special keymaps that bind
  45 ;; the single letter command keys to emacs functions that directly send the
  46 ;; character to the scheme process.  Cmuscheme mode does *not* provide this
  47 ;; functionality. If you are a cscheme user, you may prefer to use the
  48 ;; xscheme.el/cscheme -emacs interaction.
  49 ;;
  50 ;; Here's a summary of the pros and cons, as I see them.
  51 ;; xscheme: Tightly integrated with inferior cscheme process!  A few commands
  52 ;;           not in cmuscheme. But. Integration is a bit of a hack.  Input
  53 ;;           history only keeps the immediately prior input. Bizarre
  54 ;;           keybindings.
  55 ;;
  56 ;; cmuscheme: Not tightly integrated with inferior cscheme process.  But.
  57 ;;            Carefully integrated functionality with the entire suite of
  58 ;;            comint-derived CMU process modes. Keybindings reminiscent of
  59 ;;            Zwei and Hemlock. Good input history. A few commands not in
  60 ;;            xscheme.
  61 ;;
  62 ;; It's a tradeoff. Pay your money; take your choice. If you use a Scheme
  63 ;; that isn't Cscheme, of course, there isn't a choice. Xscheme.el is *very*
  64 ;; Cscheme-specific; you must use cmuscheme.el.  Interested parties are
  65 ;; invited to port xscheme functionality on top of comint mode...
  66
  67 ;;; CHANGE LOG
  68 ;; ===========================================================================
  69 ;; 8/88 Olin
  70 ;; Created.
  71 ;;
  72 ;; 2/15/89 Olin
  73 ;; Removed -emacs flag from process invocation. It's only useful for
  74 ;; cscheme, and makes cscheme assume it's running under xscheme.el,
  75 ;; which messes things up royally. A bug.
  76 ;;
  77 ;; 5/22/90 Olin
  78 ;; - Upgraded to use comint-send-string and comint-send-region.
  79 ;; - run-scheme now offers to let you edit the command line if
  80 ;;   you invoke it with a prefix-arg. M-x scheme is redundant, and
  81 ;;   has been removed.
  82 ;; - Explicit references to process "scheme" have been replaced with
  83 ;;   (scheme-proc). This allows better handling of multiple process bufs.
  84 ;; - Added scheme-send-last-sexp, bound to C-x C-e. A gnu convention.
  85 ;; - Have not added process query facility a la cmulisp.el's lisp-show-arglist
  86 ;;   and friends, but interested hackers might find a useful application
  87 ;;   of this facility.
  88 ;;
  89 ;; 3/12/90 Olin
  90 ;; - scheme-load-file and scheme-compile-file no longer switch-to-scheme.
  91 ;;   Tale suggested this.
  92
  93 ;;; Code:
  94
  95 (require 'scheme)
  96 (require 'comint)
  97
  98
  99 (defgroup cmuscheme nil
 100   "Run a scheme process in a buffer."
 101   :group 'scheme)
 102
 103 ;;; INFERIOR SCHEME MODE STUFF
 104 ;;;============================================================================
 105
 106 (defcustom inferior-scheme-mode-hook nil
 107   "Hook for customizing inferior-scheme mode."
 108   :type 'hook
 109   :group 'cmuscheme)
 110
 111 (defvar inferior-scheme-mode-map
 112   (let ((m (make-sparse-keymap)))
 113     (define-key m "\M-\C-x" 'scheme-send-definition) ;gnu convention
 114     (define-key m "\C-x\C-e" 'scheme-send-last-sexp)
 115     (define-key m "\C-c\C-l" 'scheme-load-file)
 116     (define-key m "\C-c\C-k" 'scheme-compile-file)
 117     (scheme-mode-commands m)
 118     m))
 119
 120 ;; Install the process communication commands in the scheme-mode keymap.
 121 (define-key scheme-mode-map "\M-\C-x" 'scheme-send-definition);gnu convention
 122 (define-key scheme-mode-map "\C-x\C-e" 'scheme-send-last-sexp);gnu convention
 123 (define-key scheme-mode-map "\C-c\C-e" 'scheme-send-definition)
 124 (define-key scheme-mode-map "\C-c\M-e" 'scheme-send-definition-and-go)
 125 (define-key scheme-mode-map "\C-c\C-r" 'scheme-send-region)
 126 (define-key scheme-mode-map "\C-c\M-r" 'scheme-send-region-and-go)
 127 (define-key scheme-mode-map "\C-c\M-c" 'scheme-compile-definition)
 128 (define-key scheme-mode-map "\C-c\C-c" 'scheme-compile-definition-and-go)
 129 (define-key scheme-mode-map "\C-c\C-t" 'scheme-trace-procedure)
 130 (define-key scheme-mode-map "\C-c\C-x" 'scheme-expand-current-form)
 131 (define-key scheme-mode-map "\C-c\C-z" 'switch-to-scheme)
 132 (define-key scheme-mode-map "\C-c\C-l" 'scheme-load-file)
 133 (define-key scheme-mode-map "\C-c\C-k" 'scheme-compile-file) ;k for "kompile"
 134
 135 (let ((map (lookup-key scheme-mode-map [menu-bar scheme])))
 136   (define-key map [separator-eval] '("--"))
 137   (define-key map [compile-file]
 138     '("Compile Scheme File" . scheme-compile-file))
 139   (define-key map [load-file]
 140     '("Load Scheme File" . scheme-load-file))
 141   (define-key map [switch]
 142     '("Switch to Scheme" . switch-to-scheme))
 143   (define-key map [com-def-go]
 144     '("Compile Definition & Go" . scheme-compile-definition-and-go))
 145   (define-key map [com-def]
 146     '("Compile Definition" . scheme-compile-definition))
 147   (define-key map [exp-form]
 148     '("Expand current form" . scheme-expand-current-form))
 149   (define-key map [trace-proc]
 150     '("Trace procedure" . scheme-trace-procedure))
 151   (define-key map [send-def-go]
 152     '("Evaluate Last Definition & Go" . scheme-send-definition-and-go))
 153   (define-key map [send-def]
 154     '("Evaluate Last Definition" . scheme-send-definition))
 155   (define-key map [send-region-go]
 156     '("Evaluate Region & Go" . scheme-send-region-and-go))
 157   (define-key map [send-region]
 158     '("Evaluate Region" . scheme-send-region))
 159   (define-key map [send-sexp]
 160     '("Evaluate Last S-expression" . scheme-send-last-sexp))
 161   )
 162
 163 (defvar scheme-buffer)
 164
 165 (define-derived-mode inferior-scheme-mode comint-mode "Inferior Scheme"
 166   "Major mode for interacting with an inferior Scheme process.
 167
 168 The following commands are available:
 169 \\{inferior-scheme-mode-map}
 170
 171 A Scheme process can be fired up with M-x run-scheme.
 172
 173 Customization: Entry to this mode runs the hooks on `comint-mode-hook' and
 174 `inferior-scheme-mode-hook' (in that order).
 175
 176 You can send text to the inferior Scheme process from other buffers containing
 177 Scheme source.
 178     `switch-to-scheme' switches the current buffer to the Scheme process buffer.
 179     `scheme-send-definition' sends the current definition to the Scheme process.
 180     `scheme-compile-definition' compiles the current definition.
 181     `scheme-send-region' sends the current region to the Scheme process.
 182     `scheme-compile-region' compiles the current region.
 183
 184     `scheme-send-definition-and-go', `scheme-compile-definition-and-go',
 185         `scheme-send-region-and-go', and `scheme-compile-region-and-go'
 186         switch to the Scheme process buffer after sending their text.
 187 For information on running multiple processes in multiple buffers, see
 188 documentation for variable `scheme-buffer'.
 189
 190 Commands:
 191 Return after the end of the process' output sends the text from the
 192     end of process to point.
 193 Return before the end of the process' output copies the sexp ending at point
 194     to the end of the process' output, and sends it.
 195 Delete converts tabs to spaces as it moves back.
 196 Tab indents for Scheme; with argument, shifts rest
 197     of expression rigidly with the current line.
 198 C-M-q does Tab on each line starting within following expression.
 199 Paragraphs are separated only by blank lines.  Semicolons start comments.
 200 If you accidentally suspend your process, use \\[comint-continue-subjob]
 201 to continue it."
 202   ;; Customize in inferior-scheme-mode-hook
 203   (setq comint-prompt-regexp "^[^>\n]*>+ *") ; OK for cscheme, oaklisp, T,...
 204   (scheme-mode-variables)
 205   (setq mode-line-process '(":%s"))
 206   (setq comint-input-filter (function scheme-input-filter))
 207   (setq comint-get-old-input (function scheme-get-old-input)))
 208
 209 (defcustom inferior-scheme-filter-regexp "\\`\\s *\\S ?\\S ?\\s *\\'"
 210   "Input matching this regexp are not saved on the history list.
 211 Defaults to a regexp ignoring all inputs of 0, 1, or 2 letters."
 212   :type 'regexp
 213   :group 'cmuscheme)
 214
 215 (defun scheme-input-filter (str)
 216   "Don't save anything matching `inferior-scheme-filter-regexp'."
 217   (not (string-match-p inferior-scheme-filter-regexp str)))
 218
 219 (defun scheme-get-old-input ()
 220   "Snarf the sexp ending at point."
 221   (save-excursion
 222     (let ((end (point)))
 223       (backward-sexp)
 224       (buffer-substring (point) end))))
 225
 226 ;;;###autoload
 227 (defun run-scheme (cmd)
 228   "Run an inferior Scheme process, input and output via buffer `*scheme*'.
 229 If there is a process already running in `*scheme*', switch to that buffer.
 230 With argument, allows you to edit the command line (default is value
 231 of `scheme-program-name').
 232 If the file `~/.emacs_SCHEMENAME' or `~/.emacs.d/init_SCHEMENAME.scm' exists,
 233 it is given as initial input.
 234 Note that this may lose due to a timing error if the Scheme processor
 235 discards input when it starts up.
 236 Runs the hook `inferior-scheme-mode-hook' (after the `comint-mode-hook'
 237 is run).
 238 \(Type \\[describe-mode] in the process buffer for a list of commands.)"
 239
 240   (interactive (list (if current-prefix-arg
 241                          (read-string "Run Scheme: " scheme-program-name)
 242                          scheme-program-name)))
 243   (if (not (comint-check-proc "*scheme*"))
 244       (let ((cmdlist (split-string-and-unquote cmd)))
 245         (set-buffer (apply 'make-comint "scheme" (car cmdlist)
 246                            (scheme-start-file (car cmdlist)) (cdr cmdlist)))
 247         (inferior-scheme-mode)))
 248   (setq scheme-program-name cmd)
 249   (setq scheme-buffer "*scheme*")
 250   (pop-to-buffer-same-window "*scheme*"))
 251
 252 (defun scheme-start-file (prog)
 253   "Return the name of the start file corresponding to PROG.
 254 Search in the directories \"~\" and `user-emacs-directory',
 255 in this order.  Return nil if no start file found."
 256   (let* ((progname (file-name-nondirectory prog))
 257          (start-file (concat "~/.emacs_" progname))
 258          (alt-start-file (concat user-emacs-directory "init_" progname ".scm")))
 259     (if (file-exists-p start-file)
 260         start-file
 261       (and (file-exists-p alt-start-file) alt-start-file))))
 262
 263 (defun scheme-send-region (start end)
 264   "Send the current region to the inferior Scheme process."
 265   (interactive "r")
 266   (comint-send-region (scheme-proc) start end)
 267   (comint-send-string (scheme-proc) "\n"))
 268
 269 (defun scheme-send-definition ()
 270   "Send the current definition to the inferior Scheme process."
 271   (interactive)
 272   (save-excursion
 273    (end-of-defun)
 274    (let ((end (point)))
 275      (beginning-of-defun)
 276      (scheme-send-region (point) end))))
 277
 278 (defun scheme-send-last-sexp ()
 279   "Send the previous sexp to the inferior Scheme process."
 280   (interactive)
 281   (scheme-send-region (save-excursion (backward-sexp) (point)) (point)))
 282
 283 (defcustom scheme-compile-exp-command "(compile '%s)"
 284   "Template for issuing commands to compile arbitrary Scheme expressions."
 285   :type 'string
 286   :group 'cmuscheme)
 287
 288 (defun scheme-compile-region (start end)
 289   "Compile the current region in the inferior Scheme process.
 290 \(A BEGIN is wrapped around the region: (BEGIN <region>))"
 291   (interactive "r")
 292   (comint-send-string (scheme-proc) (format scheme-compile-exp-command
 293                                             (format "(begin %s)"
 294                                                     (buffer-substring start end))))
 295   (comint-send-string (scheme-proc) "\n"))
 296
 297 (defun scheme-compile-definition ()
 298   "Compile the current definition in the inferior Scheme process."
 299   (interactive)
 300   (save-excursion
 301    (end-of-defun)
 302    (let ((end (point)))
 303      (beginning-of-defun)
 304      (scheme-compile-region (point) end))))
 305
 306 (defcustom scheme-trace-command "(trace %s)"
 307   "Template for issuing commands to trace a Scheme procedure.
 308 Some Scheme implementations might require more elaborate commands here.
 309 For PLT-Scheme, e.g., one should use
 310
 311    (setq scheme-trace-command \"(begin (require (lib \\\"trace.ss\\\")) (trace %s))\")
 312
 313 For Scheme 48 and Scsh use \",trace %s\"."
 314   :type 'string
 315   :group 'cmuscheme)
 316
 317 (defcustom scheme-untrace-command "(untrace %s)"
 318   "Template for switching off tracing of a Scheme procedure.
 319 Scheme 48 and Scsh users should set this variable to \",untrace %s\"."
 320
 321   :type 'string
 322   :group 'cmuscheme)
 323
 324 (defun scheme-trace-procedure (proc &optional untrace)
 325   "Trace procedure PROC in the inferior Scheme process.
 326 With a prefix argument switch off tracing of procedure PROC."
 327   (interactive
 328    (list (let ((current (symbol-at-point))
 329                (action (if current-prefix-arg "Untrace" "Trace")))
 330            (if current
 331                (read-string (format "%s procedure [%s]: " action current) nil nil (symbol-name current))
 332              (read-string (format "%s procedure: " action))))
 333          current-prefix-arg))
 334   (when (= (length proc) 0)
 335     (error "Invalid procedure name"))
 336   (comint-send-string (scheme-proc)
 337                       (format
 338                        (if untrace scheme-untrace-command scheme-trace-command)
 339                        proc))
 340   (comint-send-string (scheme-proc) "\n"))
 341
 342 (defcustom scheme-macro-expand-command "(expand %s)"
 343   "Template for macro-expanding a Scheme form.
 344 For Scheme 48 and Scsh use \",expand %s\"."
 345   :type 'string
 346   :group 'cmuscheme)
 347
 348 (defun scheme-expand-current-form ()
 349   "Macro-expand the form at point in the inferior Scheme process."
 350   (interactive)
 351   (let ((current-form (scheme-form-at-point)))
 352     (if current-form
 353         (progn
 354           (comint-send-string (scheme-proc)
 355                               (format
 356                                scheme-macro-expand-command
 357                                current-form))
 358           (comint-send-string (scheme-proc) "\n"))
 359       (error "Not at a form"))))
 360
 361 (defun scheme-form-at-point ()
 362   (let ((next-sexp (thing-at-point 'sexp)))
 363     (if (and next-sexp (string-equal (substring next-sexp 0 1) "("))
 364         next-sexp
 365       (save-excursion
 366         (backward-up-list)
 367         (scheme-form-at-point)))))
 368
 369 (defun switch-to-scheme (eob-p)
 370   "Switch to the Scheme process buffer.
 371 With argument, position cursor at end of buffer."
 372   (interactive "P")
 373   (if (or (and scheme-buffer (get-buffer scheme-buffer))
 374           (scheme-interactively-start-process))
 375       (pop-to-buffer-same-window scheme-buffer)
 376     (error "No current process buffer.  See variable `scheme-buffer'"))
 377   (when eob-p
 378     (push-mark)
 379     (goto-char (point-max))))
 380
 381 (defun scheme-send-region-and-go (start end)
 382   "Send the current region to the inferior Scheme process.
 383 Then switch to the process buffer."
 384   (interactive "r")
 385   (scheme-send-region start end)
 386   (switch-to-scheme t))
 387
 388 (defun scheme-send-definition-and-go ()
 389   "Send the current definition to the inferior Scheme.
 390 Then switch to the process buffer."
 391   (interactive)
 392   (scheme-send-definition)
 393   (switch-to-scheme t))
 394
 395 (defun scheme-compile-definition-and-go ()
 396   "Compile the current definition in the inferior Scheme.
 397 Then switch to the process buffer."
 398   (interactive)
 399   (scheme-compile-definition)
 400   (switch-to-scheme t))
 401
 402 (defun scheme-compile-region-and-go (start end)
 403   "Compile the current region in the inferior Scheme.
 404 Then switch to the process buffer."
 405   (interactive "r")
 406   (scheme-compile-region start end)
 407   (switch-to-scheme t))
 408
 409 (defcustom scheme-source-modes '(scheme-mode)
 410   "Used to determine if a buffer contains Scheme source code.
 411 If it's loaded into a buffer that is in one of these major modes, it's
 412 considered a scheme source file by `scheme-load-file' and `scheme-compile-file'.
 413 Used by these commands to determine defaults."
 414   :type '(repeat function)
 415   :group 'cmuscheme)
 416
 417 (defvar scheme-prev-l/c-dir/file nil
 418   "Caches the last (directory . file) pair.
 419 Caches the last pair used in the last `scheme-load-file' or
 420 `scheme-compile-file' command.  Used for determining the default
 421 in the next one.")
 422
 423 (defun scheme-load-file (file-name)
 424   "Load a Scheme file FILE-NAME into the inferior Scheme process."
 425   (interactive (comint-get-source "Load Scheme file: " scheme-prev-l/c-dir/file
 426                                   scheme-source-modes t)) ; t because `load'
 427                                                           ; needs an exact name
 428   (comint-check-source file-name) ; Check to see if buffer needs saved.
 429   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 430                                        (file-name-nondirectory file-name)))
 431   (comint-send-string (scheme-proc) (concat "(load \""
 432                                             file-name
 433                                             "\")\n")))
 434
 435 (defun scheme-compile-file (file-name)
 436   "Compile a Scheme file FILE-NAME in the inferior Scheme process."
 437   (interactive (comint-get-source "Compile Scheme file: "
 438                                   scheme-prev-l/c-dir/file
 439                                   scheme-source-modes
 440                                   nil)) ; nil because COMPILE doesn't
 441                                         ; need an exact name.
 442   (comint-check-source file-name) ; Check to see if buffer needs saved.
 443   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 444                                        (file-name-nondirectory file-name)))
 445   (comint-send-string (scheme-proc) (concat "(compile-file \""
 446                                             file-name
 447                                             "\")\n")))
 448
 449 \f
 450 (defvar scheme-buffer nil "The current scheme process buffer.
 451
 452 MULTIPLE PROCESS SUPPORT
 453 ===========================================================================
 454 Cmuscheme.el supports, in a fairly simple fashion, running multiple Scheme
 455 processes.  To run multiple Scheme processes, you start the first up with
 456 \\[run-scheme].  It will be in a buffer named *scheme*.  Rename this buffer
 457 with \\[rename-buffer].  You may now start up a new process with another
 458 \\[run-scheme].  It will be in a new buffer, named *scheme*.  You can
 459 switch between the different process buffers with \\[switch-to-buffer].
 460
 461 Commands that send text from source buffers to Scheme processes --
 462 like `scheme-send-definition' or `scheme-compile-region' -- have to choose a
 463 process to send to, when you have more than one Scheme process around.  This
 464 is determined by the global variable `scheme-buffer'.  Suppose you
 465 have three inferior Schemes running:
 466     Buffer      Process
 467     foo         scheme
 468     bar         scheme<2>
 469     *scheme*    scheme<3>
 470 If you do a \\[scheme-send-definition-and-go] command on some Scheme source
 471 code, what process do you send it to?
 472
 473 - If you're in a process buffer (foo, bar, or *scheme*),
 474   you send it to that process.
 475 - If you're in some other buffer (e.g., a source file), you
 476   send it to the process attached to buffer `scheme-buffer'.
 477 This process selection is performed by function `scheme-proc'.
 478
 479 Whenever \\[run-scheme] fires up a new process, it resets `scheme-buffer'
 480 to be the new process's buffer.  If you only run one process, this will
 481 do the right thing.  If you run multiple processes, you might need to
 482 set `scheme-buffer' to whichever process buffer you want to use.
 483
 484 More sophisticated approaches are, of course, possible.  If you find yourself
 485 needing to switch back and forth between multiple processes frequently,
 486 you may wish to consider ilisp.el, a larger, more sophisticated package
 487 for running inferior Lisp and Scheme processes.  The approach taken here is
 488 for a minimal, simple implementation.  Feel free to extend it.")
 489
 490 (defun scheme-proc ()
 491   "Return the current Scheme process, starting one if necessary.
 492 See variable `scheme-buffer'."
 493   (unless (and scheme-buffer
 494                (get-buffer scheme-buffer)
 495                (comint-check-proc scheme-buffer))
 496     (scheme-interactively-start-process))
 497   (or (scheme-get-process)
 498       (error "No current process.  See variable `scheme-buffer'")))
 499
 500 (defun scheme-get-process ()
 501   "Return the current Scheme process or nil if none is running."
 502   (get-buffer-process (if (eq major-mode 'inferior-scheme-mode)
 503                           (current-buffer)
 504                         scheme-buffer)))
 505
 506 (defun scheme-interactively-start-process (&optional _cmd)
 507   "Start an inferior Scheme process.  Return the process started.
 508 Since this command is run implicitly, always ask the user for the
 509 command to run."
 510   (save-window-excursion
 511     (run-scheme (read-string "Run Scheme: " scheme-program-name))))
 512
 513 ;;; Do the user's customization...
 514
 515 (defcustom cmuscheme-load-hook nil
 516   "This hook is run when cmuscheme is loaded in.
 517 This is a good place to put keybindings."
 518   :type 'hook
 519   :group 'cmuscheme)
 520
 521 (run-hooks 'cmuscheme-load-hook)
 522
 523 (provide 'cmuscheme)
 524
 525 ;;; cmuscheme.el ends here