lisp/gnus/qp.el

   1 ;;; qp.el --- Quoted-Printable functions
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: mail, extensions
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Functions for encoding and decoding quoted-printable text as
  28 ;; defined in RFC 2045.
  29
  30 ;;; Code:
  31
  32 (require 'mm-util)
  33 (eval-when-compile (defvar mm-use-ultra-safe-encoding))
  34
  35 (defun quoted-printable-decode-region (from to &optional coding-system)
  36   "Decode quoted-printable in the region between FROM and TO, per RFC 2045.
  37 If CODING-SYSTEM is non-nil, decode bytes into characters with that
  38 coding-system."
  39   (interactive "r")
  40   (unless (mm-coding-system-p coding-system) ; e.g. `ascii' from Gnus
  41     (setq coding-system nil))
  42   (save-excursion
  43     (save-restriction
  44       ;; RFC 2045:  ``An "=" followed by two hexadecimal digits, one
  45       ;; or both of which are lowercase letters in "abcdef", is
  46       ;; formally illegal. A robust implementation might choose to
  47       ;; recognize them as the corresponding uppercase letters.''
  48       (let ((case-fold-search t))
  49         (narrow-to-region from to)
  50         ;; Do this in case we're called from Gnus, say, in a buffer
  51         ;; which already contains non-ASCII characters which would
  52         ;; then get doubly-decoded below.
  53         (if coding-system
  54             (mm-encode-coding-region (point-min) (point-max) coding-system))
  55         (goto-char (point-min))
  56         (while (and (skip-chars-forward "^=")
  57                     (not (eobp)))
  58           (cond ((eq (char-after (1+ (point))) ?\n)
  59                  (delete-char 2))
  60                 ((looking-at "=[0-9A-F][0-9A-F]")
  61                  (let ((byte (string-to-int (buffer-substring (1+ (point))
  62                                                               (+ 3 (point)))
  63                                             16)))
  64                    (insert byte)
  65                    (delete-char 3)
  66                    (unless (eq byte ?=)
  67                      (backward-char))))
  68                 (t
  69                  (error "Malformed quoted-printable text")
  70                  (forward-char)))))
  71       (if coding-system
  72           (mm-decode-coding-region (point-min) (point-max) coding-system)))))
  73
  74 (defun quoted-printable-decode-string (string &optional coding-system)
  75   "Decode the quoted-printable encoded STRING and return the result.
  76 If CODING-SYSTEM is non-nil, decode the region with coding-system."
  77   (with-temp-buffer
  78     (insert string)
  79     (quoted-printable-decode-region (point-min) (point-max) coding-system)
  80     (buffer-string)))
  81
  82 (defun quoted-printable-encode-region (from to &optional fold class)
  83   "Quoted-printable encode the region between FROM and TO per RFC 2045.
  84
  85 If FOLD, fold long lines at 76 characters (as required by the RFC).
  86 If CLASS is non-nil, translate the characters not matched by that
  87 regexp class, which is in the form expected by `skip-chars-forward'.
  88 You should probably avoid non-ASCII characters in this arg.
  89
  90 If `mm-use-ultra-safe-encoding' is set, fold lines unconditionally and
  91 encode lines starting with \"From\"."
  92   (interactive "r")
  93   ;; Fixme: what should this do in XEmacs/Mule?
  94   (if (fboundp 'find-charset-region)    ; else XEmacs, non-Mule
  95       (if (delq 'unknown                ; Emacs 20 unibyte
  96                 (delq 'eight-bit-graphic ; Emacs 21
  97                       (delq 'eight-bit-control
  98                             (delq 'ascii (find-charset-region from to)))))
  99           (error "Multibyte character in QP encoding region")))
 100   (unless class
 101     ;; Avoid using 8bit characters. = is \075.
 102     ;; Equivalent to "^\000-\007\013\015-\037\200-\377="
 103     (setq class "\010-\012\014\040-\074\076-\177"))
 104   (save-excursion
 105     (save-restriction
 106       (narrow-to-region from to)
 107       ;; Encode all the non-ascii and control characters.
 108       (goto-char (point-min))
 109       (while (and (skip-chars-forward class)
 110                   (not (eobp)))
 111         (insert
 112          (prog1
 113              (format "=%02X" (char-after))
 114            (delete-char 1))))
 115       ;; Encode white space at the end of lines.
 116       (goto-char (point-min))
 117       (while (re-search-forward "[ \t]+$" nil t)
 118         (goto-char (match-beginning 0))
 119         (while (not (eolp))
 120           (insert
 121            (prog1
 122                (format "=%02X" (char-after))
 123              (delete-char 1)))))
 124       (let ((mm-use-ultra-safe-encoding
 125              (and (boundp 'mm-use-ultra-safe-encoding)
 126                   mm-use-ultra-safe-encoding)))
 127         (when (or fold mm-use-ultra-safe-encoding)
 128           (let ((tab-width 1))          ; HTAB is one character.
 129             (goto-char (point-min))
 130             (while (not (eobp))
 131               ;; In ultra-safe mode, encode "From " at the beginning
 132               ;; of a line.
 133               (when mm-use-ultra-safe-encoding
 134                 (if (looking-at "From ")
 135                     (replace-match "From=20" nil t)
 136                   (if (looking-at "-")
 137                       (replace-match "=2D" nil t))))
 138               (end-of-line)
 139               ;; Fold long lines.
 140               (while (> (current-column) 76) ; tab-width must be 1.
 141                 (beginning-of-line)
 142                 (forward-char 75)       ; 75 chars plus an "="
 143                 (search-backward "=" (- (point) 2) t)
 144                 (insert "=\n")
 145                 (end-of-line))
 146               (forward-line))))))))
 147
 148 (defun quoted-printable-encode-string (string)
 149   "Encode the STRING as quoted-printable and return the result."
 150   (let ((default-enable-multibyte-characters (mm-multibyte-string-p string)))
 151     (with-temp-buffer
 152       (insert string)
 153       (quoted-printable-encode-region (point-min) (point-max))
 154       (buffer-string))))
 155
 156 (provide 'qp)
 157
 158 ;;; qp.el ends here