lisp/complete.el

   1 ;;; complete.el --- partial completion mechanism plus other goodies
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 1999, 2000
   4 ;;  Free Software Foundation, Inc.
   5
   6 ;; Author: Dave Gillespie <daveg@synaptics.com>
   7 ;; Keywords: abbrev convenience
   8 ;; Special thanks to Hallvard Furuseth for his many ideas and contributions.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Extended completion for the Emacs minibuffer.
  30 ;;
  31 ;; The basic idea is that the command name or other completable text is
  32 ;; divided into words and each word is completed separately, so that
  33 ;; "M-x p-b" expands to "M-x print-buffer".  If the entry is ambiguous
  34 ;; each word is completed as much as possible and then the cursor is
  35 ;; left at the first position where typing another letter will resolve
  36 ;; the ambiguity.
  37 ;;
  38 ;; Word separators for this purpose are hyphen, space, and period.
  39 ;; These would most likely occur in command names, Info menu items,
  40 ;; and file names, respectively.  But all word separators are treated
  41 ;; alike at all times.
  42 ;;
  43 ;; This completion package replaces the old-style completer's key
  44 ;; bindings for TAB, SPC, RET, and `?'.  The old completer is still
  45 ;; available on the Meta versions of those keys.  If you set
  46 ;; PC-meta-flag to nil, the old completion keys will be left alone
  47 ;; and the partial completer will use the Meta versions of the keys.
  48
  49
  50 ;; Usage:  M-x partial-completion-mode.  During completable minibuffer entry,
  51 ;;
  52 ;;     TAB    means to do a partial completion;
  53 ;;     SPC    means to do a partial complete-word;
  54 ;;     RET    means to do a partial complete-and-exit;
  55 ;;     ?      means to do a partial completion-help.
  56 ;;
  57 ;; If you set PC-meta-flag to nil, then TAB, SPC, RET, and ? perform
  58 ;; original Emacs completions, and M-TAB etc. do partial completion.
  59 ;; To do this, put the command,
  60 ;;
  61 ;;       (setq PC-meta-flag nil)
  62 ;;
  63 ;; in your .emacs file.  To load partial completion automatically, put
  64 ;;
  65 ;;       (partial-completion-mode t)
  66 ;;
  67 ;; in your .emacs file, too.  Things will be faster if you byte-compile
  68 ;; this file when you install it.
  69 ;;
  70 ;; As an extra feature, in cases where RET would not normally
  71 ;; complete (such as `C-x b'), the M-RET key will always do a partial
  72 ;; complete-and-exit.  Thus `C-x b f.c RET' will select or create a
  73 ;; buffer called "f.c", but `C-x b f.c M-RET' will select the existing
  74 ;; buffer whose name matches that pattern (perhaps "filing.c").
  75 ;; (PC-meta-flag does not affect this behavior; M-RET used to be
  76 ;; undefined in this situation.)
  77 ;;
  78 ;; The regular M-TAB (lisp-complete-symbol) command also supports
  79 ;; partial completion in this package.
  80
  81 ;; File name completion does not do partial completion of directories
  82 ;; on the path, e.g., "/u/b/f" will not complete to "/usr/bin/foo",
  83 ;; but you can put *'s in the path to accomplish this:  "/u*/b*/f".
  84 ;; Stars are required for performance reasons.
  85
  86 ;; In addition, this package includes a feature for accessing include
  87 ;; files.  For example, `C-x C-f <sys/time.h> RET' reads the file
  88 ;; /usr/include/sys/time.h.  The variable PC-include-file-path is a
  89 ;; list of directories in which to search for include files.  Completion
  90 ;; is supported in include file names.
  91
  92
  93 ;;; Code:
  94
  95 (defgroup partial-completion nil
  96   "Partial Completion of items."
  97   :prefix "pc-"
  98   :group 'minibuffer
  99   :group 'convenience)
 100
 101 (defcustom PC-first-char 'find-file
 102   "*Control how the first character of a string is to be interpreted.
 103 If nil, the first character of a string is not taken literally if it is a word
 104 delimiter, so that \".e\" matches \"*.e*\".
 105 If t, the first character of a string is always taken literally even if it is a
 106 word delimiter, so that \".e\" matches \".e*\".
 107 If non-nil and non-t, the first character is taken literally only for file name
 108 completion."
 109   :type '(choice (const :tag "delimiter" nil)
 110                  (const :tag "literal" t)
 111                  (other :tag "find-file" find-file))
 112   :group 'partial-completion)
 113
 114 (defcustom PC-meta-flag t
 115   "*If non-nil, TAB means PC completion and M-TAB means normal completion.
 116 Otherwise, TAB means normal completion and M-TAB means Partial Completion."
 117   :type 'boolean
 118   :group 'partial-completion)
 119
 120 (defcustom PC-word-delimiters "-_. "
 121   "*A string of characters treated as word delimiters for completion.
 122 Some arcane rules:
 123 If `]' is in this string, it must come first.
 124 If `^' is in this string, it must not come first.
 125 If `-' is in this string, it must come first or right after `]'.
 126 In other words, if S is this string, then `[S]' must be a legal Emacs regular
 127 expression (not containing character ranges like `a-z')."
 128   :type 'string
 129   :group 'partial-completion)
 130
 131 (defcustom PC-include-file-path '("/usr/include" "/usr/local/include")
 132   "*A list of directories in which to look for include files.
 133 If nil, means use the colon-separated path in the variable $INCPATH instead."
 134   :type '(repeat directory)
 135   :group 'partial-completion)
 136
 137 (defcustom PC-disable-includes nil
 138   "*If non-nil, include-file support in \\[find-file] is disabled."
 139   :type 'boolean
 140   :group 'partial-completion)
 141
 142 (defvar PC-default-bindings t
 143   "If non-nil, default partial completion key bindings are suppressed.")
 144
 145 (defvar PC-env-vars-alist nil
 146   "A list of the environment variable names and values.")
 147
 148 \f
 149 (defvar PC-old-read-file-name-internal nil)
 150
 151 (defun PC-bindings (bind)
 152   (let ((completion-map minibuffer-local-completion-map)
 153         (must-match-map minibuffer-local-must-match-map))
 154     (cond ((not bind)
 155            ;; These bindings are the default bindings.  It would be better to
 156            ;; restore the previous bindings.
 157            (define-key completion-map "\t"      'minibuffer-complete)
 158            (define-key completion-map " "       'minibuffer-complete-word)
 159            (define-key completion-map "?"       'minibuffer-completion-help)
 160
 161            (define-key must-match-map "\t"      'minibuffer-complete)
 162            (define-key must-match-map " "       'minibuffer-complete-word)
 163            (define-key must-match-map "\r"      'minibuffer-complete-and-exit)
 164            (define-key must-match-map "\n"      'minibuffer-complete-and-exit)
 165            (define-key must-match-map "?"       'minibuffer-completion-help)
 166
 167            (define-key global-map "\e\t"        'complete-symbol))
 168           (PC-default-bindings
 169            (define-key completion-map "\t"      'PC-complete)
 170            (define-key completion-map " "       'PC-complete-word)
 171            (define-key completion-map "?"       'PC-completion-help)
 172
 173            (define-key completion-map "\e\t"    'PC-complete)
 174            (define-key completion-map "\e "     'PC-complete-word)
 175            (define-key completion-map "\e\r"    'PC-force-complete-and-exit)
 176            (define-key completion-map "\e\n"    'PC-force-complete-and-exit)
 177            (define-key completion-map "\e?"     'PC-completion-help)
 178
 179            (define-key must-match-map "\t"      'PC-complete)
 180            (define-key must-match-map " "       'PC-complete-word)
 181            (define-key must-match-map "\r"      'PC-complete-and-exit)
 182            (define-key must-match-map "\n"      'PC-complete-and-exit)
 183            (define-key must-match-map "?"       'PC-completion-help)
 184
 185            (define-key must-match-map "\e\t"    'PC-complete)
 186            (define-key must-match-map "\e "     'PC-complete-word)
 187            (define-key must-match-map "\e\r"    'PC-complete-and-exit)
 188            (define-key must-match-map "\e\n"    'PC-complete-and-exit)
 189            (define-key must-match-map "\e?"     'PC-completion-help)
 190
 191            (define-key global-map "\e\t"        'PC-lisp-complete-symbol)))))
 192
 193 ;;;###autoload
 194 (define-minor-mode partial-completion-mode
 195   "Toggle Partial Completion mode.
 196 With prefix ARG, turn Partial Completion mode on if ARG is positive.
 197
 198 When Partial Completion mode is enabled, TAB (or M-TAB if `PC-meta-flag' is
 199 nil) is enhanced so that if some string is divided into words and each word is
 200 delimited by a character in `PC-word-delimiters', partial words are completed
 201 as much as possible and `*' characters are treated likewise in file names.
 202
 203 For example, M-x p-c-m expands to M-x partial-completion-mode since no other
 204 command begins with that sequence of characters, and
 205 \\[find-file] f_b.c TAB might complete to foo_bar.c if that file existed and no
 206 other file in that directory begin with that sequence of characters.
 207
 208 Unless `PC-disable-includes' is non-nil, the `<...>' sequence is interpreted
 209 specially in \\[find-file].  For example,
 210 \\[find-file] <sys/time.h> RET finds the file `/usr/include/sys/time.h'.
 211 See also the variable `PC-include-file-path'."
 212   :global t :group 'partial-completion
 213   ;; Deal with key bindings...
 214   (PC-bindings partial-completion-mode)
 215   ;; Deal with include file feature...
 216   (cond ((not partial-completion-mode)
 217          (remove-hook 'find-file-not-found-hooks 'PC-look-for-include-file))
 218         ((not PC-disable-includes)
 219          (add-hook 'find-file-not-found-hooks 'PC-look-for-include-file)))
 220   ;; ... with some underhand redefining.
 221   (cond ((and (not partial-completion-mode)
 222               (functionp PC-old-read-file-name-internal))
 223          (fset 'read-file-name-internal PC-old-read-file-name-internal))
 224         ((and (not PC-disable-includes) (not PC-old-read-file-name-internal))
 225          (setq PC-old-read-file-name-internal
 226                (symbol-function 'read-file-name-internal))
 227          (fset 'read-file-name-internal
 228                'PC-read-include-file-name-internal)))
 229     (when (and partial-completion-mode (null PC-env-vars-alist))
 230       (setq PC-env-vars-alist
 231             (mapcar (lambda (string)
 232                       (let ((d (string-match "=" string)))
 233                         (cons (concat "$" (substring string 0 d))
 234                               (and d (substring string (1+ d))))))
 235                     process-environment))))
 236
 237 \f
 238 (defun PC-complete ()
 239   "Like minibuffer-complete, but allows \"b--di\"-style abbreviations.
 240 For example, \"M-x b--di\" would match `byte-recompile-directory', or any
 241 name which consists of three or more words, the first beginning with \"b\"
 242 and the third beginning with \"di\".
 243
 244 The pattern \"b--d\" is ambiguous for `byte-recompile-directory' and
 245 `beginning-of-defun', so this would produce a list of completions
 246 just like when normal Emacs completions are ambiguous.
 247
 248 Word-delimiters for the purposes of Partial Completion are \"-\", \"_\",
 249 \".\", and SPC."
 250   (interactive)
 251   (if (PC-was-meta-key)
 252       (minibuffer-complete)
 253     ;; If the previous command was not this one,
 254     ;; never scroll, always retry completion.
 255     (or (eq last-command this-command)
 256         (setq minibuffer-scroll-window nil))
 257     (let ((window minibuffer-scroll-window))
 258       ;; If there's a fresh completion window with a live buffer,
 259       ;; and this command is repeated, scroll that window.
 260       (if (and window (window-buffer window)
 261                (buffer-name (window-buffer window)))
 262           (save-excursion
 263             (set-buffer (window-buffer window))
 264             (if (pos-visible-in-window-p (point-max) window)
 265                 (set-window-start window (point-min) nil)
 266               (scroll-other-window)))
 267         (PC-do-completion nil)))))
 268
 269
 270 (defun PC-complete-word ()
 271   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 272 See `PC-complete' for details.
 273 This can be bound to other keys, like `-' and `.', if you wish."
 274   (interactive)
 275   (if (eq (PC-was-meta-key) PC-meta-flag)
 276       (if (eq last-command-char ? )
 277           (minibuffer-complete-word)
 278         (self-insert-command 1))
 279     (self-insert-command 1)
 280     (if (eobp)
 281         (PC-do-completion 'word))))
 282
 283
 284 (defun PC-complete-space ()
 285   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 286 See `PC-complete' for details.
 287 This is suitable for binding to other keys which should act just like SPC."
 288   (interactive)
 289   (if (eq (PC-was-meta-key) PC-meta-flag)
 290       (minibuffer-complete-word)
 291     (insert " ")
 292     (if (eobp)
 293         (PC-do-completion 'word))))
 294
 295
 296 (defun PC-complete-and-exit ()
 297   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 298 See `PC-complete' for details."
 299   (interactive)
 300   (if (eq (PC-was-meta-key) PC-meta-flag)
 301       (minibuffer-complete-and-exit)
 302     (PC-do-complete-and-exit)))
 303
 304 (defun PC-force-complete-and-exit ()
 305   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 306 See `PC-complete' for details."
 307   (interactive)
 308   (let ((minibuffer-completion-confirm nil))
 309     (PC-do-complete-and-exit)))
 310
 311 (defun PC-do-complete-and-exit ()
 312   (if (= (point-max) (minibuffer-prompt-end))  ; Duplicate the "bug" that Info-menu relies on...
 313       (exit-minibuffer)
 314     (let ((flag (PC-do-completion 'exit)))
 315       (and flag
 316            (if (or (eq flag 'complete)
 317                    (not minibuffer-completion-confirm))
 318                (exit-minibuffer)
 319              (PC-temp-minibuffer-message " [Confirm]"))))))
 320
 321
 322 (defun PC-completion-help ()
 323   "Like `minibuffer-completion-help', but allows \"b--di\"-style abbreviations.
 324 See `PC-complete' for details."
 325   (interactive)
 326   (if (eq (PC-was-meta-key) PC-meta-flag)
 327       (minibuffer-completion-help)
 328     (PC-do-completion 'help)))
 329
 330 (defun PC-was-meta-key ()
 331   (or (/= (length (this-command-keys)) 1)
 332       (let ((key (aref (this-command-keys) 0)))
 333         (if (integerp key)
 334             (>= key 128)
 335           (not (null (memq 'meta (event-modifiers key))))))))
 336
 337
 338 (defvar PC-ignored-extensions 'empty-cache)
 339 (defvar PC-delims 'empty-cache)
 340 (defvar PC-ignored-regexp nil)
 341 (defvar PC-word-failed-flag nil)
 342 (defvar PC-delim-regex nil)
 343 (defvar PC-ndelims-regex nil)
 344 (defvar PC-delims-list nil)
 345
 346 (defvar PC-completion-as-file-name-predicate
 347   (function
 348    (lambda ()
 349      (memq minibuffer-completion-table
 350            '(read-file-name-internal read-directory-name-internal))))
 351    "A function testing whether a minibuffer completion now will work filename-style.
 352 The function takes no arguments, and typically looks at the value
 353 of `minibuffer-completion-table' and the minibuffer contents.")
 354
 355 (defun PC-do-completion (&optional mode beg end)
 356   (or beg (setq beg (minibuffer-prompt-end)))
 357   (or end (setq end (point-max)))
 358   (let* ((table minibuffer-completion-table)
 359          (pred minibuffer-completion-predicate)
 360          (filename (funcall PC-completion-as-file-name-predicate))
 361          (dirname nil)
 362          (dirlength 0)
 363          (str (buffer-substring beg end))
 364          (incname (and filename (string-match "<\\([^\"<>]*\\)>?$" str)))
 365          (ambig nil)
 366          basestr
 367          env-on
 368          regex
 369          p offset
 370          (poss nil)
 371          helpposs
 372          (case-fold-search completion-ignore-case))
 373
 374     ;; Check if buffer contents can already be considered complete
 375     (if (and (eq mode 'exit)
 376              (PC-is-complete-p str table pred))
 377         'complete
 378
 379       ;; Do substitutions in directory names
 380       (and filename
 381            (setq basestr (or (file-name-directory str) ""))
 382            (setq dirlength (length basestr))
 383            ;; Do substitutions in directory names
 384            (setq p (substitute-in-file-name basestr))
 385            (not (string-equal basestr p))
 386            (setq str (concat p (file-name-nondirectory str)))
 387            (progn
 388              (delete-region beg end)
 389              (insert str)
 390              (setq end (+ beg (length str)))))
 391
 392       ;; Prepare various delimiter strings
 393       (or (equal PC-word-delimiters PC-delims)
 394           (setq PC-delims PC-word-delimiters
 395                 PC-delim-regex (concat "[" PC-delims "]")
 396                 PC-ndelims-regex (concat "[^" PC-delims "]*")
 397                 PC-delims-list (append PC-delims nil)))
 398
 399       ;; Look for wildcard expansions in directory name
 400       (and filename
 401            (string-match "\\*.*/" str)
 402            (let ((pat str)
 403                  files)
 404              (setq p (1+ (string-match "/[^/]*\\'" pat)))
 405              (while (setq p (string-match PC-delim-regex pat p))
 406                (setq pat (concat (substring pat 0 p)
 407                                  "*"
 408                                  (substring pat p))
 409                      p (+ p 2)))
 410              (setq files (PC-expand-many-files (concat pat "*")))
 411              (if files
 412                  (let ((dir (file-name-directory (car files)))
 413                        (p files))
 414                    (while (and (setq p (cdr p))
 415                                (equal dir (file-name-directory (car p)))))
 416                    (if p
 417                        (setq filename nil table nil pred nil
 418                              ambig t)
 419                      (delete-region beg end)
 420                      (setq str (concat dir (file-name-nondirectory str)))
 421                      (insert str)
 422                      (setq end (+ beg (length str)))))
 423                (setq filename nil table nil pred nil))))
 424
 425       ;; Strip directory name if appropriate
 426       (if filename
 427           (if incname
 428               (setq basestr (substring str incname)
 429                     dirname (substring str 0 incname))
 430             (setq basestr (file-name-nondirectory str)
 431                   dirname (file-name-directory str))
 432             ;; Make sure str is consistent with its directory and basename
 433             ;; parts.  This is important on DOZe'NT systems when str only
 434             ;; includes a drive letter, like in "d:".
 435             (setq str (concat dirname basestr)))
 436         (setq basestr str))
 437
 438       ;; Convert search pattern to a standard regular expression
 439       (setq regex (regexp-quote basestr)
 440             offset (if (and (> (length regex) 0)
 441                             (not (eq (aref basestr 0) ?\*))
 442                             (or (eq PC-first-char t)
 443                                 (and PC-first-char filename))) 1 0)
 444             p offset)
 445       (while (setq p (string-match PC-delim-regex regex p))
 446         (if (eq (aref regex p) ? )
 447             (setq regex (concat (substring regex 0 p)
 448                                 PC-ndelims-regex
 449                                 PC-delim-regex
 450                                 (substring regex (1+ p)))
 451                   p (+ p (length PC-ndelims-regex) (length PC-delim-regex)))
 452           (let ((bump (if (memq (aref regex p)
 453                                 '(?$ ?^ ?\. ?* ?+ ?? ?[ ?] ?\\))
 454                           -1 0)))
 455             (setq regex (concat (substring regex 0 (+ p bump))
 456                                 PC-ndelims-regex
 457                                 (substring regex (+ p bump)))
 458                   p (+ p (length PC-ndelims-regex) 1)))))
 459       (setq p 0)
 460       (if filename
 461           (while (setq p (string-match "\\\\\\*" regex p))
 462             (setq regex (concat (substring regex 0 p)
 463                                 "[^/]*"
 464                                 (substring regex (+ p 2))))))
 465       ;;(setq the-regex regex)
 466       (setq regex (concat "\\`" regex))
 467
 468       (and (> (length basestr) 0)
 469            (= (aref basestr 0) ?$)
 470            (setq env-on t
 471                  table PC-env-vars-alist
 472                  pred nil))
 473
 474       ;; Find an initial list of possible completions
 475       (if (not (setq p (string-match (concat PC-delim-regex
 476                                              (if filename "\\|\\*" ""))
 477                                      str
 478                                      (+ (length dirname) offset))))
 479
 480           ;; Minibuffer contains no hyphens -- simple case!
 481           (setq poss (all-completions (if env-on
 482                                           basestr str)
 483                                       table
 484                                       pred))
 485
 486         ;; Use all-completions to do an initial cull.  This is a big win,
 487         ;; since all-completions is written in C!
 488         (let ((compl (all-completions (if env-on
 489                                           (file-name-nondirectory (substring str 0 p))
 490                                         (substring str 0 p))
 491                                         table
 492                                         pred)))
 493           (setq p compl)
 494           (while p
 495             (and (string-match regex (car p))
 496                  (progn
 497                    (set-text-properties 0 (length (car p)) '() (car p))
 498                    (setq poss (cons (car p) poss))))
 499             (setq p (cdr p)))))
 500
 501       ;; Now we have a list of possible completions
 502       (cond
 503
 504        ;; No valid completions found
 505        ((null poss)
 506         (if (and (eq mode 'word)
 507                  (not PC-word-failed-flag))
 508             (let ((PC-word-failed-flag t))
 509               (delete-backward-char 1)
 510               (PC-do-completion 'word))
 511           (beep)
 512           (PC-temp-minibuffer-message (if ambig
 513                                           " [Ambiguous dir name]"
 514                                         (if (eq mode 'help)
 515                                             " [No completions]"
 516                                           " [No match]")))
 517           nil))
 518
 519        ;; More than one valid completion found
 520        ((or (cdr (setq helpposs poss))
 521             (memq mode '(help word)))
 522
 523         ;; Handle completion-ignored-extensions
 524         (and filename
 525              (not (eq mode 'help))
 526              (let ((p2 poss))
 527
 528                ;; Build a regular expression representing the extensions list
 529                (or (equal completion-ignored-extensions PC-ignored-extensions)
 530                    (setq PC-ignored-regexp
 531                          (concat "\\("
 532                                  (mapconcat
 533                                   'regexp-quote
 534                                   (setq PC-ignored-extensions
 535                                         completion-ignored-extensions)
 536                                   "\\|")
 537                                  "\\)\\'")))
 538
 539                ;; Check if there are any without an ignored extension.
 540                ;; Also ignore `.' and `..'.
 541                (setq p nil)
 542                (while p2
 543                  (or (string-match PC-ignored-regexp (car p2))
 544                      (string-match "\\(\\`\\|/\\)[.][.]?/?\\'" (car p2))
 545                      (setq p (cons (car p2) p)))
 546                  (setq p2 (cdr p2)))
 547
 548                ;; If there are "good" names, use them
 549                (and p (setq poss p))))
 550
 551         ;; Is the actual string one of the possible completions?
 552         (setq p (and (not (eq mode 'help)) poss))
 553         (while (and p
 554                     (not (string-equal (car p) basestr)))
 555           (setq p (cdr p)))
 556         (and p (null mode)
 557              (PC-temp-minibuffer-message " [Complete, but not unique]"))
 558         (if (and p
 559                  (not (and (null mode)
 560                            (eq this-command last-command))))
 561             t
 562
 563           ;; If ambiguous, try for a partial completion
 564           (let ((improved nil)
 565                 prefix
 566                 (pt nil)
 567                 (skip "\\`"))
 568
 569             ;; Check if next few letters are the same in all cases
 570             (if (and (not (eq mode 'help))
 571                      (setq prefix (try-completion "" (mapcar 'list poss))))
 572                 (let ((first t) i)
 573                   (if (eq mode 'word)
 574                       (setq prefix (PC-chop-word prefix basestr)))
 575                   (goto-char (+ beg (length dirname)))
 576                   (while (and (progn
 577                                 (setq i 0)
 578                                 (while (< i (length prefix))
 579                                   (if (and (< (point) end)
 580                                            (eq (aref prefix i)
 581                                                (following-char)))
 582                                       (forward-char 1)
 583                                     (if (and (< (point) end)
 584                                              (or (and (looking-at " ")
 585                                                       (memq (aref prefix i)
 586                                                             PC-delims-list))
 587                                                  (eq (downcase (aref prefix i))
 588                                                      (downcase
 589                                                       (following-char)))))
 590                                         (progn
 591                                           (delete-char 1)
 592                                           (setq end (1- end)))
 593                                       (and filename (looking-at "\\*")
 594                                            (progn
 595                                              (delete-char 1)
 596                                              (setq end (1- end))))
 597                                       (setq improved t))
 598                                     (insert (substring prefix i (1+ i)))
 599                                     (setq end (1+ end)))
 600                                   (setq i (1+ i)))
 601                                 (or pt (equal (point) beg)
 602                                     (setq pt (point)))
 603                                 (looking-at PC-delim-regex))
 604                               (setq skip (concat skip
 605                                                  (regexp-quote prefix)
 606                                                  PC-ndelims-regex)
 607                                     prefix (try-completion
 608                                             ""
 609                                             (mapcar
 610                                              (function
 611                                               (lambda (x)
 612                                                 (list
 613                                                  (and (string-match skip x)
 614                                                       (substring
 615                                                        x
 616                                                        (match-end 0))))))
 617                                              poss)))
 618                               (or (> i 0) (> (length prefix) 0))
 619                               (or (not (eq mode 'word))
 620                                   (and first (> (length prefix) 0)
 621                                        (setq first nil
 622                                              prefix (substring prefix 0 1))))))
 623                   (goto-char (if (eq mode 'word) end
 624                                (or pt beg)))))
 625
 626             (if (and (eq mode 'word)
 627                      (not PC-word-failed-flag))
 628
 629                 (if improved
 630
 631                     ;; We changed it... would it be complete without the space?
 632                     (if (PC-is-complete-p (buffer-substring 1 (1- end))
 633                                           table pred)
 634                         (delete-region (1- end) end)))
 635
 636               (if improved
 637
 638                   ;; We changed it... enough to be complete?
 639                   (and (eq mode 'exit)
 640                        (PC-is-complete-p (field-string) table pred))
 641
 642                 ;; If totally ambiguous, display a list of completions
 643                 (if (or (eq completion-auto-help t)
 644                         (and completion-auto-help
 645                              (eq last-command this-command))
 646                         (eq mode 'help))
 647                     (with-output-to-temp-buffer "*Completions*"
 648                       (display-completion-list (sort helpposs 'string-lessp))
 649                       (save-excursion
 650                         (set-buffer standard-output)
 651                         ;; Record which part of the buffer we are completing
 652                         ;; so that choosing a completion from the list
 653                         ;; knows how much old text to replace.
 654                         (setq completion-base-size dirlength)))
 655                   (PC-temp-minibuffer-message " [Next char not unique]"))
 656                 nil)))))
 657
 658        ;; Only one possible completion
 659        (t
 660         (if (and (equal basestr (car poss))
 661                  (not (and env-on filename)))
 662             (if (null mode)
 663                 (PC-temp-minibuffer-message " [Sole completion]"))
 664           (delete-region beg end)
 665           (insert (format "%s"
 666                           (if filename
 667                               (substitute-in-file-name (concat dirname (car poss)))
 668                             (car poss)))))
 669         t)))))
 670
 671
 672 (defun PC-is-complete-p (str table pred)
 673   (let ((res (if (listp table)
 674                  (assoc str table)
 675                (if (vectorp table)
 676                    (or (equal str "nil")   ; heh, heh, heh
 677                        (intern-soft str table))
 678                  (funcall table str pred 'lambda)))))
 679     (and res
 680          (or (not pred)
 681              (and (not (listp table)) (not (vectorp table)))
 682              (funcall pred res))
 683          res)))
 684
 685 (defun PC-chop-word (new old)
 686   (let ((i -1)
 687         (j -1))
 688     (while (and (setq i (string-match PC-delim-regex old (1+ i)))
 689                 (setq j (string-match PC-delim-regex new (1+ j)))))
 690     (if (and j
 691              (or (not PC-word-failed-flag)
 692                  (setq j (string-match PC-delim-regex new (1+ j)))))
 693         (substring new 0 (1+ j))
 694       new)))
 695
 696 (defvar PC-not-minibuffer nil)
 697
 698 (defun PC-temp-minibuffer-message (message)
 699   "A Lisp version of `temp_minibuffer_message' from minibuf.c."
 700   (cond (PC-not-minibuffer
 701          (message message)
 702          (sit-for 2)
 703          (message ""))
 704         ((fboundp 'temp-minibuffer-message)
 705          (temp-minibuffer-message message))
 706         (t
 707          (let ((point-max (point-max)))
 708            (save-excursion
 709              (goto-char point-max)
 710              (insert message))
 711            (let ((inhibit-quit t))
 712              (sit-for 2)
 713              (delete-region point-max (point-max))
 714              (when quit-flag
 715                (setq quit-flag nil
 716                      unread-command-events '(7))))))))
 717
 718
 719 (defun PC-lisp-complete-symbol ()
 720   "Perform completion on Lisp symbol preceding point.
 721 That symbol is compared against the symbols that exist
 722 and any additional characters determined by what is there
 723 are inserted.
 724 If the symbol starts just after an open-parenthesis,
 725 only symbols with function definitions are considered.
 726 Otherwise, all symbols with function definitions, values
 727 or properties are considered."
 728   (interactive)
 729   (let* ((end (point))
 730          (buffer-syntax (syntax-table))
 731          (beg (unwind-protect
 732                   (save-excursion
 733                     (if lisp-mode-syntax-table
 734                         (set-syntax-table lisp-mode-syntax-table))
 735                     (backward-sexp 1)
 736                     (while (= (char-syntax (following-char)) ?\')
 737                       (forward-char 1))
 738                     (point))
 739                 (set-syntax-table buffer-syntax)))
 740          (minibuffer-completion-table obarray)
 741          (minibuffer-completion-predicate
 742           (if (eq (char-after (1- beg)) ?\()
 743               'fboundp
 744             (function (lambda (sym)
 745                         (or (boundp sym) (fboundp sym)
 746                             (symbol-plist sym))))))
 747          (PC-not-minibuffer t))
 748     (PC-do-completion nil beg end)))
 749
 750 (defun PC-complete-as-file-name ()
 751    "Perform completion on file names preceding point.
 752  Environment vars are converted to their values."
 753    (interactive)
 754    (let* ((end (point))
 755           (beg (if (re-search-backward "[^\\][ \t\n\"\`\'][^ \t\n\"\`\']"
 756                                        (point-min) t)
 757                    (+ (point) 2)
 758                    (point-min)))
 759           (minibuffer-completion-table 'read-file-name-internal)
 760           (minibuffer-completion-predicate "")
 761           (PC-not-minibuffer t))
 762      (goto-char end)
 763      (PC-do-completion nil beg end)))
 764
 765 ;;; Use the shell to do globbing.
 766 ;;; This could now use file-expand-wildcards instead.
 767
 768 (defun PC-expand-many-files (name)
 769   (save-excursion
 770     (set-buffer (generate-new-buffer " *Glob Output*"))
 771     (erase-buffer)
 772     (shell-command (concat "echo " name) t)
 773     (goto-char (point-min))
 774     (if (looking-at ".*No match")
 775         nil
 776       (insert "(\"")
 777       (while (search-forward " " nil t)
 778         (delete-backward-char 1)
 779         (insert "\" \""))
 780       (goto-char (point-max))
 781       (delete-backward-char 1)
 782       (insert "\")")
 783       (goto-char (point-min))
 784       (let ((files (read (current-buffer))) (p nil))
 785         (kill-buffer (current-buffer))
 786         (or (equal completion-ignored-extensions PC-ignored-extensions)
 787             (setq PC-ignored-regexp
 788                   (concat "\\("
 789                           (mapconcat
 790                            'regexp-quote
 791                            (setq PC-ignored-extensions
 792                                  completion-ignored-extensions)
 793                            "\\|")
 794                           "\\)\\'")))
 795         (setq p nil)
 796         (while files
 797           (or (string-match PC-ignored-regexp (car files))
 798               (setq p (cons (car files) p)))
 799           (setq files (cdr files)))
 800         p))))
 801
 802 ;;; Facilities for loading C header files.  This is independent from the
 803 ;;; main completion code.  See also the variable `PC-include-file-path'
 804 ;;; at top of this file.
 805
 806 (defun PC-look-for-include-file ()
 807   (if (string-match "[\"<]\\([^\"<>]*\\)[\">]?$" (buffer-file-name))
 808       (let ((name (substring (buffer-file-name)
 809                              (match-beginning 1) (match-end 1)))
 810             (punc (aref (buffer-file-name) (match-beginning 0)))
 811             (path nil)
 812             new-buf)
 813         (kill-buffer (current-buffer))
 814         (if (equal name "")
 815             (save-excursion
 816               (set-buffer (car (buffer-list)))
 817               (save-excursion
 818                 (beginning-of-line)
 819                 (if (looking-at
 820                      "[ \t]*#[ \t]*include[ \t]+[<\"]\\(.+\\)[>\"][ \t]*[\n/]")
 821                     (setq name (buffer-substring (match-beginning 1)
 822                                                  (match-end 1))
 823                           punc (char-after (1- (match-beginning 1))))
 824                   ;; Suggested by Frank Siebenlist:
 825                   (if (or (looking-at
 826                            "[ \t]*([ \t]*load[ \t]+\"\\([^\"]+\\)\"")
 827                           (looking-at
 828                            "[ \t]*([ \t]*load-library[ \t]+\"\\([^\"]+\\)\"")
 829                           (looking-at
 830                            "[ \t]*([ \t]*require[ \t]+'\\([^\t )]+\\)[\t )]"))
 831                       (progn
 832                         (setq name (buffer-substring (match-beginning 1)
 833                                                      (match-end 1))
 834                               punc ?\<
 835                               path load-path)
 836                         (if (string-match "\\.elc$" name)
 837                             (setq name (substring name 0 -1))
 838                           (or (string-match "\\.el$" name)
 839                               (setq name (concat name ".el")))))
 840                     (error "Not on an #include line"))))))
 841         (or (string-match "\\.[[:alnum:]]+$" name)
 842             (setq name (concat name ".h")))
 843         (if (eq punc ?\<)
 844             (let ((path (or path (PC-include-file-path))))
 845               (while (and path
 846                           (not (file-exists-p
 847                                 (concat (file-name-as-directory (car path))
 848                                         name))))
 849                 (setq path (cdr path)))
 850               (if path
 851                   (setq name (concat (file-name-as-directory (car path)) name))
 852                 (error "No such include file: <%s>" name)))
 853           (let ((dir (save-excursion
 854                        (set-buffer (car (buffer-list)))
 855                        default-directory)))
 856             (if (file-exists-p (concat dir name))
 857                 (setq name (concat dir name))
 858               (error "No such include file: `%s'" name))))
 859         (setq new-buf (get-file-buffer name))
 860         (if new-buf
 861             ;; no need to verify last-modified time for this!
 862             (set-buffer new-buf)
 863           (setq new-buf (create-file-buffer name))
 864           (set-buffer new-buf)
 865           (erase-buffer)
 866           (insert-file-contents name t))
 867         ;; Returning non-nil with the new buffer current
 868         ;; is sufficient to tell find-file to use it.
 869         t)
 870     nil))
 871
 872 (defun PC-include-file-path ()
 873   (or PC-include-file-path
 874       (let ((env (getenv "INCPATH"))
 875             (path nil)
 876             pos)
 877         (or env (error "No include file path specified"))
 878         (while (setq pos (string-match ":[^:]+$" env))
 879           (setq path (cons (substring env (1+ pos)) path)
 880                 env (substring env 0 pos)))
 881         path)))
 882
 883 ;;; This is adapted from lib-complete.el, by Mike Williams.
 884 (defun PC-include-file-all-completions (file search-path &optional full)
 885   "Return all completions for FILE in any directory on SEARCH-PATH.
 886 If optional third argument FULL is non-nil, returned pathnames should be
 887 absolute rather than relative to some directory on the SEARCH-PATH."
 888   (setq search-path
 889         (mapcar (lambda (dir)
 890                   (if dir (file-name-as-directory dir) default-directory))
 891                 search-path))
 892   (if (file-name-absolute-p file)
 893       ;; It's an absolute file name, so don't need search-path
 894       (progn
 895         (setq file (expand-file-name file))
 896         (file-name-all-completions
 897          (file-name-nondirectory file) (file-name-directory file)))
 898     (let ((subdir (file-name-directory file))
 899           (ndfile (file-name-nondirectory file))
 900           file-lists)
 901       ;; Append subdirectory part to each element of search-path
 902       (if subdir
 903           (setq search-path
 904                 (mapcar (lambda (dir) (concat dir subdir))
 905                         search-path)
 906                 file ))
 907       ;; Make list of completions in each directory on search-path
 908       (while search-path
 909         (let* ((dir (car search-path))
 910                (subdir (if full dir subdir)))
 911           (if (file-directory-p dir)
 912               (progn
 913                 (setq file-lists
 914                       (cons
 915                        (mapcar (lambda (file) (concat subdir file))
 916                                (file-name-all-completions ndfile
 917                                                           (car search-path)))
 918                        file-lists))))
 919           (setq search-path (cdr search-path))))
 920       ;; Compress out duplicates while building complete list (slloooow!)
 921       (let ((sorted (sort (apply 'nconc file-lists)
 922                           (lambda (x y) (not (string-lessp x y)))))
 923             compressed)
 924         (while sorted
 925           (if (equal (car sorted) (car compressed)) nil
 926             (setq compressed (cons (car sorted) compressed)))
 927           (setq sorted (cdr sorted)))
 928         compressed))))
 929
 930 (defun PC-read-include-file-name-internal (string dir action)
 931   (if (string-match "<\\([^\"<>]*\\)>?$" string)
 932       (let* ((name (substring string (match-beginning 1) (match-end 1)))
 933              (str2 (substring string (match-beginning 0)))
 934              (completion-table
 935               (mapcar (function (lambda (x) (list (format "<%s>" x))))
 936                       (PC-include-file-all-completions
 937                        name (PC-include-file-path)))))
 938         (cond
 939          ((not completion-table) nil)
 940          ((eq action nil) (try-completion str2 completion-table nil))
 941          ((eq action t) (all-completions str2 completion-table nil))
 942          ((eq action 'lambda)
 943           (eq (try-completion str2 completion-table nil) t))))
 944     (funcall PC-old-read-file-name-internal string dir action)))
 945 \f
 946
 947 (provide 'complete)
 948
 949 ;;; complete.el ends here