lisp/find-dired.el

   1 ;;; find-dired.el --- run a `find' command and dired the output
   2
   3 ;; Copyright (C) 1992, 1994, 1995, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012 Free Software Foundation, Inc.
   5
   6 ;; Author: Roland McGrath <roland@gnu.org>,
   7 ;;         Sebastian Kremer <sk@thp.uni-koeln.de>
   8 ;; Maintainer: FSF
   9 ;; Keywords: unix
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'dired)
  31
  32 (defgroup find-dired nil
  33   "Run a `find' command and dired the output."
  34   :group 'dired
  35   :prefix "find-")
  36
  37 ;; find's -ls corresponds to these switches.
  38 ;; Note -b, at least GNU find quotes spaces etc. in filenames
  39 ;;;###autoload
  40 (defcustom find-ls-option
  41   (if (eq system-type 'berkeley-unix) (purecopy '("-ls" . "-gilsb"))
  42     (purecopy '("-exec ls -ld {} \\;" . "-ld")))
  43   "Description of the option to `find' to produce an `ls -l'-type listing.
  44 This is a cons of two strings (FIND-OPTION . LS-SWITCHES).  FIND-OPTION
  45 gives the option (or options) to `find' that produce the desired output.
  46 LS-SWITCHES is a list of `ls' switches to tell dired how to parse the output."
  47   :type '(cons (string :tag "Find Option")
  48                (string :tag "Ls Switches"))
  49   :group 'find-dired)
  50
  51 ;;;###autoload
  52 (defcustom find-ls-subdir-switches (purecopy "-al")
  53   "`ls' switches for inserting subdirectories in `*Find*' buffers.
  54 This should contain the \"-l\" switch.
  55 Use the \"-F\" or \"-b\" switches if and only if you also use
  56 them for `find-ls-option'."
  57   :type 'string
  58   :group 'find-dired
  59   :version "22.1")
  60
  61 ;;;###autoload
  62 (defcustom find-grep-options
  63   (purecopy (if (or (eq system-type 'berkeley-unix)
  64           (string-match "solaris2" system-configuration)
  65           (string-match "irix" system-configuration))
  66       "-s" "-q"))
  67   "Option to grep to be as silent as possible.
  68 On Berkeley systems, this is `-s'; on Posix, and with GNU grep, `-q' does it.
  69 On other systems, the closest you can come is to use `-l'."
  70   :type 'string
  71   :group 'find-dired)
  72
  73 ;; This used to be autoloaded (see bug#4387).
  74 (defcustom find-name-arg
  75   (purecopy (if read-file-name-completion-ignore-case
  76       "-iname"
  77     "-name"))
  78   "Argument used to specify file name pattern.
  79 If `read-file-name-completion-ignore-case' is non-nil, -iname is used so that
  80 find also ignores case.  Otherwise, -name is used."
  81   :type 'string
  82   :group 'find-dired
  83   :version "22.2")
  84
  85 (defvar find-args nil
  86   "Last arguments given to `find' by \\[find-dired].")
  87
  88 ;; History of find-args values entered in the minibuffer.
  89 (defvar find-args-history nil)
  90
  91 (defvar dired-sort-inhibit)
  92
  93 ;;;###autoload
  94 (defun find-dired (dir args)
  95   "Run `find' and go into Dired mode on a buffer of the output.
  96 The command run (after changing into DIR) is
  97
  98     find . \\( ARGS \\) -ls
  99
 100 except that the variable `find-ls-option' specifies what to use
 101 as the final argument."
 102   (interactive (list (read-file-name "Run find in directory: " nil "" t)
 103                      (read-string "Run find (with args): " find-args
 104                                   '(find-args-history . 1))))
 105   (let ((dired-buffers dired-buffers))
 106     ;; Expand DIR ("" means default-directory), and make sure it has a
 107     ;; trailing slash.
 108     (setq dir (file-name-as-directory (expand-file-name dir)))
 109     ;; Check that it's really a directory.
 110     (or (file-directory-p dir)
 111         (error "find-dired needs a directory: %s" dir))
 112     (switch-to-buffer (get-buffer-create "*Find*"))
 113
 114     ;; See if there's still a `find' running, and offer to kill
 115     ;; it first, if it is.
 116     (let ((find (get-buffer-process (current-buffer))))
 117       (when find
 118         (if (or (not (eq (process-status find) 'run))
 119                 (yes-or-no-p "A `find' process is running; kill it? "))
 120             (condition-case nil
 121                 (progn
 122                   (interrupt-process find)
 123                   (sit-for 1)
 124                   (delete-process find))
 125               (error nil))
 126           (error "Cannot have two processes in `%s' at once" (buffer-name)))))
 127
 128     (widen)
 129     (kill-all-local-variables)
 130     (setq buffer-read-only nil)
 131     (erase-buffer)
 132     (setq default-directory dir
 133           find-args args              ; save for next interactive call
 134           args (concat find-program " . "
 135                        (if (string= args "")
 136                            ""
 137                          (concat
 138                           (shell-quote-argument "(")
 139                           " " args " "
 140                           (shell-quote-argument ")")
 141                           " "))
 142                        (if (equal (car find-ls-option) "-exec ls -ld {} \\;")
 143                            (concat "-exec ls -ld "
 144                                    (shell-quote-argument "{}")
 145                                    " "
 146                                    (shell-quote-argument ";"))
 147                          (car find-ls-option))))
 148     ;; Start the find process.
 149     (shell-command (concat args "&") (current-buffer))
 150     ;; The next statement will bomb in classic dired (no optional arg allowed)
 151     (dired-mode dir (cdr find-ls-option))
 152     (let ((map (make-sparse-keymap)))
 153       (set-keymap-parent map (current-local-map))
 154       (define-key map "\C-c\C-k" 'kill-find)
 155       (use-local-map map))
 156     (make-local-variable 'dired-sort-inhibit)
 157     (setq dired-sort-inhibit t)
 158     (set (make-local-variable 'revert-buffer-function)
 159          `(lambda (ignore-auto noconfirm)
 160             (find-dired ,dir ,find-args)))
 161     ;; Set subdir-alist so that Tree Dired will work:
 162     (if (fboundp 'dired-simple-subdir-alist)
 163         ;; will work even with nested dired format (dired-nstd.el,v 1.15
 164         ;; and later)
 165         (dired-simple-subdir-alist)
 166       ;; else we have an ancient tree dired (or classic dired, where
 167       ;; this does no harm)
 168       (set (make-local-variable 'dired-subdir-alist)
 169            (list (cons default-directory (point-min-marker)))))
 170     (set (make-local-variable 'dired-subdir-switches) find-ls-subdir-switches)
 171     (setq buffer-read-only nil)
 172     ;; Subdir headlerline must come first because the first marker in
 173     ;; subdir-alist points there.
 174     (insert "  " dir ":\n")
 175     ;; Make second line a ``find'' line in analogy to the ``total'' or
 176     ;; ``wildcard'' line.
 177     (insert "  " args "\n")
 178     (setq buffer-read-only t)
 179     (let ((proc (get-buffer-process (current-buffer))))
 180       (set-process-filter proc (function find-dired-filter))
 181       (set-process-sentinel proc (function find-dired-sentinel))
 182       ;; Initialize the process marker; it is used by the filter.
 183       (move-marker (process-mark proc) 1 (current-buffer)))
 184     (setq mode-line-process '(":%s"))))
 185
 186 (defun kill-find ()
 187   "Kill the `find' process running in the current buffer."
 188   (interactive)
 189   (let ((find (get-buffer-process (current-buffer))))
 190     (and find (eq (process-status find) 'run)
 191          (eq (process-filter find) (function find-dired-filter))
 192          (condition-case nil
 193              (delete-process find)
 194            (error nil)))))
 195
 196 ;;;###autoload
 197 (defun find-name-dired (dir pattern)
 198   "Search DIR recursively for files matching the globbing pattern PATTERN,
 199 and run dired on those files.
 200 PATTERN is a shell wildcard (not an Emacs regexp) and need not be quoted.
 201 The command run (after changing into DIR) is
 202
 203     find . -name 'PATTERN' -ls"
 204   (interactive
 205    "DFind-name (directory): \nsFind-name (filename wildcard): ")
 206   (find-dired dir (concat find-name-arg " " (shell-quote-argument pattern))))
 207
 208 ;; This functionality suggested by
 209 ;; From: oblanc@watcgl.waterloo.edu (Olivier Blanc)
 210 ;; Subject: find-dired, lookfor-dired
 211 ;; Date: 10 May 91 17:50:00 GMT
 212 ;; Organization: University of Waterloo
 213
 214 (defalias 'lookfor-dired 'find-grep-dired)
 215 ;;;###autoload
 216 (defun find-grep-dired (dir regexp)
 217   "Find files in DIR containing a regexp REGEXP and start Dired on output.
 218 The command run (after changing into DIR) is
 219
 220     find . -exec grep -s -e REGEXP {} \\\; -ls
 221
 222 Thus ARG can also contain additional grep options."
 223   (interactive "DFind-grep (directory): \nsFind-grep (grep regexp): ")
 224   ;; find -exec doesn't allow shell i/o redirections in the command,
 225   ;; or we could use `grep -l >/dev/null'
 226   ;; We use -type f, not ! -type d, to avoid getting screwed
 227   ;; by FIFOs and devices.  I'm not sure what's best to do
 228   ;; about symlinks, so as far as I know this is not wrong.
 229   (find-dired dir
 230               (concat "-type f -exec " grep-program " " find-grep-options " -e "
 231                       (shell-quote-argument regexp)
 232                       " "
 233                       (shell-quote-argument "{}")
 234                       " "
 235                       (shell-quote-argument ";"))))
 236
 237 (defun find-dired-filter (proc string)
 238   ;; Filter for \\[find-dired] processes.
 239   (let ((buf (process-buffer proc))
 240         (inhibit-read-only t))
 241     (if (buffer-name buf)
 242         (with-current-buffer buf
 243           (save-excursion
 244             (save-restriction
 245               (widen)
 246               (let ((buffer-read-only nil)
 247                     (beg (point-max))
 248                     (l-opt (and (consp find-ls-option)
 249                                 (string-match "l" (cdr find-ls-option))))
 250                     (ls-regexp (concat "^ +[^ \t\r\n]+\\( +[^ \t\r\n]+\\) +"
 251                                        "[^ \t\r\n]+ +[^ \t\r\n]+\\( +[0-9]+\\)")))
 252                 (goto-char beg)
 253                 (insert string)
 254                 (goto-char beg)
 255                 (or (looking-at "^")
 256                     (forward-line 1))
 257                 (while (looking-at "^")
 258                   (insert "  ")
 259                   (forward-line 1))
 260                 ;; Convert ` ./FILE' to ` FILE'
 261                 ;; This would lose if the current chunk of output
 262                 ;; starts or ends within the ` ./', so back up a bit:
 263                 (goto-char (- beg 3))   ; no error if < 0
 264                 (while (search-forward " ./" nil t)
 265                   (delete-region (point) (- (point) 2)))
 266                 ;; Pad the number of links and file size.  This is a
 267                 ;; quick and dirty way of getting the columns to line up
 268                 ;; most of the time, but it's not foolproof.
 269                 (when l-opt
 270                   (goto-char beg)
 271                   (goto-char (line-beginning-position))
 272                   (while (re-search-forward ls-regexp nil t)
 273                     (replace-match (format "%4s" (match-string 1))
 274                                    nil nil nil 1)
 275                     (replace-match (format "%9s" (match-string 2))
 276                                    nil nil nil 2)
 277                     (forward-line 1)))
 278                 ;; Find all the complete lines in the unprocessed
 279                 ;; output and process it to add text properties.
 280                 (goto-char (point-max))
 281                 (if (search-backward "\n" (process-mark proc) t)
 282                     (progn
 283                       (dired-insert-set-properties (process-mark proc)
 284                                                    (1+ (point)))
 285                       (move-marker (process-mark proc) (1+ (point)))))))))
 286       ;; The buffer has been killed.
 287       (delete-process proc))))
 288
 289 (defun find-dired-sentinel (proc state)
 290   ;; Sentinel for \\[find-dired] processes.
 291   (let ((buf (process-buffer proc))
 292         (inhibit-read-only t))
 293     (if (buffer-name buf)
 294         (with-current-buffer buf
 295           (let ((buffer-read-only nil))
 296             (save-excursion
 297               (goto-char (point-max))
 298               (insert "\n  find " state)
 299               (forward-char -1)         ;Back up before \n at end of STATE.
 300               (insert " at " (substring (current-time-string) 0 19))
 301               (forward-char 1)
 302               (setq mode-line-process
 303                     (concat ":"
 304                             (symbol-name (process-status proc))))
 305               ;; Since the buffer and mode line will show that the
 306               ;; process is dead, we can delete it now.  Otherwise it
 307               ;; will stay around until M-x list-processes.
 308               (delete-process proc)
 309               (force-mode-line-update)))
 310           (message "find-dired %s finished." (current-buffer))))))
 311
 312 \f
 313 (provide 'find-dired)
 314
 315 ;; arch-tag: 8edece95-af00-4221-bc74-a4bd2f75f9b0
 316 ;;; find-dired.el ends here