lisp/outline.el

   1 ;;; outline.el --- outline mode commands for Emacs
   2
   3 ;; Copyright (C) 1986, 1993-1995, 1997, 2000-2013 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: outlines
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This package is a major mode for editing outline-format documents.
  27 ;; An outline can be `abstracted' to show headers at any given level,
  28 ;; with all stuff below hidden.  See the Emacs manual for details.
  29
  30 ;;; Todo:
  31
  32 ;; - subtree-terminators
  33 ;; - better handle comments before function bodies (i.e. heading)
  34 ;; - don't bother hiding whitespace
  35
  36 ;;; Code:
  37
  38 (defvar font-lock-warning-face)
  39
  40
  41 (defgroup outlines nil
  42   "Support for hierarchical outlining."
  43   :prefix "outline-"
  44   :group 'wp)
  45
  46 (defcustom outline-regexp "[*\^L]+"
  47   "Regular expression to match the beginning of a heading.
  48 Any line whose beginning matches this regexp is considered to start a heading.
  49 Note that Outline mode only checks this regexp at the start of a line,
  50 so the regexp need not (and usually does not) start with `^'.
  51 The recommended way to set this is with a Local Variables: list
  52 in the file it applies to.  See also `outline-heading-end-regexp'."
  53   :type 'regexp
  54   :group 'outlines)
  55 ;;;###autoload(put 'outline-regexp 'safe-local-variable 'stringp)
  56
  57 (defcustom outline-heading-end-regexp "\n"
  58   "Regular expression to match the end of a heading line.
  59 You can assume that point is at the beginning of a heading when this
  60 regexp is searched for.  The heading ends at the end of the match.
  61 The recommended way to set this is with a `Local Variables:' list
  62 in the file it applies to."
  63   :type 'regexp
  64   :group 'outlines)
  65 ;;;###autoload(put 'outline-heading-end-regexp 'safe-local-variable 'stringp)
  66
  67 (defvar outline-mode-prefix-map
  68   (let ((map (make-sparse-keymap)))
  69     (define-key map "@" 'outline-mark-subtree)
  70     (define-key map "\C-n" 'outline-next-visible-heading)
  71     (define-key map "\C-p" 'outline-previous-visible-heading)
  72     (define-key map "\C-i" 'show-children)
  73     (define-key map "\C-s" 'show-subtree)
  74     (define-key map "\C-d" 'hide-subtree)
  75     (define-key map "\C-u" 'outline-up-heading)
  76     (define-key map "\C-f" 'outline-forward-same-level)
  77     (define-key map "\C-b" 'outline-backward-same-level)
  78     (define-key map "\C-t" 'hide-body)
  79     (define-key map "\C-a" 'show-all)
  80     (define-key map "\C-c" 'hide-entry)
  81     (define-key map "\C-e" 'show-entry)
  82     (define-key map "\C-l" 'hide-leaves)
  83     (define-key map "\C-k" 'show-branches)
  84     (define-key map "\C-q" 'hide-sublevels)
  85     (define-key map "\C-o" 'hide-other)
  86     (define-key map "\C-^" 'outline-move-subtree-up)
  87     (define-key map "\C-v" 'outline-move-subtree-down)
  88     (define-key map [(control ?<)] 'outline-promote)
  89     (define-key map [(control ?>)] 'outline-demote)
  90     (define-key map "\C-m" 'outline-insert-heading)
  91     ;; Where to bind outline-cycle ?
  92     map))
  93
  94 (defvar outline-mode-menu-bar-map
  95   (let ((map (make-sparse-keymap)))
  96
  97     (define-key map [hide] (cons "Hide" (make-sparse-keymap "Hide")))
  98
  99     (define-key map [hide hide-other]
 100       '(menu-item "Hide Other" hide-other
 101                   :help "Hide everything except current body and parent and top-level headings"))
 102     (define-key map [hide hide-sublevels]
 103       '(menu-item "Hide Sublevels" hide-sublevels
 104                   :help "Hide everything but the top LEVELS levels of headers, in whole buffer"))
 105     (define-key map [hide hide-subtree]
 106       '(menu-item "Hide Subtree" hide-subtree
 107                   :help "Hide everything after this heading at deeper levels"))
 108     (define-key map [hide hide-entry]
 109       '(menu-item "Hide Entry" hide-entry
 110                   :help "Hide the body directly following this heading"))
 111     (define-key map [hide hide-body]
 112       '(menu-item "Hide Body" hide-body
 113                   :help "Hide all body lines in buffer, leaving all headings visible"))
 114     (define-key map [hide hide-leaves]
 115       '(menu-item "Hide Leaves" hide-leaves
 116                   :help "Hide the body after this heading and at deeper levels"))
 117
 118     (define-key map [show] (cons "Show" (make-sparse-keymap "Show")))
 119
 120     (define-key map [show show-subtree]
 121       '(menu-item "Show Subtree" show-subtree
 122                   :help "Show everything after this heading at deeper levels"))
 123     (define-key map [show show-children]
 124       '(menu-item "Show Children" show-children
 125                   :help "Show all direct subheadings of this heading"))
 126     (define-key map [show show-branches]
 127       '(menu-item "Show Branches" show-branches
 128                   :help "Show all subheadings of this heading, but not their bodies"))
 129     (define-key map [show show-entry]
 130       '(menu-item "Show Entry" show-entry
 131                   :help "Show the body directly following this heading"))
 132     (define-key map [show show-all]
 133       '(menu-item "Show All" show-all
 134                   :help "Show all of the text in the buffer"))
 135
 136     (define-key map [headings]
 137       (cons "Headings" (make-sparse-keymap "Headings")))
 138
 139     (define-key map [headings demote-subtree]
 140       '(menu-item "Demote Subtree" outline-demote
 141                   :help "Demote headings lower down the tree"))
 142     (define-key map [headings promote-subtree]
 143       '(menu-item "Promote Subtree" outline-promote
 144                   :help "Promote headings higher up the tree"))
 145     (define-key map [headings move-subtree-down]
 146       '(menu-item "Move Subtree Down" outline-move-subtree-down
 147                   :help "Move the current subtree down past arg headlines of the same level"))
 148     (define-key map [headings move-subtree-up]
 149       '(menu-item "Move Subtree Up" outline-move-subtree-up
 150                   :help "Move the current subtree up past arg headlines of the same level"))
 151     (define-key map [headings copy]
 152       '(menu-item "Copy to Kill Ring" outline-headers-as-kill
 153                   :enable mark-active
 154                   :help "Save the visible outline headers in region at the start of the kill ring"))
 155     (define-key map [headings outline-insert-heading]
 156       '(menu-item "New Heading" outline-insert-heading
 157                   :help "Insert a new heading at same depth at point"))
 158     (define-key map [headings outline-backward-same-level]
 159
 160       '(menu-item "Previous Same Level" outline-backward-same-level
 161                   :help "Move backward to the arg'th subheading at same level as this one."))
 162     (define-key map [headings outline-forward-same-level]
 163
 164       '(menu-item "Next Same Level" outline-forward-same-level
 165                   :help "Move forward to the arg'th subheading at same level as this one"))
 166     (define-key map [headings outline-previous-visible-heading]
 167
 168       '(menu-item "Previous" outline-previous-visible-heading
 169                   :help "Move to the previous heading line"))
 170     (define-key map [headings outline-next-visible-heading]
 171
 172       '(menu-item "Next" outline-next-visible-heading
 173                   :help "Move to the next visible heading line"))
 174     (define-key map [headings outline-up-heading]
 175
 176       '(menu-item "Up" outline-up-heading
 177                   :help "Move to the visible heading line of which the present line is a subheading"))
 178     map))
 179
 180 (defvar outline-minor-mode-menu-bar-map
 181   (let ((map (make-sparse-keymap)))
 182     (define-key map [outline]
 183       (cons "Outline"
 184             (nconc (make-sparse-keymap "Outline")
 185                    ;; Remove extra separator
 186                    (cdr
 187                     ;; Flatten the major mode's menus into a single menu.
 188                     (apply 'append
 189                            (mapcar (lambda (x)
 190                                      (if (consp x)
 191                                          ;; Add a separator between each
 192                                          ;; part of the unified menu.
 193                                          (cons '(--- "---") (cdr x))))
 194                                    outline-mode-menu-bar-map))))))
 195     map))
 196
 197
 198 (defvar outline-mode-map
 199   (let ((map (make-sparse-keymap)))
 200     (define-key map "\C-c" outline-mode-prefix-map)
 201     (define-key map [menu-bar] outline-mode-menu-bar-map)
 202     map))
 203
 204 (defvar outline-font-lock-keywords
 205   '(;;
 206     ;; Highlight headings according to the level.
 207     (eval . (list (concat "^\\(?:" outline-regexp "\\).+")
 208                   0 '(outline-font-lock-face) nil t)))
 209   "Additional expressions to highlight in Outline mode.")
 210
 211 (defface outline-1
 212   '((t :inherit font-lock-function-name-face))
 213   "Level 1."
 214   :group 'outlines)
 215
 216 (defface outline-2
 217   '((t :inherit font-lock-variable-name-face))
 218   "Level 2."
 219   :group 'outlines)
 220
 221 (defface outline-3
 222   '((t :inherit font-lock-keyword-face))
 223   "Level 3."
 224   :group 'outlines)
 225
 226 (defface outline-4
 227   '((t :inherit font-lock-comment-face))
 228   "Level 4."
 229   :group 'outlines)
 230
 231 (defface outline-5
 232   '((t :inherit font-lock-type-face))
 233   "Level 5."
 234   :group 'outlines)
 235
 236 (defface outline-6
 237   '((t :inherit font-lock-constant-face))
 238   "Level 6."
 239   :group 'outlines)
 240
 241 (defface outline-7
 242   '((t :inherit font-lock-builtin-face))
 243   "Level 7."
 244   :group 'outlines)
 245
 246 (defface outline-8
 247   '((t :inherit font-lock-string-face))
 248   "Level 8."
 249   :group 'outlines)
 250
 251 (defvar outline-font-lock-faces
 252   [outline-1 outline-2 outline-3 outline-4
 253    outline-5 outline-6 outline-7 outline-8])
 254
 255 ;; (defvar outline-font-lock-levels nil)
 256 ;; (make-variable-buffer-local 'outline-font-lock-levels)
 257
 258 (defun outline-font-lock-face ()
 259   ;; (save-excursion
 260   ;;   (outline-back-to-heading t)
 261   ;;   (let* ((count 0)
 262   ;;       (start-level (funcall outline-level))
 263   ;;       (level start-level)
 264   ;;       face-level)
 265   ;;     (while (not (setq face-level
 266   ;;                    (if (or (bobp) (eq level 1)) 0
 267   ;;                      (cdr (assq level outline-font-lock-levels)))))
 268   ;;    (outline-up-heading 1 t)
 269   ;;    (setq count (1+ count))
 270   ;;    (setq level (funcall outline-level)))
 271   ;;     ;; Remember for later.
 272   ;;     (unless (zerop count)
 273   ;;    (setq face-level (+ face-level count))
 274   ;;    (push (cons start-level face-level) outline-font-lock-levels))
 275   ;;     (condition-case nil
 276   ;;      (aref outline-font-lock-faces face-level)
 277   ;;    (error font-lock-warning-face))))
 278   (save-excursion
 279     (goto-char (match-beginning 0))
 280     (looking-at outline-regexp)
 281     (aref outline-font-lock-faces (% (1- (funcall outline-level)) (length outline-font-lock-faces)))))
 282
 283 (defvar outline-view-change-hook nil
 284   "Normal hook to be run after outline visibility changes.")
 285
 286 (defvar outline-mode-hook nil
 287   "This hook is run when outline mode starts.")
 288
 289 (defvar outline-blank-line nil
 290   "Non-nil means to leave unhidden blank line before heading.")
 291
 292 ;;;###autoload
 293 (define-derived-mode outline-mode text-mode "Outline"
 294   "Set major mode for editing outlines with selective display.
 295 Headings are lines which start with asterisks: one for major headings,
 296 two for subheadings, etc.  Lines not starting with asterisks are body lines.
 297
 298 Body text or subheadings under a heading can be made temporarily
 299 invisible, or visible again.  Invisible lines are attached to the end
 300 of the heading, so they move with it, if the line is killed and yanked
 301 back.  A heading with text hidden under it is marked with an ellipsis (...).
 302
 303 Commands:\\<outline-mode-map>
 304 \\[outline-next-visible-heading]   outline-next-visible-heading      move by visible headings
 305 \\[outline-previous-visible-heading]   outline-previous-visible-heading
 306 \\[outline-forward-same-level]   outline-forward-same-level        similar but skip subheadings
 307 \\[outline-backward-same-level]   outline-backward-same-level
 308 \\[outline-up-heading]   outline-up-heading                 move from subheading to heading
 309
 310 \\[hide-body]   make all text invisible (not headings).
 311 \\[show-all]    make everything in buffer visible.
 312 \\[hide-sublevels]  make only the first N levels of headers visible.
 313
 314 The remaining commands are used when point is on a heading line.
 315 They apply to some of the body or subheadings of that heading.
 316 \\[hide-subtree]   hide-subtree make body and subheadings invisible.
 317 \\[show-subtree]   show-subtree make body and subheadings visible.
 318 \\[show-children]   show-children       make direct subheadings visible.
 319                  No effect on body, or subheadings 2 or more levels down.
 320                  With arg N, affects subheadings N levels down.
 321 \\[hide-entry]     make immediately following body invisible.
 322 \\[show-entry]     make it visible.
 323 \\[hide-leaves]    make body under heading and under its subheadings invisible.
 324                      The subheadings remain visible.
 325 \\[show-branches]  make all subheadings at all levels visible.
 326
 327 The variable `outline-regexp' can be changed to control what is a heading.
 328 A line is a heading if `outline-regexp' matches something at the
 329 beginning of the line.  The longer the match, the deeper the level.
 330
 331 Turning on outline mode calls the value of `text-mode-hook' and then of
 332 `outline-mode-hook', if they are non-nil."
 333   (make-local-variable 'line-move-ignore-invisible)
 334   (setq line-move-ignore-invisible t)
 335   ;; Cause use of ellipses for invisible text.
 336   (add-to-invisibility-spec '(outline . t))
 337   (set (make-local-variable 'paragraph-start)
 338        (concat paragraph-start "\\|\\(?:" outline-regexp "\\)"))
 339   ;; Inhibit auto-filling of header lines.
 340   (set (make-local-variable 'auto-fill-inhibit-regexp) outline-regexp)
 341   (set (make-local-variable 'paragraph-separate)
 342        (concat paragraph-separate "\\|\\(?:" outline-regexp "\\)"))
 343   (set (make-local-variable 'font-lock-defaults)
 344        '(outline-font-lock-keywords t nil nil backward-paragraph))
 345   (setq imenu-generic-expression
 346         (list (list nil (concat "^\\(?:" outline-regexp "\\).*$") 0)))
 347   (add-hook 'change-major-mode-hook 'show-all nil t))
 348
 349 (defcustom outline-minor-mode-prefix "\C-c@"
 350   "Prefix key to use for Outline commands in Outline minor mode.
 351 The value of this variable is checked as part of loading Outline mode.
 352 After that, changing the prefix key requires manipulating keymaps."
 353   :type 'string
 354   :group 'outlines)
 355
 356 ;;;###autoload
 357 (define-minor-mode outline-minor-mode
 358   "Toggle Outline minor mode.
 359 With a prefix argument ARG, enable Outline minor mode if ARG is
 360 positive, and disable it otherwise.  If called from Lisp, enable
 361 the mode if ARG is omitted or nil.
 362
 363 See the command `outline-mode' for more information on this mode."
 364   nil " Outl" (list (cons [menu-bar] outline-minor-mode-menu-bar-map)
 365                     (cons outline-minor-mode-prefix outline-mode-prefix-map))
 366   :group 'outlines
 367   (if outline-minor-mode
 368       (progn
 369         ;; Turn off this mode if we change major modes.
 370         (add-hook 'change-major-mode-hook
 371                   (lambda () (outline-minor-mode -1))
 372                   nil t)
 373         (set (make-local-variable 'line-move-ignore-invisible) t)
 374         ;; Cause use of ellipses for invisible text.
 375         (add-to-invisibility-spec '(outline . t)))
 376     (setq line-move-ignore-invisible nil)
 377     ;; Cause use of ellipses for invisible text.
 378     (remove-from-invisibility-spec '(outline . t))
 379     ;; When turning off outline mode, get rid of any outline hiding.
 380     (show-all)))
 381 \f
 382 (defvar outline-level 'outline-level
 383   "Function of no args to compute a header's nesting level in an outline.
 384 It can assume point is at the beginning of a header line and that the match
 385 data reflects the `outline-regexp'.")
 386 ;;;###autoload(put 'outline-level 'risky-local-variable t)
 387
 388 (defvar outline-heading-alist ()
 389   "Alist associating a heading for every possible level.
 390 Each entry is of the form (HEADING . LEVEL).
 391 This alist is used two ways: to find the heading corresponding to
 392 a given level and to find the level of a given heading.
 393 If a mode or document needs several sets of outline headings (for example
 394 numbered and unnumbered sections), list them set by set and sorted by level
 395 within each set.  For example in texinfo mode:
 396
 397      (setq outline-heading-alist
 398       '((\"@chapter\" . 2) (\"@section\" . 3) (\"@subsection\" . 4)
 399            (\"@subsubsection\" . 5)
 400         (\"@unnumbered\" . 2) (\"@unnumberedsec\" . 3)
 401            (\"@unnumberedsubsec\" . 4)  (\"@unnumberedsubsubsec\" . 5)
 402         (\"@appendix\" . 2) (\"@appendixsec\" . 3)...
 403            (\"@appendixsubsec\" . 4) (\"@appendixsubsubsec\" . 5) ..))
 404
 405 Instead of sorting the entries in each set, you can also separate the
 406 sets with nil.")
 407 (make-variable-buffer-local 'outline-heading-alist)
 408
 409 ;; This used to count columns rather than characters, but that made ^L
 410 ;; appear to be at level 2 instead of 1.  Columns would be better for
 411 ;; tab handling, but the default regexp doesn't use tabs, and anyone
 412 ;; who changes the regexp can also redefine the outline-level variable
 413 ;; as appropriate.
 414 (defun outline-level ()
 415   "Return the depth to which a statement is nested in the outline.
 416 Point must be at the beginning of a header line.
 417 This is actually either the level specified in `outline-heading-alist'
 418 or else the number of characters matched by `outline-regexp'."
 419   (or (cdr (assoc (match-string 0) outline-heading-alist))
 420       (- (match-end 0) (match-beginning 0))))
 421
 422 (defun outline-next-preface ()
 423   "Skip forward to just before the next heading line.
 424 If there's no following heading line, stop before the newline
 425 at the end of the buffer."
 426   (if (re-search-forward (concat "\n\\(?:" outline-regexp "\\)")
 427                          nil 'move)
 428       (goto-char (match-beginning 0)))
 429   (if (and (bolp) (or outline-blank-line (eobp)) (not (bobp)))
 430       (forward-char -1)))
 431
 432 (defun outline-next-heading ()
 433   "Move to the next (possibly invisible) heading line."
 434   (interactive)
 435   ;; Make sure we don't match the heading we're at.
 436   (if (and (bolp) (not (eobp))) (forward-char 1))
 437   (if (re-search-forward (concat "^\\(?:" outline-regexp "\\)")
 438                          nil 'move)
 439       (goto-char (match-beginning 0))))
 440
 441 (defun outline-previous-heading ()
 442   "Move to the previous (possibly invisible) heading line."
 443   (interactive)
 444   (re-search-backward (concat "^\\(?:" outline-regexp "\\)")
 445                       nil 'move))
 446
 447 (defsubst outline-invisible-p (&optional pos)
 448   "Non-nil if the character after point is invisible."
 449   (get-char-property (or pos (point)) 'invisible))
 450
 451 (defun outline-back-to-heading (&optional invisible-ok)
 452   "Move to previous heading line, or beg of this line if it's a heading.
 453 Only visible heading lines are considered, unless INVISIBLE-OK is non-nil."
 454   (beginning-of-line)
 455   (or (outline-on-heading-p invisible-ok)
 456       (let (found)
 457         (save-excursion
 458           (while (not found)
 459             (or (re-search-backward (concat "^\\(?:" outline-regexp "\\)")
 460                                     nil t)
 461                 (error "before first heading"))
 462             (setq found (and (or invisible-ok (not (outline-invisible-p)))
 463                              (point)))))
 464         (goto-char found)
 465         found)))
 466
 467 (defun outline-on-heading-p (&optional invisible-ok)
 468   "Return t if point is on a (visible) heading line.
 469 If INVISIBLE-OK is non-nil, an invisible heading line is ok too."
 470   (save-excursion
 471     (beginning-of-line)
 472     (and (bolp) (or invisible-ok (not (outline-invisible-p)))
 473          (looking-at outline-regexp))))
 474
 475 (defun outline-insert-heading ()
 476   "Insert a new heading at same depth at point."
 477   (interactive)
 478   (let ((head (save-excursion
 479                 (condition-case nil
 480                     (outline-back-to-heading)
 481                   (error (outline-next-heading)))
 482                 (if (eobp)
 483                     (or (caar outline-heading-alist) "")
 484                   (match-string 0)))))
 485     (unless (or (string-match "[ \t]\\'" head)
 486                 (not (string-match (concat "\\`\\(?:" outline-regexp "\\)")
 487                                    (concat head " "))))
 488       (setq head (concat head " ")))
 489     (unless (bolp) (end-of-line) (newline))
 490     (insert head)
 491     (unless (eolp)
 492       (save-excursion (newline-and-indent)))
 493     (run-hooks 'outline-insert-heading-hook)))
 494
 495 (defun outline-invent-heading (head up)
 496   (save-match-data
 497     ;; Let's try to invent one by repeating or deleting the last char.
 498     (let ((new-head (if up (substring head 0 -1)
 499                       (concat head (substring head -1)))))
 500       (if (string-match (concat "\\`\\(?:" outline-regexp "\\)")
 501                         new-head)
 502           ;; Why bother checking that it is indeed higher/lower level ?
 503           new-head
 504         ;; Didn't work, so ask what to do.
 505         (read-string (format "%s heading for `%s': "
 506                              (if up "Parent" "Demoted") head)
 507                      head nil nil t)))))
 508
 509 (defun outline-promote (&optional which)
 510   "Promote headings higher up the tree.
 511 If transient-mark-mode is on, and mark is active, promote headings in
 512 the region (from a Lisp program, pass `region' for WHICH).  Otherwise:
 513 without prefix argument, promote current heading and all headings in the
 514 subtree (from a Lisp program, pass `subtree' for WHICH); with prefix
 515 argument, promote just the current heading (from a Lisp program, pass
 516 nil for WHICH, or do not pass any argument)."
 517   (interactive
 518    (list (if (and transient-mark-mode mark-active) 'region
 519            (outline-back-to-heading)
 520            (if current-prefix-arg nil 'subtree))))
 521   (cond
 522    ((eq which 'region)
 523     (outline-map-region 'outline-promote (region-beginning) (region-end)))
 524    (which
 525     (outline-map-region 'outline-promote
 526                         (point)
 527                         (save-excursion (outline-get-next-sibling) (point))))
 528    (t
 529     (outline-back-to-heading t)
 530     (let* ((head (match-string-no-properties 0))
 531            (level (save-match-data (funcall outline-level)))
 532            (up-head (or (outline-head-from-level (1- level) head)
 533                         ;; Use the parent heading, if it is really
 534                         ;; one level less.
 535                         (save-excursion
 536                           (save-match-data
 537                             (outline-up-heading 1 t)
 538                             (and (= (1- level) (funcall outline-level))
 539                                  (match-string-no-properties 0))))
 540                         ;; Bummer!! There is no lower level heading.
 541                         (outline-invent-heading head 'up))))
 542
 543       (unless (rassoc level outline-heading-alist)
 544         (push (cons head level) outline-heading-alist))
 545
 546       (replace-match up-head nil t)))))
 547
 548 (defun outline-demote (&optional which)
 549   "Demote headings lower down the tree.
 550 If transient-mark-mode is on, and mark is active, demote headings in
 551 the region (from a Lisp program, pass `region' for WHICH).  Otherwise:
 552 without prefix argument, demote current heading and all headings in the
 553 subtree (from a Lisp program, pass `subtree' for WHICH); with prefix
 554 argument, demote just the current heading (from a Lisp program, pass
 555 nil for WHICH, or do not pass any argument)."
 556   (interactive
 557    (list (if (and transient-mark-mode mark-active) 'region
 558            (outline-back-to-heading)
 559            (if current-prefix-arg nil 'subtree))))
 560   (cond
 561    ((eq which 'region)
 562     (outline-map-region 'outline-demote (region-beginning) (region-end)))
 563    (which
 564     (outline-map-region 'outline-demote
 565                         (point)
 566                         (save-excursion (outline-get-next-sibling) (point))))
 567    (t
 568     (let* ((head (match-string-no-properties 0))
 569            (level (save-match-data (funcall outline-level)))
 570            (down-head
 571             (or (outline-head-from-level (1+ level) head)
 572                 (save-excursion
 573                   (save-match-data
 574                     (while (and (progn (outline-next-heading) (not (eobp)))
 575                                 (<= (funcall outline-level) level)))
 576                     (when (eobp)
 577                       ;; Try again from the beginning of the buffer.
 578                       (goto-char (point-min))
 579                       (while (and (progn (outline-next-heading) (not (eobp)))
 580                                   (<= (funcall outline-level) level))))
 581                     (unless (eobp)
 582                       (looking-at outline-regexp)
 583                       (match-string-no-properties 0))))
 584                 ;; Bummer!! There is no higher-level heading in the buffer.
 585                 (outline-invent-heading head nil))))
 586
 587       (unless (rassoc level outline-heading-alist)
 588         (push (cons head level) outline-heading-alist))
 589       (replace-match down-head nil t)))))
 590
 591 (defun outline-head-from-level (level head &optional alist)
 592   "Get new heading with level LEVEL from ALIST.
 593 If there are no such entries, return nil.
 594 ALIST defaults to `outline-heading-alist'.
 595 Similar to (car (rassoc LEVEL ALIST)).
 596 If there are several different entries with same new level, choose
 597 the one with the smallest distance to the association of HEAD in the alist.
 598 This makes it possible for promotion to work in modes with several
 599 independent sets of headings (numbered, unnumbered, appendix...)"
 600   (unless alist (setq alist outline-heading-alist))
 601   (let ((l (rassoc level alist))
 602         ll h hl l2 l2l)
 603     (cond
 604      ((null l) nil)
 605      ;; If there's no HEAD after L, any other entry for LEVEL after L
 606      ;; can't be much better than L.
 607      ((null (setq h (assoc head (setq ll (memq l alist))))) (car l))
 608      ;; If there's no other entry for LEVEL, just keep L.
 609      ((null (setq l2 (rassoc level (cdr ll)))) (car l))
 610      ;; Now we have L, L2, and H: see if L2 seems better than L.
 611      ;; If H is after L2, L2 is better.
 612      ((memq h (setq l2l (memq l2 (cdr ll))))
 613       (outline-head-from-level level head l2l))
 614      ;; Now we have H between L and L2.
 615      ;; If there's a separator between L and H, prefer L2.
 616      ((memq h (memq nil ll))
 617       (outline-head-from-level level head l2l))
 618      ;; If there's a separator between L2 and H, prefer L.
 619      ((memq l2 (memq nil (setq hl (memq h ll)))) (car l))
 620      ;; No separator between L and L2, check the distance.
 621      ((< (* 2 (length hl)) (+ (length ll) (length l2l)))
 622       (outline-head-from-level level head l2l))
 623      ;; If all else fails, just keep L.
 624      (t (car l)))))
 625
 626 (defun outline-map-region (fun beg end)
 627   "Call FUN for every heading between BEG and END.
 628 When FUN is called, point is at the beginning of the heading and
 629 the match data is set appropriately."
 630   (save-excursion
 631     (setq end (copy-marker end))
 632     (goto-char beg)
 633     (when (re-search-forward (concat "^\\(?:" outline-regexp "\\)") end t)
 634       (goto-char (match-beginning 0))
 635       (funcall fun)
 636       (while (and (progn
 637                     (outline-next-heading)
 638                     (< (point) end))
 639                   (not (eobp)))
 640         (funcall fun)))))
 641
 642 ;; Vertical tree motion
 643
 644 (defun outline-move-subtree-up (&optional arg)
 645   "Move the current subtree up past ARG headlines of the same level."
 646   (interactive "p")
 647   (outline-move-subtree-down (- arg)))
 648
 649 (defun outline-move-subtree-down (&optional arg)
 650   "Move the current subtree down past ARG headlines of the same level."
 651   (interactive "p")
 652   (let ((movfunc (if (> arg 0) 'outline-get-next-sibling
 653                    'outline-get-last-sibling))
 654         (ins-point (make-marker))
 655         (cnt (abs arg))
 656         beg end folded)
 657     ;; Select the tree
 658     (outline-back-to-heading)
 659     (setq beg (point))
 660     (save-match-data
 661       (save-excursion (outline-end-of-heading)
 662                       (setq folded (outline-invisible-p)))
 663       (outline-end-of-subtree))
 664     (if (= (char-after) ?\n) (forward-char 1))
 665     (setq end (point))
 666     ;; Find insertion point, with error handling
 667     (goto-char beg)
 668     (while (> cnt 0)
 669       (or (funcall movfunc)
 670           (progn (goto-char beg)
 671                  (error "Cannot move past superior level")))
 672       (setq cnt (1- cnt)))
 673     (if (> arg 0)
 674         ;; Moving forward - still need to move over subtree
 675         (progn (outline-end-of-subtree)
 676                (if (= (char-after) ?\n) (forward-char 1))))
 677     (move-marker ins-point (point))
 678     (insert (delete-and-extract-region beg end))
 679     (goto-char ins-point)
 680     (if folded (hide-subtree))
 681     (move-marker ins-point nil)))
 682
 683 (defun outline-end-of-heading ()
 684   (if (re-search-forward outline-heading-end-regexp nil 'move)
 685       (forward-char -1)))
 686
 687 (defun outline-next-visible-heading (arg)
 688   "Move to the next visible heading line.
 689 With argument, repeats or can move backward if negative.
 690 A heading line is one that starts with a `*' (or that
 691 `outline-regexp' matches)."
 692   (interactive "p")
 693   (if (< arg 0)
 694       (beginning-of-line)
 695     (end-of-line))
 696   (let (found-heading-p)
 697     (while (and (not (bobp)) (< arg 0))
 698       (while (and (not (bobp))
 699                   (setq found-heading-p
 700                         (re-search-backward
 701                          (concat "^\\(?:" outline-regexp "\\)")
 702                          nil 'move))
 703                   (outline-invisible-p)))
 704       (setq arg (1+ arg)))
 705     (while (and (not (eobp)) (> arg 0))
 706       (while (and (not (eobp))
 707                   (setq found-heading-p
 708                         (re-search-forward
 709                          (concat "^\\(?:" outline-regexp "\\)")
 710                          nil 'move))
 711                   (outline-invisible-p (match-beginning 0))))
 712       (setq arg (1- arg)))
 713     (if found-heading-p (beginning-of-line))))
 714
 715 (defun outline-previous-visible-heading (arg)
 716   "Move to the previous heading line.
 717 With argument, repeats or can move forward if negative.
 718 A heading line is one that starts with a `*' (or that
 719 `outline-regexp' matches)."
 720   (interactive "p")
 721   (outline-next-visible-heading (- arg)))
 722
 723 (defun outline-mark-subtree ()
 724   "Mark the current subtree in an outlined document.
 725 This puts point at the start of the current subtree, and mark at the end."
 726   (interactive)
 727   (let ((beg))
 728     (if (outline-on-heading-p)
 729         ;; we are already looking at a heading
 730         (beginning-of-line)
 731       ;; else go back to previous heading
 732       (outline-previous-visible-heading 1))
 733     (setq beg (point))
 734     (outline-end-of-subtree)
 735     (push-mark (point) nil t)
 736     (goto-char beg)))
 737 \f
 738
 739 (defvar outline-isearch-open-invisible-function nil
 740   "Function called if `isearch' finishes in an invisible overlay.
 741 The function is called with the overlay as its only argument.
 742 If nil, `show-entry' is called to reveal the invisible text.")
 743
 744 (put 'outline 'reveal-toggle-invisible 'outline-reveal-toggle-invisible)
 745 (defun outline-flag-region (from to flag)
 746   "Hide or show lines from FROM to TO, according to FLAG.
 747 If FLAG is nil then text is shown, while if FLAG is t the text is hidden."
 748   (remove-overlays from to 'invisible 'outline)
 749   (when flag
 750     ;; We use `front-advance' here because the invisible text begins at the
 751     ;; very end of the heading, before the newline, so text inserted at FROM
 752     ;; belongs to the heading rather than to the entry.
 753     (let ((o (make-overlay from to nil 'front-advance)))
 754       (overlay-put o 'evaporate t)
 755       (overlay-put o 'invisible 'outline)
 756       (overlay-put o 'isearch-open-invisible
 757                    (or outline-isearch-open-invisible-function
 758                        'outline-isearch-open-invisible))))
 759   ;; Seems only used by lazy-lock.  I.e. obsolete.
 760   (run-hooks 'outline-view-change-hook))
 761
 762 (defun outline-reveal-toggle-invisible (o hidep)
 763   (save-excursion
 764     (goto-char (overlay-start o))
 765     (if hidep
 766         ;; When hiding the area again, we could just clean it up and let
 767         ;; reveal do the rest, by simply doing:
 768         ;; (remove-overlays (overlay-start o) (overlay-end o)
 769         ;;                  'invisible 'outline)
 770         ;;
 771         ;; That works fine as long as everything is in sync, but if the
 772         ;; structure of the document is changed while revealing parts of it,
 773         ;; the resulting behavior can be ugly.  I.e. we need to make
 774         ;; sure that we hide exactly a subtree.
 775         (progn
 776           (let ((end (overlay-end o)))
 777             (delete-overlay o)
 778             (while (progn
 779                      (hide-subtree)
 780                      (outline-next-visible-heading 1)
 781                      (and (not (eobp)) (< (point) end))))))
 782
 783       ;; When revealing, we just need to reveal sublevels.  If point is
 784       ;; inside one of the sublevels, reveal will call us again.
 785       ;; But we need to preserve the original overlay.
 786       (let ((o1 (copy-overlay o)))
 787         (overlay-put o 'invisible nil)  ;Show (most of) the text.
 788         (while (progn
 789                  (show-entry)
 790                  (show-children)
 791                  ;; Normally just the above is needed.
 792                  ;; But in odd cases, the above might fail to show anything.
 793                  ;; To avoid an infinite loop, we have to make sure that
 794                  ;; *something* gets shown.
 795                  (and (equal (overlay-start o) (overlay-start o1))
 796                       (< (point) (overlay-end o))
 797                       (= 0 (forward-line 1)))))
 798         ;; If still nothing was shown, just kill the damn thing.
 799         (when (equal (overlay-start o) (overlay-start o1))
 800           ;; I've seen it happen at the end of buffer.
 801           (delete-overlay o1))))))
 802
 803 ;; Function to be set as an outline-isearch-open-invisible' property
 804 ;; to the overlay that makes the outline invisible (see
 805 ;; `outline-flag-region').
 806 (defun outline-isearch-open-invisible (_overlay)
 807   ;; We rely on the fact that isearch places point on the matched text.
 808   (show-entry))
 809 \f
 810 (defun hide-entry ()
 811   "Hide the body directly following this heading."
 812   (interactive)
 813   (save-excursion
 814     (outline-back-to-heading)
 815     (outline-end-of-heading)
 816     (outline-flag-region (point) (progn (outline-next-preface) (point)) t)))
 817
 818 (defun show-entry ()
 819   "Show the body directly following this heading.
 820 Show the heading too, if it is currently invisible."
 821   (interactive)
 822   (save-excursion
 823     (outline-back-to-heading t)
 824     (outline-flag-region (1- (point))
 825                          (progn (outline-next-preface) (point)) nil)))
 826
 827 (defun hide-body ()
 828   "Hide all body lines in buffer, leaving all headings visible."
 829   (interactive)
 830   (hide-region-body (point-min) (point-max)))
 831
 832 (defun hide-region-body (start end)
 833   "Hide all body lines in the region, but not headings."
 834   ;; Nullify the hook to avoid repeated calls to `outline-flag-region'
 835   ;; wasting lots of time running `lazy-lock-fontify-after-outline'
 836   ;; and run the hook finally.
 837   (let (outline-view-change-hook)
 838     (save-excursion
 839       (save-restriction
 840         (narrow-to-region start end)
 841         (goto-char (point-min))
 842         (if (outline-on-heading-p)
 843             (outline-end-of-heading)
 844           (outline-next-preface))
 845         (while (not (eobp))
 846           (outline-flag-region (point)
 847                                (progn (outline-next-preface) (point)) t)
 848           (unless (eobp)
 849             (forward-char (if (looking-at "\n\n") 2 1))
 850             (outline-end-of-heading))))))
 851   (run-hooks 'outline-view-change-hook))
 852
 853 (defun show-all ()
 854   "Show all of the text in the buffer."
 855   (interactive)
 856   (outline-flag-region (point-min) (point-max) nil))
 857
 858 (defun hide-subtree ()
 859   "Hide everything after this heading at deeper levels."
 860   (interactive)
 861   (outline-flag-subtree t))
 862
 863 (defun hide-leaves ()
 864   "Hide the body after this heading and at deeper levels."
 865   (interactive)
 866   (save-excursion
 867     (outline-back-to-heading)
 868 ;; Turned off to fix bug reported by Otto Maddox on 22 Nov 2005.
 869 ;;    (outline-end-of-heading)
 870     (hide-region-body (point) (progn (outline-end-of-subtree) (point)))))
 871
 872 (defun show-subtree ()
 873   "Show everything after this heading at deeper levels."
 874   (interactive)
 875   (outline-flag-subtree nil))
 876
 877 (defun outline-show-heading ()
 878   "Show the current heading and move to its end."
 879   (outline-flag-region (- (point)
 880                           (if (bobp) 0
 881                             (if (and outline-blank-line
 882                                      (eq (char-before (1- (point))) ?\n))
 883                                 2 1)))
 884                        (progn (outline-end-of-heading) (point))
 885                        nil))
 886
 887 (defun hide-sublevels (levels)
 888   "Hide everything but the top LEVELS levels of headers, in whole buffer."
 889   (interactive (list
 890                 (cond
 891                  (current-prefix-arg (prefix-numeric-value current-prefix-arg))
 892                  ((save-excursion (beginning-of-line)
 893                                   (looking-at outline-regexp))
 894                   (funcall outline-level))
 895                  (t 1))))
 896   (if (< levels 1)
 897       (error "Must keep at least one level of headers"))
 898   (save-excursion
 899     (let* (outline-view-change-hook
 900            (beg (progn
 901                   (goto-char (point-min))
 902                   ;; Skip the prelude, if any.
 903                   (unless (outline-on-heading-p t) (outline-next-heading))
 904                   (point)))
 905            (end (progn
 906                   (goto-char (point-max))
 907                   ;; Keep empty last line, if available.
 908                   (if (bolp) (1- (point)) (point)))))
 909       (if (< end beg)
 910           (setq beg (prog1 end (setq end beg))))
 911       ;; First hide everything.
 912       (outline-flag-region beg end t)
 913       ;; Then unhide the top level headers.
 914       (outline-map-region
 915        (lambda ()
 916          (if (<= (funcall outline-level) levels)
 917              (outline-show-heading)))
 918        beg end)
 919       ;; Finally unhide any trailing newline.
 920       (goto-char (point-max))
 921       (if (and (bolp) (not (bobp)) (outline-invisible-p (1- (point))))
 922           (outline-flag-region (1- (point)) (point) nil))))
 923   (run-hooks 'outline-view-change-hook))
 924
 925 (defun hide-other ()
 926   "Hide everything except current body and parent and top-level headings."
 927   (interactive)
 928   (hide-sublevels 1)
 929   (let (outline-view-change-hook)
 930     (save-excursion
 931       (outline-back-to-heading t)
 932       (show-entry)
 933       (while (condition-case nil (progn (outline-up-heading 1 t) (not (bobp)))
 934                (error nil))
 935         (outline-flag-region (1- (point))
 936                              (save-excursion (forward-line 1) (point))
 937                              nil))))
 938   (run-hooks 'outline-view-change-hook))
 939
 940 (defun outline-toggle-children ()
 941   "Show or hide the current subtree depending on its current state."
 942   (interactive)
 943   (save-excursion
 944     (outline-back-to-heading)
 945     (if (not (outline-invisible-p (line-end-position)))
 946         (hide-subtree)
 947       (show-children)
 948       (show-entry))))
 949
 950 (defun outline-flag-subtree (flag)
 951   (save-excursion
 952     (outline-back-to-heading)
 953     (outline-end-of-heading)
 954     (outline-flag-region (point)
 955                           (progn (outline-end-of-subtree) (point))
 956                           flag)))
 957
 958 (defun outline-end-of-subtree ()
 959   (outline-back-to-heading)
 960   (let ((first t)
 961         (level (funcall outline-level)))
 962     (while (and (not (eobp))
 963                 (or first (> (funcall outline-level) level)))
 964       (setq first nil)
 965       (outline-next-heading))
 966     (if (and (bolp) (not (eolp)))
 967         ;; We stopped at a nonempty line (the next heading).
 968         (progn
 969           ;; Go to end of line before heading
 970           (forward-char -1)
 971           (if (and outline-blank-line (bolp))
 972               ;; leave blank line before heading
 973               (forward-char -1))))))
 974 \f
 975 (defun show-branches ()
 976   "Show all subheadings of this heading, but not their bodies."
 977   (interactive)
 978   (show-children 1000))
 979
 980 (defun show-children (&optional level)
 981   "Show all direct subheadings of this heading.
 982 Prefix arg LEVEL is how many levels below the current level should be shown.
 983 Default is enough to cause the following heading to appear."
 984   (interactive "P")
 985   (setq level
 986         (if level (prefix-numeric-value level)
 987           (save-excursion
 988             (outline-back-to-heading)
 989             (let ((start-level (funcall outline-level)))
 990               (outline-next-heading)
 991               (if (eobp)
 992                   1
 993                 (max 1 (- (funcall outline-level) start-level)))))))
 994   (let (outline-view-change-hook)
 995     (save-excursion
 996       (outline-back-to-heading)
 997       (setq level (+ level (funcall outline-level)))
 998       (outline-map-region
 999        (lambda ()
1000          (if (<= (funcall outline-level) level)
1001              (outline-show-heading)))
1002        (point)
1003        (progn (outline-end-of-subtree)
1004               (if (eobp) (point-max) (1+ (point)))))))
1005   (run-hooks 'outline-view-change-hook))
1006
1007 \f
1008
1009 (defun outline-up-heading (arg &optional invisible-ok)
1010   "Move to the visible heading line of which the present line is a subheading.
1011 With argument, move up ARG levels.
1012 If INVISIBLE-OK is non-nil, also consider invisible lines."
1013   (interactive "p")
1014   (and (eq this-command 'outline-up-heading)
1015        (or (eq last-command 'outline-up-heading) (push-mark)))
1016   (outline-back-to-heading invisible-ok)
1017   (let ((start-level (funcall outline-level)))
1018     (when (<= start-level 1)
1019       (error "Already at top level of the outline"))
1020     (while (and (> start-level 1) (> arg 0) (not (bobp)))
1021       (let ((level start-level))
1022         (while (not (or (< level start-level) (bobp)))
1023           (if invisible-ok
1024               (outline-previous-heading)
1025             (outline-previous-visible-heading 1))
1026           (setq level (funcall outline-level)))
1027         (setq start-level level))
1028       (setq arg (- arg 1))))
1029   (looking-at outline-regexp))
1030
1031 (defun outline-forward-same-level (arg)
1032   "Move forward to the ARG'th subheading at same level as this one.
1033 Stop at the first and last subheadings of a superior heading."
1034   (interactive "p")
1035   (outline-back-to-heading)
1036   (while (> arg 0)
1037     (let ((point-to-move-to (save-excursion
1038                               (outline-get-next-sibling))))
1039       (if point-to-move-to
1040           (progn
1041             (goto-char point-to-move-to)
1042             (setq arg (1- arg)))
1043         (progn
1044           (setq arg 0)
1045           (error "No following same-level heading"))))))
1046
1047 (defun outline-get-next-sibling ()
1048   "Move to next heading of the same level, and return point.
1049 If there is no such heading, return nil."
1050   (let ((level (funcall outline-level)))
1051     (outline-next-visible-heading 1)
1052     (while (and (not (eobp)) (> (funcall outline-level) level))
1053       (outline-next-visible-heading 1))
1054     (if (or (eobp) (< (funcall outline-level) level))
1055         nil
1056       (point))))
1057
1058 (defun outline-backward-same-level (arg)
1059   "Move backward to the ARG'th subheading at same level as this one.
1060 Stop at the first and last subheadings of a superior heading."
1061   (interactive "p")
1062   (outline-back-to-heading)
1063   (while (> arg 0)
1064     (let ((point-to-move-to (save-excursion
1065                               (outline-get-last-sibling))))
1066       (if point-to-move-to
1067           (progn
1068             (goto-char point-to-move-to)
1069             (setq arg (1- arg)))
1070         (progn
1071           (setq arg 0)
1072           (error "No previous same-level heading"))))))
1073
1074 (defun outline-get-last-sibling ()
1075   "Move to previous heading of the same level, and return point.
1076 If there is no such heading, return nil."
1077   (let ((opoint (point))
1078         (level (funcall outline-level)))
1079     (outline-previous-visible-heading 1)
1080     (when (and (/= (point) opoint) (outline-on-heading-p))
1081       (while (and (> (funcall outline-level) level)
1082                   (not (bobp)))
1083         (outline-previous-visible-heading 1))
1084       (if (< (funcall outline-level) level)
1085           nil
1086         (point)))))
1087 \f
1088 (defun outline-headers-as-kill (beg end)
1089   "Save the visible outline headers in region at the start of the kill ring.
1090
1091 Text shown between the headers isn't copied.  Two newlines are
1092 inserted between saved headers.  Yanking the result may be a
1093 convenient way to make a table of contents of the buffer."
1094   (interactive "r")
1095   (save-excursion
1096     (save-restriction
1097       (narrow-to-region beg end)
1098       (goto-char (point-min))
1099       (let ((buffer (current-buffer))
1100             start end)
1101         (with-temp-buffer
1102           (with-current-buffer buffer
1103             ;; Boundary condition: starting on heading:
1104             (when (outline-on-heading-p)
1105               (outline-back-to-heading)
1106               (setq start (point)
1107                     end (progn (outline-end-of-heading)
1108                                (point)))
1109               (insert-buffer-substring buffer start end)
1110               (insert "\n\n")))
1111           (let ((temp-buffer (current-buffer)))
1112             (with-current-buffer buffer
1113               (while (outline-next-heading)
1114                 (unless (outline-invisible-p)
1115                   (setq start (point)
1116                         end (progn (outline-end-of-heading) (point)))
1117                   (with-current-buffer temp-buffer
1118                     (insert-buffer-substring buffer start end)
1119                     (insert "\n\n"))))))
1120           (kill-new (buffer-string)))))))
1121
1122 (provide 'outline)
1123 (provide 'noutline)
1124
1125 ;;; outline.el ends here