admin/admin.el

   1 ;;; admin.el --- utilities for Emacs administration
   2
   3 ;; Copyright (C) 2001 Free Software Foundation, Inc.
   4
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 2, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  20 ;; Boston, MA 02111-1307, USA.
  21
  22 ;;; Commentary:
  23
  24 ;; add-release-log      add ``Version X released'' change log entries
  25 ;; set-version          change Emacs version number in source tree.
  26
  27 ;;; Code:
  28
  29 (defun process-lines (program &rest args)
  30   "Execute PROGRAM with ARGS, returning its output as a list of lines.
  31 Signal an error if the program returns with a non-zero exit status."
  32   (with-temp-buffer
  33     (let ((status (apply 'call-process program nil (current-buffer) nil args)))
  34       (unless (eq status 0)
  35         (error "%s exited with status %s" program status))
  36       (goto-char (point-min))
  37       (let (lines)
  38         (while (not (eobp))
  39           (setq lines (cons (buffer-substring-no-properties
  40                              (line-beginning-position)
  41                              (line-end-position))
  42                             lines))
  43           (forward-line 1))
  44         (nreverse lines)))))
  45
  46
  47 (defun add-release-logs (root version)
  48   "Add \"Version VERSION released.\" change log entries in ROOT.
  49 Root must be the root of an Emacs source tree."
  50   (interactive "DEmacs root directory: \nNVersion number: ")
  51   (unless (file-exists-p (expand-file-name "src/emacs.c" root))
  52     (error "%s doesn't seem to be the root of an Emacs source tree" root))
  53   (let* ((logs (process-lines "find" root "-name" "ChangeLog"))
  54          (entry (format "%s  %s  <%s>\n\n\t* Version %s released.\n\n"
  55                         (format-time-string "%Y-%m-%d")
  56                         (user-full-name) user-mail-address version)))
  57     (dolist (log logs)
  58       (unless (string-match "/gnus/" log)
  59         (find-file log)
  60         (goto-char (point-min))
  61         (insert entry)))))
  62
  63
  64 (defun set-version-in-file (root file version rx)
  65   (find-file (expand-file-name file root))
  66   (goto-char (point-min))
  67   (unless (re-search-forward rx nil t)
  68     (error "Version not found in %s" file))
  69   (replace-match (format "%s" version) nil nil nil 1))
  70
  71
  72 (defun set-version (root version)
  73   "Set Emacs version to VERSION in relevant files under ROOT.
  74 Root must be the root of an Emacs source tree."
  75   (interactive "DEmacs root directory: \nsVersion number: ")
  76   (unless (file-exists-p (expand-file-name "src/emacs.c" root))
  77     (error "%s doesn't seem to be the root of an Emacs source tree" root))
  78   (set-version-in-file root "lisp/version.el" version
  79                        (rx (and "emacs-version" (0+ space)
  80                                 ?\" (submatch (1+ (not (in ?\")))) ?\")))
  81   (set-version-in-file root "README" version
  82                        (rx (and "version" (1+ space)
  83                                 (submatch (1+ (in "0-9."))))))
  84   (set-version-in-file root "man/emacs.texi" version
  85                        (rx (and "EMACSVER" (1+ space)
  86                                 (submatch (1+ (in "0-9.")))))))
  87
  88 ;; admin.el ends here.