lisp/composite.el

   1 ;;; composite.el --- support character composition
   2
   3 ;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 ;;   2008
   5 ;;   National Institute of Advanced Industrial Science and Technology (AIST)
   6 ;;   Registration Number H14PRO021
   7
   8 ;; Keywords: mule, multilingual, character composition
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (defconst reference-point-alist
  30   '((tl . 0) (tc . 1) (tr . 2)
  31     (Bl . 3) (Bc . 4) (Br . 5)
  32     (bl . 6) (bc . 7) (br . 8)
  33     (cl . 9) (cc . 10) (cr . 11)
  34     (top-left . 0) (top-center . 1) (top-right . 2)
  35     (base-left . 3) (base-center . 4) (base-right . 5)
  36     (bottom-left . 6) (bottom-center . 7) (bottom-right . 8)
  37     (center-left . 9) (center-center . 10) (center-right . 11)
  38     ;; For backward compatibility...
  39     (ml . 3) (mc . 10) (mr . 5)
  40     (mid-left . 3) (mid-center . 10) (mid-right . 5))
  41   "Alist of symbols vs integer codes of glyph reference points.
  42 A glyph reference point symbol is to be used to specify a composition
  43 rule in COMPONENTS argument to such functions as `compose-region'.
  44
  45 Meanings of glyph reference point codes are as follows:
  46
  47     0----1----2 <---- ascent    0:tl or top-left
  48     |         |                 1:tc or top-center
  49     |         |                 2:tr or top-right
  50     |         |                 3:Bl or base-left     9:cl or center-left
  51     9   10   11 <---- center    4:Bc or base-center  10:cc or center-center
  52     |         |                 5:Br or base-right   11:cr or center-right
  53   --3----4----5-- <-- baseline  6:bl or bottom-left
  54     |         |                 7:bc or bottom-center
  55     6----7----8 <---- descent   8:br or bottom-right
  56
  57 Glyph reference point symbols are to be used to specify composition
  58 rule of the form \(GLOBAL-REF-POINT . NEW-REF-POINT), where
  59 GLOBAL-REF-POINT is a reference point in the overall glyphs already
  60 composed, and NEW-REF-POINT is a reference point in the new glyph to
  61 be added.
  62
  63 For instance, if GLOBAL-REF-POINT is `br' (bottom-right) and
  64 NEW-REF-POINT is `tc' (top-center), the overall glyph is updated as
  65 follows (the point `*' corresponds to both reference points):
  66
  67     +-------+--+ <--- new ascent
  68     |       |  |
  69     | global|  |
  70     | glyph |  |
  71  -- |       |  |-- <--- baseline \(doesn't change)
  72     +----+--*--+
  73     |    | new |
  74     |    |glyph|
  75     +----+-----+ <--- new descent
  76
  77 A composition rule may have the form \(GLOBAL-REF-POINT
  78 NEW-REF-POINT XOFF YOFF), where XOFF and YOFF specifies how much
  79 to shift NEW-REF-POINT from GLOBAL-REF-POINT.  In this case, XOFF
  80 and YOFF are integers in the range -100..100 representing the
  81 shifting percentage against the font size.")
  82
  83
  84 ;;;###autoload
  85 (defun encode-composition-rule (rule)
  86   "Encode composition rule RULE into an integer value.
  87 RULE is a cons of global and new reference point symbols
  88 \(see `reference-point-alist')."
  89
  90   ;; This must be compatible with C macro COMPOSITION_ENCODE_RULE
  91   ;; defined in composite.h.
  92
  93   (if (and (integerp rule) (< rule 144))
  94       ;; Already encoded.
  95       rule
  96     (if (consp rule)
  97         (let ((gref (car rule))
  98               (nref (cdr rule))
  99               xoff yoff)
 100           (if (consp nref)              ; (GREF NREF XOFF YOFF)
 101               (progn
 102                 (setq xoff (nth 1 nref)
 103                       yoff (nth 2 nref)
 104                       nref (car nref))
 105                 (or (and (>= xoff -100) (<= xoff 100)
 106                          (>= yoff -100) (<= yoff 100))
 107                     (error "Invalid composition rule: %s" rule))
 108                 (setq xoff (+ xoff 128) yoff (+ yoff 128)))
 109             ;; (GREF . NREF)
 110             (setq xoff 0 yoff 0))
 111           (or (integerp gref)
 112               (setq gref (cdr (assq gref reference-point-alist))))
 113           (or (integerp nref)
 114               (setq nref (cdr (assq nref reference-point-alist))))
 115           (or (and (>= gref 0) (< gref 12) (>= nref 0) (< nref 12))
 116               (error "Invalid composition rule: %S" rule))
 117           (logior (lsh xoff 16) (lsh yoff 8) (+ (* gref 12) nref)))
 118       (error "Invalid composition rule: %S" rule))))
 119
 120 ;; Decode encoded composition rule RULE-CODE.  The value is a cons of
 121 ;; global and new reference point symbols.
 122 ;; This must be compatible with C macro COMPOSITION_DECODE_RULE
 123 ;; defined in composite.h.
 124
 125 (defun decode-composition-rule (rule-code)
 126   (or (and (natnump rule-code) (< rule-code #x1000000))
 127       (error "Invalid encoded composition rule: %S" rule-code))
 128   (let ((xoff (lsh rule-code -16))
 129         (yoff (logand (lsh rule-code -8) #xFF))
 130         gref nref)
 131     (setq rule-code (logand rule-code #xFF)
 132           gref (car (rassq (/ rule-code 12) reference-point-alist))
 133           nref (car (rassq (% rule-code 12) reference-point-alist)))
 134     (or (and gref (symbolp gref) nref (symbolp nref))
 135         (error "Invalid composition rule code: %S" rule-code))
 136     (if (and (= xoff 0) (= yoff 0))
 137         (cons gref nref)
 138       (setq xoff (- xoff 128) yoff (- yoff 128))
 139       (list gref xoff yoff nref))))
 140
 141 ;; Encode composition rules in composition components COMPONENTS.  The
 142 ;; value is a copy of COMPONENTS, where composition rules (cons of
 143 ;; global and new glyph reference point symbols) are replaced with
 144 ;; encoded composition rules.  Optional 2nd argument NOCOPY non-nil
 145 ;; means don't make a copy but modify COMPONENTS directly.
 146
 147 (defun encode-composition-components (components &optional nocopy)
 148   (or nocopy
 149       (setq components (copy-sequence components)))
 150   (if (vectorp components)
 151       (let ((len (length components))
 152             (i 1))
 153         (while (< i len)
 154           (aset components i
 155                 (encode-composition-rule (aref components i)))
 156           (setq i (+ i 2))))
 157     (let ((tail (cdr components)))
 158       (while tail
 159         (setcar tail
 160                 (encode-composition-rule (car tail)))
 161         (setq tail (nthcdr 2 tail)))))
 162   components)
 163
 164 ;; Decode composition rule codes in composition components COMPONENTS.
 165 ;; The value is a copy of COMPONENTS, where composition rule codes are
 166 ;; replaced with composition rules (cons of global and new glyph
 167 ;; reference point symbols).  Optional 2nd argument NOCOPY non-nil
 168 ;; means don't make a copy but modify COMPONENTS directly.
 169 ;; It is assumed that COMPONENTS is a vector and is for rule-base
 170 ;; composition, thus (2N+1)th elements are rule codes.
 171
 172 (defun decode-composition-components (components &optional nocopy)
 173   (or nocopy
 174       (setq components (copy-sequence components)))
 175   (let ((len (length components))
 176         (i 1))
 177     (while (< i len)
 178       (aset components i
 179             (decode-composition-rule (aref components i)))
 180       (setq i (+ i 2))))
 181   components)
 182
 183 (defun compose-region (start end &optional components modification-func)
 184   "Compose characters in the current region.
 185
 186 Characters are composed relatively, i.e. composed by overstricking or
 187 stacking depending on ascent, descent and other properties.
 188
 189 When called from a program, expects these four arguments.
 190
 191 First two arguments START and END are positions (integers or markers)
 192 specifying the region.
 193
 194 Optional 3rd argument COMPONENTS, if non-nil, is a character, a string
 195 or a vector or list of integers and rules.
 196
 197 If it is a character, it is an alternate character to display instead
 198 of the text in the region.
 199
 200 If it is a string, the elements are alternate characters.  In
 201 this case, TAB element has a special meaning.  If the first
 202 characer is TAB, the glyphs are displayed with left padding space
 203 so that no pixel overlaps with the previous column.  If the last
 204 character is TAB, the glyphs are displayed with rigth padding
 205 space so that no pixel overlaps with the following column.
 206
 207 If it is a vector or list, it is a sequence of alternate characters and
 208 composition rules, where (2N)th elements are characters and (2N+1)th
 209 elements are composition rules to specify how to compose (2N+2)th
 210 elements with previously composed N glyphs.
 211
 212 A composition rule is a cons of global and new glyph reference point
 213 symbols.  See the documentation of `reference-point-alist' for more
 214 detail.
 215
 216 Optional 4th argument MODIFICATION-FUNC is a function to call to
 217 adjust the composition when it gets invalid because of a change of
 218 text in the composition."
 219   (interactive "r")
 220   (let ((modified-p (buffer-modified-p))
 221         (inhibit-read-only t))
 222     (if (or (vectorp components) (listp components))
 223         (setq components (encode-composition-components components)))
 224     (compose-region-internal start end components modification-func)
 225     (restore-buffer-modified-p modified-p)))
 226
 227 (defun decompose-region (start end)
 228   "Decompose text in the current region.
 229
 230 When called from a program, expects two arguments,
 231 positions (integers or markers) specifying the region."
 232   (interactive "r")
 233   (let ((modified-p (buffer-modified-p))
 234         (inhibit-read-only t))
 235     (remove-text-properties start end '(composition nil))
 236     (restore-buffer-modified-p modified-p)))
 237
 238 (defun compose-string (string &optional start end components modification-func)
 239   "Compose characters in string STRING.
 240
 241 The return value is STRING with the `composition' property put on all
 242 the characters in it.
 243
 244 Optional 2nd and 3rd arguments START and END specify the range of
 245 STRING to be composed.  They default to the beginning and the end of
 246 STRING respectively.
 247
 248 Optional 4th argument COMPONENTS, if non-nil, is a character or a
 249 sequence (vector, list, or string) of integers.  See the function
 250 `compose-region' for more detail.
 251
 252 Optional 5th argument MODIFICATION-FUNC is a function to call to
 253 adjust the composition when it gets invalid because of a change of
 254 text in the composition."
 255   (if (or (vectorp components) (listp components))
 256       (setq components (encode-composition-components components)))
 257   (or start (setq start 0))
 258   (or end (setq end (length string)))
 259   (compose-string-internal string start end components modification-func)
 260   string)
 261
 262 (defun decompose-string (string)
 263   "Return STRING where `composition' property is removed."
 264   (remove-text-properties 0 (length string) '(composition nil) string)
 265   string)
 266
 267 (defun compose-chars (&rest args)
 268   "Return a string from arguments in which all characters are composed.
 269 For relative composition, arguments are characters.
 270 For rule-based composition, Mth \(where M is odd) arguments are
 271 characters, and Nth \(where N is even) arguments are composition rules.
 272 A composition rule is a cons of glyph reference points of the form
 273 \(GLOBAL-REF-POINT . NEW-REF-POINT).  See the documentation of
 274 `reference-point-alist' for more detail."
 275   (let (str components)
 276     (if (consp (car (cdr args)))
 277         ;; Rule-base composition.
 278         (let ((len (length args))
 279               (tail (encode-composition-components args 'nocopy)))
 280
 281           (while tail
 282             (setq str (cons (car tail) str))
 283             (setq tail (nthcdr 2 tail)))
 284           (setq str (concat (nreverse str))
 285                 components args))
 286       ;; Relative composition.
 287       (setq str (concat args)))
 288     (compose-string-internal str 0 (length str) components)))
 289
 290 (defun find-composition (pos &optional limit string detail-p)
 291   "Return information about a composition at or nearest to buffer position POS.
 292
 293 If the character at POS has `composition' property, the value is a list
 294 of FROM, TO, and VALID-P.
 295
 296 FROM and TO specify the range of text that has the same `composition'
 297 property, VALID-P is t if this composition is valid, and nil if not.
 298
 299 If there's no composition at POS, and the optional 2nd argument LIMIT
 300 is non-nil, search for a composition toward LIMIT.
 301
 302 If no composition is found, return nil.
 303
 304 Optional 3rd argument STRING, if non-nil, is a string to look for a
 305 composition in; nil means the current buffer.
 306
 307 If a valid composition is found and the optional 4th argument DETAIL-P
 308 is non-nil, the return value is a list of FROM, TO, COMPONENTS,
 309 RELATIVE-P, MOD-FUNC, and WIDTH.
 310
 311 COMPONENTS is a vector of integers, the meaning depends on RELATIVE-P.
 312
 313 RELATIVE-P is t if the composition method is relative, else nil.
 314
 315 If RELATIVE-P is t, COMPONENTS is a vector of characters to be
 316 composed.  If RELATIVE-P is nil, COMPONENTS is a vector of characters
 317 and composition rules as described in `compose-region'.
 318
 319 MOD-FUNC is a modification function of the composition.
 320
 321 WIDTH is a number of columns the composition occupies on the screen.
 322
 323 When Automatic Compostion mode is on, this function also finds a
 324 chunk of text that is automatically composed.  If such a chunk is
 325 found closer to POS than the position that has `composition'
 326 property, the value is a list of FROM, TO, and a glyph gstring
 327 the specify how the chunk is composed.  See the function
 328 `composition-get-gstring' for the format of the glyph string."
 329   (let ((result (find-composition-internal pos limit string detail-p)))
 330     (if (and detail-p (> (length result) 3) (nth 2 result) (not (nth 3 result)))
 331         ;; This is a valid rule-base composition.
 332         (decode-composition-components (nth 2 result) 'nocopy))
 333     result))
 334
 335 \f
 336 (defun compose-chars-after (pos &optional limit object)
 337   "Compose characters in current buffer after position POS.
 338
 339 It looks up the char-table `composition-function-table' (which
 340 see) by a character at POS, and compose characters after POS
 341 according to the contents of `composition-function-table'.
 342
 343 Optional 2nd arg LIMIT, if non-nil, limits characters to compose.
 344
 345 Optional 3rd arg OBJECT, if non-nil, is a string that contains the
 346 text to compose.  In that case, POS and LIMIT index into the string.
 347
 348 This function is the default value of `compose-chars-after-function'."
 349   (let ((tail (aref composition-function-table (char-after pos)))
 350         (font-obj (and (display-multi-font-p)
 351                        (and (not (stringp object))
 352                             (font-at pos (selected-window)))))
 353         pattern func result)
 354     (or limit
 355         (setq limit (if (stringp object) (length object) (point-max))))
 356     (when (and font-obj tail)
 357       (save-match-data
 358         (save-excursion
 359           (while tail
 360             (if (functionp (car tail))
 361                 (setq pattern nil func (car tail))
 362               (setq pattern (car (car tail))
 363                     func (cdr (car tail))))
 364             (goto-char pos)
 365             (if pattern
 366                 (if (and (if (stringp object)
 367                              (eq (string-match pattern object) 0)
 368                            (looking-at pattern))
 369                          (<= (match-end 0) limit))
 370                     (setq result
 371                           (funcall func pos (match-end 0) font-obj object)))
 372               (setq result (funcall func pos limit font-obj  object)))
 373             (if result (setq tail nil))))))
 374     result))
 375
 376 (defun compose-last-chars (args)
 377   "Compose last characters.
 378 The argument is a parameterized event of the form
 379         \(compose-last-chars N COMPONENTS),
 380 where N is the number of characters before point to compose,
 381 COMPONENTS, if non-nil, is the same as the argument to `compose-region'
 382 \(which see).  If it is nil, `compose-chars-after' is called,
 383 and that function finds a proper rule to compose the target characters.
 384 This function is intended to be used from input methods.
 385 The global keymap binds special event `compose-last-chars' to this
 386 function.  Input method may generate an event (compose-last-chars N COMPONENTS)
 387 after a sequence of character events."
 388   (interactive "e")
 389   (let ((chars (nth 1 args)))
 390     (if (and (numberp chars)
 391              (>= (- (point) (point-min)) chars))
 392         (if (nth 2 args)
 393             (compose-region (- (point) chars) (point) (nth 2 args))
 394           (compose-chars-after (- (point) chars) (point))))))
 395
 396 (global-set-key [compose-last-chars] 'compose-last-chars)
 397
 398 \f
 399 ;;; Automatic character composition.
 400
 401 ;; Copied from font-lock.el.
 402 (eval-when-compile
 403   ;; Borrowed from lazy-lock.el.
 404   ;; We use this to preserve or protect things when modifying text properties.
 405   (defmacro save-buffer-state (varlist &rest body)
 406     "Bind variables according to VARLIST and eval BODY restoring buffer state."
 407     `(let* ,(append varlist
 408                     '((modified (buffer-modified-p)) (buffer-undo-list t)
 409                       (inhibit-read-only t) (inhibit-point-motion-hooks t)
 410                       (inhibit-modification-hooks t)
 411                       deactivate-mark buffer-file-name buffer-file-truename))
 412        ,@body
 413        (unless modified
 414          (restore-buffer-modified-p nil))))
 415   ;; Fixme: This makes bootstrapping fail with this error.
 416   ;;   Symbol's function definition is void: eval-defun
 417   ;;(def-edebug-spec save-buffer-state let)
 418   )
 419
 420 (put 'save-buffer-state 'lisp-indent-function 1)
 421
 422 ;; These macros must match with C macros LGSTRING_XXX and LGLYPH_XXX in font.h
 423 (defsubst lgstring-header (gstring) (aref gstring 0))
 424 (defsubst lgstring-set-header (gstring header) (aset gstring 0 header))
 425 (defsubst lgstring-font (gstring) (aref (lgstring-header gstring) 0))
 426 (defsubst lgstring-char (gstring i) (aref (lgstring-header gstring) (1+ i)))
 427 (defsubst lgstring-char-len (gstring) (1- (length (lgstring-header gstring))))
 428 (defsubst lgstring-shaped-p (gstring) (aref gstring 1))
 429 (defsubst lgstring-set-id (gstring id) (aset gstring 1 id))
 430 (defsubst lgstring-glyph (gstring i) (aref gstring (+ i 2)))
 431 (defsubst lgstring-glyph-len (gstring) (- (length gstring) 2))
 432 (defsubst lgstring-set-glyph (gstring i glyph) (aset gstring (+ i 2) glyph))
 433
 434 (defsubst lglyph-from (glyph) (aref glyph 0))
 435 (defsubst lglyph-to (glyph) (aref glyph 1))
 436 (defsubst lglyph-char (glyph) (aref glyph 2))
 437 (defsubst lglyph-code (glyph) (aref glyph 3))
 438 (defsubst lglyph-width (glyph) (aref glyph 4))
 439 (defsubst lglyph-lbearing (glyph) (aref glyph 5))
 440 (defsubst lglyph-rbearing (glyph) (aref glyph 6))
 441 (defsubst lglyph-ascent (glyph) (aref glyph 7))
 442 (defsubst lglyph-descent (glyph) (aref glyph 8))
 443 (defsubst lglyph-adjustment (glyph) (aref glyph 9))
 444
 445 (defsubst lglyph-set-from-to (glyph from to)
 446   (progn (aset glyph 0 from) (aset glyph 1 to)))
 447 (defsubst lglyph-set-char (glyph char) (aset glyph 2 char))
 448 (defsubst lglyph-set-width (glyph width) (aset glyph 4 width))
 449 (defsubst lglyph-set-adjustment (glyph &optional xoff yoff wadjust)
 450   (aset glyph 9 (vector (or xoff 0) (or yoff 0) (or wadjust 0))))
 451
 452 (defsubst lglyph-copy (glyph) (copy-sequence glyph))
 453
 454 (defun lgstring-insert-glyph (gstring idx glyph)
 455   (let ((nglyphs (lgstring-glyph-len gstring))
 456         (i idx) g)
 457     (while (and (< i nglyphs) (setq g (lgstring-glyph gstring i)))
 458       (setq i (1+ i)))
 459     (if (= i nglyphs)
 460         (setq gstring (vconcat gstring (vector glyph)))
 461       (if (< (1+ i) nglyphs)
 462           (lgstring-set-glyph gstring (1+ i) nil)))
 463     (while (> i idx)
 464       (lgstring-set-glyph gstring i (lgstring-glyph gstring (1- i)))
 465       (setq i (1- i)))
 466     (lgstring-set-glyph gstring i glyph)
 467     gstring))
 468
 469 (defun compose-glyph-string (gstring from to)
 470   (let ((glyph (lgstring-glyph gstring from))
 471         from-pos to-pos
 472         ascent descent lbearing rbearing)
 473     (setq from-pos (lglyph-from glyph)
 474           to-pos (lglyph-to (lgstring-glyph gstring (1- to))))
 475     (lglyph-set-from-to glyph from-pos to-pos)
 476     (setq from (1+ from))
 477     (while (and (< from to)
 478                 (setq glyph (lgstring-glyph gstring from)))
 479       (lglyph-set-from-to glyph from-pos to-pos)
 480       (let ((xoff (if (<= (lglyph-rbearing glyph) 0) 0
 481                     (- (lglyph-width glyph)))))
 482         (lglyph-set-adjustment glyph xoff 0 0))
 483       (setq from (1+ from)))
 484     gstring))
 485
 486 (defun compose-glyph-string-relative (gstring from to &optional gap)
 487   (let ((font-object (lgstring-font gstring))
 488         (glyph (lgstring-glyph gstring from))
 489         from-pos to-pos
 490         ascent descent lbearing rbearing)
 491     (if gap
 492         (setq gap (floor (* (font-get font-object :size) gap)))
 493       (setq gap 0))
 494     (setq from-pos (lglyph-from glyph)
 495           to-pos (lglyph-to (lgstring-glyph gstring (1- to)))
 496           ascent (lglyph-ascent glyph)
 497           descent (lglyph-descent glyph))
 498     (lglyph-set-from-to glyph from-pos to-pos)
 499     (setq from (1+ from))
 500     (while (< from to)
 501       (setq glyph (lgstring-glyph gstring from))
 502       (lglyph-set-from-to glyph from-pos to-pos)
 503       (let ((this-ascent (lglyph-ascent glyph))
 504             (this-descent (lglyph-descent glyph))
 505             xoff yoff wadjust)
 506         (setq xoff (if (<= (lglyph-rbearing glyph) 0) 0
 507                      (- (lglyph-width glyph))))
 508         (if (> this-ascent 0)
 509             (if (< this-descent 0)
 510                 (setq yoff (- 0 ascent gap this-descent)
 511                       ascent (+ ascent gap this-ascent this-descent))
 512               (setq yoff 0))
 513           (setq yoff (+ descent gap this-ascent)
 514                 descent (+ descent gap this-ascent this-descent)))
 515         (if (or (/= xoff 0) (/= yoff 0))
 516             (lglyph-set-adjustment glyph xoff yoff 0)))
 517       (setq from (1+ from)))
 518     gstring))
 519
 520 (defun compose-gstring-for-graphic (gstring)
 521   "Compose glyph-string GSTRING for graphic display.
 522 Non-spacing characters are composed with the preceding base
 523 character.  If the preceding character is not a base character,
 524 each non-spacing character is composed as a spacing character by
 525 a padding space before and/or after the character.
 526
 527 All non-spacing characters has this function in
 528 `composition-function-table' unless overwritten."
 529   (let* ((header (lgstring-header gstring))
 530          (nchars (lgstring-char-len gstring))
 531          (nglyphs (lgstring-glyph-len gstring))
 532          (glyph (lgstring-glyph gstring 0)))
 533     (cond
 534      ;; A non-spacing character not following a proper base character.
 535      ((= nchars 1)
 536       (let ((lbearing (lglyph-lbearing glyph))
 537             (rbearing (lglyph-rbearing glyph))
 538             (width (lglyph-width glyph))
 539             xoff wadjust)
 540         (if (< lbearing 0)
 541             (setq xoff (- lbearing))
 542           (setq xoff 0 lbearing 0))
 543         (if (< rbearing width)
 544             (setq rbearing width))
 545         (lglyph-set-adjustment glyph xoff 0 (- rbearing lbearing))
 546         gstring))
 547
 548      ;; This sequence doesn't start with a proper base character.
 549      ((memq (get-char-code-property (lgstring-char gstring 0)
 550                                     'general-category)
 551             '(Mn Mc Me Zs Zl Zp Cc Cf Cs))
 552       nil)
 553
 554      ;; A base character and the following non-spacing characters.
 555      (t
 556       (let ((gstr (font-shape-gstring gstring)))
 557         (if (and gstr
 558                  (> (lglyph-to (lgstring-glyph gstr 0)) 0))
 559             gstr
 560           ;; The shaper of the font couldn't shape the gstring.
 561           ;; Shape them according to canonical-combining-class.
 562           (lgstring-set-id gstring nil)
 563           (let* ((width (lglyph-width glyph))
 564                  (ascent (lglyph-ascent glyph))
 565                  (descent (lglyph-descent glyph))
 566                  (rbearing (lglyph-rbearing glyph))
 567                  (lbearing (lglyph-lbearing glyph))
 568                  (center (/ (+ lbearing rbearing) 2))
 569                  (gap (round (* (font-get (lgstring-font gstring) :size) 0.1)))
 570                  xoff yoff)
 571             (dotimes (i nchars)
 572               (setq glyph (lgstring-glyph gstring i))
 573               (when (> i 0)
 574                 (let* ((class (get-char-code-property
 575                                (lglyph-char glyph) 'canonical-combining-class))
 576                        (lb (lglyph-lbearing glyph))
 577                        (rb (lglyph-rbearing glyph))
 578                        (as (lglyph-ascent glyph))
 579                        (de (lglyph-descent glyph))
 580                        (ce (/ (+ lb rb) 2))
 581                        xoff yoff)
 582                   (when (and class (>= class 200) (<= class 240))
 583                     (setq xoff 0 yoff 0)
 584                     (cond
 585                      ((= class 200)
 586                       (setq xoff (- lbearing ce)
 587                             yoff (if (> as 0) 0 (+ descent as))))
 588                      ((= class 202)
 589                       (if (> as 0) (setq as 0))
 590                       (setq xoff (- center ce)
 591                             yoff (if (> as 0) 0 (+ descent as))))
 592                      ((= class 204)
 593                       (if (> as 0) (setq as 0))
 594                       (setq xoff (- rbearing ce)
 595                             yoff (if (> as 0) 0 (+ descent as))))
 596                      ((= class 208)
 597                       (setq xoff (- lbearing rb)))
 598                      ((= class 210)
 599                       (setq xoff (- rbearing lb)))
 600                      ((= class 212)
 601                       (setq xoff (- lbearing ce)
 602                             yoff (if (>= de 0) 0 (- (- ascent) de))))
 603                      ((= class 214)
 604                       (setq xoff (- center ce)
 605                             yoff (if (>= de 0) 0 (- (- ascent) de))))
 606                      ((= class 216)
 607                       (setq xoff (- rbearing ce)
 608                             yoff (if (>= de 0) 0 (- (- ascent) de))))
 609                      ((= class 218)
 610                       (setq xoff (- lbearing ce)
 611                             yoff (if (> as 0) 0 (+ descent as gap))))
 612                      ((= class 220)
 613                       (setq xoff (- center ce)
 614                             yoff (if (> as 0) 0 (+ descent as gap))))
 615                      ((= class 222)
 616                       (setq xoff (- rbearing ce)
 617                             yoff (if (> as 0) 0 (+ descent as gap))))
 618                      ((= class 224)
 619                       (setq xoff (- lbearing rb)))
 620                      ((= class 226)
 621                       (setq xoff (- rbearing lb)))
 622                      ((= class 228)
 623                       (setq xoff (- lbearing ce)
 624                             yoff (if (>= de 0) 0 (- (- ascent) de gap))))
 625                      ((= class 230)
 626                       (setq xoff (- center ce)
 627                             yoff (if (>= de 0) 0 (- (- ascent) de gap))))
 628                      ((= class 232)
 629                       (setq xoff (- rbearing ce)
 630                             yoff (if (>= de 0) 0 (- (+ ascent de) gap)))))
 631                     (lglyph-set-adjustment glyph (- xoff width) yoff)
 632                     (setq lb (+ lb xoff)
 633                           rb (+ lb xoff)
 634                           as (- as yoff)
 635                           de (+ de yoff)))
 636                   (if (< ascent as)
 637                       (setq ascent as))
 638                   (if (< descent de)
 639                       (setq descent de))))))
 640           (let ((i 0))
 641             (while (and (< i nglyphs) (setq glyph (lgstring-glyph gstring i)))
 642               (lglyph-set-from-to glyph 0 (1- nchars))
 643               (setq i (1+ i))))
 644           gstring))))))
 645
 646 (let ((elt '(["[[:alpha:]]\\c^+" 1 compose-gstring-for-graphic]
 647              [nil 0 compose-gstring-for-graphic])))
 648   (map-char-table
 649    #'(lambda (key val)
 650        (if (= val 0)
 651            (set-char-table-range composition-function-table key elt)))
 652    char-width-table))
 653
 654 (defun compose-gstring-for-terminal (gstring)
 655   "Compose glyph string GSTRING for terminal display.
 656 Non-spacing characters are composed with the preceding base
 657 character.  If the preceding character is not a base character,
 658 each non-spacing character is composed as a spacing character by
 659 a prepending a space before it."
 660   (let* ((header (lgstring-header gstring))
 661          (nchars (lgstring-char-len gstring))
 662          (nglyphs (lgstring-glyph-len gstring))
 663          (i 0)
 664          glyph)
 665     (while (and (< i nglyphs)
 666                 (setq glyph (lgstring-glyph gstring i)))
 667       (if (= (lglyph-width glyph) 0)
 668           (progn
 669             ;; Compose by prepending a space.
 670             (setq gstring (lgstring-insert-glyph gstring i (lglyph-copy glyph))
 671                   nglyphs (lgstring-glyph-len gstring))
 672             (lglyph-set-char (lgstring-glyph gstring i) 32)
 673             (setq i (+ 2)))
 674         (let ((from (lglyph-from glyph))
 675               (to (lglyph-to glyph))
 676               (j (1+ i)))
 677           (while (and (< j nglyphs)
 678                       (setq glyph (lgstring-glyph gstring j))
 679                       (= (lglyph-width glyph) 0))
 680             (setq to (lglyph-to glyph)
 681                   j (1+ j)))
 682           (while (< i j)
 683             (setq glyph (lgstring-glyph gstring i))
 684             (lglyph-set-from-to glyph from to)
 685             (setq i (1+ i))))))
 686     gstring))
 687
 688
 689 (defun auto-compose-chars (func from to font-object string)
 690   "Compose the characters at FROM by FUNC.
 691 FUNC is called with one argument GSTRING which is built for characters
 692 in the region FROM (inclusive) and TO (exclusive).
 693
 694 If the character are composed on a graphic display, FONT-OBJECT
 695 is a font to use.
 696
 697 Otherwise, FONT-OBJECT is nil, and the fucntion
 698 `compose-gstring-for-terminal' is used instead of FUNC.
 699
 700 If STRING is non-nil, it is a string, and FROM and TO are indices
 701 into the string.  In that case, compose characters in the string.
 702
 703 The value is a gstring containing information for shaping the characters.
 704
 705 This function is the default value of `auto-composition-function' (which see)."
 706   (let ((gstring (composition-get-gstring from to font-object string)))
 707     (if (lgstring-shaped-p gstring)
 708         gstring
 709       (or font-object
 710           (setq func 'compose-gstring-for-terminal))
 711       (funcall func gstring))))
 712
 713 (make-variable-buffer-local 'auto-composition-function)
 714
 715 ;;;###autoload
 716 (define-minor-mode auto-composition-mode
 717   "Toggle Auto Composition mode.
 718 With ARG, turn Auto Composition mode off if and only if ARG is a non-positive
 719 number; if ARG is nil, toggle Auto Composition mode; anything else turns Auto
 720 Composition on.
 721
 722 When Auto Composition is enabled, text characters are automatically composed
 723 by functions registered in `composition-function-table' (which see).
 724
 725 You can use `global-auto-composition-mode' to turn on
 726 Auto Composition mode in all buffers (this is the default)."
 727   nil nil nil
 728   (if noninteractive
 729       (setq auto-composition-mode nil))
 730   (cond (auto-composition-mode
 731          (add-hook 'after-change-functions 'auto-composition-after-change nil t)
 732          (setq auto-composition-function 'auto-compose-chars))
 733         (t
 734          (remove-hook 'after-change-functions 'auto-composition-after-change t)
 735          (setq auto-composition-function nil)))
 736   (save-buffer-state nil
 737     (save-restriction
 738       (widen)
 739       (remove-text-properties (point-min) (point-max) '(auto-composed nil))
 740       (decompose-region (point-min) (point-max)))))
 741
 742 (defun auto-composition-after-change (start end old-len)
 743   (save-buffer-state nil
 744     (if (< start (point-min))
 745         (setq start (point-min)))
 746     (if (> end (point-max))
 747         (setq end (point-max)))
 748     (when (and auto-composition-mode (not memory-full))
 749       (let (func1 func2)
 750         (when (and (> start (point-min))
 751                    (setq func2 (aref composition-function-table
 752                                      (char-after (1- start))))
 753                    (or (= start (point-max))
 754                        (not (setq func1 (aref composition-function-table
 755                                               (char-after start))))
 756                        (eq func1 func2)))
 757           (setq start (1- start)
 758                 func1 func2)
 759           (while (eq func1 func2)
 760             (if (> start (point-min))
 761                 (setq start (1- start)
 762                       func2 (aref composition-function-table
 763                                   (char-after start)))
 764               (setq func2 nil))))
 765         (when (and (< end (point-max))
 766                    (setq func2 (aref composition-function-table
 767                                      (char-after end)))
 768                    (or (= end (point-min))
 769                        (not (setq func1 (aref composition-function-table
 770                                               (char-after (1- end)))))
 771                        (eq func1 func2)))
 772           (setq end (1+ end)
 773                 func1 func2)
 774           (while (eq func1 func2)
 775             (if (< end (point-max))
 776                 (setq func2 (aref composition-function-table
 777                                   (char-after end))
 778                       end (1+ end))
 779               (setq func2 nil))))
 780         (if (< start end)
 781             (remove-text-properties start end '(auto-composed nil)))))))
 782
 783 (defun turn-on-auto-composition-if-enabled ()
 784   (if enable-multibyte-characters
 785       (auto-composition-mode 1)))
 786
 787 ;;;###autoload
 788 (define-global-minor-mode global-auto-composition-mode
 789   auto-composition-mode turn-on-auto-composition-if-enabled
 790   :extra-args (dummy)
 791   :initialize 'custom-initialize-safe-default
 792   :init-value (not noninteractive)
 793   :group 'auto-composition
 794   :version "23.1")
 795
 796 (defun toggle-auto-composition (&optional arg)
 797   "Change whether automatic character composition is enabled in this buffer.
 798 With arg, enable it if and only if arg is positive."
 799   (interactive "P")
 800   (let ((enable (if (null arg) (not auto-composition-function)
 801                   (> (prefix-numeric-value arg) 0))))
 802     (if enable
 803         (kill-local-variable 'auto-composition-function)
 804       (make-local-variable 'auto-composition-function)
 805       (setq auto-composition-function nil)
 806       (save-buffer-state nil
 807         (save-restriction
 808           (widen)
 809           (decompose-region (point-min) (point-max)))))
 810
 811     (save-buffer-state nil
 812       (save-restriction
 813         (widen)
 814         (remove-text-properties (point-min) (point-max)
 815                                 '(auto-composed nil))))))
 816
 817 (defun auto-compose-region (from to)
 818   "Force automatic character composition on the region FROM and TO."
 819   (save-excursion
 820     (if (get-text-property from 'auto-composed)
 821         (setq from (next-single-property-change from 'auto-composed nil to)))
 822     (goto-char from)
 823     (let ((modified-p (buffer-modified-p))
 824           (inhibit-read-only '(composition auto-composed))
 825           (stop (next-single-property-change (point) 'auto-composed nil to)))
 826       (while (< (point) to)
 827         (if (= (point) stop)
 828             (progn
 829               (goto-char (next-single-property-change (point)
 830                                                       'auto-composed nil to))
 831               (setq stop (next-single-property-change (point)
 832                                                       'auto-composed nil to)))
 833           (let ((func (aref composition-function-table (following-char)))
 834                 (font-obj (and (display-multi-font-p)
 835                                (font-at (point) (selected-window))))
 836                 (pos (point)))
 837             (if (and (functionp func) font-obj)
 838                 (goto-char (funcall func (point) to font-obj nil)))
 839             (if (<= (point) pos)
 840                 (forward-char 1)))))
 841       (put-text-property from to 'auto-composed t)
 842       (set-buffer-modified-p modified-p))))
 843
 844 \f
 845 ;; The following codes are only for backward compatibility with Emacs
 846 ;; 20.4 and earlier.
 847
 848 (defun decompose-composite-char (char &optional type with-composition-rule)
 849   "Convert CHAR to string.
 850
 851 If optional 2nd arg TYPE is non-nil, it is `string', `list', or
 852 `vector'.  In this case, CHAR is converted to string, list of CHAR, or
 853 vector of CHAR respectively.
 854 Optional 3rd arg WITH-COMPOSITION-RULE is ignored."
 855   (cond ((or (null type) (eq type 'string)) (char-to-string char))
 856         ((eq type 'list) (list char))
 857         (t (vector char))))
 858
 859 (make-obsolete 'decompose-composite-char 'char-to-string "21.1")
 860
 861 \f
 862
 863 ;; arch-tag: ee703d77-1723-45d4-a31f-e9f0f867aa33
 864 ;;; composite.el ends here