lisp/password-cache.el

   1 ;;; password-cache.el --- Read passwords, possibly using a password cache.
   2
   3 ;; Copyright (C) 1999, 2000, 2003, 2004, 2005, 2006, 2007, 2008, 2009,
   4 ;;   2010  Free Software Foundation, Inc.
   5
   6 ;; Author: Simon Josefsson <simon@josefsson.org>
   7 ;; Created: 2003-12-21
   8 ;; Keywords: password cache passphrase key
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Greatly influenced by pgg.el written by Daiki Ueno, with timer
  28 ;; fixes for XEmacs by Katsumi Yamaoka.  In fact, this is mostly just
  29 ;; a rip-off.
  30 ;;
  31 ;; (password-read "Password? " "test")
  32 ;; ;; Minibuffer prompt for password.
  33 ;;  => "foo"
  34 ;;
  35 ;; (password-cache-add "test" "foo")
  36 ;;  => nil
  37
  38 ;; (password-read "Password? " "test")
  39 ;; ;; No minibuffer prompt
  40 ;;  => "foo"
  41 ;;
  42 ;; (password-read "Password? " "test")
  43 ;; ;; No minibuffer prompt
  44 ;;  => "foo"
  45 ;;
  46 ;; ;; Wait `password-cache-expiry' seconds.
  47 ;;
  48 ;; (password-read "Password? " "test")
  49 ;; ;; Minibuffer prompt for password is back.
  50 ;;  => "foo"
  51
  52 ;;; Code:
  53
  54 ;; Options are autoloaded since they are used by eg mml-sec.el.
  55
  56 ;;;###autoload
  57 (defcustom password-cache t
  58   "Whether to cache passwords."
  59   :group 'password
  60   :type 'boolean)
  61
  62 ;;;###autoload
  63 (defcustom password-cache-expiry 16
  64   "How many seconds passwords are cached, or nil to disable expiring.
  65 Whether passwords are cached at all is controlled by `password-cache'."
  66   :group 'password
  67   :type '(choice (const :tag "Never" nil)
  68                  (integer :tag "Seconds")))
  69
  70 (defvar password-data (make-vector 7 0))
  71
  72 (defun password-read-from-cache (key)
  73   "Obtain passphrase for KEY from time-limited passphrase cache.
  74 Custom variables `password-cache' and `password-cache-expiry'
  75 regulate cache behavior."
  76   (and password-cache
  77        key
  78        (symbol-value (intern-soft key password-data))))
  79
  80 (defun password-read (prompt &optional key)
  81   "Read password, for use with KEY, from user, or from cache if wanted.
  82 KEY indicate the purpose of the password, so the cache can
  83 separate passwords.  The cache is not used if KEY is nil.  It is
  84 typically a string.
  85 The variable `password-cache' control whether the cache is used."
  86   (or (password-read-from-cache key)
  87       (read-passwd prompt)))
  88
  89 (defun password-read-and-add (prompt &optional key)
  90   "Read password, for use with KEY, from user, or from cache if wanted.
  91 Then store the password in the cache.  Uses `password-read' and
  92 `password-cache-add'.  Custom variables `password-cache' and
  93 `password-cache-expiry' regulate cache behavior.
  94
  95 Warning: the password is cached without checking that it is
  96 correct.  It is better to check the password before caching.  If
  97 you must use this function, take care to check passwords and
  98 remove incorrect ones from the cache."
  99   (let ((password (password-read prompt key)))
 100     (when (and password key)
 101       (password-cache-add key password))
 102     password))
 103
 104 (make-obsolete 'password-read-and-add 'password-read "23.1")
 105
 106 (defun password-cache-remove (key)
 107   "Remove password indexed by KEY from password cache.
 108 This is typically run by a timer setup from `password-cache-add',
 109 but can be invoked at any time to forcefully remove passwords
 110 from the cache.  This may be useful when it has been detected
 111 that a password is invalid, so that `password-read' query the
 112 user again."
 113   (let ((password (symbol-value (intern-soft key password-data))))
 114     (when password
 115       (if (fboundp 'clear-string)
 116           (clear-string password)
 117         (fillarray password ?_))
 118       (unintern key password-data))))
 119
 120 (defun password-cache-add (key password)
 121   "Add password to cache.
 122 The password is removed by a timer after `password-cache-expiry' seconds."
 123   (when (and password-cache-expiry (null (intern-soft key password-data)))
 124     (run-at-time password-cache-expiry nil
 125                  #'password-cache-remove
 126                  key))
 127   (set (intern key password-data) password)
 128   nil)
 129
 130 (defun password-reset ()
 131   "Clear the password cache."
 132   (interactive)
 133   (fillarray password-data 0))
 134
 135 (provide 'password-cache)
 136
 137 ;; arch-tag: ab160494-16c8-4c68-a4a1-73eebf6686e5
 138 ;;; password-cache.el ends here