lisp/abbrev.el

   1 ;;; abbrev.el --- abbrev mode commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1992 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: abbrev convenience
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This facility is documented in the Emacs Manual.
  28
  29 ;;; Code:
  30
  31 (defcustom only-global-abbrevs nil
  32   "*t means user plans to use global abbrevs only.
  33 This makes the commands that normally define mode-specific abbrevs
  34 define global abbrevs instead."
  35   :type 'boolean
  36   :group 'abbrev-mode
  37   :group 'convenience)
  38
  39 (defun abbrev-mode (&optional arg)
  40   "Toggle abbrev mode.
  41 With argument ARG, turn abbrev mode on iff ARG is positive.
  42 In abbrev mode, inserting an abbreviation causes it to expand
  43 and be replaced by its expansion."
  44   (interactive "P")
  45   (setq abbrev-mode
  46         (if (null arg) (not abbrev-mode)
  47           (> (prefix-numeric-value arg) 0)))
  48   (force-mode-line-update))
  49
  50 (defcustom abbrev-mode nil
  51   "Toggle abbrev mode.
  52 Non-nil means automatically expand abbrevs as they are inserted.
  53
  54 Changing it with \\[customize] sets the default value.
  55 Use the command `abbrev-mode' to enable or disable Abbrev mode in the current
  56 buffer."
  57   :type 'boolean
  58   :group 'abbrev-mode)
  59
  60 \f
  61 (defvar edit-abbrevs-map nil
  62   "Keymap used in edit-abbrevs.")
  63 (if edit-abbrevs-map
  64     nil
  65   (setq edit-abbrevs-map (make-sparse-keymap))
  66   (define-key edit-abbrevs-map "\C-x\C-s" 'edit-abbrevs-redefine)
  67   (define-key edit-abbrevs-map "\C-c\C-c" 'edit-abbrevs-redefine))
  68
  69 (defun kill-all-abbrevs ()
  70   "Undefine all defined abbrevs."
  71   (interactive)
  72   (let ((tables abbrev-table-name-list))
  73     (while tables
  74       (clear-abbrev-table (symbol-value (car tables)))
  75       (setq tables (cdr tables)))))
  76
  77 (defun insert-abbrevs ()
  78   "Insert after point a description of all defined abbrevs.
  79 Mark is set after the inserted text."
  80   (interactive)
  81   (push-mark
  82    (save-excursion
  83     (let ((tables abbrev-table-name-list))
  84       (while tables
  85         (insert-abbrev-table-description (car tables) t)
  86         (setq tables (cdr tables))))
  87     (point))))
  88
  89 (defun list-abbrevs (&optional local)
  90   "Display a list of defined abbrevs.
  91 If LOCAL is non-nil, interactively when invoked with a
  92 prefix arg, display only local, i.e. mode-specific, abbrevs.
  93 Otherwise display all abbrevs."
  94   (interactive "P")
  95   (display-buffer (prepare-abbrev-list-buffer local)))
  96
  97 (defun abbrev-table-name (table)
  98   "Value is the name of abbrev table TABLE."
  99   (let ((tables abbrev-table-name-list)
 100         found)
 101     (while (and (not found) tables)
 102       (when (eq (symbol-value (car tables)) table)
 103         (setq found (car tables)))
 104       (setq tables (cdr tables)))
 105     found))
 106
 107 (defun prepare-abbrev-list-buffer (&optional local)
 108   (save-excursion
 109     (let ((table local-abbrev-table))
 110       (set-buffer (get-buffer-create "*Abbrevs*"))
 111       (erase-buffer)
 112       (if local
 113           (insert-abbrev-table-description (abbrev-table-name table) t)
 114         (dolist (table abbrev-table-name-list)
 115           (insert-abbrev-table-description table t)))
 116       (goto-char (point-min))
 117       (set-buffer-modified-p nil)
 118       (edit-abbrevs-mode)
 119       (current-buffer))))
 120
 121 (defun edit-abbrevs-mode ()
 122   "Major mode for editing the list of abbrev definitions.
 123 \\{edit-abbrevs-map}"
 124   (interactive)
 125   (setq major-mode 'edit-abbrevs-mode)
 126   (setq mode-name "Edit-Abbrevs")
 127   (use-local-map edit-abbrevs-map))
 128
 129 (defun edit-abbrevs ()
 130   "Alter abbrev definitions by editing a list of them.
 131 Selects a buffer containing a list of abbrev definitions.
 132 You can edit them and type \\<edit-abbrevs-map>\\[edit-abbrevs-redefine] to redefine abbrevs
 133 according to your editing.
 134 Buffer contains a header line for each abbrev table,
 135  which is the abbrev table name in parentheses.
 136 This is followed by one line per abbrev in that table:
 137 NAME   USECOUNT   EXPANSION   HOOK
 138 where NAME and EXPANSION are strings with quotes,
 139 USECOUNT is an integer, and HOOK is any valid function
 140 or may be omitted (it is usually omitted)."
 141   (interactive)
 142   (switch-to-buffer (prepare-abbrev-list-buffer)))
 143
 144 (defun edit-abbrevs-redefine ()
 145   "Redefine abbrevs according to current buffer contents."
 146   (interactive)
 147   (define-abbrevs t)
 148   (set-buffer-modified-p nil))
 149
 150 (defun define-abbrevs (&optional arg)
 151   "Define abbrevs according to current visible buffer contents.
 152 See documentation of `edit-abbrevs' for info on the format of the
 153 text you must have in the buffer.
 154 With argument, eliminate all abbrev definitions except
 155 the ones defined from the buffer now."
 156   (interactive "P")
 157   (if arg (kill-all-abbrevs))
 158   (save-excursion
 159    (goto-char (point-min))
 160    (while (and (not (eobp)) (re-search-forward "^(" nil t))
 161      (let* ((buf (current-buffer))
 162             (table (read buf))
 163             abbrevs name hook exp count)
 164        (forward-line 1)
 165        (while (progn (forward-line 1)
 166                      (not (eolp)))
 167          (setq name (read buf) count (read buf) exp (read buf))
 168          (skip-chars-backward " \t\n\f")
 169          (setq hook (if (not (eolp)) (read buf)))
 170          (skip-chars-backward " \t\n\f")
 171          (setq abbrevs (cons (list name exp hook count) abbrevs)))
 172        (define-abbrev-table table abbrevs)))))
 173
 174 (defun read-abbrev-file (&optional file quietly)
 175   "Read abbrev definitions from file written with `write-abbrev-file'.
 176 Optional argument FILE is the name of the file to read;
 177 it defaults to the value of `abbrev-file-name'.
 178 Optional second argument QUIETLY non-nil means don't display a message."
 179   (interactive "fRead abbrev file: ")
 180   (load (if (and file (> (length file) 0)) file abbrev-file-name)
 181         nil quietly)
 182   (setq abbrevs-changed nil))
 183
 184 (defun quietly-read-abbrev-file (&optional file)
 185   "Read abbrev definitions from file written with write-abbrev-file.
 186 Optional argument FILE is the name of the file to read;
 187 it defaults to the value of `abbrev-file-name'.
 188 Does not display any message."
 189   ;(interactive "fRead abbrev file: ")
 190   (read-abbrev-file file t))
 191
 192 (defun write-abbrev-file (file)
 193   "Write all abbrev definitions to a file of Lisp code.
 194 The file written can be loaded in another session to define the same abbrevs.
 195 The argument FILE is the file name to write."
 196   (interactive
 197    (list
 198     (read-file-name "Write abbrev file: "
 199                     (file-name-directory (expand-file-name abbrev-file-name))
 200                     abbrev-file-name)))
 201   (or (and file (> (length file) 0))
 202       (setq file abbrev-file-name))
 203   (save-excursion
 204    (set-buffer (get-buffer-create " write-abbrev-file"))
 205    (erase-buffer)
 206    (let ((tables abbrev-table-name-list))
 207      (while tables
 208        (insert-abbrev-table-description (car tables) nil)
 209        (setq tables (cdr tables))))
 210    (write-region 1 (point-max) file)
 211    (erase-buffer)))
 212 \f
 213 (defun add-mode-abbrev (arg)
 214   "Define mode-specific abbrev for last word(s) before point.
 215 Argument is how many words before point form the expansion;
 216 or zero means the region is the expansion.
 217 A negative argument means to undefine the specified abbrev.
 218 Reads the abbreviation in the minibuffer.
 219
 220 Don't use this function in a Lisp program; use `define-abbrev' instead."
 221   (interactive "p")
 222   (add-abbrev
 223    (if only-global-abbrevs
 224        global-abbrev-table
 225      (or local-abbrev-table
 226          (error "No per-mode abbrev table")))
 227    "Mode" arg))
 228
 229 (defun add-global-abbrev (arg)
 230   "Define global (all modes) abbrev for last word(s) before point.
 231 The prefix argument specifies the number of words before point that form the
 232 expansion; or zero means the region is the expansion.
 233 A negative argument means to undefine the specified abbrev.
 234 This command uses the minibuffer to read the abbreviation.
 235
 236 Don't use this function in a Lisp program; use `define-abbrev' instead."
 237   (interactive "p")
 238   (add-abbrev global-abbrev-table "Global" arg))
 239
 240 (defun add-abbrev (table type arg)
 241   (let ((exp (and (>= arg 0)
 242                   (buffer-substring-no-properties
 243                    (point)
 244                    (if (= arg 0) (mark)
 245                      (save-excursion (forward-word (- arg)) (point))))))
 246         name)
 247     (setq name
 248           (read-string (format (if exp "%s abbrev for \"%s\": "
 249                                  "Undefine %s abbrev: ")
 250                                type exp)))
 251     (set-text-properties 0 (length name) nil name)
 252     (if (or (null exp)
 253             (not (abbrev-expansion name table))
 254             (y-or-n-p (format "%s expands to \"%s\"; redefine? "
 255                               name (abbrev-expansion name table))))
 256         (define-abbrev table (downcase name) exp))))
 257
 258 (defun inverse-add-mode-abbrev (arg)
 259   "Define last word before point as a mode-specific abbrev.
 260 With prefix argument N, defines the Nth word before point.
 261 This command uses the minibuffer to read the expansion.
 262 Expands the abbreviation after defining it."
 263   (interactive "p")
 264   (inverse-add-abbrev
 265    (if only-global-abbrevs
 266        global-abbrev-table
 267      (or local-abbrev-table
 268          (error "No per-mode abbrev table")))
 269    "Mode" arg))
 270
 271 (defun inverse-add-global-abbrev (arg)
 272   "Define last word before point as a global (mode-independent) abbrev.
 273 With prefix argument N, defines the Nth word before point.
 274 This command uses the minibuffer to read the expansion.
 275 Expands the abbreviation after defining it."
 276   (interactive "p")
 277   (inverse-add-abbrev global-abbrev-table "Global" arg))
 278
 279 (defun inverse-add-abbrev (table type arg)
 280   (let (name exp start end)
 281     (save-excursion
 282       (forward-word (1+ (- arg)))
 283       (setq end (point))
 284       (backward-word 1)
 285       (setq start (point)
 286             name (buffer-substring-no-properties start end)))
 287
 288     (setq exp (read-string (format "%s expansion for \"%s\": " type name)
 289                            nil nil nil t))
 290     (when (or (not (abbrev-expansion name table))
 291               (y-or-n-p (format "%s expands to \"%s\"; redefine? "
 292                                 name (abbrev-expansion name table))))
 293       (define-abbrev table (downcase name) exp)
 294       (save-excursion
 295         (goto-char end)
 296         (expand-abbrev)))))
 297
 298 (defun abbrev-prefix-mark (&optional arg)
 299   "Mark current point as the beginning of an abbrev.
 300 Abbrev to be expanded starts here rather than at beginning of word.
 301 This way, you can expand an abbrev with a prefix: insert the prefix,
 302 use this command, then insert the abbrev."
 303   (interactive "P")
 304   (or arg (expand-abbrev))
 305   (setq abbrev-start-location (point-marker)
 306         abbrev-start-location-buffer (current-buffer))
 307   (insert "-"))
 308
 309 (defun expand-region-abbrevs (start end &optional noquery)
 310   "For abbrev occurrence in the region, offer to expand it.
 311 The user is asked to type y or n for each occurrence.
 312 A prefix argument means don't query; expand all abbrevs.
 313 If called from a Lisp program, arguments are START END &optional NOQUERY."
 314   (interactive "r\nP")
 315   (save-excursion
 316     (goto-char start)
 317     (let ((lim (- (point-max) end))
 318           pnt string)
 319       (while (and (not (eobp))
 320                   (progn (forward-word 1)
 321                          (<= (setq pnt (point)) (- (point-max) lim))))
 322         (if (abbrev-expansion
 323              (setq string
 324                    (buffer-substring-no-properties
 325                     (save-excursion (forward-word -1) (point))
 326                     pnt)))
 327             (if (or noquery (y-or-n-p (format "Expand `%s'? " string)))
 328                 (expand-abbrev)))))))
 329
 330 ;;; abbrev.el ends here