lisp/which-func.el

   1 ;;; which-func.el --- Print current function in mode line
   2
   3 ;; Copyright (C) 1994, 1997, 1998 Free Software Foundation, Inc.
   4
   5 ;; Author:   Alex Rezinsky <alexr@msil.sps.mot.com>
   6 ;;           (doesn't seem to be responsive any more)
   7 ;; Keywords: mode-line, imenu, tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package prints name of function where your current point is
  29 ;; located in mode line. It assumes that you work with imenu package
  30 ;; and imenu--index-alist is up to date.
  31
  32 ;; KNOWN BUGS
  33 ;; ----------
  34 ;; Really this package shows not "function where the current point is
  35 ;; located now", but "nearest function which defined above the current
  36 ;; point". So if your current point is located after end of function
  37 ;; FOO but before begin of function BAR, FOO will be displayed in mode
  38 ;; line.
  39
  40 ;; TODO LIST
  41 ;; ---------
  42 ;;     1. Dependence on imenu package should be removed.  Separate
  43 ;; function determination mechanism should be used to determine the end
  44 ;; of a function as well as the beginning of a function.
  45 ;;     2. This package should be realized with the help of overlay
  46 ;; properties instead of imenu--index-alist variable.
  47
  48 ;;; History:
  49
  50 ;; THANKS TO
  51 ;; ---------
  52 ;; Per Abrahamsen   <abraham@iesd.auc.dk>
  53 ;;     Some ideas (inserting  in mode-line,  using of post-command  hook
  54 ;;     and toggling this  mode) have  been   borrowed from  his  package
  55 ;;     column.el
  56 ;; Peter Eisenhauer <pipe@fzi.de>
  57 ;;     Bug fixing in case nested indexes.
  58 ;; Terry Tateyama   <ttt@ursa0.cs.utah.edu>
  59 ;;     Suggestion to use find-file-hooks for first imenu
  60 ;;     index building.
  61
  62 ;;; Code:
  63
  64 ;; Variables for customization
  65 ;; ---------------------------
  66 ;;
  67 (defvar which-func-unknown "???"
  68   "String to display in the mode line when current function is unknown.")
  69
  70 (defgroup which-func nil
  71   "Mode to display the current function name in the modeline."
  72   :group 'tools
  73   :version "20.3")
  74
  75 (defcustom which-func-modes
  76   '(emacs-lisp-mode c-mode c++-mode perl-mode makefile-mode sh-mode
  77                     fortran-mode)
  78   "List of major modes for which Which Function mode should be used.
  79 For other modes it is disabled.  If this is equal to t,
  80 then Which Function mode is enabled in any major mode that supports it."
  81   :group 'which-func
  82   :type '(choice (const :tag "All modes" t)
  83                  (repeat (symbol :tag "Major mode"))))
  84
  85 (defcustom which-func-non-auto-modes nil
  86   "List of major modes where Which Function mode is inactive till Imenu is used.
  87 This means that Which Function mode won't really do anything
  88 until you use Imenu, in these modes.  Note that files
  89 larger than `which-func-maxout' behave in this way too;
  90 Which Function mode doesn't do anything until you use Imenu."
  91   :group 'which-func
  92   :type '(repeat (symbol :tag "Major mode")))
  93
  94 (defcustom which-func-maxout 100000
  95   "Don't automatically compute the Imenu menu if buffer is this big or bigger.
  96 Zero means compute the Imenu menu regardless of size."
  97   :group 'which-func
  98   :type 'integer)
  99
 100 (defcustom which-func-format '("[" which-func-current "]")
 101   "Format for displaying the function in the mode line."
 102   :group 'which-func
 103   :type 'sexp)
 104
 105 ;;;###autoload
 106 (defcustom which-func-mode-global nil
 107   "*Toggle `which-func-mode' globally.
 108 Setting this variable directly does not take effect;
 109 use either \\[customize] or the function `which-func-mode'."
 110   :set #'(lambda (symbol value)
 111            (which-func-mode (if value 1 0)))
 112   :initialize 'custom-initialize-default
 113   :type    'boolean
 114   :group   'which-func
 115   :require 'which-func)
 116
 117 (defvar which-func-cleanup-function nil
 118   "Function to transform a string before displaying it in the mode line.
 119 The function is called with one argument, the string to display.
 120 Its return value is displayed in the modeline.
 121 If nil, no function is called.  The default value is nil.
 122
 123 This feature can be useful if Imenu is set up to make more
 124 detailed entries (e.g., containing the argument list of a function),
 125 and you want to simplify them for the mode line
 126 \(e.g., removing the parameter list to just have the function name.)")
 127
 128 ;;; Code, nothing to customize below here
 129 ;;; -------------------------------------
 130 ;;;
 131 (require 'imenu)
 132
 133 (defvar which-func-current  which-func-unknown)
 134 (defvar which-func-previous which-func-unknown)
 135 (make-variable-buffer-local 'which-func-current)
 136 (make-variable-buffer-local 'which-func-previous)
 137
 138 (defvar which-func-mode nil
 139   "Non-nil means display current function name in mode line.
 140 This makes a difference only if `which-func-mode-global' is non-nil")
 141 (make-variable-buffer-local 'which-func-mode)
 142 ;;(put 'which-func-mode 'permanent-local t)
 143
 144 (add-hook 'find-file-hooks 'which-func-ff-hook t)
 145
 146 (defun which-func-ff-hook ()
 147   "File find hook for Which Function mode.
 148 It creates the Imenu index for the buffer, if necessary."
 149   (setq which-func-mode
 150         (and which-func-mode-global
 151              (or (eq which-func-modes t) (member major-mode which-func-modes))))
 152
 153   (condition-case nil
 154       (if (and which-func-mode
 155                (not (member major-mode which-func-non-auto-modes))
 156                (or (null which-func-maxout)
 157                    (< buffer-saved-size which-func-maxout)
 158                    (= which-func-maxout 0)))
 159           (setq imenu--index-alist
 160                 (save-excursion (funcall imenu-create-index-function))))
 161     (error
 162      (setq which-func-mode nil))))
 163
 164 (defun which-func-update ()
 165   ;; Update the string containing the current function.
 166   (when which-func-mode
 167     (condition-case info
 168         (progn
 169           (setq which-func-current (or (which-function) which-func-unknown))
 170           (unless (string= which-func-current which-func-previous)
 171             (force-mode-line-update)
 172             (setq which-func-previous which-func-current)))
 173       (error
 174        (which-func-mode -1)
 175        (error "Error in which-func-update: %s" info)))))
 176
 177 ;; This is the name people would normally expect.
 178 ;;;###autoload
 179 (defalias 'which-function-mode 'which-func-mode)
 180
 181 ;;;###autoload
 182 (defun which-func-mode (&optional arg)
 183   "Toggle Which Function mode, globally.
 184 When Which Function mode is enabled, the current function name is
 185 continuously displayed in the mode line, in certain major modes.
 186
 187 With prefix ARG, turn Which Function mode on iff arg is positive,
 188 and off otherwise."
 189   (interactive "P")
 190   (setq which-func-mode-global
 191         (or (and (null arg) which-func-mode-global)
 192             (<= (prefix-numeric-value arg) 0)))
 193   (if which-func-mode-global
 194       ;; Turn it off
 195       (progn
 196         (remove-hook 'post-command-idle-hook 'which-func-update)
 197         (dolist (buf (buffer-list))
 198           (with-current-buffer buf (setq which-func-mode nil))))
 199     ;;Turn it on
 200     (add-hook 'post-command-idle-hook 'which-func-update)
 201     (dolist (buf (buffer-list))
 202       (with-current-buffer buf
 203         (setq which-func-mode
 204               (or (eq which-func-modes t)
 205                   (member major-mode which-func-modes)))))))
 206
 207 (defun which-function ()
 208   "Return current function name based on point.
 209 If `imenu--index-alist' does not exist, or is empty  or if point
 210 is located before first function, returns nil."
 211   (let (name)
 212     ;; First try using imenu support.
 213     (when (and (boundp 'imenu--index-alist) imenu--index-alist)
 214       (let ((pair (car-safe imenu--index-alist))
 215             (rest (cdr-safe imenu--index-alist)))
 216         (while (and (or rest pair)
 217                     (or (not (number-or-marker-p (cdr pair)))
 218                         (> (point) (cdr pair))))
 219           (setq name (car pair))
 220           (setq pair (car-safe rest))
 221           (setq rest (cdr-safe rest)))))
 222     ;; Try using add-log support.
 223     (when (and (null name) (boundp 'add-log-current-defun-function)
 224                add-log-current-defun-function)
 225       (setq name (funcall add-log-current-defun-function)))
 226     ;; Filter the name if requested.
 227     (when name
 228       (if which-func-cleanup-function
 229           (funcall which-func-cleanup-function name)
 230         name))))
 231
 232 (provide 'which-func)
 233
 234 ;; which-func.el ends here