lisp/progmodes/flymake.el

   1 ;;; flymake.el -- a universal on-the-fly syntax checker
   2
   3 ;; Copyright (C) 2003-2011  Free Software Foundation, Inc.
   4
   5 ;; Author:  Pavel Kobyakov <pk_at_work@yahoo.com>
   6 ;; Maintainer: Pavel Kobyakov <pk_at_work@yahoo.com>
   7 ;; Version: 0.3
   8 ;; Keywords: c languages tools
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26 ;;
  27 ;; Flymake is a minor Emacs mode performing on-the-fly syntax
  28 ;; checks using the external syntax check tool (for C/C++ this
  29 ;; is usually the compiler)
  30
  31 ;;; Bugs/todo:
  32
  33 ;; - Only uses "Makefile", not "makefile" or "GNUmakefile"
  34 ;;   (from http://bugs.debian.org/337339).
  35
  36 ;;; Code:
  37
  38 (eval-when-compile (require 'cl))
  39 (if (featurep 'xemacs) (require 'overlay))
  40
  41 (defvar flymake-is-running nil
  42   "If t, flymake syntax check process is running for the current buffer.")
  43 (make-variable-buffer-local 'flymake-is-running)
  44
  45 (defvar flymake-timer nil
  46   "Timer for starting syntax check.")
  47 (make-variable-buffer-local 'flymake-timer)
  48
  49 (defvar flymake-last-change-time nil
  50   "Time of last buffer change.")
  51 (make-variable-buffer-local 'flymake-last-change-time)
  52
  53 (defvar flymake-check-start-time nil
  54   "Time at which syntax check was started.")
  55 (make-variable-buffer-local 'flymake-check-start-time)
  56
  57 (defvar flymake-check-was-interrupted nil
  58   "Non-nil if syntax check was killed by `flymake-compile'.")
  59 (make-variable-buffer-local 'flymake-check-was-interrupted)
  60
  61 (defvar flymake-err-info nil
  62   "Sorted list of line numbers and lists of err info in the form (file, err-text).")
  63 (make-variable-buffer-local 'flymake-err-info)
  64
  65 (defvar flymake-new-err-info nil
  66   "Same as `flymake-err-info', effective when a syntax check is in progress.")
  67 (make-variable-buffer-local 'flymake-new-err-info)
  68
  69 ;;;; [[ cross-emacs compatibility routines
  70 (defsubst flymake-makehash (&optional test)
  71   (if (fboundp 'make-hash-table)
  72       (if test (make-hash-table :test test) (make-hash-table))
  73     (with-no-warnings
  74       (makehash test))))
  75
  76 (defalias 'flymake-float-time
  77   (if (fboundp 'float-time)
  78       'float-time
  79     (if (featurep 'xemacs)
  80         (lambda ()
  81           (multiple-value-bind (s0 s1 s2) (values-list (current-time))
  82             (+ (* (float (ash 1 16)) s0) (float s1) (* 0.0000001 s2)))))))
  83
  84 (defalias 'flymake-replace-regexp-in-string
  85   (if (eval-when-compile (fboundp 'replace-regexp-in-string))
  86       'replace-regexp-in-string
  87     (lambda (regexp rep str)
  88       (replace-in-string str regexp rep))))
  89
  90 (defalias 'flymake-split-string
  91   (if (condition-case nil (equal (split-string " bc " " " t) '("bc"))
  92         (error nil))
  93       (lambda (str pattern) (split-string str pattern t))
  94     (lambda (str pattern)
  95       "Split STR into a list of substrings bounded by PATTERN.
  96 Zero-length substrings at the beginning and end of the list are omitted."
  97       (let ((split (split-string str pattern)))
  98         (while (equal (car split) "") (setq split (cdr split)))
  99         (setq split (nreverse split))
 100         (while (equal (car split) "") (setq split (cdr split)))
 101         (nreverse split)))))
 102
 103 (defalias 'flymake-get-temp-dir
 104   (if (fboundp 'temp-directory)
 105       'temp-directory
 106     (lambda () temporary-file-directory)))
 107
 108 (defun flymake-posn-at-point-as-event (&optional position window dx dy)
 109   "Return pixel position of top left corner of glyph at POSITION,
 110 relative to top left corner of WINDOW, as a mouse-1 click
 111 event (identical to the event that would be triggered by clicking
 112 mouse button 1 at the top left corner of the glyph).
 113
 114 POSITION and WINDOW default to the position of point in the
 115 selected window.
 116
 117 DX and DY specify optional offsets from the top left of the glyph."
 118   (unless window (setq window (selected-window)))
 119   (unless position (setq position (window-point window)))
 120   (unless dx (setq dx 0))
 121   (unless dy (setq dy 0))
 122
 123   (let* ((pos (posn-at-point position window))
 124          (x-y (posn-x-y pos))
 125          (edges (window-inside-pixel-edges window))
 126          (win-x-y (window-pixel-edges window)))
 127     ;; adjust for window edges
 128     (setcar (nthcdr 2 pos)
 129             (cons (+ (car x-y) (car  edges) (- (car win-x-y))  dx)
 130                   (+ (cdr x-y) (cadr edges) (- (cadr win-x-y)) dy)))
 131     (list 'mouse-1 pos)))
 132
 133 (defun flymake-popup-menu (menu-data)
 134   "Pop up the flymake menu at point, using the data MENU-DATA.
 135 POS is a list of the form ((X Y) WINDOW), where X and Y are
 136 pixels positions from the top left corner of WINDOW's frame.
 137 MENU-DATA is a list of error and warning messages returned by
 138 `flymake-make-err-menu-data'."
 139   (if (featurep 'xemacs)
 140       (let* ((pos         (flymake-get-point-pixel-pos))
 141              (x-pos       (nth 0 pos))
 142              (y-pos       (nth 1 pos))
 143              (fake-event-props  '(button 1 x 1 y 1)))
 144         (setq fake-event-props (plist-put fake-event-props 'x x-pos))
 145         (setq fake-event-props (plist-put fake-event-props 'y y-pos))
 146         (popup-menu (flymake-make-xemacs-menu menu-data)
 147                     (make-event 'button-press fake-event-props)))
 148     (x-popup-menu (if (eval-when-compile (fboundp 'posn-at-point))
 149                       (flymake-posn-at-point-as-event)
 150                     (list (flymake-get-point-pixel-pos) (selected-window)))
 151                   (flymake-make-emacs-menu menu-data))))
 152
 153 (defun flymake-make-emacs-menu (menu-data)
 154   "Return a menu specifier using MENU-DATA.
 155 MENU-DATA is a list of error and warning messages returned by
 156 `flymake-make-err-menu-data'.
 157 See `x-popup-menu' for the menu specifier format."
 158   (let* ((menu-title     (nth 0 menu-data))
 159          (menu-items     (nth 1 menu-data))
 160          (menu-commands  (mapcar (lambda (foo)
 161                                    (cons (nth 0 foo) (nth 1 foo)))
 162                                  menu-items)))
 163     (list menu-title (cons "" menu-commands))))
 164
 165 (if (featurep 'xemacs) (progn
 166
 167 (defun flymake-nop ())
 168
 169 (defun flymake-make-xemacs-menu (menu-data)
 170   "Return a menu specifier using MENU-DATA."
 171   (let* ((menu-title     (nth 0 menu-data))
 172          (menu-items     (nth 1 menu-data))
 173          (menu-commands  nil))
 174     (setq menu-commands (mapcar (lambda (foo)
 175                                   (vector (nth 0 foo) (or (nth 1 foo) '(flymake-nop)) t))
 176                                 menu-items))
 177     (cons menu-title menu-commands)))
 178
 179 )) ;; xemacs
 180
 181 (unless (eval-when-compile (fboundp 'posn-at-point))
 182
 183 (defun flymake-current-row ()
 184   "Return current row number in current frame."
 185   (if (fboundp 'window-edges)
 186       (+ (car (cdr (window-edges))) (count-lines (window-start) (point)))
 187     (count-lines (window-start) (point))))
 188
 189 (defun flymake-selected-frame ()
 190   (if (fboundp 'window-edges)
 191       (selected-frame)
 192     (selected-window)))
 193
 194 (defun flymake-get-point-pixel-pos ()
 195   "Return point position in pixels: (x, y)."
 196   (let ((mouse-pos  (mouse-position))
 197         (pixel-pos  nil)
 198         (ret        nil))
 199     (if (car (cdr mouse-pos))
 200         (progn
 201           (set-mouse-position (flymake-selected-frame) (current-column) (flymake-current-row))
 202           (setq pixel-pos (mouse-pixel-position))
 203           (set-mouse-position (car mouse-pos) (car (cdr mouse-pos)) (cdr (cdr mouse-pos)))
 204           (setq ret (list (car (cdr pixel-pos)) (cdr (cdr pixel-pos)))))
 205       (progn
 206         (setq ret '(0 0))))
 207     (flymake-log 3 "mouse pos is %s" ret)
 208     ret))
 209
 210 ) ;; End of (unless (fboundp 'posn-at-point)
 211
 212 ;;;; ]]
 213
 214 (defcustom flymake-log-level -1
 215   "Logging level, only messages with level lower or equal will be logged.
 216 -1 = NONE, 0 = ERROR, 1 = WARNING, 2 = INFO, 3 = DEBUG"
 217   :group 'flymake
 218   :type 'integer)
 219
 220 (defun flymake-log (level text &rest args)
 221   "Log a message at level LEVEL.
 222 If LEVEL is higher than `flymake-log-level', the message is
 223 ignored.  Otherwise, it is printed using `message'.
 224 TEXT is a format control string, and the remaining arguments ARGS
 225 are the string substitutions (see `format')."
 226   (if (<= level flymake-log-level)
 227       (let* ((msg (apply 'format text args)))
 228         (message "%s" msg)
 229         ;;(with-temp-buffer
 230         ;;    (insert msg)
 231         ;;   (insert "\n")
 232         ;;   (flymake-save-buffer-in-file "d:/flymake.log" t)  ; make log file name customizable
 233         ;;)
 234         )))
 235
 236 (defun flymake-ins-after (list pos val)
 237   "Insert VAL into LIST after position POS."
 238   (let ((tmp (copy-sequence list)))     ; (???)
 239     (setcdr (nthcdr pos tmp) (cons val (nthcdr (1+ pos) tmp)))
 240     tmp))
 241
 242 (defun flymake-set-at (list pos val)
 243   "Set VAL at position POS in LIST."
 244   (let ((tmp (copy-sequence list)))     ; (???)
 245     (setcar (nthcdr pos tmp) val)
 246     tmp))
 247
 248 (defvar flymake-processes nil
 249   "List of currently active flymake processes.")
 250
 251 (defvar flymake-output-residual nil)
 252
 253 (make-variable-buffer-local 'flymake-output-residual)
 254
 255 (defgroup flymake nil
 256   "A universal on-the-fly syntax checker."
 257   :version "23.1"
 258   :group 'tools)
 259
 260 (defcustom flymake-allowed-file-name-masks
 261   '(("\\.\\(?:c\\(?:pp\\|xx\\|\\+\\+\\)?\\|CC\\)\\'" flymake-simple-make-init)
 262     ("\\.xml\\'" flymake-xml-init)
 263     ("\\.html?\\'" flymake-xml-init)
 264     ("\\.cs\\'" flymake-simple-make-init)
 265     ("\\.p[ml]\\'" flymake-perl-init)
 266     ("\\.php[345]?\\'" flymake-php-init)
 267     ("\\.h\\'" flymake-master-make-header-init flymake-master-cleanup)
 268     ("\\.java\\'" flymake-simple-make-java-init flymake-simple-java-cleanup)
 269     ("[0-9]+\\.tex\\'" flymake-master-tex-init flymake-master-cleanup)
 270     ("\\.tex\\'" flymake-simple-tex-init)
 271     ("\\.idl\\'" flymake-simple-make-init)
 272     ;; ("\\.cpp\\'" 1)
 273     ;; ("\\.java\\'" 3)
 274     ;; ("\\.h\\'" 2 ("\\.cpp\\'" "\\.c\\'")
 275     ;; ("[ \t]*#[ \t]*include[ \t]*\"\\([\w0-9/\\_\.]*[/\\]*\\)\\(%s\\)\"" 1 2))
 276     ;; ("\\.idl\\'" 1)
 277     ;; ("\\.odl\\'" 1)
 278     ;; ("[0-9]+\\.tex\\'" 2 ("\\.tex\\'")
 279     ;; ("[ \t]*\\input[ \t]*{\\(.*\\)\\(%s\\)}" 1 2 ))
 280     ;; ("\\.tex\\'" 1)
 281     )
 282   "Files syntax checking is allowed for."
 283   :group 'flymake
 284   :type '(repeat (string symbol symbol symbol)))
 285
 286 (defun flymake-get-file-name-mode-and-masks (file-name)
 287   "Return the corresponding entry from `flymake-allowed-file-name-masks'."
 288   (unless (stringp file-name)
 289     (error "Invalid file-name"))
 290   (let ((fnm flymake-allowed-file-name-masks)
 291         (mode-and-masks  nil))
 292     (while (and (not mode-and-masks) fnm)
 293       (if (string-match (car (car fnm)) file-name)
 294           (setq mode-and-masks (cdr (car fnm))))
 295       (setq fnm (cdr fnm)))
 296     (flymake-log 3 "file %s, init=%s" file-name (car mode-and-masks))
 297     mode-and-masks))
 298
 299 (defun flymake-can-syntax-check-file (file-name)
 300   "Determine whether we can syntax check FILE-NAME.
 301 Return nil if we cannot, non-nil if we can."
 302   (if (flymake-get-init-function file-name) t nil))
 303
 304 (defun flymake-get-init-function (file-name)
 305   "Return init function to be used for the file."
 306   (let* ((init-f  (nth 0 (flymake-get-file-name-mode-and-masks file-name))))
 307     ;;(flymake-log 0 "calling %s" init-f)
 308     ;;(funcall init-f (current-buffer))
 309     init-f))
 310
 311 (defun flymake-get-cleanup-function (file-name)
 312   "Return cleanup function to be used for the file."
 313   (or (nth 1 (flymake-get-file-name-mode-and-masks file-name))
 314       'flymake-simple-cleanup))
 315
 316 (defun flymake-get-real-file-name-function (file-name)
 317   (or (nth 2 (flymake-get-file-name-mode-and-masks file-name))
 318       'flymake-get-real-file-name))
 319
 320 (defvar flymake-find-buildfile-cache (flymake-makehash 'equal))
 321
 322 (defun flymake-get-buildfile-from-cache (dir-name)
 323   (gethash dir-name flymake-find-buildfile-cache))
 324
 325 (defun flymake-add-buildfile-to-cache (dir-name buildfile)
 326   (puthash dir-name buildfile flymake-find-buildfile-cache))
 327
 328 (defun flymake-clear-buildfile-cache ()
 329   (clrhash flymake-find-buildfile-cache))
 330
 331 (defun flymake-find-buildfile (buildfile-name source-dir-name)
 332   "Find buildfile starting from current directory.
 333 Buildfile includes Makefile, build.xml etc.
 334 Return its file name if found, or nil if not found."
 335   (or (flymake-get-buildfile-from-cache source-dir-name)
 336       (let* ((file (locate-dominating-file source-dir-name buildfile-name)))
 337         (if file
 338             (progn
 339               (flymake-log 3 "found buildfile at %s" file)
 340               (flymake-add-buildfile-to-cache source-dir-name file)
 341               file)
 342           (progn
 343             (flymake-log 3 "buildfile for %s not found" source-dir-name)
 344             nil)))))
 345
 346 (defun flymake-fix-file-name (name)
 347   "Replace all occurrences of '\' with '/'."
 348   (when name
 349     (setq name (expand-file-name name))
 350     (setq name (abbreviate-file-name name))
 351     (setq name (directory-file-name name))
 352     name))
 353
 354 (defun flymake-same-files (file-name-one file-name-two)
 355   "Check if FILE-NAME-ONE and FILE-NAME-TWO point to same file.
 356 Return t if so, nil if not."
 357   (equal (flymake-fix-file-name file-name-one)
 358          (flymake-fix-file-name file-name-two)))
 359
 360 (defcustom flymake-master-file-dirs '("." "./src" "./UnitTest")
 361   "Dirs where to look for master files."
 362   :group 'flymake
 363   :type '(repeat (string)))
 364
 365 (defcustom flymake-master-file-count-limit 32
 366   "Max number of master files to check."
 367   :group 'flymake
 368   :type 'integer)
 369
 370 ;; This is bound dynamically to pass a parameter to a sort predicate below
 371 (defvar flymake-included-file-name)
 372
 373 (defun flymake-find-possible-master-files (file-name master-file-dirs masks)
 374   "Find (by name and location) all possible master files.
 375 Master files include .cpp and .c for .h.  Files are searched for
 376 starting from the .h directory and max max-level parent dirs.
 377 File contents are not checked."
 378   (let* ((dirs master-file-dirs)
 379          (files  nil)
 380          (done   nil))
 381
 382     (while (and (not done) dirs)
 383       (let* ((dir (expand-file-name (car dirs) (file-name-directory file-name)))
 384              (masks masks))
 385         (while (and (file-exists-p dir) (not done) masks)
 386           (let* ((mask        (car masks))
 387                  (dir-files   (directory-files dir t mask)))
 388
 389             (flymake-log 3 "dir %s, %d file(s) for mask %s"
 390                          dir (length dir-files) mask)
 391             (while (and (not done) dir-files)
 392               (when (not (file-directory-p (car dir-files)))
 393                 (setq files (cons (car dir-files) files))
 394                 (when (>= (length files) flymake-master-file-count-limit)
 395                   (flymake-log 3 "master file count limit (%d) reached" flymake-master-file-count-limit)
 396                   (setq done t)))
 397               (setq dir-files (cdr dir-files))))
 398           (setq masks (cdr masks))))
 399       (setq dirs (cdr dirs)))
 400     (when files
 401       (let ((flymake-included-file-name (file-name-nondirectory file-name)))
 402         (setq files (sort files 'flymake-master-file-compare))))
 403     (flymake-log 3 "found %d possible master file(s)" (length files))
 404     files))
 405
 406 (defun flymake-master-file-compare (file-one file-two)
 407   "Compare two files specified by FILE-ONE and FILE-TWO.
 408 This function is used in sort to move most possible file names
 409 to the beginning of the list (File.h -> File.cpp moved to top)."
 410   (and (equal (file-name-sans-extension flymake-included-file-name)
 411               (file-name-sans-extension (file-name-nondirectory file-one)))
 412        (not (equal file-one file-two))))
 413
 414 (defcustom flymake-check-file-limit 8192
 415   "Maximum number of chars to look at when checking possible master file.
 416 Nil means search the entire file."
 417   :group 'flymake
 418   :type '(choice (const :tag "No limit" nil)
 419                  (integer :tag "Characters")))
 420
 421 (defun flymake-check-patch-master-file-buffer
 422        (master-file-temp-buffer
 423         master-file-name patched-master-file-name
 424         source-file-name patched-source-file-name
 425         include-dirs regexp)
 426   "Check if MASTER-FILE-NAME is a master file for SOURCE-FILE-NAME.
 427 If yes, patch a copy of MASTER-FILE-NAME to include PATCHED-SOURCE-FILE-NAME
 428 instead of SOURCE-FILE-NAME.
 429
 430 For example, foo.cpp is a master file if it includes foo.h.
 431
 432 Whether a buffer for MATER-FILE-NAME exists, use it as a source
 433 instead of reading master file from disk."
 434   (let* ((source-file-nondir (file-name-nondirectory source-file-name))
 435          (source-file-extension (file-name-extension source-file-nondir))
 436          (source-file-nonext (file-name-sans-extension source-file-nondir))
 437          (found                     nil)
 438          (inc-name                  nil)
 439          (search-limit              flymake-check-file-limit))
 440     (setq regexp
 441           (format regexp        ; "[ \t]*#[ \t]*include[ \t]*\"\\(.*%s\\)\""
 442                   ;; Hack for tex files, where \include often excludes .tex.
 443                   ;; Maybe this is safe generally.
 444                   (if (and (> (length source-file-extension) 1)
 445                            (string-equal source-file-extension "tex"))
 446                       (format "%s\\(?:\\.%s\\)?"
 447                               (regexp-quote source-file-nonext)
 448                               (regexp-quote source-file-extension))
 449                     (regexp-quote source-file-nondir))))
 450     (unwind-protect
 451         (with-current-buffer master-file-temp-buffer
 452           (if (or (not search-limit)
 453                   (> search-limit (point-max)))
 454               (setq search-limit (point-max)))
 455           (flymake-log 3 "checking %s against regexp %s"
 456                        master-file-name regexp)
 457           (goto-char (point-min))
 458           (while (and (< (point) search-limit)
 459                       (re-search-forward regexp search-limit t))
 460             (let ((match-beg   (match-beginning 1))
 461                   (match-end   (match-end 1)))
 462
 463               (flymake-log 3 "found possible match for %s" source-file-nondir)
 464               (setq inc-name (match-string 1))
 465               (and (> (length source-file-extension) 1)
 466                    (string-equal source-file-extension "tex")
 467                    (not (string-match (format "\\.%s\\'" source-file-extension)
 468                                       inc-name))
 469                    (setq inc-name (concat inc-name "." source-file-extension)))
 470               (when (eq t (compare-strings
 471                            source-file-nondir nil nil
 472                            inc-name (- (length inc-name)
 473                                        (length source-file-nondir)) nil))
 474                 (flymake-log 3 "inc-name=%s" inc-name)
 475                 (when (flymake-check-include source-file-name inc-name
 476                                              include-dirs)
 477                   (setq found t)
 478                   ;;  replace-match is not used here as it fails in
 479                   ;; XEmacs with 'last match not a buffer' error as
 480                   ;; check-includes calls replace-in-string
 481                   (flymake-replace-region
 482                    match-beg match-end
 483                    (file-name-nondirectory patched-source-file-name))))
 484               (forward-line 1)))
 485           (when found
 486             (flymake-save-buffer-in-file patched-master-file-name)))
 487       ;;+(flymake-log 3 "killing buffer %s"
 488       ;;                (buffer-name master-file-temp-buffer))
 489       (kill-buffer master-file-temp-buffer))
 490     ;;+(flymake-log 3 "check-patch master file %s: %s" master-file-name found)
 491     (when found
 492       (flymake-log 2 "found master file %s" master-file-name))
 493     found))
 494
 495 (defun flymake-replace-region (beg end rep)
 496   "Replace text in BUFFER in region (BEG END) with REP."
 497   (save-excursion
 498     (goto-char end)
 499     ;; Insert before deleting, so as to better preserve markers's positions.
 500     (insert rep)
 501     (delete-region beg end)))
 502
 503 (defun flymake-read-file-to-temp-buffer (file-name)
 504   "Insert contents of FILE-NAME into newly created temp buffer."
 505   (let* ((temp-buffer (get-buffer-create (generate-new-buffer-name (concat "flymake:" (file-name-nondirectory file-name))))))
 506     (with-current-buffer temp-buffer
 507       (insert-file-contents file-name))
 508     temp-buffer))
 509
 510 (defun flymake-copy-buffer-to-temp-buffer (buffer)
 511   "Copy contents of BUFFER into newly created temp buffer."
 512   (with-current-buffer
 513       (get-buffer-create (generate-new-buffer-name
 514                           (concat "flymake:" (buffer-name buffer))))
 515     (insert-buffer-substring buffer)
 516     (current-buffer)))
 517
 518 (defun flymake-check-include (source-file-name inc-name include-dirs)
 519   "Check if SOURCE-FILE-NAME can be found in include path.
 520 Return t if it can be found via include path using INC-NAME."
 521   (if (file-name-absolute-p inc-name)
 522       (flymake-same-files source-file-name inc-name)
 523     (while (and include-dirs
 524                 (not (flymake-same-files
 525                       source-file-name
 526                       (concat (file-name-directory source-file-name)
 527                               "/" (car include-dirs)
 528                               "/" inc-name))))
 529       (setq include-dirs (cdr include-dirs)))
 530     include-dirs))
 531
 532 (defun flymake-find-buffer-for-file (file-name)
 533   "Check if there exists a buffer visiting FILE-NAME.
 534 Return t if so, nil if not."
 535   (let ((buffer-name (get-file-buffer file-name)))
 536     (if buffer-name
 537         (get-buffer buffer-name))))
 538
 539 (defun flymake-create-master-file (source-file-name patched-source-file-name get-incl-dirs-f create-temp-f masks include-regexp)
 540   "Save SOURCE-FILE-NAME with a different name.
 541 Find master file, patch and save it."
 542   (let* ((possible-master-files     (flymake-find-possible-master-files source-file-name flymake-master-file-dirs masks))
 543          (master-file-count         (length possible-master-files))
 544          (idx                       0)
 545          (temp-buffer               nil)
 546          (master-file-name          nil)
 547          (patched-master-file-name  nil)
 548          (found                     nil))
 549
 550     (while (and (not found) (< idx master-file-count))
 551       (setq master-file-name (nth idx possible-master-files))
 552       (setq patched-master-file-name (funcall create-temp-f master-file-name "flymake_master"))
 553       (if (flymake-find-buffer-for-file master-file-name)
 554           (setq temp-buffer (flymake-copy-buffer-to-temp-buffer (flymake-find-buffer-for-file master-file-name)))
 555         (setq temp-buffer (flymake-read-file-to-temp-buffer master-file-name)))
 556       (setq found
 557             (flymake-check-patch-master-file-buffer
 558              temp-buffer
 559              master-file-name
 560              patched-master-file-name
 561              source-file-name
 562              patched-source-file-name
 563              (funcall get-incl-dirs-f (file-name-directory master-file-name))
 564              include-regexp))
 565       (setq idx (1+ idx)))
 566     (if found
 567         (list master-file-name patched-master-file-name)
 568       (progn
 569         (flymake-log 3 "none of %d master file(s) checked includes %s" master-file-count
 570                      (file-name-nondirectory source-file-name))
 571         nil))))
 572
 573 (defun flymake-save-buffer-in-file (file-name)
 574   (make-directory (file-name-directory file-name) 1)
 575   (write-region nil nil file-name nil 566)
 576   (flymake-log 3 "saved buffer %s in file %s" (buffer-name) file-name))
 577
 578 (defun flymake-save-string-to-file (file-name data)
 579   "Save string DATA to file FILE-NAME."
 580   (write-region data nil file-name nil 566))
 581
 582 (defun flymake-read-file-to-string (file-name)
 583   "Read contents of file FILE-NAME and return as a string."
 584   (with-temp-buffer
 585     (insert-file-contents file-name)
 586     (buffer-substring (point-min) (point-max))))
 587
 588 (defun flymake-process-filter (process output)
 589   "Parse OUTPUT and highlight error lines.
 590 It's flymake process filter."
 591   (let ((source-buffer (process-buffer process)))
 592
 593     (flymake-log 3 "received %d byte(s) of output from process %d"
 594                  (length output) (process-id process))
 595     (when (buffer-live-p source-buffer)
 596       (with-current-buffer source-buffer
 597         (flymake-parse-output-and-residual output)))))
 598
 599 (defun flymake-process-sentinel (process _event)
 600   "Sentinel for syntax check buffers."
 601   (when (memq (process-status process) '(signal exit))
 602     (let* ((exit-status       (process-exit-status process))
 603            (command           (process-command process))
 604            (source-buffer     (process-buffer process))
 605            (cleanup-f         (flymake-get-cleanup-function (buffer-file-name source-buffer))))
 606
 607       (flymake-log 2 "process %d exited with code %d"
 608                    (process-id process) exit-status)
 609       (condition-case err
 610           (progn
 611             (flymake-log 3 "cleaning up using %s" cleanup-f)
 612             (when (buffer-live-p source-buffer)
 613               (with-current-buffer source-buffer
 614                 (funcall cleanup-f)))
 615
 616             (delete-process process)
 617             (setq flymake-processes (delq process flymake-processes))
 618
 619             (when (buffer-live-p source-buffer)
 620               (with-current-buffer source-buffer
 621
 622                 (flymake-parse-residual)
 623                 (flymake-post-syntax-check exit-status command)
 624                 (setq flymake-is-running nil))))
 625         (error
 626          (let ((err-str (format "Error in process sentinel for buffer %s: %s"
 627                                 source-buffer (error-message-string err))))
 628            (flymake-log 0 err-str)
 629            (with-current-buffer source-buffer
 630              (setq flymake-is-running nil))))))))
 631
 632 (defun flymake-post-syntax-check (exit-status command)
 633   (setq flymake-err-info flymake-new-err-info)
 634   (setq flymake-new-err-info nil)
 635   (setq flymake-err-info
 636         (flymake-fix-line-numbers
 637          flymake-err-info 1 (flymake-count-lines)))
 638   (flymake-delete-own-overlays)
 639   (flymake-highlight-err-lines flymake-err-info)
 640   (let (err-count warn-count)
 641     (setq err-count (flymake-get-err-count flymake-err-info "e"))
 642     (setq warn-count  (flymake-get-err-count flymake-err-info "w"))
 643     (flymake-log 2 "%s: %d error(s), %d warning(s) in %.2f second(s)"
 644                  (buffer-name) err-count warn-count
 645                  (- (flymake-float-time) flymake-check-start-time))
 646     (setq flymake-check-start-time nil)
 647
 648     (if (and (equal 0 err-count) (equal 0 warn-count))
 649         (if (equal 0 exit-status)
 650             (flymake-report-status "" "")       ; PASSED
 651           (if (not flymake-check-was-interrupted)
 652               (flymake-report-fatal-status "CFGERR"
 653                                            (format "Configuration error has occurred while running %s" command))
 654             (flymake-report-status nil ""))) ; "STOPPED"
 655       (flymake-report-status (format "%d/%d" err-count warn-count) ""))))
 656
 657 (defun flymake-parse-output-and-residual (output)
 658   "Split OUTPUT into lines, merge in residual if necessary."
 659   (let* ((buffer-residual     flymake-output-residual)
 660          (total-output        (if buffer-residual (concat buffer-residual output) output))
 661          (lines-and-residual  (flymake-split-output total-output))
 662          (lines               (nth 0 lines-and-residual))
 663          (new-residual        (nth 1 lines-and-residual)))
 664     (setq flymake-output-residual new-residual)
 665     (setq flymake-new-err-info
 666           (flymake-parse-err-lines
 667            flymake-new-err-info lines))))
 668
 669 (defun flymake-parse-residual ()
 670   "Parse residual if it's non empty."
 671   (when flymake-output-residual
 672     (setq flymake-new-err-info
 673           (flymake-parse-err-lines
 674            flymake-new-err-info
 675            (list flymake-output-residual)))
 676     (setq flymake-output-residual nil)))
 677
 678 (defun flymake-er-make-er (line-no line-err-info-list)
 679   (list line-no line-err-info-list))
 680
 681 (defun flymake-er-get-line (err-info)
 682   (nth 0 err-info))
 683
 684 (defun flymake-er-get-line-err-info-list (err-info)
 685   (nth 1 err-info))
 686
 687 (defstruct (flymake-ler
 688             (:constructor nil)
 689             (:constructor flymake-ler-make-ler (file line type text &optional full-file)))
 690   file line type text full-file)
 691
 692 (defun flymake-ler-set-file (line-err-info file)
 693   (flymake-ler-make-ler file
 694                         (flymake-ler-line line-err-info)
 695                         (flymake-ler-type line-err-info)
 696                         (flymake-ler-text line-err-info)
 697                         (flymake-ler-full-file line-err-info)))
 698
 699 (defun flymake-ler-set-full-file (line-err-info full-file)
 700   (flymake-ler-make-ler (flymake-ler-file line-err-info)
 701                         (flymake-ler-line line-err-info)
 702                         (flymake-ler-type line-err-info)
 703                         (flymake-ler-text line-err-info)
 704                         full-file))
 705
 706 (defun flymake-ler-set-line (line-err-info line)
 707   (flymake-ler-make-ler (flymake-ler-file line-err-info)
 708                         line
 709                         (flymake-ler-type line-err-info)
 710                         (flymake-ler-text line-err-info)
 711                         (flymake-ler-full-file line-err-info)))
 712
 713 (defun flymake-get-line-err-count (line-err-info-list type)
 714   "Return number of errors of specified TYPE.
 715 Value of TYPE is either \"e\" or \"w\"."
 716   (let* ((idx        0)
 717          (count      (length line-err-info-list))
 718          (err-count  0))
 719
 720     (while (< idx count)
 721       (when (equal type (flymake-ler-type (nth idx line-err-info-list)))
 722         (setq err-count (1+ err-count)))
 723       (setq idx (1+ idx)))
 724     err-count))
 725
 726 (defun flymake-get-err-count (err-info-list type)
 727   "Return number of errors of specified TYPE for ERR-INFO-LIST."
 728   (let* ((idx        0)
 729          (count      (length err-info-list))
 730          (err-count  0))
 731     (while (< idx count)
 732       (setq err-count (+ err-count (flymake-get-line-err-count (nth 1 (nth idx err-info-list)) type)))
 733       (setq idx (1+ idx)))
 734     err-count))
 735
 736 (defun flymake-fix-line-numbers (err-info-list min-line max-line)
 737   "Replace line numbers with fixed value.
 738 If line-numbers is less than MIN-LINE, set line numbers to MIN-LINE.
 739 If line numbers is greater than MAX-LINE, set line numbers to MAX-LINE.
 740 The reason for this fix is because some compilers might report
 741 line number outside the file being compiled."
 742   (let* ((count     (length err-info-list))
 743          (err-info  nil)
 744          (line      0))
 745     (while (> count 0)
 746       (setq err-info (nth (1- count) err-info-list))
 747       (setq line (flymake-er-get-line err-info))
 748       (when (or (< line min-line) (> line max-line))
 749         (setq line (if (< line min-line) min-line max-line))
 750         (setq err-info-list (flymake-set-at err-info-list (1- count)
 751                                             (flymake-er-make-er line
 752                                                                 (flymake-er-get-line-err-info-list err-info)))))
 753       (setq count (1- count))))
 754   err-info-list)
 755
 756 (defun flymake-highlight-err-lines (err-info-list)
 757   "Highlight error lines in BUFFER using info from ERR-INFO-LIST."
 758   (save-excursion
 759     (dolist (err err-info-list)
 760       (flymake-highlight-line (car err) (nth 1 err)))))
 761
 762 (defun flymake-overlay-p (ov)
 763   "Determine whether overlay OV was created by flymake."
 764   (and (overlayp ov) (overlay-get ov 'flymake-overlay)))
 765
 766 (defun flymake-make-overlay (beg end tooltip-text face mouse-face)
 767   "Allocate a flymake overlay in range BEG and END."
 768   (when (not (flymake-region-has-flymake-overlays beg end))
 769     (let ((ov (make-overlay beg end nil t t)))
 770       (overlay-put ov 'face           face)
 771       (overlay-put ov 'mouse-face     mouse-face)
 772       (overlay-put ov 'help-echo      tooltip-text)
 773       (overlay-put ov 'flymake-overlay  t)
 774       (overlay-put ov 'priority 100)
 775       ;;+(flymake-log 3 "created overlay %s" ov)
 776       ov)
 777     (flymake-log 3 "created an overlay at (%d-%d)" beg end)))
 778
 779 (defun flymake-delete-own-overlays ()
 780   "Delete all flymake overlays in BUFFER."
 781   (dolist (ol (overlays-in (point-min) (point-max)))
 782     (when (flymake-overlay-p ol)
 783       (delete-overlay ol)
 784       ;;+(flymake-log 3 "deleted overlay %s" ol)
 785       )))
 786
 787 (defun flymake-region-has-flymake-overlays (beg end)
 788   "Check if region specified by BEG and END has overlay.
 789 Return t if it has at least one flymake overlay, nil if no overlay."
 790   (let ((ov                  (overlays-in beg end))
 791         (has-flymake-overlays  nil))
 792     (while (consp ov)
 793       (when (flymake-overlay-p (car ov))
 794         (setq has-flymake-overlays t))
 795       (setq ov (cdr ov)))
 796     has-flymake-overlays))
 797
 798 (defface flymake-errline
 799   '((((class color) (background dark)) (:background "Firebrick4"))
 800     (((class color) (background light)) (:background "LightPink"))
 801     (t (:bold t)))
 802   "Face used for marking error lines."
 803   :group 'flymake)
 804
 805 (defface flymake-warnline
 806   '((((class color) (background dark)) (:background "DarkBlue"))
 807     (((class color) (background light)) (:background "LightBlue2"))
 808     (t (:bold t)))
 809   "Face used for marking warning lines."
 810   :group 'flymake)
 811
 812 (defun flymake-highlight-line (line-no line-err-info-list)
 813   "Highlight line LINE-NO in current buffer.
 814 Perhaps use text from LINE-ERR-INFO-LIST to enhance highlighting."
 815   (goto-char (point-min))
 816   (forward-line (1- line-no))
 817   (let* ((line-beg (point-at-bol))
 818          (line-end (point-at-eol))
 819          (beg      line-beg)
 820          (end      line-end)
 821          (tooltip-text (flymake-ler-text (nth 0 line-err-info-list)))
 822          (face     nil))
 823
 824     (goto-char line-beg)
 825     (while (looking-at "[ \t]")
 826       (forward-char))
 827
 828     (setq beg (point))
 829
 830     (goto-char line-end)
 831     (while (and (looking-at "[ \t\r\n]") (> (point) 1))
 832       (backward-char))
 833
 834     (setq end (1+ (point)))
 835
 836     (when (<= end beg)
 837       (setq beg line-beg)
 838       (setq end line-end))
 839
 840     (when (= end beg)
 841       (goto-char end)
 842       (forward-line)
 843       (setq end (point)))
 844
 845     (if (> (flymake-get-line-err-count line-err-info-list "e") 0)
 846         (setq face 'flymake-errline)
 847       (setq face 'flymake-warnline))
 848
 849     (flymake-make-overlay beg end tooltip-text face nil)))
 850
 851 (defun flymake-parse-err-lines (err-info-list lines)
 852   "Parse err LINES, store info in ERR-INFO-LIST."
 853   (let* ((count              (length lines))
 854          (idx                0)
 855          (line-err-info      nil)
 856          (real-file-name     nil)
 857          (source-file-name   buffer-file-name)
 858          (get-real-file-name-f (flymake-get-real-file-name-function source-file-name)))
 859
 860     (while (< idx count)
 861       (setq line-err-info (flymake-parse-line (nth idx lines)))
 862       (when line-err-info
 863         (setq real-file-name (funcall get-real-file-name-f
 864                                       (flymake-ler-file line-err-info)))
 865         (setq line-err-info (flymake-ler-set-full-file line-err-info real-file-name))
 866
 867         (when (flymake-same-files real-file-name source-file-name)
 868           (setq line-err-info (flymake-ler-set-file line-err-info nil))
 869           (setq err-info-list (flymake-add-err-info err-info-list line-err-info))))
 870       (flymake-log 3 "parsed '%s', %s line-err-info" (nth idx lines) (if line-err-info "got" "no"))
 871       (setq idx (1+ idx)))
 872     err-info-list))
 873
 874 (defun flymake-split-output (output)
 875   "Split OUTPUT into lines.
 876 Return last one as residual if it does not end with newline char.
 877 Returns ((LINES) RESIDUAL)."
 878   (when (and output (> (length output) 0))
 879     (let* ((lines (flymake-split-string output "[\n\r]+"))
 880            (complete (equal "\n" (char-to-string (aref output (1- (length output))))))
 881            (residual nil))
 882       (when (not complete)
 883         (setq residual (car (last lines)))
 884         (setq lines (butlast lines)))
 885       (list lines residual))))
 886
 887 (defun flymake-reformat-err-line-patterns-from-compile-el (original-list)
 888   "Grab error line patterns from ORIGINAL-LIST in compile.el format.
 889 Convert it to flymake internal format."
 890   (let* ((converted-list '()))
 891     (dolist (item original-list)
 892       (setq item (cdr item))
 893       (let ((regexp (nth 0 item))
 894             (file (nth 1 item))
 895             (line (nth 2 item))
 896             (col (nth 3 item)))
 897         (if (consp file)        (setq file (car file)))
 898         (if (consp line)        (setq line (car line)))
 899         (if (consp col) (setq col (car col)))
 900
 901         (when (not (functionp line))
 902           (setq converted-list (cons (list regexp file line col) converted-list)))))
 903     converted-list))
 904
 905 (require 'compile)
 906
 907 (defvar flymake-err-line-patterns ; regexp file-idx line-idx col-idx (optional) text-idx(optional), match-end to end of string is error text
 908   (append
 909    '(
 910      ;; MS Visual C++ 6.0
 911      ("\\(\\([a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)) \: \\(\\(error\\|warning\\|fatal error\\) \\(C[0-9]+\\):[ \t\n]*\\(.+\\)\\)"
 912       1 3 nil 4)
 913      ;; jikes
 914      ("\\(\\([a-zA-Z]:\\)?[^:(\t\n]+\\)\:\\([0-9]+\\)\:[0-9]+\:[0-9]+\:[0-9]+\: \\(\\(Error\\|Warning\\|Caution\\|Semantic Error\\):[ \t\n]*\\(.+\\)\\)"
 915       1 3 nil 4)
 916      ;; MS midl
 917      ("midl[ ]*:[ ]*\\(command line error .*\\)"
 918       nil nil nil 1)
 919      ;; MS C#
 920      ("\\(\\([a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\),[0-9]+)\: \\(\\(error\\|warning\\|fatal error\\) \\(CS[0-9]+\\):[ \t\n]*\\(.+\\)\\)"
 921       1 3 nil 4)
 922      ;; perl
 923      ("\\(.*\\) at \\([^ \n]+\\) line \\([0-9]+\\)[,.\n]" 2 3 nil 1)
 924      ;; PHP
 925      ("\\(?:Parse\\|Fatal\\) error: \\(.*\\) in \\(.*\\) on line \\([0-9]+\\)" 2 3 nil 1)
 926      ;; LaTeX warnings (fileless) ("\\(LaTeX \\(Warning\\|Error\\): .*\\) on input line \\([0-9]+\\)" 20 3 nil 1)
 927      ;; ant/javac.  Note this also matches gcc warnings!
 928      (" *\\(\\[javac\\] *\\)?\\(\\([a-zA-Z]:\\)?[^:(\t\n]+\\)\:\\([0-9]+\\)\\(?:\:[0-9]+\\)?\:[ \t\n]*\\(.+\\)"
 929       2 4 nil 5))
 930    ;; compilation-error-regexp-alist)
 931    (flymake-reformat-err-line-patterns-from-compile-el compilation-error-regexp-alist-alist))
 932   "Patterns for matching error/warning lines.  Each pattern has the form
 933 \(REGEXP FILE-IDX LINE-IDX COL-IDX ERR-TEXT-IDX).
 934 Use `flymake-reformat-err-line-patterns-from-compile-el' to add patterns
 935 from compile.el")
 936
 937 ;;(defcustom flymake-err-line-patterns
 938 ;;  '(
 939 ;;    ; MS Visual C++ 6.0
 940 ;;    ("\\(\\([a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)) \: \\(\\(error\\|warning\\|fatal error\\) \\(C[0-9]+\\):[ \t\n]*\\(.+\\)\\)"
 941 ;;       1 3 4)
 942 ;;   ; jikes
 943 ;;   ("\\(\\([a-zA-Z]:\\)?[^:(\t\n]+\\)\:\\([0-9]+\\)\:[0-9]+\:[0-9]+\:[0-9]+\: \\(\\(Error\\|Warning\\|Caution\\):[ \t\n]*\\(.+\\)\\)"
 944 ;;       1 3 4))
 945 ;;    "patterns for matching error/warning lines, (regexp file-idx line-idx err-text-idx)"
 946 ;;   :group 'flymake
 947 ;;   :type '(repeat (string number number number))
 948 ;;)
 949
 950 (defun flymake-parse-line (line)
 951   "Parse LINE to see if it is an error or warning.
 952 Return its components if so, nil otherwise."
 953   (let ((raw-file-name nil)
 954         (line-no 0)
 955         (err-type "e")
 956         (err-text nil)
 957         (patterns flymake-err-line-patterns)
 958         (matched nil))
 959     (while (and patterns (not matched))
 960       (when (string-match (car (car patterns)) line)
 961         (let* ((file-idx (nth 1 (car patterns)))
 962                (line-idx (nth 2 (car patterns))))
 963
 964           (setq raw-file-name (if file-idx (match-string file-idx line) nil))
 965           (setq line-no       (if line-idx (string-to-number (match-string line-idx line)) 0))
 966           (setq err-text      (if (> (length (car patterns)) 4)
 967                                   (match-string (nth 4 (car patterns)) line)
 968                                 (flymake-patch-err-text (substring line (match-end 0)))))
 969           (or err-text (setq err-text "<no error text>"))
 970           (if (and err-text (string-match "^[wW]arning" err-text))
 971               (setq err-type "w")
 972             )
 973           (flymake-log 3 "parse line: file-idx=%s line-idx=%s file=%s line=%s text=%s" file-idx line-idx
 974                        raw-file-name line-no err-text)
 975           (setq matched t)))
 976       (setq patterns (cdr patterns)))
 977     (if matched
 978         (flymake-ler-make-ler raw-file-name line-no err-type err-text)
 979       ())))
 980
 981 (defun flymake-find-err-info (err-info-list line-no)
 982   "Find (line-err-info-list pos) for specified LINE-NO."
 983   (if err-info-list
 984       (let* ((line-err-info-list  nil)
 985              (pos       0)
 986              (count     (length err-info-list)))
 987
 988         (while (and (< pos count) (< (car (nth pos err-info-list)) line-no))
 989           (setq pos (1+ pos)))
 990         (when (and (< pos count) (equal (car (nth pos err-info-list)) line-no))
 991           (setq line-err-info-list (flymake-er-get-line-err-info-list (nth pos err-info-list))))
 992         (list line-err-info-list pos))
 993     '(nil 0)))
 994
 995 (defun flymake-line-err-info-is-less-or-equal (line-one line-two)
 996   (or (string< (flymake-ler-type line-one) (flymake-ler-type line-two))
 997       (and (string= (flymake-ler-type line-one) (flymake-ler-type line-two))
 998            (not (flymake-ler-file line-one)) (flymake-ler-file line-two))
 999       (and (string= (flymake-ler-type line-one) (flymake-ler-type line-two))
1000            (or (and      (flymake-ler-file line-one)       (flymake-ler-file line-two))
1001                (and (not (flymake-ler-file line-one)) (not (flymake-ler-file line-two)))))))
1002
1003 (defun flymake-add-line-err-info (line-err-info-list line-err-info)
1004   "Update LINE-ERR-INFO-LIST with the error LINE-ERR-INFO.
1005 For the format of LINE-ERR-INFO, see `flymake-ler-make-ler'.
1006 The new element is inserted in the proper position, according to
1007 the predicate `flymake-line-err-info-is-less-or-equal'.
1008 The updated value of LINE-ERR-INFO-LIST is returned."
1009   (if (not line-err-info-list)
1010       (list line-err-info)
1011     (let* ((count  (length line-err-info-list))
1012            (idx    0))
1013       (while (and (< idx count) (flymake-line-err-info-is-less-or-equal (nth idx line-err-info-list) line-err-info))
1014         (setq idx (1+ idx)))
1015       (cond ((equal 0     idx)    (setq line-err-info-list (cons line-err-info line-err-info-list)))
1016             (t                    (setq line-err-info-list (flymake-ins-after line-err-info-list (1- idx) line-err-info))))
1017       line-err-info-list)))
1018
1019 (defun flymake-add-err-info (err-info-list line-err-info)
1020   "Update ERR-INFO-LIST with the error LINE-ERR-INFO, preserving sort order.
1021 Returns the updated value of ERR-INFO-LIST.
1022 For the format of ERR-INFO-LIST, see `flymake-err-info'.
1023 For the format of LINE-ERR-INFO, see `flymake-ler-make-ler'."
1024   (let* ((line-no             (if (flymake-ler-file line-err-info) 1 (flymake-ler-line line-err-info)))
1025          (info-and-pos        (flymake-find-err-info err-info-list line-no))
1026          (exists              (car info-and-pos))
1027          (pos                 (nth 1 info-and-pos))
1028          (line-err-info-list  nil)
1029          (err-info            nil))
1030
1031     (if exists
1032         (setq line-err-info-list (flymake-er-get-line-err-info-list (car (nthcdr pos err-info-list)))))
1033     (setq line-err-info-list (flymake-add-line-err-info line-err-info-list line-err-info))
1034
1035     (setq err-info (flymake-er-make-er line-no line-err-info-list))
1036     (cond (exists             (setq err-info-list (flymake-set-at err-info-list pos err-info)))
1037           ((equal 0 pos)      (setq err-info-list (cons err-info err-info-list)))
1038           (t                  (setq err-info-list (flymake-ins-after err-info-list (1- pos) err-info))))
1039     err-info-list))
1040
1041 (defun flymake-get-project-include-dirs-imp (basedir)
1042   "Include dirs for the project current file belongs to."
1043   (if (flymake-get-project-include-dirs-from-cache basedir)
1044       (progn
1045         (flymake-get-project-include-dirs-from-cache basedir))
1046     ;;else
1047     (let* ((command-line  (concat "make -C "
1048                                   (shell-quote-argument basedir)
1049                                   " DUMPVARS=INCLUDE_DIRS dumpvars"))
1050            (output        (shell-command-to-string command-line))
1051            (lines         (flymake-split-string output "\n"))
1052            (count         (length lines))
1053            (idx           0)
1054            (inc-dirs      nil))
1055       (while (and (< idx count) (not (string-match "^INCLUDE_DIRS=.*" (nth idx lines))))
1056         (setq idx (1+ idx)))
1057       (when (< idx count)
1058         (let* ((inc-lines  (flymake-split-string (nth idx lines) " *-I"))
1059                (inc-count  (length inc-lines)))
1060           (while (> inc-count 0)
1061             (when (not (string-match "^INCLUDE_DIRS=.*" (nth (1- inc-count) inc-lines)))
1062               (push (flymake-replace-regexp-in-string "\"" "" (nth (1- inc-count) inc-lines)) inc-dirs))
1063             (setq inc-count (1- inc-count)))))
1064       (flymake-add-project-include-dirs-to-cache basedir inc-dirs)
1065       inc-dirs)))
1066
1067 (defcustom flymake-get-project-include-dirs-function 'flymake-get-project-include-dirs-imp
1068   "Function used to get project include dirs, one parameter: basedir name."
1069   :group 'flymake
1070   :type 'function)
1071
1072 (defun flymake-get-project-include-dirs (basedir)
1073   (funcall flymake-get-project-include-dirs-function basedir))
1074
1075 (defun flymake-get-system-include-dirs ()
1076   "System include dirs - from the 'INCLUDE' env setting."
1077   (let* ((includes (getenv "INCLUDE")))
1078     (if includes (flymake-split-string includes path-separator) nil)))
1079
1080 (defvar flymake-project-include-dirs-cache (flymake-makehash 'equal))
1081
1082 (defun flymake-get-project-include-dirs-from-cache (base-dir)
1083   (gethash base-dir flymake-project-include-dirs-cache))
1084
1085 (defun flymake-add-project-include-dirs-to-cache (base-dir include-dirs)
1086   (puthash base-dir include-dirs flymake-project-include-dirs-cache))
1087
1088 (defun flymake-clear-project-include-dirs-cache ()
1089   (clrhash flymake-project-include-dirs-cache))
1090
1091 (defun flymake-get-include-dirs (base-dir)
1092   "Get dirs to use when resolving local file names."
1093   (let* ((include-dirs (append '(".") (flymake-get-project-include-dirs base-dir) (flymake-get-system-include-dirs))))
1094     include-dirs))
1095
1096 ;; (defun flymake-restore-formatting ()
1097 ;;   "Remove any formatting made by flymake."
1098 ;;   )
1099
1100 ;; (defun flymake-get-program-dir (buffer)
1101 ;;   "Get dir to start program in."
1102 ;;   (unless (bufferp buffer)
1103 ;;     (error "Invalid buffer"))
1104 ;;   (with-current-buffer buffer
1105 ;;     default-directory))
1106
1107 (defun flymake-safe-delete-file (file-name)
1108   (when (and file-name (file-exists-p file-name))
1109     (delete-file file-name)
1110     (flymake-log 1 "deleted file %s" file-name)))
1111
1112 (defun flymake-safe-delete-directory (dir-name)
1113   (condition-case nil
1114       (progn
1115         (delete-directory dir-name)
1116         (flymake-log 1 "deleted dir %s" dir-name))
1117     (error
1118      (flymake-log 1 "Failed to delete dir %s, error ignored" dir-name))))
1119
1120 (defcustom flymake-compilation-prevents-syntax-check t
1121   "If non-nil, don't start syntax check if compilation is running."
1122   :group 'flymake
1123   :type 'boolean)
1124
1125 (defun flymake-start-syntax-check ()
1126   "Start syntax checking for current buffer."
1127   (interactive)
1128   (flymake-log 3 "flymake is running: %s" flymake-is-running)
1129   (when (and (not flymake-is-running)
1130              (flymake-can-syntax-check-file buffer-file-name))
1131     (when (or (not flymake-compilation-prevents-syntax-check)
1132               (not (flymake-compilation-is-running))) ;+ (flymake-rep-ort-status buffer "COMP")
1133       (flymake-clear-buildfile-cache)
1134       (flymake-clear-project-include-dirs-cache)
1135
1136       (setq flymake-check-was-interrupted nil)
1137
1138       (let* ((source-file-name  buffer-file-name)
1139              (init-f (flymake-get-init-function source-file-name))
1140              (cleanup-f (flymake-get-cleanup-function source-file-name))
1141              (cmd-and-args (funcall init-f))
1142              (cmd          (nth 0 cmd-and-args))
1143              (args         (nth 1 cmd-and-args))
1144              (dir          (nth 2 cmd-and-args)))
1145         (if (not cmd-and-args)
1146             (progn
1147               (flymake-log 0 "init function %s for %s failed, cleaning up" init-f source-file-name)
1148               (funcall cleanup-f))
1149           (progn
1150             (setq flymake-last-change-time nil)
1151             (flymake-start-syntax-check-process cmd args dir)))))))
1152
1153 (defun flymake-start-syntax-check-process (cmd args dir)
1154   "Start syntax check process."
1155   (condition-case err
1156       (let* ((process
1157               (let ((default-directory (or dir default-directory)))
1158                 (when dir
1159                   (flymake-log 3 "starting process on dir %s" dir))
1160                 (apply 'start-file-process
1161                        "flymake-proc" (current-buffer) cmd args))))
1162         (set-process-sentinel process 'flymake-process-sentinel)
1163         (set-process-filter process 'flymake-process-filter)
1164         (push process flymake-processes)
1165
1166         (setq flymake-is-running t)
1167         (setq flymake-last-change-time nil)
1168         (setq flymake-check-start-time (flymake-float-time))
1169
1170         (flymake-report-status nil "*")
1171         (flymake-log 2 "started process %d, command=%s, dir=%s"
1172                      (process-id process) (process-command process)
1173                      default-directory)
1174         process)
1175     (error
1176      (let* ((err-str (format "Failed to launch syntax check process '%s' with args %s: %s"
1177                              cmd args (error-message-string err)))
1178             (source-file-name buffer-file-name)
1179             (cleanup-f        (flymake-get-cleanup-function source-file-name)))
1180        (flymake-log 0 err-str)
1181        (funcall cleanup-f)
1182        (flymake-report-fatal-status "PROCERR" err-str)))))
1183
1184 (defun flymake-kill-process (proc)
1185   "Kill process PROC."
1186   (kill-process proc)
1187   (let* ((buf (process-buffer proc)))
1188     (when (buffer-live-p buf)
1189       (with-current-buffer buf
1190         (setq flymake-check-was-interrupted t))))
1191   (flymake-log 1 "killed process %d" (process-id proc)))
1192
1193 (defun flymake-stop-all-syntax-checks ()
1194   "Kill all syntax check processes."
1195   (interactive)
1196   (while flymake-processes
1197     (flymake-kill-process (pop flymake-processes))))
1198
1199 (defun flymake-compilation-is-running ()
1200   (and (boundp 'compilation-in-progress)
1201        compilation-in-progress))
1202
1203 (defun flymake-compile ()
1204   "Kill all flymake syntax checks, start compilation."
1205   (interactive)
1206   (flymake-stop-all-syntax-checks)
1207   (call-interactively 'compile))
1208
1209 (defcustom flymake-no-changes-timeout 0.5
1210   "Time to wait after last change before starting compilation."
1211   :group 'flymake
1212   :type 'number)
1213
1214 (defun flymake-on-timer-event (buffer)
1215   "Start a syntax check for buffer BUFFER if necessary."
1216   (when (buffer-live-p buffer)
1217     (with-current-buffer buffer
1218       (when (and (not flymake-is-running)
1219                  flymake-last-change-time
1220                  (> (- (flymake-float-time) flymake-last-change-time)
1221                     flymake-no-changes-timeout))
1222
1223         (setq flymake-last-change-time nil)
1224         (flymake-log 3 "starting syntax check as more than 1 second passed since last change")
1225         (flymake-start-syntax-check)))))
1226
1227 (defun flymake-current-line-no ()
1228   "Return number of current line in current buffer."
1229   (count-lines (point-min) (if (eobp) (point) (1+ (point)))))
1230
1231 (defun flymake-count-lines ()
1232   "Return number of lines in buffer BUFFER."
1233   (count-lines (point-min) (point-max)))
1234
1235 (defun flymake-display-err-menu-for-current-line ()
1236   "Display a menu with errors/warnings for current line if it has errors and/or warnings."
1237   (interactive)
1238   (let* ((line-no             (flymake-current-line-no))
1239          (line-err-info-list  (nth 0 (flymake-find-err-info flymake-err-info line-no)))
1240          (menu-data           (flymake-make-err-menu-data line-no line-err-info-list))
1241          (choice              nil))
1242     (if menu-data
1243         (progn
1244           (setq choice (flymake-popup-menu menu-data))
1245           (flymake-log 3 "choice=%s" choice)
1246           (when choice
1247             (eval choice)))
1248       (flymake-log 1 "no errors for line %d" line-no))))
1249
1250 (defun flymake-make-err-menu-data (line-no line-err-info-list)
1251   "Make a (menu-title (item-title item-action)*) list with errors/warnings from LINE-ERR-INFO-LIST."
1252   (let* ((menu-items  nil))
1253     (when line-err-info-list
1254       (let* ((count           (length line-err-info-list))
1255              (menu-item-text  nil))
1256         (while (> count 0)
1257           (setq menu-item-text (flymake-ler-text (nth (1- count) line-err-info-list)))
1258           (let* ((file       (flymake-ler-file (nth (1- count) line-err-info-list)))
1259                  (full-file  (flymake-ler-full-file (nth (1- count) line-err-info-list)))
1260                  (line       (flymake-ler-line (nth (1- count) line-err-info-list))))
1261             (if file
1262                 (setq menu-item-text (concat menu-item-text " - " file "(" (format "%d" line) ")")))
1263             (setq menu-items (cons (list menu-item-text
1264                                          (if file (list 'flymake-goto-file-and-line full-file line) nil))
1265                                    menu-items)))
1266           (setq count (1- count)))
1267         (flymake-log 3 "created menu-items with %d item(s)" (length menu-items))))
1268     (if menu-items
1269         (let* ((menu-title  (format "Line %d: %d error(s), %d warning(s)" line-no
1270                                     (flymake-get-line-err-count line-err-info-list "e")
1271                                     (flymake-get-line-err-count line-err-info-list "w"))))
1272           (list menu-title menu-items))
1273       nil)))
1274
1275 (defun flymake-goto-file-and-line (file line)
1276   "Try to get buffer for FILE and goto line LINE in it."
1277   (if (not (file-exists-p file))
1278       (flymake-log 1 "File %s does not exist" file)
1279     (find-file file)
1280     (goto-char (point-min))
1281     (forward-line (1- line))))
1282
1283 ;; flymake minor mode declarations
1284 (defvar flymake-mode-line nil)
1285
1286 (make-variable-buffer-local 'flymake-mode-line)
1287
1288 (defvar flymake-mode-line-e-w nil)
1289
1290 (make-variable-buffer-local 'flymake-mode-line-e-w)
1291
1292 (defvar flymake-mode-line-status nil)
1293
1294 (make-variable-buffer-local 'flymake-mode-line-status)
1295
1296 (defun flymake-report-status (e-w &optional status)
1297   "Show status in mode line."
1298   (when e-w
1299     (setq flymake-mode-line-e-w e-w))
1300   (when status
1301     (setq flymake-mode-line-status status))
1302   (let* ((mode-line " Flymake"))
1303     (when (> (length flymake-mode-line-e-w) 0)
1304       (setq mode-line (concat mode-line ":" flymake-mode-line-e-w)))
1305     (setq mode-line (concat mode-line flymake-mode-line-status))
1306     (setq flymake-mode-line mode-line)
1307     (force-mode-line-update)))
1308
1309 (defun flymake-display-warning (warning)
1310   "Display a warning to user."
1311   (message-box warning))
1312
1313 (defcustom flymake-gui-warnings-enabled t
1314   "Enables/disables GUI warnings."
1315   :group 'flymake
1316   :type 'boolean)
1317
1318 (defun flymake-report-fatal-status (status warning)
1319   "Display a warning and switch flymake mode off."
1320   (when flymake-gui-warnings-enabled
1321     (flymake-display-warning (format "Flymake: %s. Flymake will be switched OFF" warning))
1322     )
1323   (flymake-mode 0)
1324   (flymake-log 0 "switched OFF Flymake mode for buffer %s due to fatal status %s, warning %s"
1325                (buffer-name) status warning))
1326
1327 (defcustom flymake-start-syntax-check-on-find-file t
1328   "Start syntax check on find file."
1329   :group 'flymake
1330   :type 'boolean)
1331
1332 ;;;###autoload
1333 (define-minor-mode flymake-mode
1334   "Minor mode to do on-the-fly syntax checking.
1335 When called interactively, toggles the minor mode.
1336 With arg, turn Flymake mode on if and only if arg is positive."
1337   :group 'flymake :lighter flymake-mode-line
1338   (cond
1339
1340    ;; Turning the mode ON.
1341    (flymake-mode
1342     (cond
1343      ((not buffer-file-name)
1344       (message "Flymake unable to run without a buffer file name"))
1345      ((not (flymake-can-syntax-check-file buffer-file-name))
1346       (flymake-log 2 "flymake cannot check syntax in buffer %s" (buffer-name)))
1347      (t
1348       (add-hook 'after-change-functions 'flymake-after-change-function nil t)
1349       (add-hook 'after-save-hook 'flymake-after-save-hook nil t)
1350       (add-hook 'kill-buffer-hook 'flymake-kill-buffer-hook nil t)
1351       ;;+(add-hook 'find-file-hook 'flymake-find-file-hook)
1352
1353       (flymake-report-status "" "")
1354
1355       (setq flymake-timer
1356             (run-at-time nil 1 'flymake-on-timer-event (current-buffer)))
1357
1358       (when flymake-start-syntax-check-on-find-file
1359         (flymake-start-syntax-check)))))
1360
1361    ;; Turning the mode OFF.
1362    (t
1363     (remove-hook 'after-change-functions 'flymake-after-change-function t)
1364     (remove-hook 'after-save-hook 'flymake-after-save-hook t)
1365     (remove-hook 'kill-buffer-hook 'flymake-kill-buffer-hook t)
1366     ;;+(remove-hook 'find-file-hook (function flymake-find-file-hook) t)
1367
1368     (flymake-delete-own-overlays)
1369
1370     (when flymake-timer
1371       (cancel-timer flymake-timer)
1372       (setq flymake-timer nil))
1373
1374     (setq flymake-is-running nil))))
1375
1376 ;;;###autoload
1377 (defun flymake-mode-on ()
1378   "Turn flymake mode on."
1379   (flymake-mode 1)
1380   (flymake-log 1 "flymake mode turned ON for buffer %s" (buffer-name)))
1381
1382 ;;;###autoload
1383 (defun flymake-mode-off ()
1384   "Turn flymake mode off."
1385   (flymake-mode 0)
1386   (flymake-log 1 "flymake mode turned OFF for buffer %s" (buffer-name)))
1387
1388 (defcustom flymake-start-syntax-check-on-newline t
1389   "Start syntax check if newline char was added/removed from the buffer."
1390   :group 'flymake
1391   :type 'boolean)
1392
1393 (defun flymake-after-change-function (start stop _len)
1394   "Start syntax check for current buffer if it isn't already running."
1395   ;;+(flymake-log 0 "setting change time to %s" (flymake-float-time))
1396   (let((new-text (buffer-substring start stop)))
1397     (when (and flymake-start-syntax-check-on-newline (equal new-text "\n"))
1398       (flymake-log 3 "starting syntax check as new-line has been seen")
1399       (flymake-start-syntax-check))
1400     (setq flymake-last-change-time (flymake-float-time))))
1401
1402 (defun flymake-after-save-hook ()
1403   (if (local-variable-p 'flymake-mode (current-buffer)) ; (???) other way to determine whether flymake is active in buffer being saved?
1404       (progn
1405         (flymake-log 3 "starting syntax check as buffer was saved")
1406         (flymake-start-syntax-check)))) ; no more mode 3. cannot start check if mode 3 (to temp copies) is active - (???)
1407
1408 (defun flymake-kill-buffer-hook ()
1409   (when flymake-timer
1410     (cancel-timer flymake-timer)
1411     (setq flymake-timer nil)))
1412
1413 ;;;###autoload
1414 (defun flymake-find-file-hook ()
1415   ;;+(when flymake-start-syntax-check-on-find-file
1416   ;;+    (flymake-log 3 "starting syntax check on file open")
1417   ;;+    (flymake-start-syntax-check)
1418   ;;+)
1419   (when (and (not (local-variable-p 'flymake-mode (current-buffer)))
1420              (flymake-can-syntax-check-file buffer-file-name))
1421     (flymake-mode)
1422     (flymake-log 3 "automatically turned ON flymake mode")))
1423
1424 (defun flymake-get-first-err-line-no (err-info-list)
1425   "Return first line with error."
1426   (when err-info-list
1427     (flymake-er-get-line (car err-info-list))))
1428
1429 (defun flymake-get-last-err-line-no (err-info-list)
1430   "Return last line with error."
1431   (when err-info-list
1432     (flymake-er-get-line (nth (1- (length err-info-list)) err-info-list))))
1433
1434 (defun flymake-get-next-err-line-no (err-info-list line-no)
1435   "Return next line with error."
1436   (when err-info-list
1437     (let* ((count  (length err-info-list))
1438            (idx    0))
1439       (while (and (< idx count) (>= line-no (flymake-er-get-line (nth idx err-info-list))))
1440         (setq idx (1+ idx)))
1441       (if (< idx count)
1442           (flymake-er-get-line (nth idx err-info-list))))))
1443
1444 (defun flymake-get-prev-err-line-no (err-info-list line-no)
1445   "Return previous line with error."
1446   (when err-info-list
1447     (let* ((count (length err-info-list)))
1448       (while (and (> count 0) (<= line-no (flymake-er-get-line (nth (1- count) err-info-list))))
1449         (setq count (1- count)))
1450       (if (> count 0)
1451           (flymake-er-get-line (nth (1- count) err-info-list))))))
1452
1453 (defun flymake-skip-whitespace ()
1454   "Move forward until non-whitespace is reached."
1455   (while (looking-at "[ \t]")
1456     (forward-char)))
1457
1458 (defun flymake-goto-line (line-no)
1459   "Go to line LINE-NO, then skip whitespace."
1460   (goto-char (point-min))
1461   (forward-line (1- line-no))
1462   (flymake-skip-whitespace))
1463
1464 (defun flymake-goto-next-error ()
1465   "Go to next error in err ring."
1466   (interactive)
1467   (let ((line-no (flymake-get-next-err-line-no flymake-err-info (flymake-current-line-no))))
1468     (when (not line-no)
1469       (setq line-no (flymake-get-first-err-line-no flymake-err-info))
1470       (flymake-log 1 "passed end of file"))
1471     (if line-no
1472         (flymake-goto-line line-no)
1473       (flymake-log 1 "no errors in current buffer"))))
1474
1475 (defun flymake-goto-prev-error ()
1476   "Go to previous error in err ring."
1477   (interactive)
1478   (let ((line-no (flymake-get-prev-err-line-no flymake-err-info (flymake-current-line-no))))
1479     (when (not line-no)
1480       (setq line-no (flymake-get-last-err-line-no flymake-err-info))
1481       (flymake-log 1 "passed beginning of file"))
1482     (if line-no
1483         (flymake-goto-line line-no)
1484       (flymake-log 1 "no errors in current buffer"))))
1485
1486 (defun flymake-patch-err-text (string)
1487   (if (string-match "^[\n\t :0-9]*\\(.*\\)$" string)
1488       (match-string 1 string)
1489     string))
1490
1491 ;;;; general init-cleanup and helper routines
1492 (defun flymake-create-temp-inplace (file-name prefix)
1493   (unless (stringp file-name)
1494     (error "Invalid file-name"))
1495   (or prefix
1496       (setq prefix "flymake"))
1497   (let* ((temp-name   (concat (file-name-sans-extension file-name)
1498                               "_" prefix
1499                               (and (file-name-extension file-name)
1500                                    (concat "." (file-name-extension file-name))))))
1501     (flymake-log 3 "create-temp-inplace: file=%s temp=%s" file-name temp-name)
1502     temp-name))
1503
1504 (defun flymake-create-temp-with-folder-structure (file-name _prefix)
1505   (unless (stringp file-name)
1506     (error "Invalid file-name"))
1507
1508   (let* ((dir       (file-name-directory file-name))
1509          ;; Not sure what this slash-pos is all about, but I guess it's just
1510          ;; trying to remove the leading / of absolute file names.
1511          (slash-pos (string-match "/" dir))
1512          (temp-dir  (expand-file-name (substring dir (1+ slash-pos))
1513                                       (flymake-get-temp-dir))))
1514
1515     (file-truename (expand-file-name (file-name-nondirectory file-name)
1516                                      temp-dir))))
1517
1518 (defun flymake-delete-temp-directory (dir-name)
1519   "Attempt to delete temp dir created by `flymake-create-temp-with-folder-structure', do not fail on error."
1520   (let* ((temp-dir    (flymake-get-temp-dir))
1521          (suffix      (substring dir-name (1+ (length temp-dir)))))
1522
1523     (while (> (length suffix) 0)
1524       (setq suffix (directory-file-name suffix))
1525       ;;+(flymake-log 0 "suffix=%s" suffix)
1526       (flymake-safe-delete-directory
1527        (file-truename (expand-file-name suffix temp-dir)))
1528       (setq suffix (file-name-directory suffix)))))
1529
1530 (defvar flymake-temp-source-file-name nil)
1531 (make-variable-buffer-local 'flymake-temp-source-file-name)
1532
1533 (defvar flymake-master-file-name nil)
1534 (make-variable-buffer-local 'flymake-master-file-name)
1535
1536 (defvar flymake-temp-master-file-name nil)
1537 (make-variable-buffer-local 'flymake-temp-master-file-name)
1538
1539 (defvar flymake-base-dir nil)
1540 (make-variable-buffer-local 'flymake-base-dir)
1541
1542 (defun flymake-init-create-temp-buffer-copy (create-temp-f)
1543   "Make a temporary copy of the current buffer, save its name in buffer data and return the name."
1544   (let*  ((source-file-name       buffer-file-name)
1545           (temp-source-file-name  (funcall create-temp-f source-file-name "flymake")))
1546
1547     (flymake-save-buffer-in-file temp-source-file-name)
1548     (setq flymake-temp-source-file-name temp-source-file-name)
1549     temp-source-file-name))
1550
1551 (defun flymake-simple-cleanup ()
1552   "Do cleanup after `flymake-init-create-temp-buffer-copy'.
1553 Delete temp file."
1554   (flymake-safe-delete-file flymake-temp-source-file-name)
1555   (setq flymake-last-change-time nil))
1556
1557 (defun flymake-get-real-file-name (file-name-from-err-msg)
1558   "Translate file name from error message to \"real\" file name.
1559 Return full-name.  Names are real, not patched."
1560   (let* ((real-name             nil)
1561          (source-file-name      buffer-file-name)
1562          (master-file-name      flymake-master-file-name)
1563          (temp-source-file-name flymake-temp-source-file-name)
1564          (temp-master-file-name flymake-temp-master-file-name)
1565          (base-dirs
1566           (list flymake-base-dir
1567                 (file-name-directory source-file-name)
1568                 (if master-file-name (file-name-directory master-file-name))))
1569          (files (list (list source-file-name       source-file-name)
1570                       (list temp-source-file-name  source-file-name)
1571                       (list master-file-name       master-file-name)
1572                       (list temp-master-file-name  master-file-name))))
1573
1574     (when (equal 0 (length file-name-from-err-msg))
1575       (setq file-name-from-err-msg source-file-name))
1576
1577     (setq real-name (flymake-get-full-patched-file-name file-name-from-err-msg base-dirs files))
1578     ;; if real-name is nil, than file name from err msg is none of the files we've patched
1579     (if (not real-name)
1580         (setq real-name (flymake-get-full-nonpatched-file-name file-name-from-err-msg base-dirs)))
1581     (if (not real-name)
1582         (setq real-name file-name-from-err-msg))
1583     (setq real-name (flymake-fix-file-name real-name))
1584     (flymake-log 3 "get-real-file-name: file-name=%s real-name=%s" file-name-from-err-msg real-name)
1585     real-name))
1586
1587 (defun flymake-get-full-patched-file-name (file-name-from-err-msg base-dirs files)
1588   (let* ((base-dirs-count  (length base-dirs))
1589          (file-count       (length files))
1590          (real-name        nil))
1591
1592     (while (and (not real-name) (> base-dirs-count 0))
1593       (setq file-count (length files))
1594       (while (and (not real-name) (> file-count 0))
1595         (let* ((this-dir        (nth (1- base-dirs-count) base-dirs))
1596                (this-file       (nth 0 (nth (1- file-count) files)))
1597                (this-real-name  (nth 1 (nth (1- file-count) files))))
1598           ;;+(flymake-log 0 "this-dir=%s this-file=%s this-real=%s msg-file=%s" this-dir this-file this-real-name file-name-from-err-msg)
1599           (when (and this-dir this-file (flymake-same-files
1600                                          (expand-file-name file-name-from-err-msg this-dir)
1601                                          this-file))
1602             (setq real-name this-real-name)))
1603         (setq file-count (1- file-count)))
1604       (setq base-dirs-count (1- base-dirs-count)))
1605     real-name))
1606
1607 (defun flymake-get-full-nonpatched-file-name (file-name-from-err-msg base-dirs)
1608   (let* ((real-name  nil))
1609     (if (file-name-absolute-p file-name-from-err-msg)
1610         (setq real-name file-name-from-err-msg)
1611       (let* ((base-dirs-count  (length base-dirs)))
1612         (while (and (not real-name) (> base-dirs-count 0))
1613           (let* ((full-name (expand-file-name file-name-from-err-msg
1614                                               (nth (1- base-dirs-count) base-dirs))))
1615             (if (file-exists-p full-name)
1616                 (setq real-name full-name))
1617             (setq base-dirs-count (1- base-dirs-count))))))
1618     real-name))
1619
1620 (defun flymake-init-find-buildfile-dir (source-file-name buildfile-name)
1621   "Find buildfile, store its dir in buffer data and return its dir, if found."
1622   (let* ((buildfile-dir
1623           (flymake-find-buildfile buildfile-name
1624                                   (file-name-directory source-file-name))))
1625     (if buildfile-dir
1626         (setq flymake-base-dir buildfile-dir)
1627       (flymake-log 1 "no buildfile (%s) for %s" buildfile-name source-file-name)
1628       (flymake-report-fatal-status
1629        "NOMK" (format "No buildfile (%s) found for %s"
1630                       buildfile-name source-file-name)))))
1631
1632 (defun flymake-init-create-temp-source-and-master-buffer-copy (get-incl-dirs-f create-temp-f master-file-masks include-regexp)
1633   "Find master file (or buffer), create its copy along with a copy of the source file."
1634   (let* ((source-file-name       buffer-file-name)
1635          (temp-source-file-name  (flymake-init-create-temp-buffer-copy create-temp-f))
1636          (master-and-temp-master (flymake-create-master-file
1637                                   source-file-name temp-source-file-name
1638                                   get-incl-dirs-f create-temp-f
1639                                   master-file-masks include-regexp)))
1640
1641     (if (not master-and-temp-master)
1642         (progn
1643           (flymake-log 1 "cannot find master file for %s" source-file-name)
1644           (flymake-report-status "!" "")        ; NOMASTER
1645           nil)
1646       (setq flymake-master-file-name (nth 0 master-and-temp-master))
1647       (setq flymake-temp-master-file-name (nth 1 master-and-temp-master)))))
1648
1649 (defun flymake-master-cleanup ()
1650   (flymake-simple-cleanup)
1651   (flymake-safe-delete-file flymake-temp-master-file-name))
1652
1653 ;;;; make-specific init-cleanup routines
1654 (defun flymake-get-syntax-check-program-args (source-file-name base-dir use-relative-base-dir use-relative-source get-cmd-line-f)
1655   "Create a command line for syntax check using GET-CMD-LINE-F."
1656   (funcall get-cmd-line-f
1657            (if use-relative-source
1658                (file-relative-name source-file-name base-dir)
1659              source-file-name)
1660            (if use-relative-base-dir
1661                (file-relative-name base-dir
1662                                    (file-name-directory source-file-name))
1663              base-dir)))
1664
1665 (defun flymake-get-make-cmdline (source base-dir)
1666   (list "make"
1667         (list "-s"
1668               "-C"
1669               base-dir
1670               (concat "CHK_SOURCES=" source)
1671               "SYNTAX_CHECK_MODE=1"
1672               "check-syntax")))
1673
1674 (defun flymake-get-ant-cmdline (source base-dir)
1675   (list "ant"
1676         (list "-buildfile"
1677               (concat base-dir "/" "build.xml")
1678               (concat "-DCHK_SOURCES=" source)
1679               "check-syntax")))
1680
1681 (defun flymake-simple-make-init-impl (create-temp-f use-relative-base-dir use-relative-source build-file-name get-cmdline-f)
1682   "Create syntax check command line for a directly checked source file.
1683 Use CREATE-TEMP-F for creating temp copy."
1684   (let* ((args nil)
1685          (source-file-name   buffer-file-name)
1686          (buildfile-dir      (flymake-init-find-buildfile-dir source-file-name build-file-name)))
1687     (if buildfile-dir
1688         (let* ((temp-source-file-name  (flymake-init-create-temp-buffer-copy create-temp-f)))
1689           (setq args (flymake-get-syntax-check-program-args temp-source-file-name buildfile-dir
1690                                                             use-relative-base-dir use-relative-source
1691                                                             get-cmdline-f))))
1692     args))
1693
1694 (defun flymake-simple-make-init ()
1695   (flymake-simple-make-init-impl 'flymake-create-temp-inplace t t "Makefile" 'flymake-get-make-cmdline))
1696
1697 (defun flymake-master-make-init (get-incl-dirs-f master-file-masks include-regexp)
1698   "Create make command line for a source file checked via master file compilation."
1699   (let* ((make-args nil)
1700          (temp-master-file-name (flymake-init-create-temp-source-and-master-buffer-copy
1701                                  get-incl-dirs-f 'flymake-create-temp-inplace
1702                                  master-file-masks include-regexp)))
1703     (when temp-master-file-name
1704       (let* ((buildfile-dir (flymake-init-find-buildfile-dir temp-master-file-name "Makefile")))
1705         (if  buildfile-dir
1706             (setq make-args (flymake-get-syntax-check-program-args
1707                              temp-master-file-name buildfile-dir nil nil 'flymake-get-make-cmdline)))))
1708     make-args))
1709
1710 (defun flymake-find-make-buildfile (source-dir)
1711   (flymake-find-buildfile "Makefile" source-dir))
1712
1713 ;;;; .h/make specific
1714 (defun flymake-master-make-header-init ()
1715   (flymake-master-make-init
1716    'flymake-get-include-dirs
1717    '("\\.\\(?:c\\(?:pp\\|xx\\|\\+\\+\\)?\\|CC\\)\\'")
1718    "[ \t]*#[ \t]*include[ \t]*\"\\([[:word:]0-9/\\_.]*%s\\)\""))
1719
1720 ;;;; .java/make specific
1721 (defun flymake-simple-make-java-init ()
1722   (flymake-simple-make-init-impl 'flymake-create-temp-with-folder-structure nil nil "Makefile" 'flymake-get-make-cmdline))
1723
1724 (defun flymake-simple-ant-java-init ()
1725   (flymake-simple-make-init-impl 'flymake-create-temp-with-folder-structure nil nil "build.xml" 'flymake-get-ant-cmdline))
1726
1727 (defun flymake-simple-java-cleanup ()
1728   "Cleanup after `flymake-simple-make-java-init' -- delete temp file and dirs."
1729   (flymake-safe-delete-file flymake-temp-source-file-name)
1730   (when flymake-temp-source-file-name
1731     (flymake-delete-temp-directory
1732      (file-name-directory flymake-temp-source-file-name))))
1733
1734 ;;;; perl-specific init-cleanup routines
1735 (defun flymake-perl-init ()
1736   (let* ((temp-file   (flymake-init-create-temp-buffer-copy
1737                        'flymake-create-temp-inplace))
1738          (local-file  (file-relative-name
1739                        temp-file
1740                        (file-name-directory buffer-file-name))))
1741     (list "perl" (list "-wc " local-file))))
1742
1743 ;;;; php-specific init-cleanup routines
1744 (defun flymake-php-init ()
1745   (let* ((temp-file   (flymake-init-create-temp-buffer-copy
1746                        'flymake-create-temp-inplace))
1747          (local-file  (file-relative-name
1748                        temp-file
1749                        (file-name-directory buffer-file-name))))
1750     (list "php" (list "-f" local-file "-l"))))
1751
1752 ;;;; tex-specific init-cleanup routines
1753 (defun flymake-get-tex-args (file-name)
1754   ;;(list "latex" (list "-c-style-errors" file-name))
1755   (list "texify" (list "--pdf" "--tex-option=-c-style-errors" file-name)))
1756
1757 (defun flymake-simple-tex-init ()
1758   (flymake-get-tex-args (flymake-init-create-temp-buffer-copy 'flymake-create-temp-inplace)))
1759
1760 ;; Perhaps there should be a buffer-local variable flymake-master-file
1761 ;; that people can set to override this stuff.  Could inherit from
1762 ;; the similar AUCTeX variable.
1763 (defun flymake-master-tex-init ()
1764   (let* ((temp-master-file-name (flymake-init-create-temp-source-and-master-buffer-copy
1765                                  'flymake-get-include-dirs-dot 'flymake-create-temp-inplace
1766                                  '("\\.tex\\'")
1767                                  "[ \t]*\\in\\(?:put\\|clude\\)[ \t]*{\\(.*%s\\)}")))
1768     (when temp-master-file-name
1769       (flymake-get-tex-args temp-master-file-name))))
1770
1771 (defun flymake-get-include-dirs-dot (_base-dir)
1772   '("."))
1773
1774 ;;;; xml-specific init-cleanup routines
1775 (defun flymake-xml-init ()
1776   (list "xml" (list "val" (flymake-init-create-temp-buffer-copy 'flymake-create-temp-inplace))))
1777
1778 (provide 'flymake)
1779
1780 ;;; flymake.el ends here