lisp/disp-table.el

   1 ;;; disp-table.el --- functions for dealing with char tables
   2
   3 ;; Copyright (C) 1987, 1994, 1995, 1999, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   5
   6 ;; Author: Erik Naggum <erik@naggum.no>
   7 ;; Based on a previous version by Howard Gayle
   8 ;; Maintainer: FSF
   9 ;; Keywords: i18n
  10 ;; Package: emacs
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;;; Code:
  30
  31 (put 'display-table 'char-table-extra-slots 6)
  32
  33 ;;;###autoload
  34 (defun make-display-table ()
  35   "Return a new, empty display table."
  36   (make-char-table 'display-table nil))
  37
  38 (or standard-display-table
  39     (setq standard-display-table (make-display-table)))
  40
  41 ;;; Display-table slot names.  The property value says which slot.
  42
  43 (put 'truncation 'display-table-slot 0)
  44 (put 'wrap 'display-table-slot 1)
  45 (put 'escape 'display-table-slot 2)
  46 (put 'control 'display-table-slot 3)
  47 (put 'selective-display 'display-table-slot 4)
  48 (put 'vertical-border 'display-table-slot 5)
  49
  50 ;;;###autoload
  51 (defun display-table-slot (display-table slot)
  52   "Return the value of the extra slot in DISPLAY-TABLE named SLOT.
  53 SLOT may be a number from 0 to 5 inclusive, or a slot name (symbol).
  54 Valid symbols are `truncation', `wrap', `escape', `control',
  55 `selective-display', and `vertical-border'."
  56   (let ((slot-number
  57          (if (numberp slot) slot
  58            (or (get slot 'display-table-slot)
  59                (error "Invalid display-table slot name: %s" slot)))))
  60     (char-table-extra-slot display-table slot-number)))
  61
  62 ;;;###autoload
  63 (defun set-display-table-slot (display-table slot value)
  64   "Set the value of the extra slot in DISPLAY-TABLE named SLOT to VALUE.
  65 SLOT may be a number from 0 to 5 inclusive, or a name (symbol).
  66 Valid symbols are `truncation', `wrap', `escape', `control',
  67 `selective-display', and `vertical-border'."
  68   (let ((slot-number
  69          (if (numberp slot) slot
  70            (or (get slot 'display-table-slot)
  71                (error "Invalid display-table slot name: %s" slot)))))
  72     (set-char-table-extra-slot display-table slot-number value)))
  73
  74 ;;;###autoload
  75 (defun describe-display-table (dt)
  76   "Describe the display table DT in a help buffer."
  77   (with-help-window "*Help*"
  78     (princ "\nTruncation glyph: ")
  79     (prin1 (display-table-slot dt 'truncation))
  80     (princ "\nWrap glyph: ")
  81     (prin1 (display-table-slot dt 'wrap))
  82     (princ "\nEscape glyph: ")
  83     (prin1 (display-table-slot dt 'escape))
  84     (princ "\nCtrl glyph: ")
  85     (prin1 (display-table-slot dt 'control))
  86     (princ "\nSelective display glyph sequence: ")
  87     (prin1 (display-table-slot dt 'selective-display))
  88     (princ "\nVertical window border glyph: ")
  89     (prin1 (display-table-slot dt 'vertical-border))
  90     (princ "\nCharacter display glyph sequences:\n")
  91     (with-current-buffer standard-output
  92       (let ((vector (make-vector 256 nil))
  93             (i 0))
  94         (while (< i 256)
  95           (aset vector i (aref dt i))
  96           (setq i (1+ i)))
  97         (describe-vector vector))
  98       (help-mode))))
  99
 100 ;;;###autoload
 101 (defun describe-current-display-table ()
 102   "Describe the display table in use in the selected window and buffer."
 103   (interactive)
 104   (let ((disptab (or (window-display-table (selected-window))
 105                      buffer-display-table
 106                      standard-display-table)))
 107     (if disptab
 108         (describe-display-table disptab)
 109       (message "No display table"))))
 110
 111 ;;;###autoload
 112 (defun standard-display-8bit (l h)
 113   "Display characters in the range L to H literally."
 114   (or standard-display-table
 115       (setq standard-display-table (make-display-table)))
 116   (while (<= l h)
 117     (aset standard-display-table l (if (or (< l ?\s) (>= l 127)) (vector l)))
 118     (setq l (1+ l))))
 119
 120 ;;;###autoload
 121 (defun standard-display-default (l h)
 122   "Display characters in the range L to H using the default notation."
 123   (or standard-display-table
 124       (setq standard-display-table (make-display-table)))
 125   (while (<= l h)
 126     (if (and (>= l ?\s) (characterp l))
 127         (aset standard-display-table l nil))
 128     (setq l (1+ l))))
 129
 130 ;; This function does NOT take terminal-dependent escape sequences.
 131 ;; For that, you need to go through create-glyph.  Use one of the
 132 ;; other functions below, or roll your own.
 133 ;;;###autoload
 134 (defun standard-display-ascii (c s)
 135   "Display character C using printable string S."
 136   (or standard-display-table
 137       (setq standard-display-table (make-display-table)))
 138   (aset standard-display-table c (vconcat s)))
 139
 140 ;;;###autoload
 141 (defun standard-display-g1 (c sc)
 142   "Display character C as character SC in the g1 character set.
 143 This function assumes that your terminal uses the SO/SI characters;
 144 it is meaningless for an X frame."
 145   (if (memq window-system '(x w32 ns))
 146       (error "Cannot use string glyphs in a windowing system"))
 147   (or standard-display-table
 148       (setq standard-display-table (make-display-table)))
 149   (aset standard-display-table c
 150         (vector (create-glyph (concat "\016" (char-to-string sc) "\017")))))
 151
 152 ;;;###autoload
 153 (defun standard-display-graphic (c gc)
 154   "Display character C as character GC in graphics character set.
 155 This function assumes VT100-compatible escapes; it is meaningless for an
 156 X frame."
 157   (if (memq window-system '(x w32 ns))
 158       (error "Cannot use string glyphs in a windowing system"))
 159   (or standard-display-table
 160       (setq standard-display-table (make-display-table)))
 161   (aset standard-display-table c
 162         (vector (create-glyph (concat "\e(0" (char-to-string gc) "\e(B")))))
 163
 164 ;;;###autoload
 165 (defun standard-display-underline (c uc)
 166   "Display character C as character UC plus underlining."
 167   (or standard-display-table
 168       (setq standard-display-table (make-display-table)))
 169   (aset standard-display-table c
 170         (vector
 171          (if window-system
 172              (make-glyph-code uc 'underline)
 173            (create-glyph (concat "\e[4m" (char-to-string uc) "\e[m"))))))
 174
 175 ;;;###autoload
 176 (defun create-glyph (string)
 177   "Allocate a glyph code to display by sending STRING to the terminal."
 178   (if (= (length glyph-table) 65536)
 179       (error "No free glyph codes remain"))
 180   ;; Don't use slots that correspond to ASCII characters.
 181   (if (= (length glyph-table) 32)
 182       (setq glyph-table (vconcat glyph-table (make-vector 224 nil))))
 183   (setq glyph-table (vconcat glyph-table (list string)))
 184   (1- (length glyph-table)))
 185
 186 ;;;###autoload
 187 (defun make-glyph-code (char &optional face)
 188   "Return a glyph code representing char CHAR with face FACE."
 189   ;; Due to limitations on Emacs integer values, faces with
 190   ;; face id greater that 512 are silently ignored.
 191   (if (not face)
 192       char
 193     (let ((fid (face-id face)))
 194       (if (< fid 64) ; we have 32 - 3(LSB) - 1(SIGN) - 22(CHAR) = 6 bits for face id
 195           (logior char (lsh fid 22))
 196         (cons char fid)))))
 197
 198 ;;;###autoload
 199 (defun glyph-char (glyph)
 200   "Return the character of glyph code GLYPH."
 201   (if (consp glyph)
 202       (car glyph)
 203     (logand glyph #x3fffff)))
 204
 205 ;;;###autoload
 206 (defun glyph-face (glyph)
 207   "Return the face of glyph code GLYPH, or nil if glyph has default face."
 208   (let ((face-id (if (consp glyph) (cdr glyph) (lsh glyph -22))))
 209     (and (> face-id 0)
 210          (catch 'face
 211            (dolist (face (face-list))
 212              (when (eq (face-id face) face-id)
 213                (throw 'face face)))))))
 214
 215 ;;;###autoload
 216 (defun standard-display-european (arg)
 217   "Semi-obsolete way to toggle display of ISO 8859 European characters.
 218
 219 This function is semi-obsolete; you probably don't need it, or else you
 220 probably should use `set-language-environment' or `set-locale-environment'.
 221
 222 This function enables European character display if ARG is positive,
 223 disables it if negative.  Otherwise, it toggles European character display.
 224
 225 When this mode is enabled, characters in the range of 160 to 255
 226 display not as octal escapes, but as accented characters.  Codes 146
 227 and 160 display as apostrophe and space, even though they are not the
 228 ASCII codes for apostrophe and space.
 229
 230 Enabling European character display with this command noninteractively
 231 from Lisp code also selects Latin-1 as the language environment.
 232 This provides increased compatibility for users who call this function
 233 in `.emacs'."
 234
 235   (if (or (<= (prefix-numeric-value arg) 0)
 236           (and (null arg)
 237                (char-table-p standard-display-table)
 238                ;; Test 161, because 160 displays as a space.
 239                (equal (aref standard-display-table 161) [161])))
 240       (progn
 241         (standard-display-default 160 255)
 242         (unless (or (memq window-system '(x w32 ns)))
 243           (and (terminal-coding-system)
 244                (set-terminal-coding-system nil))))
 245
 246     (display-warning 'i18n
 247                      "`standard-display-european' is semi-obsolete; see its doc string for details"
 248                      :warning)
 249
 250     ;; Switch to Latin-1 language environment
 251     ;; unless some other has been specified.
 252     (if (equal current-language-environment "English")
 253         (set-language-environment "latin-1"))
 254     (unless (or noninteractive (memq window-system '(x w32 ns)))
 255       ;; Send those codes literally to a character-based terminal.
 256       ;; If we are using single-byte characters,
 257       ;; it doesn't matter which coding system we use.
 258       (set-terminal-coding-system
 259        (let ((c (intern (downcase current-language-environment))))
 260          (if (coding-system-p c) c 'latin-1))))
 261     (standard-display-european-internal)))
 262
 263 (provide 'disp-table)
 264
 265 ;; arch-tag: ffe4c28c-960c-47aa-b8a8-ae89d371ffc7
 266 ;;; disp-table.el ends here