| blob | aac4e108b09a39caa04eacda0ae68138fb13e238 |
1 @echo off\r
2 rem ----------------------------------------------------------------------\r
3 rem Configuration script for MSDOS\r
4 rem Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2001, 2002, 2003\r
5 rem 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.\r
6 \r
7 rem This file is part of GNU Emacs.\r
8 \r
9 rem GNU Emacs is free software: you can redistribute it and/or modify\r
10 rem it under the terms of the GNU General Public License as published by\r
11 rem the Free Software Foundation, either version 3 of the License, or\r
12 rem (at your option) any later version.\r
13 \r
14 rem GNU Emacs is distributed in the hope that it will be useful,\r
15 rem but WITHOUT ANY WARRANTY; without even the implied warranty of\r
16 rem MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the\r
17 rem GNU General Public License for more details.\r
18 \r
19 rem You should have received a copy of the GNU General Public License\r
20 rem along with GNU Emacs. If not, see http://www.gnu.org/licenses/.\r
21 \r
22 rem ----------------------------------------------------------------------\r
23 rem YOU'LL NEED THE FOLLOWING UTILITIES TO MAKE EMACS:\r
24 rem\r
25 rem + msdos version 3 or better.\r
26 rem + DJGPP version 2.0 or later (version 2.03 or later recommended).\r
27 rem + make utility that allows breaking of the 128 chars limit on\r
28 rem command lines. ndmake (as of version 4.5) won't work due to a\r
29 rem line length limit. The make that comes with DJGPP does work (and is\r
30 rem recommended).\r
31 rem + rm, mv, and cp (from GNU file utilities).\r
32 rem + sed (you can use the port that comes with DJGPP).\r
33 rem\r
34 rem You should be able to get all the above utilities from the DJGPP FTP\r
35 rem site, ftp.delorie.com, in the directory "pub/djgpp/current/v2gnu".\r
36 rem ----------------------------------------------------------------------\r
37 set X11=\r
38 set nodebug=\r
39 set djgpp_ver=\r
40 set sys_malloc=\r
41 if "%1" == "" goto usage\r
42 rem ----------------------------------------------------------------------\r
43 rem See if their environment is large enough. We need 28 bytes.\r
44 set $foo$=789012345678901234567\r
45 if not "%$foo$%" == "789012345678901234567" goto SmallEnv\r
46 set $foo$=\r
47 :again\r
48 if "%1" == "" goto usage\r
49 if "%1" == "--with-x" goto withx\r
50 if "%1" == "--no-debug" goto nodebug\r
51 if "%1" == "msdos" goto msdos\r
52 if "%1" == "--with-system-malloc" goto sysmalloc\r
53 :usage\r
54 echo Usage: config [--no-debug] [--with-system-malloc] [--with-x] msdos\r
55 echo [Read the script before you run it.]\r
56 goto end\r
57 rem ----------------------------------------------------------------------\r
58 :withx\r
59 set X11=Y\r
60 shift\r
61 goto again\r
62 rem ----------------------------------------------------------------------\r
63 :nodebug\r
64 set nodebug=Y\r
65 shift\r
66 goto again\r
67 rem ----------------------------------------------------------------------\r
68 :sysmalloc\r
69 set sys_malloc=Y\r
70 shift\r
71 goto again\r
72 rem ----------------------------------------------------------------------\r
73 :msdos\r
74 Echo Checking whether 'sed' is available...\r
75 sed -e "w junk.$$$" <Nul\r
76 If Exist junk.$$$ Goto sedOk\r
77 Echo To configure 'Emacs' you need to have 'sed'!\r
78 Goto End\r
79 :sedOk\r
80 Echo Checking whether 'rm' is available...\r
81 rm -f junk.$$$\r
82 If Not Exist junk.$$$ Goto rmOk\r
83 Echo To configure 'Emacs' you need to have 'rm'!\r
84 Goto End\r
85 :rmOk\r
86 Echo Checking whether 'mv' is available...\r
87 rm -f junk.1 junk.2\r
88 echo foo >junk.1\r
89 mv junk.1 ./junk.2\r
90 If Exist junk.2 Goto mvOk\r
91 Echo To configure 'Emacs' you need to have 'mv'!\r
92 rm -f junk.1\r
93 Goto End\r
94 :mvOk\r
95 rm -f junk.2\r
96 Echo Checking whether 'gcc' is available...\r
97 echo main(){} >junk.c\r
98 gcc -c junk.c\r
99 if exist junk.o goto gccOk\r
100 Echo To configure 'Emacs' you need to have 'gcc'!\r
101 rm -f junk.c\r
102 Goto End\r
103 :gccOk\r
104 rm -f junk.c junk.o junk junk.exe\r
105 Echo Checking what version of DJGPP is installed...\r
106 If Not "%DJGPP%" == "" goto djgppOk\r
107 Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!\r
108 Goto End\r
109 :djgppOk\r
110 echo int main() >junk.c\r
111 echo #ifdef __DJGPP__ >>junk.c\r
112 echo {return (__DJGPP__)*10;} >>junk.c\r
113 echo #else >>junk.c\r
114 echo #ifdef __GO32__ >>junk.c\r
115 echo {return 10;} >>junk.c\r
116 echo #else >>junk.c\r
117 echo {return 0;} >>junk.c\r
118 echo #endif >>junk.c\r
119 echo #endif >>junk.c\r
120 gcc -o junk junk.c\r
121 if not exist junk.exe coff2exe junk\r
122 junk\r
123 If ErrorLevel 10 Goto go32Ok\r
124 rm -f junk.c junk junk.exe\r
125 Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!\r
126 Goto End\r
127 :go32Ok\r
128 set djgpp_ver=2\r
129 If Not ErrorLevel 20 Echo To build 'Emacs' you need DJGPP v2.0 or later!\r
130 If Not ErrorLevel 20 Goto End\r
131 rm -f junk.c junk junk.exe\r
132 rem DJECHO is used by the top-level Makefile in the v2.x build\r
133 Echo Checking whether 'djecho' is available...\r
134 redir -o Nul -eo djecho -o junk.$$$ foo\r
135 If Exist junk.$$$ Goto djechoOk\r
136 Echo To build 'Emacs' you need the 'djecho.exe' program!\r
137 Echo 'djecho.exe' is part of 'djdevNNN.zip' basic DJGPP development kit.\r
138 Echo Versions of DJGPP before 2.02 called this program 'echo.exe'.\r
139 Echo Either unpack 'djecho.exe' from the 'djdevNNN.zip' archive,\r
140 Echo or, if you have 'echo.exe', copy it to 'djecho.exe'.\r
141 Echo Then run CONFIG.BAT again with the same arguments you did now.\r
142 Goto End\r
143 :djechoOk\r
144 rm -f junk.$$$\r
145 Echo Configuring for DJGPP Version %DJGPP_VER% ...\r
146 Rem ----------------------------------------------------------------------\r
147 Echo Configuring the source directory...\r
148 cd src\r
149 \r
150 rem Create "epaths.h"\r
151 sed -f ../msdos/sed4.inp <epaths.in >epaths.tmp\r
152 update epaths.tmp epaths.h >nul\r
153 rm -f epaths.tmp\r
154 \r
155 rem Create "config.h"\r
156 rm -f config.h2 config.tmp\r
157 sed -e '' config.in > config.tmp\r
158 if "%X11%" == "" goto src4\r
159 sed -f ../msdos/sed2x.inp <config.in >config.tmp\r
160 :src4\r
161 sed -f ../msdos/sed2v2.inp <config.tmp >config.h2\r
162 Rem See if DECL_ALIGN can be supported with this GCC\r
163 rm -f junk.c junk.o junk junk.exe\r
164 echo struct { int i; char *p; } __attribute__((__aligned__(8))) foo; >junk.c\r
165 rem Two percent signs because it is a special character for COMMAND.COM/CMD\r
166 rem Filter thru Sed because "&" is special for CMD.EXE\r
167 echo int main(void) { return (unsigned long)"&"foo %% 8; } | sed "s/.&./\&/" >>junk.c\r
168 gcc -o junk junk.c\r
169 if not exist junk.exe coff2exe junk\r
170 junk\r
171 If Not ErrorLevel 1 Goto alignOk\r
172 Echo WARNING: Your GCC does not support 8-byte aligned variables.\r
173 Echo WARNING: Therefore Emacs cannot support buffers larger than 128MB.\r
174 rem The following line disables DECL_ALIGN which in turn disables USE_LSB_TAG\r
175 rem For details see lisp.h where it defines USE_LSB_TAG\r
176 echo #define NO_DECL_ALIGN >>config.h2\r
177 :alignOk\r
178 Rem See if they requested a SYSTEM_MALLOC build\r
179 if "%sys_malloc%" == "" Goto cfgDone\r
180 rm -f config.tmp\r
181 ren config.h2 config.tmp\r
182 sed -f ../msdos/sedalloc.inp <config.tmp >config.h2\r
183 \r
184 :cfgDone\r
185 rm -f junk.c junk junk.exe\r
186 update config.h2 config.h >nul\r
187 rm -f config.tmp config.h2\r
188 \r
189 rem On my system dir.h gets in the way. It's a VMS file so who cares.\r
190 if exist dir.h ren dir.h vmsdir.h\r
191 \r
192 rem Create "makefile" from "makefile.in".\r
193 rm -f Makefile makefile.tmp\r
194 copy Makefile.in+deps.mk makefile.tmp\r
195 sed -f ../msdos/sed1v2.inp <makefile.tmp >Makefile\r
196 rm -f makefile.tmp\r
197 \r
198 if "%X11%" == "" goto src5\r
199 mv Makefile makefile.tmp\r
200 sed -f ../msdos/sed1x.inp <makefile.tmp >Makefile\r
201 rm -f makefile.tmp\r
202 :src5\r
203 \r
204 if "%sys_malloc%" == "" goto src5a\r
205 sed -e "/^GMALLOC_OBJ *=/s/gmalloc.o//" <Makefile >makefile.tmp\r
206 sed -e "/^VMLIMIT_OBJ *=/s/vm-limit.o//" <makefile.tmp >makefile.tmp2\r
207 sed -e "/^RALLOC_OBJ *=/s/ralloc.o//" <makefile.tmp2 >Makefile\r
208 rm -f makefile.tmp makefile.tmp2\r
209 :src5a\r
210 \r
211 if "%nodebug%" == "" goto src6\r
212 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp\r
213 sed -e "/^LDFLAGS *=/s/=/=-s/" <makefile.tmp >Makefile\r
214 rm -f makefile.tmp\r
215 :src6\r
216 cd ..\r
217 rem ----------------------------------------------------------------------\r
218 Echo Configuring the library source directory...\r
219 cd lib-src\r
220 sed -f ../msdos/sed3v2.inp <Makefile.in >Makefile\r
221 if "%X11%" == "" goto libsrc2a\r
222 mv Makefile makefile.tmp\r
223 sed -f ../msdos/sed3x.inp <makefile.tmp >Makefile\r
224 rm -f makefile.tmp\r
225 :libsrc2a\r
226 if "%nodebug%" == "" goto libsrc3\r
227 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp\r
228 sed -e "/^ALL_CFLAGS *=/s/=/= -s/" <makefile.tmp >Makefile\r
229 rm -f makefile.tmp\r
230 :libsrc3\r
231 cd ..\r
232 rem ----------------------------------------------------------------------\r
233 if "%X11%" == "" goto oldx1\r
234 Echo Configuring the oldxmenu directory...\r
235 cd oldxmenu\r
236 sed -f ../msdos/sed5x.inp <Makefile.in >Makefile\r
237 if "%nodebug%" == "" goto oldx2\r
238 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp\r
239 mv -f makefile.tmp Makefile\r
240 :oldx2\r
241 cd ..\r
242 :oldx1\r
243 rem ----------------------------------------------------------------------\r
244 Echo Configuring the doc directory, expect one "File not found" message...\r
245 cd doc\r
246 Rem The two variants for lispintro below is for when the shell\r
247 Rem supports long file names but DJGPP does not\r
248 for %%d in (emacs lispref lispintro lispintr misc) do sed -f ../msdos/sed6.inp < %%d\Makefile.in > %%d\Makefile\r
249 cd ..\r
250 rem ----------------------------------------------------------------------\r
251 Echo Configuring the lisp directory...\r
252 cd lisp\r
253 sed -f ../msdos/sedlisp.inp < Makefile.in > Makefile\r
254 cd ..\r
255 rem ----------------------------------------------------------------------\r
256 If not Exist leim\quail\latin-pre.el goto maindir\r
257 Echo Configuring the leim directory...\r
258 cd leim\r
259 sed -f ../msdos/sedleim.inp < Makefile.in > Makefile\r
260 cd ..\r
261 rem ----------------------------------------------------------------------\r
262 :maindir\r
263 Echo Configuring the main directory...\r
264 If Exist .dir-locals.el update .dir-locals.el _dir-locals.el\r
265 If Exist src\.dbxinit update src/.dbxinit src/_dbxinit\r
266 Echo Looking for the GDB init file...\r
267 If Exist src\.gdbinit update src/.gdbinit src/_gdbinit\r
268 If Exist src\_gdbinit goto gdbinitOk\r
269 Echo ERROR:\r
270 Echo I cannot find the GDB init file. It was called ".gdbinit" in\r
271 Echo the Emacs distribution, but was probably renamed to some other\r
272 Echo name without the leading dot when you untarred the archive.\r
273 Echo It should be in the "src/" subdirectory. Please make sure this\r
274 Echo file exists and is called "_gdbinit" with a leading underscore.\r
275 Echo Then run CONFIG.BAT again with the same arguments you did now.\r
276 goto End\r
277 :gdbinitOk\r
278 Echo Looking for the GDB init file...found\r
279 copy msdos\mainmake.v2 Makefile >nul\r
280 rem ----------------------------------------------------------------------\r
281 goto End\r
282 :SmallEnv\r
283 echo Your environment size is too small. Please enlarge it and run me again.\r
284 echo For example, type "command.com /e:2048" to have 2048 bytes available.\r
285 set $foo$=\r
286 :end\r
287 set X11=\r
288 set nodebug=\r
289 set djgpp_ver=\r
290 set sys_malloc=\r
291 \r
292 goto skipArchTag\r
293 arch-tag: 2d2fed23-4dc6-4006-a2e4-49daf0031f33\r
294 :skipArchTag\r